New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2014/dev_r4704_NOC5_MPP_BDY_UPDATE/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2014/dev_r4704_NOC5_MPP_BDY_UPDATE/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 6225

Last change on this file since 6225 was 6225, checked in by jamesharle, 8 years ago

Update MPP_BDY_UPDATE branch to be consistent with head of trunk

  • Property svn:keywords set to Id
File size: 20.7 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
29   !!             -   !  2014-12  (G. Madec) remove KPP scheme
30   !!             -   !  2015-11  (J. Chanut) free surface simplification
31   !!----------------------------------------------------------------------
32
33   !!----------------------------------------------------------------------
34   !!   stp             : OPA system time-stepping
35   !!----------------------------------------------------------------------
36   USE step_oce         ! time stepping definition modules
37   !
38   USE iom              ! xIOs server
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   stp   ! called by nemogcm.F90
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52#if defined key_agrif
53   RECURSIVE SUBROUTINE stp( )
54      INTEGER             ::   kstp   ! ocean time-step index
55#else
56   SUBROUTINE stp( kstp )
57      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
58#endif
59      !!----------------------------------------------------------------------
60      !!                     ***  ROUTINE stp  ***
61      !!
62      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
63      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
64      !!              - Tme stepping  of TRC (passive tracer eqs.)
65      !!
66      !! ** Method  : -1- Update forcings and data
67      !!              -2- Update ocean physics
68      !!              -3- Compute the t and s trends
69      !!              -4- Update t and s
70      !!              -5- Compute the momentum trends
71      !!              -6- Update the horizontal velocity
72      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
73      !!              -8- Outputs and diagnostics
74      !!----------------------------------------------------------------------
75      INTEGER ::   jk       ! dummy loop indice
76      INTEGER ::   indic    ! error indicator if < 0
77      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
78      !! ---------------------------------------------------------------------
79#if defined key_agrif
80      kstp = nit000 + Agrif_Nb_Step()
81      IF( lk_agrif_debug ) THEN
82         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
83         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
84      ENDIF
85      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
86# if defined key_iomput
87      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
88# endif
89#endif
90      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
91      ! update I/O and calendar
92      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
93                             indic = 0                ! reset to no error condition
94                             
95      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
96                             CALL iom_init(      cxios_context          )  ! for model grid (including passible AGRIF zoom)
97         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
98      ENDIF
99      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
100                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
101      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
102
103      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
104      ! Update external forcing (tides, open boundaries, and surface boundary condition (including sea-ice)
105      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
106      IF( lk_tide    )   CALL sbc_tide( kstp )                   ! update tide potential
107      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                   ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
108      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
109                         CALL sbc     ( kstp )                   ! Sea Boundary Condition (including sea-ice)
110
111      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
112      ! Update stochastic parameters and random T/S fluctuations
113      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
114                         CALL sto_par( kstp )          ! Stochastic parameters
115
116      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
117      ! Ocean physics update                (ua, va, tsa used as workspace)
118      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
119      !  THERMODYNAMICS
120                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
121                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
122                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
123                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
124
125      !
126      !  VERTICAL PHYSICS
127                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
128      !                                               ! Vertical eddy viscosity and diffusivity coefficients
129      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
130      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
131      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
132      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
133         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
134         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
135         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
136      ENDIF
137
138      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
139         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
140      ENDIF
141      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
142
143      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
144
145      IF( lk_zdfddm  )   CALL zdf_ddm( kstp )         ! double diffusive mixing
146
147                         CALL zdf_mxl( kstp )         ! mixed layer depth
148
149                                                      ! write TKE or GLS information in the restart file
150      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
151      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
152      !
153      !  LATERAL  PHYSICS
154      !
155      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
156!!gm : why this here ????
157         IF(ln_sto_eos ) CALL sto_pts( tsn )          ! Random T/S fluctuations
158!!gm
159                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
160
161         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
162            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
163            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
164
165         IF( ln_zps .AND.       ln_isfcav)                               &
166            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
167            &                                          rhd, gru , grv , grui, grvi   )  ! of t, s, rd at the first ocean level
168         IF( ln_traldf_triad ) THEN
169                         CALL ldf_slp_triad( kstp )                       ! before slope for triad operator
170         ELSE     
171                         CALL ldf_slp     ( kstp, rhd, rn2b )             ! before slope for standard operator
172         ENDIF
173      ENDIF
174      !                                               ! eddy diffusivity coeff. and/or eiv coeff.
175      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp ) 
176
177      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
178      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
179      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
180
181                            CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_hor)
182      IF(.NOT.ln_linssh )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
183                            CALL wzv           ( kstp )  ! now cross-level velocity
184!!gm : why also here ????
185      IF( ln_sto_eos    )   CALL sto_pts( tsn )                             ! Random T/S fluctuations
186!!gm
187                            CALL eos    ( tsn, rhd, rhop, gdept_n(:,:,:) )  ! now in situ density for hpg computation
188                           
189!!jc: fs simplification
190!!jc: lines below are useless if ln_linssh=F. Keep them here (which maintains a bug if ln_linssh=T and ln_zps=T, cf ticket #1636)
191!!                                         but ensures reproductible results
192!!                                         with previous versions using split-explicit free surface         
193            IF( ln_zps .AND. .NOT. ln_isfcav )                               &
194               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,   &  ! Partial steps: before horizontal gradient
195               &                                          rhd, gru , grv     )  ! of t, s, rd at the last ocean level
196            IF( ln_zps .AND.       ln_isfcav )                                          &
197               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
198               &                                          rhd, gru , grv , grui, grvi   )  ! of t, s, rd at the first ocean level
199!!jc: fs simplification
200                           
201                         ua(:,:,:) = 0._wp            ! set dynamics trends to zero
202                         va(:,:,:) = 0._wp
203
204      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
205                         CALL dyn_asm_inc   ( kstp )  ! apply dynamics assimilation increment
206      IF( lk_bdy     )   CALL bdy_dyn3d_dmp ( kstp )  ! bdy damping trends
207#if defined key_agrif
208      IF(.NOT. Agrif_Root())  & 
209               &         CALL Agrif_Sponge_dyn        ! momentum sponge
210#endif
211                         CALL dyn_adv       ( kstp )  ! advection (vector or flux form)
212                         CALL dyn_vor       ( kstp )  ! vorticity term including Coriolis
213                         CALL dyn_ldf       ( kstp )  ! lateral mixing
214                         CALL dyn_hpg       ( kstp )  ! horizontal gradient of Hydrostatic pressure
215                         CALL dyn_spg       ( kstp )  ! surface pressure gradient
216
217                                                      ! With split-explicit free surface, since now transports have been updated and ssha as well
218      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
219                            CALL div_hor    ( kstp )              ! Horizontal divergence  (2nd call in time-split case)
220         IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
221                            CALL wzv        ( kstp )              ! now cross-level velocity
222      ENDIF
223
224                         CALL dyn_bfr       ( kstp )  ! bottom friction
225                         CALL dyn_zdf       ( kstp )  ! vertical diffusion
226
227      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
228      ! cool skin
229      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
230      IF ( ln_diurnal )  CALL stp_diurnal( kstp )
231     
232      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
233      ! diagnostics and outputs             (ua, va, tsa used as workspace)
234      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
235      IF( lk_floats  )   CALL flo_stp( kstp )         ! drifting Floats
236      IF( nn_diacfl == 1 )   CALL dia_cfl( kstp )         ! Courant number diagnostics
237      IF( lk_diahth  )   CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
238      IF(.NOT.ln_cpl )   CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
239      IF( lk_diadct  )   CALL dia_dct( kstp )         ! Transports
240      IF( lk_diaar5  )   CALL dia_ar5( kstp )         ! ar5 diag
241      IF( lk_diaharm )   CALL dia_harm( kstp )        ! Tidal harmonic analysis
242                         CALL dia_wri( kstp )         ! ocean model: outputs
243      !
244      IF( ln_crs     )   CALL crs_fld       ( kstp )  ! ocean model: online field coarsening & output
245     
246#if defined key_top
247      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248      ! Passive Tracer Model
249      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250                         CALL trc_stp       ( kstp )  ! time-stepping
251#endif
252
253      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
254      ! Active tracers                             
255      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
256                         tsa(:,:,:,:) = 0._wp         ! set tracer trends to zero
257
258      IF(  lk_asminc .AND. ln_asmiau .AND. &
259         & ln_trainc )   CALL tra_asm_inc   ( kstp )  ! apply tracer assimilation increment
260                         CALL tra_sbc       ( kstp )  ! surface boundary condition
261      IF( ln_traqsr  )   CALL tra_qsr       ( kstp )  ! penetrative solar radiation qsr
262      IF( ln_trabbc  )   CALL tra_bbc       ( kstp )  ! bottom heat flux
263      IF( lk_trabbl  )   CALL tra_bbl       ( kstp )  ! advective (and/or diffusive) bottom boundary layer scheme
264      IF( ln_tradmp  )   CALL tra_dmp       ( kstp )  ! internal damping trends
265      IF( lk_bdy     )   CALL bdy_tra_dmp   ( kstp )  ! bdy damping trends
266#if defined key_agrif
267      IF(.NOT. Agrif_Root())  & 
268               &         CALL Agrif_Sponge_tra        ! tracers sponge
269#endif
270                         CALL tra_adv       ( kstp )  ! horizontal & vertical advection
271                         CALL tra_ldf       ( kstp )  ! lateral mixing
272
273!!gm : why CALL to dia_ptr has been moved here??? (use trends info?)
274      IF( ln_diaptr  )   CALL dia_ptr                 ! Poleward adv/ldf TRansports diagnostics
275!!gm
276                         CALL tra_zdf       ( kstp )  ! vertical mixing and after tracer fields
277      IF( ln_zdfnpc  )   CALL tra_npc       ( kstp )  ! update after fields by non-penetrative convection
278
279      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
280      ! Set boundary conditions and Swap
281      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
282!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
283!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
284!!    If so:
285!!    (i) no need to call agrif update at initialization time
286!!    (ii) no need to update "before" fields
287!!
288!!    Apart from creating new tra_swp/dyn_swp routines, this however:
289!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
290!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
291!!    e.g. a shift of the feedback interface inside child domain.
292!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
293!!    place.
294!!
295!!jc2: dynnxt must be the latest call. e3t_b are indeed updated in that routine
296                         CALL tra_nxt       ( kstp )  ! finalize (bcs) tracer fields at next time step and swap
297                         CALL dyn_nxt       ( kstp )  ! finalize (bcs) velocities at next time step and swap
298                         CALL ssh_swp       ( kstp )  ! swap of sea surface height
299      IF(.NOT.ln_linssh) CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
300      !
301
302!!gm : This does not only concern the dynamics ==>>> add a new title
303!!gm2: why ouput restart before AGRIF update?
304!!
305!!jc: That would be better, but see comment above
306!!
307      IF( lrst_oce   )   CALL rst_write     ( kstp )  ! write output ocean restart file
308
309#if defined key_agrif
310      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
311      ! AGRIF
312      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
313                         CALL Agrif_Integrate_ChildGrids( stp ) 
314
315      IF( Agrif_NbStepint() == 0 ) THEN               ! AGRIF Update
316!!jc in fact update is useless at last time step, but do it for global diagnostics
317                         CALL Agrif_Update_Tra()      ! Update active tracers
318                         CALL Agrif_Update_Dyn()      ! Update momentum
319      ENDIF
320#endif
321      IF( ln_diahsb  )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
322      IF( ln_diaobs  )   CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
323
324      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
325      ! Control
326      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
327                         CALL stp_ctl       ( kstp, indic )
328      IF( indic < 0  ) THEN
329                         CALL ctl_stop( 'step: indic < 0' )
330                         CALL dia_wri_state( 'output.abort', kstp )
331      ENDIF
332      IF( kstp == nit000 ) THEN
333                 CALL iom_close( numror )     ! close input  ocean restart file
334         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
335         IF(lwm.AND.numoni /= -1 )   &
336            &    CALL FLUSH    ( numoni )     ! flush output namelist ice (if exist)
337      ENDIF
338
339      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
340      ! Coupled mode
341      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
342!!gm why lk_oasis and not lk_cpl ????
343      IF( lk_oasis   )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
344      !
345#if defined key_iomput
346      IF( kstp == nitend .OR. indic < 0 ) THEN
347                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
348         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
349      ENDIF
350#endif
351      !
352      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
353      !
354   END SUBROUTINE stp
355   
356END MODULE step
Note: See TracBrowser for help on using the repository browser.