New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfgls.F90 in branches/2014/dev_r4765_CNRS_agrif/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2014/dev_r4765_CNRS_agrif/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfgls.F90 @ 4789

Last change on this file since 4789 was 4789, checked in by rblod, 10 years ago

dev_r4765_CNRS_agrif: First update of AGRIF for dynamic only (_flt and _ts), see ticket #1380 and associated wiki page
  • Property svn:keywords set to Id
File size: 60.7 KB
Line 
1MODULE zdfgls
2   !!======================================================================
3   !!                       ***  MODULE  zdfgls  ***
4   !! Ocean physics:  vertical mixing coefficient computed from the gls
5   !!                 turbulent closure parameterization
6   !!======================================================================
7   !! History :   3.0  !  2009-09  (G. Reffray)  Original code
8   !!             3.3  !  2010-10  (C. Bricaud)  Add in the reference
9   !!----------------------------------------------------------------------
10#if defined key_zdfgls   ||   defined key_esopa
11   !!----------------------------------------------------------------------
12   !!   'key_zdfgls'                 Generic Length Scale vertical physics
13   !!----------------------------------------------------------------------
14   !!   zdf_gls       : update momentum and tracer Kz from a gls scheme
15   !!   zdf_gls_init  : initialization, namelist read, and parameters control
16   !!   gls_rst       : read/write gls restart in ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   USE domvvl         ! ocean space and time domain : variable volume layer
21   USE zdf_oce        ! ocean vertical physics
22   USE sbc_oce        ! surface boundary condition: ocean
23   USE phycst         ! physical constants
24   USE zdfmxl         ! mixed layer
25   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp        ! MPP manager
27   USE wrk_nemo       ! work arrays
28   USE prtctl         ! Print control
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE timing         ! Timing
32   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   zdf_gls        ! routine called in step module
38   PUBLIC   zdf_gls_init   ! routine called in opa module
39   PUBLIC   gls_rst        ! routine called in step module
40
41   LOGICAL , PUBLIC, PARAMETER ::   lk_zdfgls = .TRUE.   !: TKE vertical mixing flag
42   !
43   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   en      !: now turbulent kinetic energy
44   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   mxln    !: now mixing length
45   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   zwall   !: wall function
46   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustars2 !: Squared surface velocity scale at T-points
47   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   ustarb2 !: Squared bottom  velocity scale at T-points
48
49   !                              !! ** Namelist  namzdf_gls  **
50   LOGICAL  ::   ln_crban          ! =T use Craig and Banner scheme
51   LOGICAL  ::   ln_length_lim     ! use limit on the dissipation rate under stable stratification (Galperin et al. 1988)
52   LOGICAL  ::   ln_sigpsi         ! Activate Burchard (2003) modification for k-eps closure & wave breaking mixing
53   INTEGER  ::   nn_tkebc_surf     ! TKE surface boundary condition (=0/1)
54   INTEGER  ::   nn_tkebc_bot      ! TKE bottom boundary condition (=0/1)
55   INTEGER  ::   nn_psibc_surf     ! PSI surface boundary condition (=0/1)
56   INTEGER  ::   nn_psibc_bot      ! PSI bottom boundary condition (=0/1)
57   INTEGER  ::   nn_stab_func      ! stability functions G88, KC or Canuto (=0/1/2)
58   INTEGER  ::   nn_clos           ! closure 0/1/2/3 MY82/k-eps/k-w/gen
59   REAL(wp) ::   rn_clim_galp      ! Holt 2008 value for k-eps: 0.267
60   REAL(wp) ::   rn_epsmin         ! minimum value of dissipation (m2/s3)
61   REAL(wp) ::   rn_emin           ! minimum value of TKE (m2/s2)
62   REAL(wp) ::   rn_charn          ! Charnock constant for surface breaking waves mixing : 1400. (standard) or 2.e5 (Stacey value)
63   REAL(wp) ::   rn_crban          ! Craig and Banner constant for surface breaking waves mixing
64
65   REAL(wp) ::   hsro          =  0.003_wp    ! Minimum surface roughness
66   REAL(wp) ::   hbro          =  0.003_wp    ! Bottom roughness (m)
67   REAL(wp) ::   rcm_sf        =  0.73_wp     ! Shear free turbulence parameters
68   REAL(wp) ::   ra_sf         = -2.0_wp      ! Must be negative -2 < ra_sf < -1
69   REAL(wp) ::   rl_sf         =  0.2_wp      ! 0 <rl_sf<vkarmn   
70   REAL(wp) ::   rghmin        = -0.28_wp
71   REAL(wp) ::   rgh0          =  0.0329_wp
72   REAL(wp) ::   rghcri        =  0.03_wp
73   REAL(wp) ::   ra1           =  0.92_wp
74   REAL(wp) ::   ra2           =  0.74_wp
75   REAL(wp) ::   rb1           = 16.60_wp
76   REAL(wp) ::   rb2           = 10.10_wp         
77   REAL(wp) ::   re2           =  1.33_wp         
78   REAL(wp) ::   rl1           =  0.107_wp
79   REAL(wp) ::   rl2           =  0.0032_wp
80   REAL(wp) ::   rl3           =  0.0864_wp
81   REAL(wp) ::   rl4           =  0.12_wp
82   REAL(wp) ::   rl5           = 11.9_wp
83   REAL(wp) ::   rl6           =  0.4_wp
84   REAL(wp) ::   rl7           =  0.0_wp
85   REAL(wp) ::   rl8           =  0.48_wp
86   REAL(wp) ::   rm1           =  0.127_wp
87   REAL(wp) ::   rm2           =  0.00336_wp
88   REAL(wp) ::   rm3           =  0.0906_wp
89   REAL(wp) ::   rm4           =  0.101_wp
90   REAL(wp) ::   rm5           = 11.2_wp
91   REAL(wp) ::   rm6           =  0.4_wp
92   REAL(wp) ::   rm7           =  0.0_wp
93   REAL(wp) ::   rm8           =  0.318_wp
94   
95   REAL(wp) ::   rc02, rc02r, rc03, rc04                          ! coefficients deduced from above parameters
96   REAL(wp) ::   rc03_sqrt2_galp                                  !     -           -           -        -
97   REAL(wp) ::   rsbc_tke1, rsbc_tke2, rsbc_tke3, rfact_tke       !     -           -           -        -
98   REAL(wp) ::   rsbc_psi1, rsbc_psi2, rsbc_psi3, rfact_psi       !     -           -           -        -
99   REAL(wp) ::   rsbc_mb  , rsbc_std , rsbc_zs                    !     -           -           -        -
100   REAL(wp) ::   rc0, rc2, rc3, rf6, rcff, rc_diff                !     -           -           -        -
101   REAL(wp) ::   rs0, rs1, rs2, rs4, rs5, rs6                     !     -           -           -        -
102   REAL(wp) ::   rd0, rd1, rd2, rd3, rd4, rd5                     !     -           -           -        -
103   REAL(wp) ::   rsc_tke, rsc_psi, rpsi1, rpsi2, rpsi3, rsc_psi0  !     -           -           -        -
104   REAL(wp) ::   rpsi3m, rpsi3p, rpp, rmm, rnn                    !     -           -           -        -
105
106   !! * Substitutions
107#  include "domzgr_substitute.h90"
108#  include "vectopt_loop_substitute.h90"
109   !!----------------------------------------------------------------------
110   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
111   !! $Id$
112   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
113   !!----------------------------------------------------------------------
114CONTAINS
115
116   INTEGER FUNCTION zdf_gls_alloc()
117      !!----------------------------------------------------------------------
118      !!                ***  FUNCTION zdf_gls_alloc  ***
119      !!----------------------------------------------------------------------
120      ALLOCATE( en(jpi,jpj,jpk),  mxln(jpi,jpj,jpk), zwall(jpi,jpj,jpk) ,     &
121         &      ustars2(jpi,jpj), ustarb2(jpi,jpj)                      , STAT= zdf_gls_alloc )
122         !
123      IF( lk_mpp             )   CALL mpp_sum ( zdf_gls_alloc )
124      IF( zdf_gls_alloc /= 0 )   CALL ctl_warn('zdf_gls_alloc: failed to allocate arrays')
125   END FUNCTION zdf_gls_alloc
126
127
128   SUBROUTINE zdf_gls( kt )
129      !!----------------------------------------------------------------------
130      !!                   ***  ROUTINE zdf_gls  ***
131      !!
132      !! ** Purpose :   Compute the vertical eddy viscosity and diffusivity
133      !!              coefficients using the GLS turbulent closure scheme.
134      !!----------------------------------------------------------------------
135      INTEGER, INTENT(in) ::   kt ! ocean time step
136      INTEGER  ::   ji, jj, jk, ibot, ibotm1, dir  ! dummy loop arguments
137      REAL(wp) ::   zesh2, zsigpsi, zcoef, zex1, zex2   ! local scalars
138      REAL(wp) ::   ztx2, zty2, zup, zdown, zcof        !   -      -
139      REAL(wp) ::   zratio, zrn2, zflxb, sh             !   -      -
140      REAL(wp) ::   prod, buoy, diss, zdiss, sm         !   -      -
141      REAL(wp) ::   gh, gm, shr, dif, zsqen, zav        !   -      -
142      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zdep
143      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zflxs       ! Turbulence fluxed induced by internal waves
144      REAL(wp), POINTER, DIMENSION(:,:  ) ::   zhsro       ! Surface roughness (surface waves)
145      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eb          ! tke at time before
146      REAL(wp), POINTER, DIMENSION(:,:,:) ::   mxlb        ! mixing length at time before
147      REAL(wp), POINTER, DIMENSION(:,:,:) ::   shear       ! vertical shear
148      REAL(wp), POINTER, DIMENSION(:,:,:) ::   eps         ! dissipation rate
149      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zwall_psi   ! Wall function use in the wb case (ln_sigpsi.AND.ln_crban=T)
150      REAL(wp), POINTER, DIMENSION(:,:,:) ::   z_elem_a, z_elem_b, z_elem_c, psi
151      !!--------------------------------------------------------------------
152      !
153      IF( nn_timing == 1 )  CALL timing_start('zdf_gls')
154      !
155      CALL wrk_alloc( jpi,jpj, zdep, zflxs, zhsro )
156      CALL wrk_alloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
157
158      ! Preliminary computing
159
160      ustars2 = 0._wp   ;   ustarb2 = 0._wp   ;   psi  = 0._wp   ;   zwall_psi = 0._wp
161
162      IF( kt /= nit000 ) THEN   ! restore before value to compute tke
163         avt (:,:,:) = avt_k (:,:,:)
164         avm (:,:,:) = avm_k (:,:,:)
165         avmu(:,:,:) = avmu_k(:,:,:)
166         avmv(:,:,:) = avmv_k(:,:,:) 
167      ENDIF
168
169      ! Compute surface and bottom friction at T-points
170!CDIR NOVERRCHK
171      DO jj = 2, jpjm1
172!CDIR NOVERRCHK
173         DO ji = fs_2, fs_jpim1   ! vector opt.
174            !
175            ! surface friction
176            ustars2(ji,jj) = r1_rau0 * taum(ji,jj) * tmask(ji,jj,1)
177            !
178            ! bottom friction (explicit before friction)
179            ! Note that we chose here not to bound the friction as in dynbfr)
180            ztx2 = (  bfrua(ji,jj)  * ub(ji,jj,mbku(ji,jj)) + bfrua(ji-1,jj) * ub(ji-1,jj,mbku(ji-1,jj))  )   &
181               & * ( 1._wp - 0.5_wp * umask(ji,jj,1) * umask(ji-1,jj,1)  )
182            zty2 = (  bfrva(ji,jj)  * vb(ji,jj,mbkv(ji,jj)) + bfrva(ji,jj-1) * vb(ji,jj-1,mbkv(ji,jj-1))  )   &
183               & * ( 1._wp - 0.5_wp * vmask(ji,jj,1) * vmask(ji,jj-1,1)  )
184            ustarb2(ji,jj) = SQRT( ztx2 * ztx2 + zty2 * zty2 ) * tmask(ji,jj,1)
185         END DO
186      END DO 
187
188      ! In case of breaking surface waves mixing,
189      ! Compute surface roughness length according to Charnock formula:
190      IF( ln_crban ) THEN   ;   zhsro(:,:) = MAX(rsbc_zs * ustars2(:,:), hsro)
191      ELSE                  ;   zhsro(:,:) = hsro
192      ENDIF
193
194      ! Compute shear and dissipation rate
195      DO jk = 2, jpkm1
196         DO jj = 2, jpjm1
197            DO ji = fs_2, fs_jpim1   ! vector opt.
198               avmu(ji,jj,jk) = avmu(ji,jj,jk) * ( un(ji,jj,jk-1) - un(ji,jj,jk) )   &
199                  &                            * ( ub(ji,jj,jk-1) - ub(ji,jj,jk) )   &
200                  &                            / (  fse3uw_n(ji,jj,jk)               &
201                  &                            *    fse3uw_b(ji,jj,jk) )
202               avmv(ji,jj,jk) = avmv(ji,jj,jk) * ( vn(ji,jj,jk-1) - vn(ji,jj,jk) )   &
203                  &                            * ( vb(ji,jj,jk-1) - vb(ji,jj,jk) )   &
204                  &                            / (  fse3vw_n(ji,jj,jk)               &
205                  &                            *    fse3vw_b(ji,jj,jk) )
206               eps(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT(en(ji,jj,jk)) / mxln(ji,jj,jk)
207            END DO
208         END DO
209      END DO
210      !
211      ! Lateral boundary conditions (avmu,avmv) (sign unchanged)
212      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )
213
214      ! Save tke at before time step
215      eb  (:,:,:) = en  (:,:,:)
216      mxlb(:,:,:) = mxln(:,:,:)
217
218      IF( nn_clos == 0 ) THEN    ! Mellor-Yamada
219         DO jk = 2, jpkm1
220            DO jj = 2, jpjm1 
221               DO ji = fs_2, fs_jpim1   ! vector opt.
222                  zup   = mxln(ji,jj,jk) * fsdepw(ji,jj,mbkt(ji,jj)+1)
223                  zdown = vkarmn * fsdepw(ji,jj,jk) * ( -fsdepw(ji,jj,jk) + fsdepw(ji,jj,mbkt(ji,jj)+1) )
224                  zcoef = ( zup / MAX( zdown, rsmall ) )
225                  zwall (ji,jj,jk) = ( 1._wp + re2 * zcoef*zcoef ) * tmask(ji,jj,jk)
226               END DO
227            END DO
228         END DO
229      ENDIF
230
231      !!---------------------------------!!
232      !!   Equation to prognostic k      !!
233      !!---------------------------------!!
234      !
235      ! Now Turbulent kinetic energy (output in en)
236      ! -------------------------------
237      ! Resolution of a tridiagonal linear system by a "methode de chasse"
238      ! computation from level 2 to jpkm1  (e(1) computed after and e(jpk)=0 ).
239      ! The surface boundary condition are set after
240      ! The bottom boundary condition are also set after. In standard e(bottom)=0.
241      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
242      ! Warning : after this step, en : right hand side of the matrix
243
244      DO jk = 2, jpkm1
245         DO jj = 2, jpjm1
246            DO ji = fs_2, fs_jpim1   ! vector opt.
247               !
248               ! shear prod. at w-point weightened by mask
249               shear(ji,jj,jk) =  ( avmu(ji-1,jj,jk) + avmu(ji,jj,jk) ) / MAX( 1.e0 , umask(ji-1,jj,jk) + umask(ji,jj,jk) )   &
250                  &             + ( avmv(ji,jj-1,jk) + avmv(ji,jj,jk) ) / MAX( 1.e0 , vmask(ji,jj-1,jk) + vmask(ji,jj,jk) )
251               !
252               ! stratif. destruction
253               buoy = - avt(ji,jj,jk) * rn2(ji,jj,jk)
254               !
255               ! shear prod. - stratif. destruction
256               diss = eps(ji,jj,jk)
257               !
258               dir = 0.5_wp + SIGN( 0.5_wp, shear(ji,jj,jk) + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
259               !
260               zesh2 = dir*(shear(ji,jj,jk)+buoy)+(1._wp-dir)*shear(ji,jj,jk)          ! production term
261               zdiss = dir*(diss/en(ji,jj,jk))   +(1._wp-dir)*(diss-buoy)/en(ji,jj,jk) ! dissipation term
262               !
263               ! Compute a wall function from 1. to rsc_psi*zwall/rsc_psi0
264               ! Note that as long that Dirichlet boundary conditions are NOT set at the first and last levels (GOTM style)
265               ! there is no need to set a boundary condition for zwall_psi at the top and bottom boundaries.
266               ! Otherwise, this should be rsc_psi/rsc_psi0
267               IF( ln_sigpsi ) THEN
268                  zsigpsi = MIN( 1._wp, zesh2 / eps(ji,jj,jk) )     ! 0. <= zsigpsi <= 1.
269                  zwall_psi(ji,jj,jk) = rsc_psi /   & 
270                     &     (  zsigpsi * rsc_psi + (1._wp-zsigpsi) * rsc_psi0 / MAX( zwall(ji,jj,jk), 1._wp )  )
271               ELSE
272                  zwall_psi(ji,jj,jk) = 1._wp
273               ENDIF
274               !
275               ! building the matrix
276               zcof = rfact_tke * tmask(ji,jj,jk)
277               !
278               ! lower diagonal
279               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
280                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
281               !
282               ! upper diagonal
283               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
284                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
285               !
286               ! diagonal
287               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
288                  &                       + rdt * zdiss * tmask(ji,jj,jk) 
289               !
290               ! right hand side in en
291               en(ji,jj,jk) = en(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
292            END DO
293         END DO
294      END DO
295      !
296      z_elem_b(:,:,jpk) = 1._wp
297      !
298      ! Set surface condition on zwall_psi (1 at the bottom)
299      IF( ln_sigpsi ) THEN
300         zcoef = rsc_psi / rsc_psi0
301         DO jj = 2, jpjm1
302            DO ji = fs_2, fs_jpim1   ! vector opt.
303               zwall_psi(ji,jj,1) = zcoef
304            END DO
305         END DO
306      ENDIF
307
308      ! Surface boundary condition on tke
309      ! ---------------------------------
310      !
311      SELECT CASE ( nn_tkebc_surf )
312      !
313      CASE ( 0 )             ! Dirichlet case
314         !
315         IF (ln_crban) THEN     ! Wave induced mixing case
316            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
317            !                      ! balance between the production and the dissipation terms including the wave effect
318            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
319            z_elem_a(:,:,1) = en(:,:,1)
320            z_elem_c(:,:,1) = 0._wp
321            z_elem_b(:,:,1) = 1._wp
322            !
323            ! one level below
324            en(:,:,2) = MAX( rsbc_tke1 * ustars2(:,:) * ( (zhsro(:,:)+fsdepw(:,:,2))/zhsro(:,:) )**ra_sf, rn_emin )
325            z_elem_a(:,:,2) = 0._wp
326            z_elem_c(:,:,2) = 0._wp
327            z_elem_b(:,:,2) = 1._wp
328            !
329         ELSE                   ! No wave induced mixing case
330            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
331            !                      ! balance between the production and the dissipation terms
332            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
333            z_elem_a(:,:,1) = en(:,:,1) 
334            z_elem_c(:,:,1) = 0._wp
335            z_elem_b(:,:,1) = 1._wp
336            !
337            ! one level below
338            en(:,:,2) = MAX( rc02r * ustars2(:,:), rn_emin )
339            z_elem_a(:,:,2) = 0._wp
340            z_elem_c(:,:,2) = 0._wp
341            z_elem_b(:,:,2) = 1._wp
342            !
343         ENDIF
344         !
345      CASE ( 1 )             ! Neumann boundary condition on d(e)/dz
346         !
347         IF (ln_crban) THEN ! Shear free case: d(e)/dz= Fw
348            !
349            ! Dirichlet conditions at k=1 (Cosmetic)
350            en(:,:,1) = MAX( rsbc_tke1 * ustars2(:,:), rn_emin )
351            z_elem_a(:,:,1) = en(:,:,1)
352            z_elem_c(:,:,1) = 0._wp
353            z_elem_b(:,:,1) = 1._wp
354            ! at k=2, set de/dz=Fw
355            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
356            z_elem_a(:,:,2) = 0._wp       
357            zflxs(:,:) = rsbc_tke3 * ustars2(:,:)**1.5_wp * ( (zhsro(:,:)+fsdept(:,:,1) ) / zhsro(:,:) )**(1.5*ra_sf)
358            en(:,:,2) = en(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
359            !
360         ELSE                   ! No wave induced mixing case: d(e)/dz=0.
361            !
362            ! Dirichlet conditions at k=1 (Cosmetic)
363            en(:,:,1) = MAX( rc02r * ustars2(:,:), rn_emin )
364            z_elem_a(:,:,1) = en(:,:,1)
365            z_elem_c(:,:,1) = 0._wp
366            z_elem_b(:,:,1) = 1._wp
367            ! at k=2 set de/dz=0.:
368            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2)  ! Remove z_elem_a from z_elem_b
369            z_elem_a(:,:,2) = 0._wp
370            !
371         ENDIF
372         !
373      END SELECT
374
375      ! Bottom boundary condition on tke
376      ! --------------------------------
377      !
378      SELECT CASE ( nn_tkebc_bot )
379      !
380      CASE ( 0 )             ! Dirichlet
381         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = rn_lmin
382         !                      ! Balance between the production and the dissipation terms
383!CDIR NOVERRCHK
384         DO jj = 2, jpjm1
385!CDIR NOVERRCHK
386            DO ji = fs_2, fs_jpim1   ! vector opt.
387               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
388               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
389               !
390               ! Bottom level Dirichlet condition:
391               z_elem_a(ji,jj,ibot  ) = 0._wp
392               z_elem_c(ji,jj,ibot  ) = 0._wp
393               z_elem_b(ji,jj,ibot  ) = 1._wp
394               en(ji,jj,ibot  ) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
395               !
396               ! Just above last level, Dirichlet condition again
397               z_elem_a(ji,jj,ibotm1) = 0._wp
398               z_elem_c(ji,jj,ibotm1) = 0._wp
399               z_elem_b(ji,jj,ibotm1) = 1._wp
400               en(ji,jj,ibotm1) = MAX( rc02r * ustarb2(ji,jj), rn_emin ) 
401            END DO
402         END DO
403         !
404      CASE ( 1 )             ! Neumman boundary condition
405         !                     
406!CDIR NOVERRCHK
407         DO jj = 2, jpjm1
408!CDIR NOVERRCHK
409            DO ji = fs_2, fs_jpim1   ! vector opt.
410               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
411               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
412               !
413               ! Bottom level Dirichlet condition:
414               z_elem_a(ji,jj,ibot) = 0._wp
415               z_elem_c(ji,jj,ibot) = 0._wp
416               z_elem_b(ji,jj,ibot) = 1._wp
417               en(ji,jj,ibot) = MAX( rc02r * ustarb2(ji,jj), rn_emin )
418               !
419               ! Just above last level: Neumann condition
420               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1)   ! Remove z_elem_c from z_elem_b
421               z_elem_c(ji,jj,ibotm1) = 0._wp
422            END DO
423         END DO
424         !
425      END SELECT
426
427      ! Matrix inversion (en prescribed at surface and the bottom)
428      ! ----------------------------------------------------------
429      !
430      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
431         DO jj = 2, jpjm1
432            DO ji = fs_2, fs_jpim1    ! vector opt.
433               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
434            END DO
435         END DO
436      END DO
437      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
438         DO jj = 2, jpjm1
439            DO ji = fs_2, fs_jpim1    ! vector opt.
440               z_elem_a(ji,jj,jk) = en(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
441            END DO
442         END DO
443      END DO
444      DO jk = jpk-1, 2, -1                         ! thrid recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
445         DO jj = 2, jpjm1
446            DO ji = fs_2, fs_jpim1    ! vector opt.
447               en(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * en(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
448            END DO
449         END DO
450      END DO
451      !                                            ! set the minimum value of tke
452      en(:,:,:) = MAX( en(:,:,:), rn_emin )
453     
454      !!----------------------------------------!!
455      !!   Solve prognostic equation for psi    !!
456      !!----------------------------------------!!
457
458      ! Set psi to previous time step value
459      !
460      SELECT CASE ( nn_clos )
461      !
462      CASE( 0 )               ! k-kl  (Mellor-Yamada)
463         DO jk = 2, jpkm1
464            DO jj = 2, jpjm1
465               DO ji = fs_2, fs_jpim1   ! vector opt.
466                  psi(ji,jj,jk)  = eb(ji,jj,jk) * mxlb(ji,jj,jk)
467               END DO
468            END DO
469         END DO
470         !
471      CASE( 1 )               ! k-eps
472         DO jk = 2, jpkm1
473            DO jj = 2, jpjm1
474               DO ji = fs_2, fs_jpim1   ! vector opt.
475                  psi(ji,jj,jk)  = eps(ji,jj,jk)
476               END DO
477            END DO
478         END DO
479         !
480      CASE( 2 )               ! k-w
481         DO jk = 2, jpkm1
482            DO jj = 2, jpjm1
483               DO ji = fs_2, fs_jpim1   ! vector opt.
484                  psi(ji,jj,jk)  = SQRT( eb(ji,jj,jk) ) / ( rc0 * mxlb(ji,jj,jk) )
485               END DO
486            END DO
487         END DO
488         !
489      CASE( 3 )               ! generic
490         DO jk = 2, jpkm1
491            DO jj = 2, jpjm1
492               DO ji = fs_2, fs_jpim1   ! vector opt.
493                  psi(ji,jj,jk)  = rc02 * eb(ji,jj,jk) * mxlb(ji,jj,jk)**rnn 
494               END DO
495            END DO
496         END DO
497         !
498      END SELECT
499      !
500      ! Now gls (output in psi)
501      ! -------------------------------
502      ! Resolution of a tridiagonal linear system by a "methode de chasse"
503      ! computation from level 2 to jpkm1  (e(1) already computed and e(jpk)=0 ).
504      ! z_elem_b : diagonal z_elem_c : upper diagonal z_elem_a : lower diagonal
505      ! Warning : after this step, en : right hand side of the matrix
506
507      DO jk = 2, jpkm1
508         DO jj = 2, jpjm1
509            DO ji = fs_2, fs_jpim1   ! vector opt.
510               !
511               ! psi / k
512               zratio = psi(ji,jj,jk) / eb(ji,jj,jk) 
513               !
514               ! psi3+ : stable : B=-KhN²<0 => N²>0 if rn2>0 dir = 1 (stable) otherwise dir = 0 (unstable)
515               dir = 0.5_wp + SIGN( 0.5_wp, rn2(ji,jj,jk) )
516               !
517               rpsi3 = dir * rpsi3m + ( 1._wp - dir ) * rpsi3p
518               !
519               ! shear prod. - stratif. destruction
520               prod = rpsi1 * zratio * shear(ji,jj,jk)
521               !
522               ! stratif. destruction
523               buoy = rpsi3 * zratio * (- avt(ji,jj,jk) * rn2(ji,jj,jk) )
524               !
525               ! shear prod. - stratif. destruction
526               diss = rpsi2 * zratio * zwall(ji,jj,jk) * eps(ji,jj,jk)
527               !
528               dir = 0.5_wp + SIGN( 0.5_wp, prod + buoy )   ! dir =1(=0) if shear(ji,jj,jk)+buoy >0(<0)
529               !
530               zesh2 = dir * ( prod + buoy )          + (1._wp - dir ) * prod                        ! production term
531               zdiss = dir * ( diss / psi(ji,jj,jk) ) + (1._wp - dir ) * (diss-buoy) / psi(ji,jj,jk) ! dissipation term
532               !                                                       
533               ! building the matrix
534               zcof = rfact_psi * zwall_psi(ji,jj,jk) * tmask(ji,jj,jk)
535               ! lower diagonal
536               z_elem_a(ji,jj,jk) = zcof * ( avm  (ji,jj,jk  ) + avm  (ji,jj,jk-1) )   &
537                  &                      / ( fse3t(ji,jj,jk-1) * fse3w(ji,jj,jk  ) )
538               ! upper diagonal
539               z_elem_c(ji,jj,jk) = zcof * ( avm  (ji,jj,jk+1) + avm  (ji,jj,jk  ) )   &
540                  &                      / ( fse3t(ji,jj,jk  ) * fse3w(ji,jj,jk) )
541               ! diagonal
542               z_elem_b(ji,jj,jk) = 1._wp - z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk)  &
543                  &                       + rdt * zdiss * tmask(ji,jj,jk)
544               !
545               ! right hand side in psi
546               psi(ji,jj,jk) = psi(ji,jj,jk) + rdt * zesh2 * tmask(ji,jj,jk)
547            END DO
548         END DO
549      END DO
550      !
551      z_elem_b(:,:,jpk) = 1._wp
552
553      ! Surface boundary condition on psi
554      ! ---------------------------------
555      !
556      SELECT CASE ( nn_psibc_surf )
557      !
558      CASE ( 0 )             ! Dirichlet boundary conditions
559         !
560         IF( ln_crban ) THEN       ! Wave induced mixing case
561            !                      ! en(1) = q2(1) = 0.5 * (15.8 * Ccb)^(2/3) * u*^2
562            !                      ! balance between the production and the dissipation terms including the wave effect
563            zdep(:,:) = rl_sf * zhsro(:,:)
564            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
565            z_elem_a(:,:,1) = psi(:,:,1)
566            z_elem_c(:,:,1) = 0._wp
567            z_elem_b(:,:,1) = 1._wp
568            !
569            ! one level below
570            zex1 = (rmm*ra_sf+rnn)
571            zex2 = (rmm*ra_sf)
572            zdep(:,:) = ( (zhsro(:,:) + fsdepw(:,:,2))**zex1 ) / zhsro(:,:)**zex2
573            psi (:,:,2) = rsbc_psi1 * ustars2(:,:)**rmm * zdep(:,:) * tmask(:,:,1)
574            z_elem_a(:,:,2) = 0._wp
575            z_elem_c(:,:,2) = 0._wp
576            z_elem_b(:,:,2) = 1._wp
577            !
578         ELSE                   ! No wave induced mixing case
579            !                      ! en(1) = u*^2/C0^2  &  l(1)  = K*zs
580            !                      ! balance between the production and the dissipation terms
581            !
582            zdep(:,:) = vkarmn * zhsro(:,:)
583            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
584            z_elem_a(:,:,1) = psi(:,:,1)
585            z_elem_c(:,:,1) = 0._wp
586            z_elem_b(:,:,1) = 1._wp
587            !
588            ! one level below
589            zdep(:,:) = vkarmn * ( zhsro(:,:) + fsdepw(:,:,2) )
590            psi (:,:,2) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
591            z_elem_a(:,:,2) = 0._wp
592            z_elem_c(:,:,2) = 0._wp
593            z_elem_b(:,:,2) = 1.
594            !
595         ENDIF
596         !
597      CASE ( 1 )             ! Neumann boundary condition on d(psi)/dz
598         !
599         IF( ln_crban ) THEN     ! Wave induced mixing case
600            !
601            zdep(:,:) = rl_sf * zhsro(:,:)
602            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
603            z_elem_a(:,:,1) = psi(:,:,1)
604            z_elem_c(:,:,1) = 0._wp
605            z_elem_b(:,:,1) = 1._wp
606            !
607            ! Neumann condition at k=2
608            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
609            z_elem_a(:,:,2) = 0._wp
610            !
611            ! Set psi vertical flux at the surface:
612            zdep(:,:) = (zhsro(:,:) + fsdept(:,:,1))**(rmm*ra_sf+rnn-1._wp) / zhsro(:,:)**(rmm*ra_sf)
613            zflxs(:,:) = rsbc_psi3 * ( zwall_psi(:,:,1)*avm(:,:,1) + zwall_psi(:,:,2)*avm(:,:,2) ) & 
614               &                   * en(:,:,1)**rmm * zdep         
615            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
616            !
617      ELSE                   ! No wave induced mixing
618            !
619            zdep(:,:) = vkarmn * zhsro(:,:)
620            psi (:,:,1) = rc0**rpp * en(:,:,1)**rmm * zdep(:,:)**rnn * tmask(:,:,1)
621            z_elem_a(:,:,1) = psi(:,:,1)
622            z_elem_c(:,:,1) = 0._wp
623            z_elem_b(:,:,1) = 1._wp
624            !
625            ! Neumann condition at k=2
626            z_elem_b(:,:,2) = z_elem_b(:,:,2) +  z_elem_a(:,:,2) ! Remove z_elem_a from z_elem_b
627            z_elem_a(ji,jj,2) = 0._wp
628            !
629            ! Set psi vertical flux at the surface:
630            zdep(:,:)  = zhsro(:,:) + fsdept(:,:,1)
631            zflxs(:,:) = rsbc_psi2 * ( avm(:,:,1) + avm(:,:,2) ) * en(:,:,1)**rmm * zdep**(rnn-1._wp)
632            psi(:,:,2) = psi(:,:,2) + zflxs(:,:) / fse3w(:,:,2)
633            !     
634         ENDIF
635         !
636      END SELECT
637
638      ! Bottom boundary condition on psi
639      ! --------------------------------
640      !
641      SELECT CASE ( nn_psibc_bot )
642      !
643      CASE ( 0 )             ! Dirichlet
644         !                      ! en(ibot) = u*^2 / Co2 and mxln(ibot) = vkarmn * hbro
645         !                      ! Balance between the production and the dissipation terms
646!CDIR NOVERRCHK
647         DO jj = 2, jpjm1
648!CDIR NOVERRCHK
649            DO ji = fs_2, fs_jpim1   ! vector opt.
650               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
651               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
652               zdep(ji,jj) = vkarmn * hbro
653               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
654               z_elem_a(ji,jj,ibot) = 0._wp
655               z_elem_c(ji,jj,ibot) = 0._wp
656               z_elem_b(ji,jj,ibot) = 1._wp
657               !
658               ! Just above last level, Dirichlet condition again (GOTM like)
659               zdep(ji,jj) = vkarmn * ( hbro + fse3t(ji,jj,ibotm1) )
660               psi (ji,jj,ibotm1) = rc0**rpp * en(ji,jj,ibot  )**rmm * zdep(ji,jj)**rnn
661               z_elem_a(ji,jj,ibotm1) = 0._wp
662               z_elem_c(ji,jj,ibotm1) = 0._wp
663               z_elem_b(ji,jj,ibotm1) = 1._wp
664            END DO
665         END DO
666         !
667      CASE ( 1 )             ! Neumman boundary condition
668         !                     
669!CDIR NOVERRCHK
670         DO jj = 2, jpjm1
671!CDIR NOVERRCHK
672            DO ji = fs_2, fs_jpim1   ! vector opt.
673               ibot   = mbkt(ji,jj) + 1      ! k   bottom level of w-point
674               ibotm1 = mbkt(ji,jj)          ! k-1 bottom level of w-point but >=1
675               !
676               ! Bottom level Dirichlet condition:
677               zdep(ji,jj) = vkarmn * hbro
678               psi (ji,jj,ibot) = rc0**rpp * en(ji,jj,ibot)**rmm * zdep(ji,jj)**rnn
679               !
680               z_elem_a(ji,jj,ibot) = 0._wp
681               z_elem_c(ji,jj,ibot) = 0._wp
682               z_elem_b(ji,jj,ibot) = 1._wp
683               !
684               ! Just above last level: Neumann condition with flux injection
685               z_elem_b(ji,jj,ibotm1) = z_elem_b(ji,jj,ibotm1) + z_elem_c(ji,jj,ibotm1) ! Remove z_elem_c from z_elem_b
686               z_elem_c(ji,jj,ibotm1) = 0.
687               !
688               ! Set psi vertical flux at the bottom:
689               zdep(ji,jj) = hbro + 0.5_wp*fse3t(ji,jj,ibotm1)
690               zflxb = rsbc_psi2 * ( avm(ji,jj,ibot) + avm(ji,jj,ibotm1) )   &
691                  &  * (0.5_wp*(en(ji,jj,ibot)+en(ji,jj,ibotm1)))**rmm * zdep(ji,jj)**(rnn-1._wp)
692               psi(ji,jj,ibotm1) = psi(ji,jj,ibotm1) + zflxb / fse3w(ji,jj,ibotm1)
693            END DO
694         END DO
695         !
696      END SELECT
697
698      ! Matrix inversion
699      ! ----------------
700      !
701      DO jk = 2, jpkm1                             ! First recurrence : Dk = Dk - Lk * Uk-1 / Dk-1
702         DO jj = 2, jpjm1
703            DO ji = fs_2, fs_jpim1    ! vector opt.
704               z_elem_b(ji,jj,jk) = z_elem_b(ji,jj,jk) - z_elem_a(ji,jj,jk) * z_elem_c(ji,jj,jk-1) / z_elem_b(ji,jj,jk-1)
705            END DO
706         END DO
707      END DO
708      DO jk = 2, jpk                               ! Second recurrence : Lk = RHSk - Lk / Dk-1 * Lk-1
709         DO jj = 2, jpjm1
710            DO ji = fs_2, fs_jpim1    ! vector opt.
711               z_elem_a(ji,jj,jk) = psi(ji,jj,jk) - z_elem_a(ji,jj,jk) / z_elem_b(ji,jj,jk-1) * z_elem_a(ji,jj,jk-1)
712            END DO
713         END DO
714      END DO
715      DO jk = jpk-1, 2, -1                         ! Third recurrence : Ek = ( Lk - Uk * Ek+1 ) / Dk
716         DO jj = 2, jpjm1
717            DO ji = fs_2, fs_jpim1    ! vector opt.
718               psi(ji,jj,jk) = ( z_elem_a(ji,jj,jk) - z_elem_c(ji,jj,jk) * psi(ji,jj,jk+1) ) / z_elem_b(ji,jj,jk)
719            END DO
720         END DO
721      END DO
722
723      ! Set dissipation
724      !----------------
725
726      SELECT CASE ( nn_clos )
727      !
728      CASE( 0 )               ! k-kl  (Mellor-Yamada)
729         DO jk = 1, jpkm1
730            DO jj = 2, jpjm1
731               DO ji = fs_2, fs_jpim1   ! vector opt.
732                  eps(ji,jj,jk) = rc03 * en(ji,jj,jk) * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / psi(ji,jj,jk)
733               END DO
734            END DO
735         END DO
736         !
737      CASE( 1 )               ! k-eps
738         DO jk = 1, jpkm1
739            DO jj = 2, jpjm1
740               DO ji = fs_2, fs_jpim1   ! vector opt.
741                  eps(ji,jj,jk) = psi(ji,jj,jk)
742               END DO
743            END DO
744         END DO
745         !
746      CASE( 2 )               ! k-w
747         DO jk = 1, jpkm1
748            DO jj = 2, jpjm1
749               DO ji = fs_2, fs_jpim1   ! vector opt.
750                  eps(ji,jj,jk) = rc04 * en(ji,jj,jk) * psi(ji,jj,jk) 
751               END DO
752            END DO
753         END DO
754         !
755      CASE( 3 )               ! generic
756         zcoef = rc0**( 3._wp  + rpp/rnn )
757         zex1  =      ( 1.5_wp + rmm/rnn )
758         zex2  = -1._wp / rnn
759         DO jk = 1, jpkm1
760            DO jj = 2, jpjm1
761               DO ji = fs_2, fs_jpim1   ! vector opt.
762                  eps(ji,jj,jk) = zcoef * en(ji,jj,jk)**zex1 * psi(ji,jj,jk)**zex2
763               END DO
764            END DO
765         END DO
766         !
767      END SELECT
768
769      ! Limit dissipation rate under stable stratification
770      ! --------------------------------------------------
771      DO jk = 1, jpkm1 ! Note that this set boundary conditions on mxln at the same time
772         DO jj = 2, jpjm1
773            DO ji = fs_2, fs_jpim1    ! vector opt.
774               ! limitation
775               eps(ji,jj,jk)  = MAX( eps(ji,jj,jk), rn_epsmin )
776               mxln(ji,jj,jk)  = rc03 * en(ji,jj,jk) * SQRT( en(ji,jj,jk) ) / eps(ji,jj,jk)
777               ! Galperin criterium (NOTE : Not required if the proper value of C3 in stable cases is calculated)
778               zrn2 = MAX( rn2(ji,jj,jk), rsmall )
779               mxln(ji,jj,jk) = MIN(  rn_clim_galp * SQRT( 2._wp * en(ji,jj,jk) / zrn2 ), mxln(ji,jj,jk)  )
780            END DO
781         END DO
782      END DO 
783
784      !
785      ! Stability function and vertical viscosity and diffusivity
786      ! ---------------------------------------------------------
787      !
788      SELECT CASE ( nn_stab_func )
789      !
790      CASE ( 0 , 1 )             ! Galperin or Kantha-Clayson stability functions
791         DO jk = 2, jpkm1
792            DO jj = 2, jpjm1
793               DO ji = fs_2, fs_jpim1   ! vector opt.
794                  ! zcof =  l²/q²
795                  zcof = mxlb(ji,jj,jk) * mxlb(ji,jj,jk) / ( 2._wp*eb(ji,jj,jk) )
796                  ! Gh = -N²l²/q²
797                  gh = - rn2(ji,jj,jk) * zcof
798                  gh = MIN( gh, rgh0   )
799                  gh = MAX( gh, rghmin )
800                  ! Stability functions from Kantha and Clayson (if C2=C3=0 => Galperin)
801                  sh = ra2*( 1._wp-6._wp*ra1/rb1 ) / ( 1.-3.*ra2*gh*(6.*ra1+rb2*( 1._wp-rc3 ) ) )
802                  sm = ( rb1**(-1._wp/3._wp) + ( 18._wp*ra1*ra1 + 9._wp*ra1*ra2*(1._wp-rc2) )*sh*gh ) / (1._wp-9._wp*ra1*ra2*gh)
803                  !
804                  ! Store stability function in avmu and avmv
805                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
806                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
807               END DO
808            END DO
809         END DO
810         !
811      CASE ( 2, 3 )               ! Canuto stability functions
812         DO jk = 2, jpkm1
813            DO jj = 2, jpjm1
814               DO ji = fs_2, fs_jpim1   ! vector opt.
815                  ! zcof =  l²/q²
816                  zcof = mxlb(ji,jj,jk)*mxlb(ji,jj,jk) / ( 2._wp * eb(ji,jj,jk) )
817                  ! Gh = -N²l²/q²
818                  gh = - rn2(ji,jj,jk) * zcof
819                  gh = MIN( gh, rgh0   )
820                  gh = MAX( gh, rghmin )
821                  gh = gh * rf6
822                  ! Gm =  M²l²/q² Shear number
823                  shr = shear(ji,jj,jk) / MAX( avm(ji,jj,jk), rsmall )
824                  gm = MAX( shr * zcof , 1.e-10 )
825                  gm = gm * rf6
826                  gm = MIN ( (rd0 - rd1*gh + rd3*gh*gh) / (rd2-rd4*gh) , gm )
827                  ! Stability functions from Canuto
828                  rcff = rd0 - rd1*gh +rd2*gm + rd3*gh*gh - rd4*gh*gm + rd5*gm*gm
829                  sm = (rs0 - rs1*gh + rs2*gm) / rcff
830                  sh = (rs4 - rs5*gh + rs6*gm) / rcff
831                  !
832                  ! Store stability function in avmu and avmv
833                  avmu(ji,jj,jk) = rc_diff * sh * tmask(ji,jj,jk)
834                  avmv(ji,jj,jk) = rc_diff * sm * tmask(ji,jj,jk)
835               END DO
836            END DO
837         END DO
838         !
839      END SELECT
840
841      ! Boundary conditions on stability functions for momentum (Neumann):
842      ! Lines below are useless if GOTM style Dirichlet conditions are used
843      zcoef = rcm_sf / SQRT( 2._wp )
844      DO jj = 2, jpjm1
845         DO ji = fs_2, fs_jpim1   ! vector opt.
846            avmv(ji,jj,1) = zcoef
847         END DO
848      END DO
849      zcoef = rc0 / SQRT( 2._wp )
850      DO jj = 2, jpjm1
851         DO ji = fs_2, fs_jpim1   ! vector opt.
852            avmv(ji,jj,mbkt(ji,jj)+1) = zcoef
853         END DO
854      END DO
855
856      ! Compute diffusivities/viscosities
857      ! The computation below could be restrained to jk=2 to jpkm1 if GOTM style Dirichlet conditions are used
858      DO jk = 1, jpk
859         DO jj = 2, jpjm1
860            DO ji = fs_2, fs_jpim1   ! vector opt.
861               zsqen         = SQRT( 2._wp * en(ji,jj,jk) ) * mxln(ji,jj,jk)
862               zav           = zsqen * avmu(ji,jj,jk)
863               avt(ji,jj,jk) = MAX( zav, avtb(jk) )*tmask(ji,jj,jk) ! apply mask for zdfmxl routine
864               zav           = zsqen * avmv(ji,jj,jk)
865               avm(ji,jj,jk) = MAX( zav, avmb(jk) ) ! Note that avm is not masked at the surface and the bottom
866            END DO
867         END DO
868      END DO
869      !
870      ! Lateral boundary conditions (sign unchanged)
871      avt(:,:,1)  = 0._wp
872      CALL lbc_lnk( avm, 'W', 1. )   ;   CALL lbc_lnk( avt, 'W', 1. )
873
874      DO jk = 2, jpkm1            !* vertical eddy viscosity at u- and v-points
875         DO jj = 2, jpjm1
876            DO ji = fs_2, fs_jpim1   ! vector opt.
877               avmu(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji+1,jj  ,jk) ) * umask(ji,jj,jk)
878               avmv(ji,jj,jk) = 0.5 * ( avm(ji,jj,jk) + avm(ji  ,jj+1,jk) ) * vmask(ji,jj,jk)
879            END DO
880         END DO
881      END DO
882      avmu(:,:,1) = 0._wp             ;   avmv(:,:,1) = 0._wp                 ! set surface to zero
883      CALL lbc_lnk( avmu, 'U', 1. )   ;   CALL lbc_lnk( avmv, 'V', 1. )       ! Lateral boundary conditions
884
885      IF(ln_ctl) THEN
886         CALL prt_ctl( tab3d_1=en  , clinfo1=' gls  - e: ', tab3d_2=avt, clinfo2=' t: ', ovlap=1, kdim=jpk)
887         CALL prt_ctl( tab3d_1=avmu, clinfo1=' gls  - u: ', mask1=umask,                   &
888            &          tab3d_2=avmv, clinfo2=       ' v: ', mask2=vmask, ovlap=1, kdim=jpk )
889      ENDIF
890      !
891      avt_k (:,:,:) = avt (:,:,:)
892      avm_k (:,:,:) = avm (:,:,:)
893      avmu_k(:,:,:) = avmu(:,:,:)
894      avmv_k(:,:,:) = avmv(:,:,:)
895      !
896      CALL wrk_dealloc( jpi,jpj, zdep, zflxs, zhsro )
897      CALL wrk_dealloc( jpi,jpj,jpk, eb, mxlb, shear, eps, zwall_psi, z_elem_a, z_elem_b, z_elem_c, psi )
898      !
899      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls')
900      !
901      !
902   END SUBROUTINE zdf_gls
903
904
905   SUBROUTINE zdf_gls_init
906      !!----------------------------------------------------------------------
907      !!                  ***  ROUTINE zdf_gls_init  ***
908      !!                     
909      !! ** Purpose :   Initialization of the vertical eddy diffivity and
910      !!      viscosity when using a gls turbulent closure scheme
911      !!
912      !! ** Method  :   Read the namzdf_gls namelist and check the parameters
913      !!      called at the first timestep (nit000)
914      !!
915      !! ** input   :   Namlist namzdf_gls
916      !!
917      !! ** Action  :   Increase by 1 the nstop flag is setting problem encounter
918      !!
919      !!----------------------------------------------------------------------
920      USE dynzdf_exp
921      USE trazdf_exp
922      !
923      INTEGER ::   jk    ! dummy loop indices
924      INTEGER ::   ios   ! Local integer output status for namelist read
925      REAL(wp)::   zcr   ! local scalar
926      !!
927      NAMELIST/namzdf_gls/rn_emin, rn_epsmin, ln_length_lim, &
928         &            rn_clim_galp, ln_crban, ln_sigpsi,     &
929         &            rn_crban, rn_charn,                    &
930         &            nn_tkebc_surf, nn_tkebc_bot,           &
931         &            nn_psibc_surf, nn_psibc_bot,           &
932         &            nn_stab_func, nn_clos
933      !!----------------------------------------------------------
934      !
935      IF( nn_timing == 1 )  CALL timing_start('zdf_gls_init')
936      !
937      REWIND( numnam_ref )              ! Namelist namzdf_gls in reference namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
938      READ  ( numnam_ref, namzdf_gls, IOSTAT = ios, ERR = 901)
939901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in reference namelist', lwp )
940
941      REWIND( numnam_cfg )              ! Namelist namzdf_gls in configuration namelist : Vertical eddy diffivity and viscosity using gls turbulent closure scheme
942      READ  ( numnam_cfg, namzdf_gls, IOSTAT = ios, ERR = 902 )
943902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf_gls in configuration namelist', lwp )
944      IF(lwm) WRITE ( numond, namzdf_gls )
945
946      IF(lwp) THEN                     !* Control print
947         WRITE(numout,*)
948         WRITE(numout,*) 'zdf_gls_init : gls turbulent closure scheme'
949         WRITE(numout,*) '~~~~~~~~~~~~'
950         WRITE(numout,*) '   Namelist namzdf_gls : set gls mixing parameters'
951         WRITE(numout,*) '      minimum value of en                           rn_emin       = ', rn_emin
952         WRITE(numout,*) '      minimum value of eps                          rn_epsmin     = ', rn_epsmin
953         WRITE(numout,*) '      Limit dissipation rate under stable stratif.  ln_length_lim = ', ln_length_lim
954         WRITE(numout,*) '      Galperin limit (Standard: 0.53, Holt: 0.26)   rn_clim_galp  = ', rn_clim_galp
955         WRITE(numout,*) '      TKE Surface boundary condition                nn_tkebc_surf = ', nn_tkebc_surf
956         WRITE(numout,*) '      TKE Bottom boundary condition                 nn_tkebc_bot  = ', nn_tkebc_bot
957         WRITE(numout,*) '      PSI Surface boundary condition                nn_psibc_surf = ', nn_psibc_surf
958         WRITE(numout,*) '      PSI Bottom boundary condition                 nn_psibc_bot  = ', nn_psibc_bot
959         WRITE(numout,*) '      Craig and Banner scheme                       ln_crban      = ', ln_crban
960         WRITE(numout,*) '      Modify psi Schmidt number (wb case)           ln_sigpsi     = ', ln_sigpsi
961         WRITE(numout,*) '      Craig and Banner coefficient                  rn_crban       = ', rn_crban
962         WRITE(numout,*) '      Charnock coefficient                          rn_charn       = ', rn_charn
963         WRITE(numout,*) '      Stability functions                           nn_stab_func   = ', nn_stab_func
964         WRITE(numout,*) '      Type of closure                               nn_clos        = ', nn_clos
965         WRITE(numout,*) '   Hard coded parameters'
966         WRITE(numout,*) '      Surface roughness (m)                         hsro          = ', hsro
967         WRITE(numout,*) '      Bottom roughness (m)                          hbro          = ', hbro
968      ENDIF
969
970      !                                !* allocate gls arrays
971      IF( zdf_gls_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_gls_init : unable to allocate arrays' )
972
973      !                                !* Check of some namelist values
974      IF( nn_tkebc_surf < 0 .OR. nn_tkebc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_surf is 0 or 1' )
975      IF( nn_psibc_surf < 0 .OR. nn_psibc_surf > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_surf is 0 or 1' )
976      IF( nn_tkebc_bot  < 0 .OR. nn_tkebc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_tkebc_bot is 0 or 1' )
977      IF( nn_psibc_bot  < 0 .OR. nn_psibc_bot  > 1 ) CALL ctl_stop( 'bad flag: nn_psibc_bot is 0 or 1' )
978      IF( nn_stab_func  < 0 .OR. nn_stab_func  > 3 ) CALL ctl_stop( 'bad flag: nn_stab_func is 0, 1, 2 and 3' )
979      IF( nn_clos       < 0 .OR. nn_clos       > 3 ) CALL ctl_stop( 'bad flag: nn_clos is 0, 1, 2 or 3' )
980
981      SELECT CASE ( nn_clos )          !* set the parameters for the chosen closure
982      !
983      CASE( 0 )                              ! k-kl  (Mellor-Yamada)
984         !
985         IF(lwp) WRITE(numout,*) 'The choosen closure is k-kl closed to the classical Mellor-Yamada'
986         rpp     = 0._wp
987         rmm     = 1._wp
988         rnn     = 1._wp
989         rsc_tke = 1.96_wp
990         rsc_psi = 1.96_wp
991         rpsi1   = 0.9_wp
992         rpsi3p  = 1._wp
993         rpsi2   = 0.5_wp
994         !
995         SELECT CASE ( nn_stab_func )
996         CASE( 0, 1 )   ;   rpsi3m = 2.53_wp       ! G88 or KC stability functions
997         CASE( 2 )      ;   rpsi3m = 2.38_wp       ! Canuto A stability functions
998         CASE( 3 )      ;   rpsi3m = 2.38          ! Canuto B stability functions (caution : constant not identified)
999         END SELECT
1000         !
1001      CASE( 1 )                              ! k-eps
1002         !
1003         IF(lwp) WRITE(numout,*) 'The choosen closure is k-eps'
1004         rpp     =  3._wp
1005         rmm     =  1.5_wp
1006         rnn     = -1._wp
1007         rsc_tke =  1._wp
1008         rsc_psi =  1.3_wp  ! Schmidt number for psi
1009         rpsi1   =  1.44_wp
1010         rpsi3p  =  1._wp
1011         rpsi2   =  1.92_wp
1012         !
1013         SELECT CASE ( nn_stab_func )
1014         CASE( 0, 1 )   ;   rpsi3m = -0.52_wp      ! G88 or KC stability functions
1015         CASE( 2 )      ;   rpsi3m = -0.629_wp     ! Canuto A stability functions
1016         CASE( 3 )      ;   rpsi3m = -0.566        ! Canuto B stability functions
1017         END SELECT
1018         !
1019      CASE( 2 )                              ! k-omega
1020         !
1021         IF(lwp) WRITE(numout,*) 'The choosen closure is k-omega'
1022         rpp     = -1._wp
1023         rmm     =  0.5_wp
1024         rnn     = -1._wp
1025         rsc_tke =  2._wp
1026         rsc_psi =  2._wp
1027         rpsi1   =  0.555_wp
1028         rpsi3p  =  1._wp
1029         rpsi2   =  0.833_wp
1030         !
1031         SELECT CASE ( nn_stab_func )
1032         CASE( 0, 1 )   ;   rpsi3m = -0.58_wp       ! G88 or KC stability functions
1033         CASE( 2 )      ;   rpsi3m = -0.64_wp       ! Canuto A stability functions
1034         CASE( 3 )      ;   rpsi3m = -0.64_wp       ! Canuto B stability functions caution : constant not identified)
1035         END SELECT
1036         !
1037      CASE( 3 )                              ! generic
1038         !
1039         IF(lwp) WRITE(numout,*) 'The choosen closure is generic'
1040         rpp     = 2._wp
1041         rmm     = 1._wp
1042         rnn     = -0.67_wp
1043         rsc_tke = 0.8_wp
1044         rsc_psi = 1.07_wp
1045         rpsi1   = 1._wp
1046         rpsi3p  = 1._wp
1047         rpsi2   = 1.22_wp
1048         !
1049         SELECT CASE ( nn_stab_func )
1050         CASE( 0, 1 )   ;   rpsi3m = 0.1_wp         ! G88 or KC stability functions
1051         CASE( 2 )      ;   rpsi3m = 0.05_wp        ! Canuto A stability functions
1052         CASE( 3 )      ;   rpsi3m = 0.05_wp        ! Canuto B stability functions caution : constant not identified)
1053         END SELECT
1054         !
1055      END SELECT
1056
1057      !
1058      SELECT CASE ( nn_stab_func )     !* set the parameters of the stability functions
1059      !
1060      CASE ( 0 )                             ! Galperin stability functions
1061         !
1062         IF(lwp) WRITE(numout,*) 'Stability functions from Galperin'
1063         rc2     =  0._wp
1064         rc3     =  0._wp
1065         rc_diff =  1._wp
1066         rc0     =  0.5544_wp
1067         rcm_sf  =  0.9884_wp
1068         rghmin  = -0.28_wp
1069         rgh0    =  0.0233_wp
1070         rghcri  =  0.02_wp
1071         !
1072      CASE ( 1 )                             ! Kantha-Clayson stability functions
1073         !
1074         IF(lwp) WRITE(numout,*) 'Stability functions from Kantha-Clayson'
1075         rc2     =  0.7_wp
1076         rc3     =  0.2_wp
1077         rc_diff =  1._wp
1078         rc0     =  0.5544_wp
1079         rcm_sf  =  0.9884_wp
1080         rghmin  = -0.28_wp
1081         rgh0    =  0.0233_wp
1082         rghcri  =  0.02_wp
1083         !
1084      CASE ( 2 )                             ! Canuto A stability functions
1085         !
1086         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto A'
1087         rs0 = 1.5_wp * rl1 * rl5*rl5
1088         rs1 = -rl4*(rl6+rl7) + 2._wp*rl4*rl5*(rl1-(1._wp/3._wp)*rl2-rl3) + 1.5_wp*rl1*rl5*rl8
1089         rs2 = -(3._wp/8._wp) * rl1*(rl6*rl6-rl7*rl7)
1090         rs4 = 2._wp * rl5
1091         rs5 = 2._wp * rl4
1092         rs6 = (2._wp/3._wp) * rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.5_wp * rl5*rl1 * (3._wp*rl3-rl2)   &
1093            &                                                    + 0.75_wp * rl1 * ( rl6 - rl7 )
1094         rd0 = 3._wp * rl5*rl5
1095         rd1 = rl5 * ( 7._wp*rl4 + 3._wp*rl8 )
1096         rd2 = rl5*rl5 * ( 3._wp*rl3*rl3 - rl2*rl2 ) - 0.75_wp*(rl6*rl6 - rl7*rl7 )
1097         rd3 = rl4 * ( 4._wp*rl4 + 3._wp*rl8)
1098         rd4 = rl4 * ( rl2 * rl6 - 3._wp*rl3*rl7 - rl5*(rl2*rl2 - rl3*rl3 ) ) + rl5*rl8 * ( 3._wp*rl3*rl3 - rl2*rl2 )
1099         rd5 = 0.25_wp * ( rl2*rl2 - 3._wp *rl3*rl3 ) * ( rl6*rl6 - rl7*rl7 )
1100         rc0 = 0.5268_wp
1101         rf6 = 8._wp / (rc0**6._wp)
1102         rc_diff = SQRT(2._wp) / (rc0**3._wp)
1103         rcm_sf  =  0.7310_wp
1104         rghmin  = -0.28_wp
1105         rgh0    =  0.0329_wp
1106         rghcri  =  0.03_wp
1107         !
1108      CASE ( 3 )                             ! Canuto B stability functions
1109         !
1110         IF(lwp) WRITE(numout,*) 'Stability functions from Canuto B'
1111         rs0 = 1.5_wp * rm1 * rm5*rm5
1112         rs1 = -rm4 * (rm6+rm7) + 2._wp * rm4*rm5*(rm1-(1._wp/3._wp)*rm2-rm3) + 1.5_wp * rm1*rm5*rm8
1113         rs2 = -(3._wp/8._wp) * rm1 * (rm6*rm6-rm7*rm7 )
1114         rs4 = 2._wp * rm5
1115         rs5 = 2._wp * rm4
1116         rs6 = (2._wp/3._wp) * rm5 * (3._wp*rm3*rm3-rm2*rm2) - 0.5_wp * rm5*rm1*(3._wp*rm3-rm2) + 0.75_wp * rm1*(rm6-rm7)
1117         rd0 = 3._wp * rm5*rm5
1118         rd1 = rm5 * (7._wp*rm4 + 3._wp*rm8)
1119         rd2 = rm5*rm5 * (3._wp*rm3*rm3 - rm2*rm2) - 0.75_wp * (rm6*rm6 - rm7*rm7)
1120         rd3 = rm4 * ( 4._wp*rm4 + 3._wp*rm8 )
1121         rd4 = rm4 * ( rm2*rm6 -3._wp*rm3*rm7 - rm5*(rm2*rm2 - rm3*rm3) ) + rm5 * rm8 * ( 3._wp*rm3*rm3 - rm2*rm2 )
1122         rd5 = 0.25_wp * ( rm2*rm2 - 3._wp*rm3*rm3 ) * ( rm6*rm6 - rm7*rm7 )
1123         rc0 = 0.5268_wp            !!       rc0 = 0.5540_wp (Warner ...) to verify !
1124         rf6 = 8._wp / ( rc0**6._wp )
1125         rc_diff = SQRT(2._wp)/(rc0**3.)
1126         rcm_sf  =  0.7470_wp
1127         rghmin  = -0.28_wp
1128         rgh0    =  0.0444_wp
1129         rghcri  =  0.0414_wp
1130         !
1131      END SELECT
1132   
1133      !                                !* Set Schmidt number for psi diffusion in the wave breaking case
1134      !                                     ! See Eq. (13) of Carniel et al, OM, 30, 225-239, 2009
1135      !                                     !  or Eq. (17) of Burchard, JPO, 31, 3133-3145, 2001
1136      IF( ln_sigpsi .AND. ln_crban ) THEN
1137         zcr = SQRT( 1.5_wp*rsc_tke ) * rcm_sf / vkarmn
1138         rsc_psi0 = vkarmn*vkarmn / ( rpsi2 * rcm_sf*rcm_sf )                       & 
1139        &         * ( rnn*rnn - 4._wp/3._wp * zcr*rnn*rmm - 1._wp/3._wp * zcr*rnn   &
1140        &           + 2._wp/9._wp * rmm * zcr*zcr + 4._wp/9._wp * zcr*zcr * rmm*rmm )                                 
1141      ELSE
1142         rsc_psi0 = rsc_psi
1143      ENDIF
1144 
1145      !                                !* Shear free turbulence parameters
1146      !
1147      ra_sf  = -4._wp * rnn * SQRT( rsc_tke ) / ( (1._wp+4._wp*rmm) * SQRT( rsc_tke )   &
1148         &                                      - SQRT(rsc_tke + 24._wp*rsc_psi0*rpsi2 ) )
1149      rl_sf  = rc0 * SQRT( rc0 / rcm_sf )                                                                   &
1150         &         * SQRT(  (  (1._wp + 4._wp*rmm + 8._wp*rmm*rmm) * rsc_tke                                &
1151         &                   + 12._wp * rsc_psi0 * rpsi2                                                    &
1152         &                   - (1._wp + 4._wp*rmm) * SQRT( rsc_tke*(rsc_tke+ 24._wp*rsc_psi0*rpsi2) )  )    &
1153         &                / ( 12._wp*rnn*rnn )                                                              )
1154
1155      !
1156      IF(lwp) THEN                     !* Control print
1157         WRITE(numout,*)
1158         WRITE(numout,*) 'Limit values'
1159         WRITE(numout,*) '~~~~~~~~~~~~'
1160         WRITE(numout,*) 'Parameter  m = ',rmm
1161         WRITE(numout,*) 'Parameter  n = ',rnn
1162         WRITE(numout,*) 'Parameter  p = ',rpp
1163         WRITE(numout,*) 'rpsi1   = ',rpsi1
1164         WRITE(numout,*) 'rpsi2   = ',rpsi2
1165         WRITE(numout,*) 'rpsi3m  = ',rpsi3m
1166         WRITE(numout,*) 'rpsi3p  = ',rpsi3p
1167         WRITE(numout,*) 'rsc_tke = ',rsc_tke
1168         WRITE(numout,*) 'rsc_psi = ',rsc_psi
1169         WRITE(numout,*) 'rsc_psi0 = ',rsc_psi0
1170         WRITE(numout,*) 'rc0     = ',rc0
1171         WRITE(numout,*)
1172         WRITE(numout,*) 'Shear free turbulence parameters:'
1173         WRITE(numout,*) 'rcm_sf  = ',rcm_sf
1174         WRITE(numout,*) 'ra_sf   = ',ra_sf
1175         WRITE(numout,*) 'rl_sf   = ',rl_sf
1176         WRITE(numout,*)
1177      ENDIF
1178
1179      !                                !* Constants initialization
1180      rc02  = rc0  * rc0   ;   rc02r = 1. / rc02
1181      rc03  = rc02 * rc0
1182      rc04  = rc03 * rc0
1183      rc03_sqrt2_galp = rc03 / SQRT(2._wp) / rn_clim_galp
1184      rsbc_mb   = 0.5_wp * (15.8_wp*rn_crban)**(2._wp/3._wp)               ! Surf. bound. cond. from Mellor and Blumberg
1185      rsbc_std  = 3.75_wp                                                  ! Surf. bound. cond. standard (prod=diss)
1186      rsbc_tke1 = (-rsc_tke*rn_crban/(rcm_sf*ra_sf*rl_sf))**(2._wp/3._wp)  ! k_eps = 53.  Dirichlet + Wave breaking
1187      rsbc_tke2 = 0.5_wp / rau0
1188      rsbc_tke3 = rdt * rn_crban                                                         ! Neumann + Wave breaking
1189      rsbc_zs   = rn_charn / grav                                                        ! Charnock formula
1190      rsbc_psi1 = rc0**rpp * rsbc_tke1**rmm * rl_sf**rnn                           ! Dirichlet + Wave breaking
1191      rsbc_psi2 = -0.5_wp * rdt * rc0**rpp * rnn * vkarmn**rnn / rsc_psi                   ! Neumann + NO Wave breaking
1192      rsbc_psi3 = -0.5_wp * rdt * rc0**rpp * rl_sf**rnn / rsc_psi  * (rnn + rmm*ra_sf) ! Neumann + Wave breaking
1193      rfact_tke = -0.5_wp / rsc_tke * rdt               ! Cst used for the Diffusion term of tke
1194      rfact_psi = -0.5_wp / rsc_psi * rdt               ! Cst used for the Diffusion term of tke
1195
1196      !                                !* Wall proximity function
1197      zwall (:,:,:) = 1._wp * tmask(:,:,:)
1198
1199      !                                !* set vertical eddy coef. to the background value
1200      DO jk = 1, jpk
1201         avt (:,:,jk) = avtb(jk) * tmask(:,:,jk)
1202         avm (:,:,jk) = avmb(jk) * tmask(:,:,jk)
1203         avmu(:,:,jk) = avmb(jk) * umask(:,:,jk)
1204         avmv(:,:,jk) = avmb(jk) * vmask(:,:,jk)
1205      END DO
1206      !                             
1207      CALL gls_rst( nit000, 'READ' )   !* read or initialize all required files
1208      !
1209      IF( nn_timing == 1 )  CALL timing_stop('zdf_gls_init')
1210      !
1211   END SUBROUTINE zdf_gls_init
1212
1213
1214   SUBROUTINE gls_rst( kt, cdrw )
1215      !!---------------------------------------------------------------------
1216      !!                   ***  ROUTINE ts_rst  ***
1217      !!                     
1218      !! ** Purpose :   Read or write TKE file (en) in restart file
1219      !!
1220      !! ** Method  :   use of IOM library
1221      !!                if the restart does not contain TKE, en is either
1222      !!                set to rn_emin or recomputed (nn_igls/=0)
1223      !!----------------------------------------------------------------------
1224      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1225      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1226      !
1227      INTEGER ::   jit, jk   ! dummy loop indices
1228      INTEGER ::   id1, id2, id3, id4, id5, id6
1229      INTEGER ::   ji, jj, ikbu, ikbv
1230      REAL(wp)::   cbx, cby
1231      !!----------------------------------------------------------------------
1232      !
1233      IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
1234         !                                   ! ---------------
1235         IF( ln_rstart ) THEN                   !* Read the restart file
1236            id1 = iom_varid( numror, 'en'   , ldstop = .FALSE. )
1237            id2 = iom_varid( numror, 'avt'  , ldstop = .FALSE. )
1238            id3 = iom_varid( numror, 'avm'  , ldstop = .FALSE. )
1239            id4 = iom_varid( numror, 'avmu' , ldstop = .FALSE. )
1240            id5 = iom_varid( numror, 'avmv' , ldstop = .FALSE. )
1241            id6 = iom_varid( numror, 'mxln' , ldstop = .FALSE. )
1242            !
1243            IF( MIN( id1, id2, id3, id4, id5, id6 ) > 0 ) THEN        ! all required arrays exist
1244               CALL iom_get( numror, jpdom_autoglo, 'en'    , en     )
1245               CALL iom_get( numror, jpdom_autoglo, 'avt'   , avt    )
1246               CALL iom_get( numror, jpdom_autoglo, 'avm'   , avm    )
1247               CALL iom_get( numror, jpdom_autoglo, 'avmu'  , avmu   )
1248               CALL iom_get( numror, jpdom_autoglo, 'avmv'  , avmv   )
1249               CALL iom_get( numror, jpdom_autoglo, 'mxln'  , mxln   )
1250            ELSE                       
1251               IF(lwp) WRITE(numout,*) ' ===>>>> : previous run without gls scheme, en and mxln computed by iterative loop'
1252               en  (:,:,:) = rn_emin
1253               mxln(:,:,:) = 0.001       
1254               DO jit = nit000 + 1, nit000 + 10   ;   CALL zdf_gls( jit )   ;   END DO
1255            ENDIF
1256         ELSE                                   !* Start from rest
1257            IF(lwp) WRITE(numout,*) ' ===>>>> : Initialisation of en and mxln by background values'
1258            en  (:,:,:) = rn_emin
1259            mxln(:,:,:) = 0.001       
1260         ENDIF
1261         !
1262      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
1263         !                                   ! -------------------
1264         IF(lwp) WRITE(numout,*) '---- gls-rst ----'
1265         CALL iom_rstput( kt, nitrst, numrow, 'en'   , en     )
1266         CALL iom_rstput( kt, nitrst, numrow, 'avt'  , avt_k  )
1267         CALL iom_rstput( kt, nitrst, numrow, 'avm'  , avm_k  )
1268         CALL iom_rstput( kt, nitrst, numrow, 'avmu' , avmu_k )
1269         CALL iom_rstput( kt, nitrst, numrow, 'avmv' , avmv_k )
1270         CALL iom_rstput( kt, nitrst, numrow, 'mxln' , mxln   )
1271         !
1272      ENDIF
1273      !
1274   END SUBROUTINE gls_rst
1275
1276#else
1277   !!----------------------------------------------------------------------
1278   !!   Dummy module :                                        NO TKE scheme
1279   !!----------------------------------------------------------------------
1280   LOGICAL, PUBLIC, PARAMETER ::   lk_zdfgls = .FALSE.   !: TKE flag
1281CONTAINS
1282   SUBROUTINE zdf_gls_init           ! Empty routine
1283      WRITE(*,*) 'zdf_gls_init: You should not have seen this print! error?'
1284   END SUBROUTINE zdf_gls_init
1285   SUBROUTINE zdf_gls( kt )          ! Empty routine
1286      WRITE(*,*) 'zdf_gls: You should not have seen this print! error?', kt
1287   END SUBROUTINE zdf_gls
1288   SUBROUTINE gls_rst( kt, cdrw )          ! Empty routine
1289      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
1290      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
1291      WRITE(*,*) 'gls_rst: You should not have seen this print! error?', kt, cdrw
1292   END SUBROUTINE gls_rst
1293#endif
1294
1295   !!======================================================================
1296END MODULE zdfgls
1297
Note: See TracBrowser for help on using the repository browser.