New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zfechem.F90 in branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2014/dev_r4650_UKMO2_ice_shelves/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zfechem.F90 @ 4924

Last change on this file since 4924 was 4924, checked in by mathiot, 9 years ago

UKM02_ice_shelves merged and SETTE tested with revision 4879 of trunk

File size: 19.8 KB
Line 
1MODULE p4zfechem
2   !!======================================================================
3   !!                         ***  MODULE p4zfechem  ***
4   !! TOP :   PISCES Compute iron chemistry and scavenging
5   !!======================================================================
6   !! History :   3.5  !  2012-07 (O. Aumont, A. Tagliabue, C. Ethe) Original code
7   !!----------------------------------------------------------------------
8#if defined key_pisces
9   !!----------------------------------------------------------------------
10   !!   'key_top'       and                                      TOP models
11   !!   'key_pisces'                                       PISCES bio-model
12   !!----------------------------------------------------------------------
13   !!   p4z_fechem       :  Compute remineralization/scavenging of iron
14   !!   p4z_fechem_init  :  Initialisation of parameters for remineralisation
15   !!   p4z_fechem_alloc :  Allocate remineralisation variables
16   !!----------------------------------------------------------------------
17   USE oce_trc         !  shared variables between ocean and passive tracers
18   USE trc             !  passive tracers common variables
19   USE sms_pisces      !  PISCES Source Minus Sink variables
20   USE p4zopt          !  optical model
21   USE p4zche          !  chemical model
22   USE p4zsbc          !  Boundary conditions from sediments
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_fechem      ! called in p4zbio.F90
30   PUBLIC   p4z_fechem_init ! called in trcsms_pisces.F90
31
32   !! * Shared module variables
33   LOGICAL          ::  ln_fechem    !: boolean for complex iron chemistry following Tagliabue and voelker
34   LOGICAL          ::  ln_ligvar    !: boolean for variable ligand concentration following Tagliabue and voelker
35   REAL(wp), PUBLIC ::  xlam1        !: scavenging rate of Iron
36   REAL(wp), PUBLIC ::  xlamdust     !: scavenging rate of Iron by dust
37   REAL(wp), PUBLIC ::  ligand       !: ligand concentration in the ocean
38
39   REAL(wp) :: kl1, kl2, kb1, kb2, ks, kpr, spd, con, kth
40
41   !!* Substitution
42#  include "top_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
45   !! $Id: p4zrem.F90 3160 2011-11-20 14:27:18Z cetlod $
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE p4z_fechem( kt, jnt )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p4z_fechem  ***
53      !!
54      !! ** Purpose :   Compute remineralization/scavenging of iron
55      !!
56      !! ** Method  :   2 different chemistry models are available for iron
57      !!                (1) The simple chemistry model of Aumont and Bopp (2006)
58      !!                    based on one ligand and one inorganic form
59      !!                (2) The complex chemistry model of Tagliabue and
60      !!                    Voelker (2009) based on 2 ligands, 2 inorganic forms
61      !!                    and one particulate form (ln_fechem)
62      !!---------------------------------------------------------------------
63      !
64      INTEGER, INTENT(in) ::   kt, jnt ! ocean time step
65      !
66      INTEGER  ::   ji, jj, jk, jic
67      REAL(wp) ::   zdep, zlam1a, zlam1b, zlamfac
68      REAL(wp) ::   zkeq, zfeequi, zfesatur, zfecoll
69      REAL(wp) ::   zdenom1, zscave, zaggdfea, zaggdfeb, zcoag
70      REAL(wp) ::   ztrc, zdust
71#if ! defined key_kriest
72      REAL(wp) ::   zdenom, zdenom2
73#endif
74      REAL(wp), POINTER, DIMENSION(:,:,:) :: zTL1, zFe3, ztotlig
75      REAL(wp), POINTER, DIMENSION(:,:,:) :: zFeL1, zFeL2, zTL2, zFe2, zFeP
76      REAL(wp) :: zkox, zkph1, zkph2, zph, zionic, ztligand
77      REAL(wp) :: za, zb, zc, zkappa1, zkappa2, za0, za1, za2
78      REAL(wp) :: zxs, zfunc, zp, zq, zd, zr, zphi, zfff, zp3, zq2
79      REAL(wp) :: ztfe, zoxy
80      REAL(wp) :: zstep
81      CHARACTER (len=25) :: charout
82      !!---------------------------------------------------------------------
83      !
84      IF( nn_timing == 1 )  CALL timing_start('p4z_fechem')
85      !
86      ! Allocate temporary workspace
87      CALL wrk_alloc( jpi, jpj, jpk, zFe3, zFeL1, zTL1, ztotlig )
88      zFe3 (:,:,:) = 0.
89      zFeL1(:,:,:) = 0.
90      zTL1 (:,:,:) = 0.
91      IF( ln_fechem ) THEN
92         CALL wrk_alloc( jpi, jpj, jpk, zFe2, zFeL2, zTL2, zFeP )
93         zFe2 (:,:,:) = 0.
94         zFeL2(:,:,:) = 0.
95         zTL2 (:,:,:) = 0.
96         zFeP (:,:,:) = 0.
97      ENDIF
98
99      ! Total ligand concentration : Ligands can be chosen to be constant or variable
100      ! Parameterization from Tagliabue and Voelker (2011)
101      ! -------------------------------------------------
102      IF( ln_ligvar ) THEN
103         ztotlig(:,:,:) =  0.09 * trn(:,:,:,jpdoc) * 1E6 + ligand * 1E9
104         ztotlig(:,:,:) =  MIN( ztotlig(:,:,:), 10. )
105      ELSE
106         ztotlig(:,:,:) = ligand * 1E9
107      ENDIF
108
109      IF( ln_fechem ) THEN
110         ! ------------------------------------------------------------
111         ! NEW FE CHEMISTRY ROUTINE from Tagliabue and Volker (2009)
112         ! This model is based on two ligands, Fe2+, Fe3+ and Fep
113         ! Chemistry is supposed to be fast enough to be at equilibrium
114         ! ------------------------------------------------------------
115!CDIR NOVERRCHK
116         DO jk = 1, jpkm1
117!CDIR NOVERRCHK
118            DO jj = 1, jpj
119!CDIR NOVERRCHK
120               DO ji = 1, jpi
121                  ! Calculate ligand concentrations : assume 2/3rd of excess goes to
122                  ! strong ligands (L1) and 1/3rd to weak ligands (L2)
123                  ztligand       = ztotlig(ji,jj,jk) - ligand * 1E9
124                  zTL1(ji,jj,jk) =                0.000001 + 0.67 * ztligand
125                  zTL2(ji,jj,jk) = ligand * 1E9 - 0.000001 + 0.33 * ztligand
126                  ! ionic strength from Millero et al. 1987
127                  zionic = 19.9201 * tsn(ji,jj,jk,jp_sal) / ( 1000. - 1.00488 * tsn(ji,jj,jk,jp_sal) + rtrn )
128                  zph    = -LOG10( MAX( hi(ji,jj,jk), rtrn) )
129                  zoxy   = trn(ji,jj,jk,jpoxy) * ( rhop(ji,jj,jk) / 1.e3 )
130                  ! Fe2+ oxydation rate from Santana-Casiano et al. (2005)
131                  zkox   = 35.407 - 6.7109 * zph + 0.5342 * zph * zph - 5362.6 / ( tsn(ji,jj,jk,jp_tem) + 273.15 )  &
132                    &    - 0.04406 * SQRT( tsn(ji,jj,jk,jp_sal) ) - 0.002847 * tsn(ji,jj,jk,jp_sal)
133                  zkox   = ( 10.** zkox ) * spd
134                  zkox   = zkox * MAX( 1.e-6, zoxy) / ( chemo2(ji,jj,jk) + rtrn )
135                  ! PHOTOREDUCTION of complexed iron : Tagliabue and Arrigo (2006)
136                  zkph2 = MAX( 0., 15. * etot(ji,jj,jk) / ( etot(ji,jj,jk) + 2. ) )
137                  zkph1 = zkph2 / 5.
138                  ! pass the dfe concentration from PISCES
139                  ztfe = trn(ji,jj,jk,jpfer) * 1e9
140                  ! ----------------------------------------------------------
141                  ! ANALYTICAL SOLUTION OF ROOTS OF THE FE3+ EQUATION
142                  ! As shown in Tagliabue and Voelker (2009), Fe3+ is the root of a 3rd order polynom.
143                  ! ----------------------------------------------------------
144                  ! calculate some parameters
145                  za = 1 + ks / kpr
146                  zb = 1 + ( zkph1 + kth ) / ( zkox + rtrn )
147                  zc = 1 + zkph2 / ( zkox + rtrn )
148                  zkappa1 = ( kb1 + zkph1 + kth ) / kl1
149                  zkappa2 = ( kb2 + zkph2 ) / kl2
150                  za2 = zTL1(ji,jj,jk) * zb / za + zTL2(ji,jj,jk) * zc / za + zkappa1 + zkappa2 - ztfe / za
151                  za1 = zkappa2 * zTL1(ji,jj,jk) * zb / za + zkappa1 * zTL2(ji,jj,jk) * zc / za &
152                      & + zkappa1 * zkappa2 - ( zkappa1 + zkappa2 ) * ztfe / za
153                  za0 = -zkappa1 * zkappa2 * ztfe / za
154                  zp  = za1 - za2 * za2 / 3.
155                  zq  = za2 * za2 * za2 * 2. / 27. - za2 * za1 / 3. + za0
156                  zp3 = zp / 3.
157                  zq2 = zq / 2.
158                  zd  = zp3 * zp3 * zp3 + zq2 * zq2
159                  zr  = zq / ABS( zq ) * SQRT( ABS( zp ) / 3. )
160                  ! compute the roots
161                  IF( zp > 0.) THEN
162                     ! zphi = ASINH( zq / ( 2. * zr * zr * zr ) )
163                     zphi =  zq / ( 2. * zr * zr * zr ) 
164                     zphi = LOG( zphi + SQRT( zphi * zphi + 1 ) )  ! asinh(x) = log(x + sqrt(x^2+1))
165                     zxs  = -2. * zr * SINH( zphi / 3. ) - za1 / 3.
166                  ELSE
167                     IF( zd > 0. ) THEN
168                        zfff = MAX( 1., zq / ( 2. * zr * zr * zr ) )
169                        ! zphi = ACOSH( zfff )
170                        zphi = LOG( zfff + SQRT( zfff * zfff - 1 ) )  ! acosh(x) = log(x + sqrt(x^2-1))
171                        zxs = -2. * zr * COSH( zphi / 3. ) - za1 / 3.
172                     ELSE
173                        zfff = MIN( 1., zq / ( 2. * zr * zr * zr ) )
174                        zphi = ACOS( zfff )
175                        DO jic = 1, 3
176                           zfunc = -2 * zr * COS( zphi / 3. + 2. * FLOAT( jic - 1 ) * rpi / 3. ) - za2 / 3.
177                           IF( zfunc > 0. .AND. zfunc <= ztfe)  zxs = zfunc
178                        END DO
179                     ENDIF
180                  ENDIF
181                  ! solve for the other Fe species
182                  zFe3(ji,jj,jk) = MAX( 0., zxs ) 
183                  zFep(ji,jj,jk) = MAX( 0., ( ks * zFe3(ji,jj,jk) / kpr ) )
184                  zkappa2 = ( kb2 + zkph2 ) / kl2
185                  zFeL2(ji,jj,jk) = MAX( 0., ( zFe3(ji,jj,jk) * zTL2(ji,jj,jk) ) / ( zkappa2 + zFe3(ji,jj,jk) ) )
186                  zFeL1(ji,jj,jk) = MAX( 0., ( ztfe / zb - za / zb * zFe3(ji,jj,jk) - zc / zb * zFeL2(ji,jj,jk) ) )
187                  zFe2 (ji,jj,jk) = MAX( 0., ( ( zkph1 * zFeL1(ji,jj,jk) + zkph2 * zFeL2(ji,jj,jk) ) / zkox ) )
188               END DO
189            END DO
190         END DO
191      ELSE
192         ! ------------------------------------------------------------
193         ! OLD FE CHEMISTRY ROUTINE from Aumont and Bopp (2006)
194         ! This model is based on one ligand and Fe'
195         ! Chemistry is supposed to be fast enough to be at equilibrium
196         ! ------------------------------------------------------------
197!CDIR NOVERRCHK
198         DO jk = 1, jpkm1
199!CDIR NOVERRCHK
200            DO jj = 1, jpj
201!CDIR NOVERRCHK
202               DO ji = 1, jpi
203                  zTL1(ji,jj,jk) = ztotlig(ji,jj,jk)
204                  zkeq           = fekeq(ji,jj,jk)
205                  zfesatur       = zTL1(ji,jj,jk) * 1E-9
206                  ztfe           = trn(ji,jj,jk,jpfer) 
207                  ! Fe' is the root of a 2nd order polynom
208                  zFe3 (ji,jj,jk) = ( -( 1. + zfesatur * zkeq - zkeq * ztfe )               &
209                     &             + SQRT( ( 1. + zfesatur * zkeq - zkeq * ztfe )**2       &
210                     &               + 4. * ztfe * zkeq) ) / ( 2. * zkeq )
211                  zFe3 (ji,jj,jk) = zFe3(ji,jj,jk) * 1E9
212                  zFeL1(ji,jj,jk) = MAX( 0., trn(ji,jj,jk,jpfer) * 1E9 - zFe3(ji,jj,jk) )
213              END DO
214            END DO
215         END DO
216         !
217      ENDIF
218
219      zdust = 0.         ! if no dust available
220!CDIR NOVERRCHK
221      DO jk = 1, jpkm1
222!CDIR NOVERRCHK
223         DO jj = 1, jpj
224!CDIR NOVERRCHK
225            DO ji = 1, jpi
226               zstep = xstep
227# if defined key_degrad
228               zstep = zstep * facvol(ji,jj,jk)
229# endif
230               ! Scavenging rate of iron. This scavenging rate depends on the load of particles of sea water.
231               ! This parameterization assumes a simple second order kinetics (k[Particles][Fe]).
232               ! Scavenging onto dust is also included as evidenced from the DUNE experiments.
233               ! --------------------------------------------------------------------------------------
234               IF( ln_fechem ) THEN
235                  zfeequi = ( zFe3(ji,jj,jk) + zFe2(ji,jj,jk) + zFeP(ji,jj,jk) ) * 1E-9
236                  zfecoll = ( 0.3 * zFeL1(ji,jj,jk) + 0.5 * zFeL2(ji,jj,jk) ) * 1E-9
237               ELSE
238                  zfeequi = zFe3(ji,jj,jk) * 1E-9 
239                  zfecoll = 0.5 * zFeL1(ji,jj,jk) * 1E-9
240               ENDIF
241#if defined key_kriest
242               ztrc   = ( trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpcal) + trn(ji,jj,jk,jpgsi) ) * 1.e6 
243#else
244               ztrc   = ( trn(ji,jj,jk,jppoc) + trn(ji,jj,jk,jpgoc) + trn(ji,jj,jk,jpcal) + trn(ji,jj,jk,jpgsi) ) * 1.e6 
245#endif
246               IF( ln_dust )  zdust  = dust(ji,jj) / ( wdust / rday ) * tmask(ji,jj,jk) ! dust in kg/m2/s
247               zlam1b = 3.e-5 + xlamdust * zdust + xlam1 * ztrc
248               zscave = zfeequi * zlam1b * zstep
249
250               ! Compute the different ratios for scavenging of iron
251               ! to later allocate scavenged iron to the different organic pools
252               ! ---------------------------------------------------------
253               zdenom1 = xlam1 * trn(ji,jj,jk,jppoc) / zlam1b
254#if ! defined key_kriest
255               zdenom2 = xlam1 * trn(ji,jj,jk,jpgoc) / zlam1b
256#endif
257
258               !  Increased scavenging for very high iron concentrations found near the coasts
259               !  due to increased lithogenic particles and let say it is unknown processes (precipitation, ...)
260               !  -----------------------------------------------------------
261               zlamfac = MAX( 0.e0, ( gphit(ji,jj) + 55.) / 30. )
262               zlamfac = MIN( 1.  , zlamfac )
263               zdep    = MIN( 1., 1000. / fsdept(ji,jj,jk) )
264               zlam1b  = xlam1 * MAX( 0.e0, ( trn(ji,jj,jk,jpfer) * 1.e9 - ztotlig(ji,jj,jk) ) )
265               zcoag   = zfeequi * zlam1b * zstep + 1E-4 * ( 1. - zlamfac ) * zdep * zstep * trn(ji,jj,jk,jpfer)
266
267               !  Compute the coagulation of colloidal iron. This parameterization
268               !  could be thought as an equivalent of colloidal pumping.
269               !  It requires certainly some more work as it is very poorly constrained.
270               !  ----------------------------------------------------------------
271               zlam1a  = ( 0.369  * 0.3 * trn(ji,jj,jk,jpdoc) + 102.4  * trn(ji,jj,jk,jppoc) ) * xdiss(ji,jj,jk)    &
272                   &   + ( 114.   * 0.3 * trn(ji,jj,jk,jpdoc) + 5.09E3 * trn(ji,jj,jk,jppoc) )
273               zaggdfea = zlam1a * zstep * zfecoll
274#if defined key_kriest
275               zaggdfeb = 0.
276               !
277               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zscave - zaggdfea - zaggdfeb - zcoag
278               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * zdenom1 + zaggdfea + zaggdfeb
279#else
280               zlam1b = 3.53E3 *   trn(ji,jj,jk,jpgoc) * xdiss(ji,jj,jk)
281               zaggdfeb = zlam1b * zstep * zfecoll
282               !
283               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - zscave - zaggdfea - zaggdfeb - zcoag
284               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) + zscave * zdenom1 + zaggdfea
285               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) + zscave * zdenom2 + zaggdfeb
286#endif
287            END DO
288         END DO
289      END DO
290      !
291      !  Define the bioavailable fraction of iron
292      !  ----------------------------------------
293      IF( ln_fechem ) THEN
294          biron(:,:,:) = MAX( 0., trn(:,:,:,jpfer) - zFeP(:,:,:) * 1E-9 )
295      ELSE
296          biron(:,:,:) = trn(:,:,:,jpfer) 
297      ENDIF
298
299      !  Output of some diagnostics variables
300      !     ---------------------------------
301      IF( ln_diatrc .AND. lk_iomput ) THEN
302         IF( jnt == nrdttrc ) THEN
303            CALL iom_put("Fe3"    , zFe3   (:,:,:)       * tmask(:,:,:) )   ! Fe3+
304            CALL iom_put("FeL1"   , zFeL1  (:,:,:)       * tmask(:,:,:) )   ! FeL1
305            CALL iom_put("TL1"    , zTL1   (:,:,:)       * tmask(:,:,:) )   ! TL1
306            CALL iom_put("Totlig" , ztotlig(:,:,:)       * tmask(:,:,:) )   ! TL
307            CALL iom_put("Biron"  , biron  (:,:,:) * 1e9 * tmask(:,:,:) )   ! biron
308            IF( ln_fechem ) THEN
309               CALL iom_put("Fe2" , zFe2   (:,:,:)       * tmask(:,:,:) )   ! Fe2+
310               CALL iom_put("FeL2", zFeL2  (:,:,:)       * tmask(:,:,:) )   ! FeL2
311               CALL iom_put("FeP" , zFeP   (:,:,:)       * tmask(:,:,:) )   ! FeP
312               CALL iom_put("TL2" , zTL2   (:,:,:)       * tmask(:,:,:) )   ! TL2
313            ENDIF
314         ENDIF
315      ENDIF
316
317      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
318         WRITE(charout, FMT="('fechem')")
319         CALL prt_ctl_trc_info(charout)
320         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
321      ENDIF
322      !
323                       CALL wrk_dealloc( jpi, jpj, jpk, zFe3, zFeL1, zTL1, ztotlig )
324      IF( ln_fechem )  CALL wrk_dealloc( jpi, jpj, jpk, zFe2, zFeL2, zTL2, zFeP )
325      !
326      IF( nn_timing == 1 )  CALL timing_stop('p4z_fechem')
327      !
328   END SUBROUTINE p4z_fechem
329
330
331   SUBROUTINE p4z_fechem_init
332      !!----------------------------------------------------------------------
333      !!                  ***  ROUTINE p4z_fechem_init  ***
334      !!
335      !! ** Purpose :   Initialization of iron chemistry parameters
336      !!
337      !! ** Method  :   Read the nampisfer namelist and check the parameters
338      !!      called at the first timestep
339      !!
340      !! ** input   :   Namelist nampisfer
341      !!
342      !!----------------------------------------------------------------------
343      NAMELIST/nampisfer/ ln_fechem, ln_ligvar, xlam1, xlamdust, ligand 
344      INTEGER :: ios                 ! Local integer output status for namelist read
345
346      REWIND( numnatp_ref )              ! Namelist nampisfer in reference namelist : Pisces iron chemistry
347      READ  ( numnatp_ref, nampisfer, IOSTAT = ios, ERR = 901)
348901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisfer in reference namelist', lwp )
349
350      REWIND( numnatp_cfg )              ! Namelist nampisfer in configuration namelist : Pisces iron chemistry
351      READ  ( numnatp_cfg, nampisfer, IOSTAT = ios, ERR = 902 )
352902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisfer in configuration namelist', lwp )
353      IF(lwm) WRITE ( numonp, nampisfer )
354
355      IF(lwp) THEN                         ! control print
356         WRITE(numout,*) ' '
357         WRITE(numout,*) ' Namelist parameters for Iron chemistry, nampisfer'
358         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
359         WRITE(numout,*) '    enable complex iron chemistry scheme      ln_fechem =', ln_fechem
360         WRITE(numout,*) '    variable concentration of ligand          ln_ligvar =', ln_ligvar
361         WRITE(numout,*) '    scavenging rate of Iron                   xlam1     =', xlam1
362         WRITE(numout,*) '    scavenging rate of Iron by dust           xlamdust  =', xlamdust
363         WRITE(numout,*) '    ligand concentration in the ocean         ligand    =', ligand
364      ENDIF
365      !
366      IF( ln_fechem ) THEN
367         ! initialization of some constants used by the complexe chemistry scheme
368         ! ----------------------------------------------------------------------
369         spd = 3600. * 24.
370         con = 1.E9
371         ! LIGAND KINETICS (values from Witter et al. 2000)
372         ! Weak (L2) ligands
373         ! Phaeophytin
374         kl2 = 12.2E5  * spd / con
375         kb2 = 12.3E-6 * spd
376         ! Strong (L1) ligands
377         ! Saccharides
378         ! kl1 = 12.2E5  * spd / con
379         ! kb1 = 12.3E-6 * spd
380         ! DFOB-
381         kl1 = 19.6e5  * spd / con
382         kb1 = 1.5e-6  * spd
383         ! pcp and remin of Fe3p
384         ks  = 0.075
385         kpr = 0.05
386         ! thermal reduction of Fe3
387         kth = 0.0048 * 24.
388         !
389      ENDIF
390      !
391   END SUBROUTINE p4z_fechem_init
392
393#else
394   !!======================================================================
395   !!  Dummy module :                                   No PISCES bio-model
396   !!======================================================================
397CONTAINS
398   SUBROUTINE p4z_fechem                    ! Empty routine
399   END SUBROUTINE p4z_fechem
400#endif 
401
402   !!======================================================================
403END MODULE p4zfechem
Note: See TracBrowser for help on using the repository browser.