New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd.F90 in branches/2014/dev_r4743_NOC2_ZTS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_r4743_NOC2_ZTS/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 4736

Last change on this file since 4736 was 4736, checked in by acc, 10 years ago

Branch 2014/dev_r4743_NOC2_ZTS, #1367. Code changes to introduce optional sub-timestepping for vertical advection. Changes in dynadv.F90, dynzad.F90, traadv.F90, traadv_tvd.F90 and namelist_ref only.
  • Property svn:keywords set to Id
File size: 31.5 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trdmod_oce     ! tracers trends
25   USE trdtra         ! tracers trends
26   USE in_out_manager ! I/O manager
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE lib_mpp        ! MPP library
29   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
30   USE diaptr         ! poleward transport diagnostics
31   USE trc_oce        ! share passive tracers/Ocean variables
32   USE wrk_nemo       ! Memory Allocation
33   USE timing         ! Timing
34   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
40   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
41
42   LOGICAL ::   l_trd   ! flag to compute trends
43
44   !! * Substitutions
45#  include "domzgr_substitute.h90"
46#  include "vectopt_loop_substitute.h90"
47   !!----------------------------------------------------------------------
48   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
55      &                                       ptb, ptn, pta, kjpt )
56      !!----------------------------------------------------------------------
57      !!                  ***  ROUTINE tra_adv_tvd  ***
58      !!
59      !! **  Purpose :   Compute the now trend due to total advection of
60      !!       tracers and add it to the general trend of tracer equations
61      !!
62      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
63      !!       corrected flux (monotonic correction)
64      !!       note: - this advection scheme needs a leap-frog time scheme
65      !!
66      !! ** Action : - update (pta) with the now advective tracer trends
67      !!             - save the trends
68      !!----------------------------------------------------------------------
69      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
70      !
71      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
72      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
73      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
74      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
75      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
76      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
77      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
79      !
80      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
81      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
82      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
83      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
85      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
89      !
90      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
91      !
92      IF( kt == kit000 )  THEN
93         IF(lwp) WRITE(numout,*)
94         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
95         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
96      ENDIF
97      !
98      l_trd = .FALSE.
99      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
100      !
101      IF( l_trd )  THEN
102         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
103         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
104      ENDIF
105      !
106      zwi(:,:,:) = 0.e0
107      !
108      !                                                          ! ===========
109      DO jn = 1, kjpt                                            ! tracer loop
110         !                                                       ! ===========
111         ! 1. Bottom value : flux set to zero
112         ! ----------------------------------
113         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
114         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
115
116         ! 2. upstream advection with initial mass fluxes & intermediate update
117         ! --------------------------------------------------------------------
118         ! upstream tracer flux in the i and j direction
119         DO jk = 1, jpkm1
120            DO jj = 1, jpjm1
121               DO ji = 1, fs_jpim1   ! vector opt.
122                  ! upstream scheme
123                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
124                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
125                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
126                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
127                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
128                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
129               END DO
130            END DO
131         END DO
132
133         ! upstream tracer flux in the k direction
134         ! Surface value
135         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
136         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
137         ENDIF
138         ! Interior value
139         DO jk = 2, jpkm1
140            DO jj = 1, jpj
141               DO ji = 1, jpi
142                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
143                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
144                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
145               END DO
146            END DO
147         END DO
148
149         ! total advective trend
150         DO jk = 1, jpkm1
151            z2dtt = p2dt(jk)
152            DO jj = 2, jpjm1
153               DO ji = fs_2, fs_jpim1   ! vector opt.
154                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
155                  ! total intermediate advective trends
156                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
157                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
158                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
159                  ! update and guess with monotonic sheme
160                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
161                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
162               END DO
163            END DO
164         END DO
165         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
166         CALL lbc_lnk( zwi, 'T', 1. ) 
167
168         !                                 ! trend diagnostics (contribution of upstream fluxes)
169         IF( l_trd )  THEN 
170            ! store intermediate advective trends
171            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
172         END IF
173         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
174         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
175           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
176           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
177         ENDIF
178
179         ! 3. antidiffusive flux : high order minus low order
180         ! --------------------------------------------------
181         ! antidiffusive flux on i and j
182         DO jk = 1, jpkm1
183            DO jj = 1, jpjm1
184               DO ji = 1, fs_jpim1   ! vector opt.
185                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
186                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
187               END DO
188            END DO
189         END DO
190     
191         ! antidiffusive flux on k
192         zwz(:,:,1) = 0.e0         ! Surface value
193         !
194         DO jk = 2, jpkm1          ! Interior value
195            DO jj = 1, jpj
196               DO ji = 1, jpi
197                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
198               END DO
199            END DO
200         END DO
201         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
202         CALL lbc_lnk( zwz, 'W',  1. )
203
204         ! 4. monotonicity algorithm
205         ! -------------------------
206         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
207
208
209         ! 5. final trend with corrected fluxes
210         ! ------------------------------------
211         DO jk = 1, jpkm1
212            DO jj = 2, jpjm1
213               DO ji = fs_2, fs_jpim1   ! vector opt. 
214                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
215                  ! total advective trends
216                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
217                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
218                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
219                  ! add them to the general tracer trends
220                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
221               END DO
222            END DO
223         END DO
224
225         !                                 ! trend diagnostics (contribution of upstream fluxes)
226         IF( l_trd )  THEN
227            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
228            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
229            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
230           
231            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
232            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
233            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
234         END IF
235         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
236         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
237           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
238           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
239         ENDIF
240         !
241      END DO
242      !
243                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
244      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
245      !
246      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
247      !
248   END SUBROUTINE tra_adv_tvd
249
250   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
251      &                                       ptb, ptn, pta, kjpt )
252      !!----------------------------------------------------------------------
253      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
254      !!
255      !! **  Purpose :   Compute the now trend due to total advection of
256      !!       tracers and add it to the general trend of tracer equations
257      !!
258      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
259      !!       corrected flux (monotonic correction). This version use sub-
260      !!       timestepping for the vertical advection which increases stability
261      !!       when vertical metrics are small.
262      !!       note: - this advection scheme needs a leap-frog time scheme
263      !!
264      !! ** Action : - update (pta) with the now advective tracer trends
265      !!             - save the trends
266      !!----------------------------------------------------------------------
267      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
268      !
269      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
270      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
271      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
272      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
273      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
274      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
275      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
276      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
277      !
278      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
279      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
280      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
281      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
282      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
283      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
284      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
285      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
286      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
287      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
288      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
289      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
290      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
291      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
292      !!----------------------------------------------------------------------
293      !
294      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
295      !
296      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
297      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
298      CALL wrk_alloc( jpi, jpj, jpk, 3, ztrs )
299      !
300      IF( kt == kit000 )  THEN
301         IF(lwp) WRITE(numout,*)
302         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
303         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
304      ENDIF
305      !
306      l_trd = .FALSE.
307      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
308      !
309      IF( l_trd )  THEN
310         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
311         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
312      ENDIF
313      !
314      zwi(:,:,:) = 0._wp
315      z_rzts = 1._wp / REAL( jnzts, wp )
316      zr_p2dt(:) = 1._wp / p2dt(:)
317      !
318      !                                                          ! ===========
319      DO jn = 1, kjpt                                            ! tracer loop
320         !                                                       ! ===========
321         ! 1. Bottom value : flux set to zero
322         ! ----------------------------------
323         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
324         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
325
326         ! 2. upstream advection with initial mass fluxes & intermediate update
327         ! --------------------------------------------------------------------
328         ! upstream tracer flux in the i and j direction
329         DO jk = 1, jpkm1
330            DO jj = 1, jpjm1
331               DO ji = 1, fs_jpim1   ! vector opt.
332                  ! upstream scheme
333                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
334                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
335                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
336                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
337                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
338                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
339               END DO
340            END DO
341         END DO
342
343         ! upstream tracer flux in the k direction
344         ! Surface value
345         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0._wp                        ! volume variable
346         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
347         ENDIF
348         ! Interior value
349         DO jk = 2, jpkm1
350            DO jj = 1, jpj
351               DO ji = 1, jpi
352                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
353                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
354                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
355               END DO
356            END DO
357         END DO
358
359         ! total advective trend
360         DO jk = 1, jpkm1
361            z2dtt = p2dt(jk)
362            DO jj = 2, jpjm1
363               DO ji = fs_2, fs_jpim1   ! vector opt.
364                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
365                  ! total intermediate advective trends
366                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
367                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
368                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
369                  ! update and guess with monotonic sheme
370                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
371                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
372               END DO
373            END DO
374         END DO
375         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
376         CALL lbc_lnk( zwi, 'T', 1. ) 
377
378         !                                 ! trend diagnostics (contribution of upstream fluxes)
379         IF( l_trd )  THEN 
380            ! store intermediate advective trends
381            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
382         END IF
383         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
384         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
385           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
386           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
387         ENDIF
388
389         ! 3. antidiffusive flux : high order minus low order
390         ! --------------------------------------------------
391         ! antidiffusive flux on i and j
392
393
394         DO jk = 1, jpkm1
395
396            DO jj = 1, jpjm1
397               DO ji = 1, fs_jpim1   ! vector opt.
398                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
399                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
400
401                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
402                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
403               END DO
404            END DO
405
406            DO jj = 2, jpjm1         ! partial horizontal divergence
407               DO ji = fs_2, fs_jpim1
408                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
409                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
410               END DO
411            END DO
412
413            DO jj = 1, jpjm1
414               DO ji = 1, fs_jpim1   ! vector opt.
415                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
416                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
417               END DO
418            END DO
419         END DO
420     
421         ! antidiffusive flux on k
422         zwz(:,:,1) = 0._wp        ! Surface value
423         zwz_sav(:,:,:) = zwz(:,:,:)
424         !
425         ztrs(:,:,:,1) = ptb(:,:,:,jn)
426         zwzts(:,:,:) = 0._wp
427
428         DO jl = 1, jnzts                   ! Start of sub timestepping loop
429
430            IF( jl == 1 ) THEN              ! Euler forward to kick things off
431              jtb = 1   ;   jtn = 1   ;   jta = 2
432              zts(:) = p2dt(:) * z_rzts
433              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
434                                            ! starting at jl =1 if jnzts is odd;
435                                            ! starting at jl =2 otherwise
436            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
437              jtb = 1   ;   jtn = 2   ;   jta = 3
438              zts(:) = 2._wp * p2dt(:) * z_rzts
439            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
440              jtb = MOD(jtb,3) + 1
441              jtn = MOD(jtn,3) + 1
442              jta = MOD(jta,3) + 1
443            ENDIF
444            DO jk = 2, jpkm1          ! Interior value
445               DO jj = 2, jpjm1
446                  DO ji = fs_2, fs_jpim1
447                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
448                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
449                  END DO
450               END DO
451            END DO
452
453            jtaken = MOD( jtaken + 1 , 2 )
454
455            DO jk = 2, jpkm1          ! Interior value
456               DO jj = 2, jpjm1
457                  DO ji = fs_2, fs_jpim1
458                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
459                     ! total advective trends
460                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
461                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
462                  END DO
463               END DO
464            END DO
465
466         END DO
467
468         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
469            DO jj = 2, jpjm1
470               DO ji = fs_2, fs_jpim1
471                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
472               END DO
473            END DO
474         END DO
475         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
476         CALL lbc_lnk( zwz, 'W',  1. )
477
478         ! 4. monotonicity algorithm
479         ! -------------------------
480         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
481
482
483         ! 5. final trend with corrected fluxes
484         ! ------------------------------------
485         DO jk = 1, jpkm1
486            DO jj = 2, jpjm1
487               DO ji = fs_2, fs_jpim1   ! vector opt. 
488                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
489                  ! total advective trends
490                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
491                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
492                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
493                  ! add them to the general tracer trends
494                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
495               END DO
496            END DO
497         END DO
498
499         !                                 ! trend diagnostics (contribution of upstream fluxes)
500         IF( l_trd )  THEN
501            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
502            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
503            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
504           
505            CALL trd_tra( kt, cdtype, jn, jptra_trd_xad, ztrdx, pun, ptn(:,:,:,jn) )   
506            CALL trd_tra( kt, cdtype, jn, jptra_trd_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
507            CALL trd_tra( kt, cdtype, jn, jptra_trd_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
508         END IF
509         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
510         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
511           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
512           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
513         ENDIF
514         !
515      END DO
516      !
517                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
518                   CALL wrk_dealloc( jpi, jpj, jpk, 3, ztrs )
519                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
520      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
521      !
522      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
523      !
524   END SUBROUTINE tra_adv_tvd_zts
525
526   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
527      !!---------------------------------------------------------------------
528      !!                    ***  ROUTINE nonosc  ***
529      !!     
530      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
531      !!       scheme and the before field by a nonoscillatory algorithm
532      !!
533      !! **  Method  :   ... ???
534      !!       warning : pbef and paft must be masked, but the boundaries
535      !!       conditions on the fluxes are not necessary zalezak (1979)
536      !!       drange (1995) multi-dimensional forward-in-time and upstream-
537      !!       in-space based differencing for fluid
538      !!----------------------------------------------------------------------
539      !
540      !!----------------------------------------------------------------------
541      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
542      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
543      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
544      !
545      INTEGER ::   ji, jj, jk   ! dummy loop indices
546      INTEGER ::   ikm1         ! local integer
547      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
548      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
549      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
550      !!----------------------------------------------------------------------
551      !
552      IF( nn_timing == 1 )  CALL timing_start('nonosc')
553      !
554      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
555      !
556
557      zbig  = 1.e+40_wp
558      zrtrn = 1.e-15_wp
559      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
560
561
562      ! Search local extrema
563      ! --------------------
564      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
565      zbup = MAX( pbef * tmask - zbig * ( 1.e0 - tmask ),   &
566         &        paft * tmask - zbig * ( 1.e0 - tmask )  )
567      zbdo = MIN( pbef * tmask + zbig * ( 1.e0 - tmask ),   &
568         &        paft * tmask + zbig * ( 1.e0 - tmask )  )
569
570      DO jk = 1, jpkm1
571         ikm1 = MAX(jk-1,1)
572         z2dtt = p2dt(jk)
573         DO jj = 2, jpjm1
574            DO ji = fs_2, fs_jpim1   ! vector opt.
575
576               ! search maximum in neighbourhood
577               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
578                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
579                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
580                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
581
582               ! search minimum in neighbourhood
583               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
584                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
585                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
586                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
587
588               ! positive part of the flux
589               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
590                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
591                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
592
593               ! negative part of the flux
594               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
595                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
596                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
597
598               ! up & down beta terms
599               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
600               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
601               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
602            END DO
603         END DO
604      END DO
605      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
606
607      ! 3. monotonic flux in the i & j direction (paa & pbb)
608      ! ----------------------------------------
609      DO jk = 1, jpkm1
610         DO jj = 2, jpjm1
611            DO ji = fs_2, fs_jpim1   ! vector opt.
612               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
613               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
614               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
615               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
616
617               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
618               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
619               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
620               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
621
622      ! monotonic flux in the k direction, i.e. pcc
623      ! -------------------------------------------
624               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
625               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
626               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
627               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
628            END DO
629         END DO
630      END DO
631      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
632      !
633      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
634      !
635      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
636      !
637   END SUBROUTINE nonosc
638
639   !!======================================================================
640END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.