| 1 | MODULE sbcmod |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE sbcmod *** |
|---|
| 4 | !! Surface module : provide to the ocean its surface boundary condition |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 3.0 ! 2006-07 (G. Madec) Original code |
|---|
| 7 | !! 3.1 ! 2008-08 (S. Masson, A. Caubel, E. Maisonnave, G. Madec) coupled interface |
|---|
| 8 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 9 | !! 3.3 ! 2010-10 (S. Masson) add diurnal cycle |
|---|
| 10 | !! 3.3 ! 2010-09 (D. Storkey) add ice boundary conditions (BDY) |
|---|
| 11 | !! - ! 2010-11 (G. Madec) ice-ocean stress always computed at each ocean time-step |
|---|
| 12 | !! - ! 2010-10 (J. Chanut, C. Bricaud, G. Madec) add the surface pressure forcing |
|---|
| 13 | !! 3.4 ! 2011-11 (C. Harris) CICE added as an option |
|---|
| 14 | !! 3.5 ! 2012-11 (A. Coward, G. Madec) Rethink of heat, mass and salt surface fluxes |
|---|
| 15 | !!---------------------------------------------------------------------- |
|---|
| 16 | |
|---|
| 17 | !!---------------------------------------------------------------------- |
|---|
| 18 | !! sbc_init : read namsbc namelist |
|---|
| 19 | !! sbc : surface ocean momentum, heat and freshwater boundary conditions |
|---|
| 20 | !!---------------------------------------------------------------------- |
|---|
| 21 | USE oce ! ocean dynamics and tracers |
|---|
| 22 | USE dom_oce ! ocean space and time domain |
|---|
| 23 | USE phycst ! physical constants |
|---|
| 24 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 25 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 26 | USE sbcdcy ! surface boundary condition: diurnal cycle |
|---|
| 27 | USE sbcssm ! surface boundary condition: sea-surface mean variables |
|---|
| 28 | USE sbcapr ! surface boundary condition: atmospheric pressure |
|---|
| 29 | USE sbcana ! surface boundary condition: analytical formulation |
|---|
| 30 | USE sbcflx ! surface boundary condition: flux formulation |
|---|
| 31 | USE sbcblk_clio ! surface boundary condition: bulk formulation : CLIO |
|---|
| 32 | USE sbcblk_core ! surface boundary condition: bulk formulation : CORE |
|---|
| 33 | USE sbcblk_mfs ! surface boundary condition: bulk formulation : MFS |
|---|
| 34 | USE sbcice_if ! surface boundary condition: ice-if sea-ice model |
|---|
| 35 | USE sbcice_lim ! surface boundary condition: LIM 3.0 sea-ice model |
|---|
| 36 | USE sbcice_lim_2 ! surface boundary condition: LIM 2.0 sea-ice model |
|---|
| 37 | USE sbcice_cice ! surface boundary condition: CICE sea-ice model |
|---|
| 38 | USE sbccpl ! surface boundary condition: coupled florulation |
|---|
| 39 | USE cpl_oasis3, ONLY:lk_cpl ! are we in coupled mode? |
|---|
| 40 | USE sbcssr ! surface boundary condition: sea surface restoring |
|---|
| 41 | USE sbcrnf ! surface boundary condition: runoffs |
|---|
| 42 | USE sbcfwb ! surface boundary condition: freshwater budget |
|---|
| 43 | USE closea ! closed sea |
|---|
| 44 | USE icbstp ! Icebergs! |
|---|
| 45 | |
|---|
| 46 | USE prtctl ! Print control (prt_ctl routine) |
|---|
| 47 | USE iom ! IOM library |
|---|
| 48 | USE in_out_manager ! I/O manager |
|---|
| 49 | USE lib_mpp ! MPP library |
|---|
| 50 | USE timing ! Timing |
|---|
| 51 | USE sbcwave ! Wave module |
|---|
| 52 | |
|---|
| 53 | IMPLICIT NONE |
|---|
| 54 | PRIVATE |
|---|
| 55 | |
|---|
| 56 | PUBLIC sbc ! routine called by step.F90 |
|---|
| 57 | PUBLIC sbc_init ! routine called by opa.F90 |
|---|
| 58 | |
|---|
| 59 | INTEGER :: nsbc ! type of surface boundary condition (deduced from namsbc informations) |
|---|
| 60 | |
|---|
| 61 | !! * Substitutions |
|---|
| 62 | # include "domzgr_substitute.h90" |
|---|
| 63 | !!---------------------------------------------------------------------- |
|---|
| 64 | !! NEMO/OPA 4.0 , NEMO-consortium (2011) |
|---|
| 65 | !! $Id$ |
|---|
| 66 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 67 | !!---------------------------------------------------------------------- |
|---|
| 68 | CONTAINS |
|---|
| 69 | |
|---|
| 70 | SUBROUTINE sbc_init |
|---|
| 71 | !!--------------------------------------------------------------------- |
|---|
| 72 | !! *** ROUTINE sbc_init *** |
|---|
| 73 | !! |
|---|
| 74 | !! ** Purpose : Initialisation of the ocean surface boundary computation |
|---|
| 75 | !! |
|---|
| 76 | !! ** Method : Read the namsbc namelist and set derived parameters |
|---|
| 77 | !! Call init routines for all other SBC modules that have one |
|---|
| 78 | !! |
|---|
| 79 | !! ** Action : - read namsbc parameters |
|---|
| 80 | !! - nsbc: type of sbc |
|---|
| 81 | !!---------------------------------------------------------------------- |
|---|
| 82 | INTEGER :: icpt ! local integer |
|---|
| 83 | !! |
|---|
| 84 | NAMELIST/namsbc/ nn_fsbc , ln_ana , ln_flx, ln_blk_clio, ln_blk_core, ln_cpl, & |
|---|
| 85 | & ln_blk_mfs, ln_apr_dyn, nn_ice, nn_ice_embd, ln_dm2dc , ln_rnf, & |
|---|
| 86 | & ln_ssr , nn_fwb , ln_cdgw , ln_wave , ln_sdw, ln_tauoc, & |
|---|
| 87 | & nn_lsm, cn_iceflx |
|---|
| 88 | INTEGER :: ios |
|---|
| 89 | !!---------------------------------------------------------------------- |
|---|
| 90 | |
|---|
| 91 | IF(lwp) THEN |
|---|
| 92 | WRITE(numout,*) |
|---|
| 93 | WRITE(numout,*) 'sbc_init : surface boundary condition setting' |
|---|
| 94 | WRITE(numout,*) '~~~~~~~~ ' |
|---|
| 95 | ENDIF |
|---|
| 96 | |
|---|
| 97 | REWIND( numnam_ref ) ! Namelist namsbc in reference namelist : Surface boundary |
|---|
| 98 | READ ( numnam_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 99 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist', lwp ) |
|---|
| 100 | |
|---|
| 101 | REWIND( numnam_cfg ) ! Namelist namsbc in configuration namelist : Parameters of the run |
|---|
| 102 | READ ( numnam_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 103 | 902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist', lwp ) |
|---|
| 104 | IF(lwm) WRITE ( numond, namsbc ) |
|---|
| 105 | |
|---|
| 106 | ! ! overwrite namelist parameter using CPP key information |
|---|
| 107 | IF( Agrif_Root() ) THEN ! AGRIF zoom |
|---|
| 108 | IF( lk_lim2 ) nn_ice = 2 |
|---|
| 109 | IF( lk_lim3 ) nn_ice = 3 |
|---|
| 110 | IF( lk_cice ) nn_ice = 4 |
|---|
| 111 | ENDIF |
|---|
| 112 | IF( cp_cfg == 'gyre' ) THEN ! GYRE configuration |
|---|
| 113 | ln_ana = .TRUE. |
|---|
| 114 | nn_ice = 0 |
|---|
| 115 | ENDIF |
|---|
| 116 | |
|---|
| 117 | IF(lwp) THEN ! Control print |
|---|
| 118 | WRITE(numout,*) ' Namelist namsbc (partly overwritten with CPP key setting)' |
|---|
| 119 | WRITE(numout,*) ' frequency update of sbc (and ice) nn_fsbc = ', nn_fsbc |
|---|
| 120 | WRITE(numout,*) ' Type of sbc : ' |
|---|
| 121 | WRITE(numout,*) ' analytical formulation ln_ana = ', ln_ana |
|---|
| 122 | WRITE(numout,*) ' flux formulation ln_flx = ', ln_flx |
|---|
| 123 | WRITE(numout,*) ' CLIO bulk formulation ln_blk_clio = ', ln_blk_clio |
|---|
| 124 | WRITE(numout,*) ' CORE bulk formulation ln_blk_core = ', ln_blk_core |
|---|
| 125 | WRITE(numout,*) ' MFS bulk formulation ln_blk_mfs = ', ln_blk_mfs |
|---|
| 126 | WRITE(numout,*) ' coupled formulation (T if key_sbc_cpl) ln_cpl = ', ln_cpl |
|---|
| 127 | WRITE(numout,*) ' Flux handling over ice categories cn_iceflx = ', TRIM (cn_iceflx) |
|---|
| 128 | WRITE(numout,*) ' Misc. options of sbc : ' |
|---|
| 129 | WRITE(numout,*) ' Patm gradient added in ocean & ice Eqs. ln_apr_dyn = ', ln_apr_dyn |
|---|
| 130 | WRITE(numout,*) ' ice management in the sbc (=0/1/2/3) nn_ice = ', nn_ice |
|---|
| 131 | WRITE(numout,*) ' ice-ocean embedded/levitating (=0/1/2) nn_ice_embd = ', nn_ice_embd |
|---|
| 132 | WRITE(numout,*) ' daily mean to diurnal cycle qsr ln_dm2dc = ', ln_dm2dc |
|---|
| 133 | WRITE(numout,*) ' runoff / runoff mouths ln_rnf = ', ln_rnf |
|---|
| 134 | WRITE(numout,*) ' Sea Surface Restoring on SST and/or SSS ln_ssr = ', ln_ssr |
|---|
| 135 | WRITE(numout,*) ' FreshWater Budget control (=0/1/2) nn_fwb = ', nn_fwb |
|---|
| 136 | WRITE(numout,*) ' closed sea (=0/1) (set in namdom) nn_closea = ', nn_closea |
|---|
| 137 | WRITE(numout,*) ' n. of iterations if land-sea-mask applied nn_lsm = ', nn_lsm |
|---|
| 138 | ENDIF |
|---|
| 139 | |
|---|
| 140 | ! Flux handling over ice categories |
|---|
| 141 | #if defined key_coupled |
|---|
| 142 | SELECT CASE ( TRIM (cn_iceflx)) |
|---|
| 143 | CASE ('ave') |
|---|
| 144 | ln_iceflx_ave = .TRUE. |
|---|
| 145 | ln_iceflx_linear = .FALSE. |
|---|
| 146 | CASE ('linear') |
|---|
| 147 | ln_iceflx_ave = .FALSE. |
|---|
| 148 | ln_iceflx_linear = .TRUE. |
|---|
| 149 | CASE default |
|---|
| 150 | ln_iceflx_ave = .FALSE. |
|---|
| 151 | ln_iceflx_linear = .FALSE. |
|---|
| 152 | END SELECT |
|---|
| 153 | IF(lwp) WRITE(numout,*) ' Fluxes averaged over all ice categories ln_iceflx_ave = ', ln_iceflx_ave |
|---|
| 154 | IF(lwp) WRITE(numout,*) ' Fluxes distributed linearly over ice categories ln_iceflx_linear = ', ln_iceflx_linear |
|---|
| 155 | #endif |
|---|
| 156 | ! |
|---|
| 157 | #if defined key_top && ! defined key_offline |
|---|
| 158 | ltrcdm2dc = (ln_dm2dc .AND. ln_blk_core .AND. nn_ice==2) |
|---|
| 159 | IF( ltrcdm2dc )THEN |
|---|
| 160 | IF(lwp)THEN |
|---|
| 161 | WRITE(numout,*)"analytical diurnal cycle, core bulk formulation and LIM2 use: " |
|---|
| 162 | WRITE(numout,*)"Diurnal cycle on physics but not in passive tracers" |
|---|
| 163 | ENDIF |
|---|
| 164 | ENDIF |
|---|
| 165 | #else |
|---|
| 166 | ltrcdm2dc = .FALSE. |
|---|
| 167 | #endif |
|---|
| 168 | |
|---|
| 169 | ! |
|---|
| 170 | ! ! allocate sbc arrays |
|---|
| 171 | IF( sbc_oce_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_oce arrays' ) |
|---|
| 172 | |
|---|
| 173 | ! ! Checks: |
|---|
| 174 | IF( .NOT. ln_rnf ) THEN ! no specific treatment in vicinity of river mouths |
|---|
| 175 | ln_rnf_mouth = .false. |
|---|
| 176 | IF( sbc_rnf_alloc() /= 0 ) CALL ctl_stop( 'STOP', 'sbc_init : unable to allocate sbc_rnf arrays' ) |
|---|
| 177 | nkrnf = 0 |
|---|
| 178 | rnf (:,:) = 0.0_wp |
|---|
| 179 | rnf_b (:,:) = 0.0_wp |
|---|
| 180 | rnfmsk (:,:) = 0.0_wp |
|---|
| 181 | rnfmsk_z(:) = 0.0_wp |
|---|
| 182 | ENDIF |
|---|
| 183 | IF( nn_ice == 0 ) fr_i(:,:) = 0.e0 ! no ice in the domain, ice fraction is always zero |
|---|
| 184 | |
|---|
| 185 | sfx(:,:) = 0.0_wp ! the salt flux due to freezing/melting will be computed (i.e. will be non-zero) |
|---|
| 186 | ! only if sea-ice is present |
|---|
| 187 | |
|---|
| 188 | fmmflx(:,:) = 0.0_wp ! freezing-melting array initialisation |
|---|
| 189 | |
|---|
| 190 | taum(:,:) = 0.0_wp ! Initialise taum for use in gls in case of reduced restart |
|---|
| 191 | |
|---|
| 192 | ! ! restartability |
|---|
| 193 | IF( MOD( nitend - nit000 + 1, nn_fsbc) /= 0 .OR. & |
|---|
| 194 | MOD( nstock , nn_fsbc) /= 0 ) THEN |
|---|
| 195 | WRITE(ctmp1,*) 'experiment length (', nitend - nit000 + 1, ') or nstock (', nstock, & |
|---|
| 196 | & ' is NOT a multiple of nn_fsbc (', nn_fsbc, ')' |
|---|
| 197 | CALL ctl_stop( ctmp1, 'Impossible to properly do model restart' ) |
|---|
| 198 | ENDIF |
|---|
| 199 | ! |
|---|
| 200 | IF( MOD( rday, REAL(nn_fsbc, wp) * rdt ) /= 0 ) & |
|---|
| 201 | & CALL ctl_warn( 'nn_fsbc is NOT a multiple of the number of time steps in a day' ) |
|---|
| 202 | ! |
|---|
| 203 | IF( ( nn_ice == 2 .OR. nn_ice ==3 ) .AND. .NOT.( ln_blk_clio .OR. ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 204 | & CALL ctl_stop( 'LIM sea-ice model requires a bulk formulation or coupled configuration' ) |
|---|
| 205 | IF( nn_ice == 4 .AND. .NOT.( ln_blk_core .OR. lk_cpl ) ) & |
|---|
| 206 | & CALL ctl_stop( 'CICE sea-ice model requires ln_blk_core or lk_cpl' ) |
|---|
| 207 | IF( nn_ice == 4 .AND. lk_agrif ) & |
|---|
| 208 | & CALL ctl_stop( 'CICE sea-ice model not currently available with AGRIF' ) |
|---|
| 209 | IF( ( nn_ice == 3 .OR. nn_ice == 4 ) .AND. nn_ice_embd == 0 ) & |
|---|
| 210 | & CALL ctl_stop( 'LIM3 and CICE sea-ice models require nn_ice_embd = 1 or 2' ) |
|---|
| 211 | #if defined key_coupled |
|---|
| 212 | IF( ln_iceflx_ave .AND. ln_iceflx_linear ) & |
|---|
| 213 | & CALL ctl_stop( ' ln_iceflx_ave and ln_iceflx_linear options are not compatible' ) |
|---|
| 214 | IF( ( nn_ice ==3 .AND. lk_cpl) .AND. .NOT. ( ln_iceflx_ave .OR. ln_iceflx_linear ) ) & |
|---|
| 215 | & CALL ctl_stop( ' With lim3 coupled, either ln_iceflx_ave or ln_iceflx_linear must be set to .TRUE.' ) |
|---|
| 216 | #endif |
|---|
| 217 | IF( ln_dm2dc ) nday_qsr = -1 ! initialisation flag |
|---|
| 218 | |
|---|
| 219 | IF( ln_dm2dc .AND. .NOT.( ln_flx .OR. ln_blk_core ) ) & |
|---|
| 220 | & CALL ctl_stop( 'diurnal cycle into qsr field from daily values requires a flux or core-bulk formulation' ) |
|---|
| 221 | |
|---|
| 222 | IF( ln_dm2dc .AND. ( ( NINT(rday) / ( nn_fsbc * NINT(rdt) ) ) < 8 ) ) & |
|---|
| 223 | & CALL ctl_warn( 'diurnal cycle for qsr: the sampling of the diurnal cycle is too small...' ) |
|---|
| 224 | |
|---|
| 225 | IF ( ln_wave ) THEN |
|---|
| 226 | !Activated wave module but neither drag nor stokes drift activated |
|---|
| 227 | IF ( .NOT.(ln_cdgw .OR. ln_sdw) ) THEN |
|---|
| 228 | CALL ctl_warn( 'Ask for wave coupling but nor drag coefficient (ln_cdgw=F) neither stokes drift activated (ln_sdw=F)' ) |
|---|
| 229 | !drag coefficient read from wave model definable only with mfs bulk formulae and core |
|---|
| 230 | ELSEIF (ln_cdgw .AND. .NOT.(ln_blk_mfs .OR. ln_blk_core) ) THEN |
|---|
| 231 | CALL ctl_stop( 'drag coefficient read from wave model definable only with mfs bulk formulae and core') |
|---|
| 232 | ENDIF |
|---|
| 233 | ELSE |
|---|
| 234 | IF ( ln_cdgw .OR. ln_sdw ) & |
|---|
| 235 | & CALL ctl_stop('Not Activated Wave Module (ln_wave=F) but & |
|---|
| 236 | & asked coupling with drag coefficient (ln_cdgw =T) or Stokes drift (ln_sdw=T) ') |
|---|
| 237 | ENDIF |
|---|
| 238 | |
|---|
| 239 | ! ! Choice of the Surface Boudary Condition (set nsbc) |
|---|
| 240 | icpt = 0 |
|---|
| 241 | IF( ln_ana ) THEN ; nsbc = 1 ; icpt = icpt + 1 ; ENDIF ! analytical formulation |
|---|
| 242 | IF( ln_flx ) THEN ; nsbc = 2 ; icpt = icpt + 1 ; ENDIF ! flux formulation |
|---|
| 243 | IF( ln_blk_clio ) THEN ; nsbc = 3 ; icpt = icpt + 1 ; ENDIF ! CLIO bulk formulation |
|---|
| 244 | IF( ln_blk_core ) THEN ; nsbc = 4 ; icpt = icpt + 1 ; ENDIF ! CORE bulk formulation |
|---|
| 245 | IF( ln_blk_mfs ) THEN ; nsbc = 6 ; icpt = icpt + 1 ; ENDIF ! MFS bulk formulation |
|---|
| 246 | IF( ln_cpl ) THEN ; nsbc = 5 ; icpt = icpt + 1 ; ENDIF ! Coupled formulation |
|---|
| 247 | IF( cp_cfg == 'gyre') THEN ; nsbc = 0 ; ENDIF ! GYRE analytical formulation |
|---|
| 248 | IF( lk_esopa ) nsbc = -1 ! esopa test, ALL formulations |
|---|
| 249 | ! |
|---|
| 250 | IF( icpt /= 1 .AND. .NOT.lk_esopa ) THEN |
|---|
| 251 | WRITE(numout,*) |
|---|
| 252 | WRITE(numout,*) ' E R R O R in setting the sbc, one and only one namelist/CPP key option ' |
|---|
| 253 | WRITE(numout,*) ' must be choosen. You choose ', icpt, ' option(s)' |
|---|
| 254 | WRITE(numout,*) ' We stop' |
|---|
| 255 | nstop = nstop + 1 |
|---|
| 256 | ENDIF |
|---|
| 257 | IF(lwp) THEN |
|---|
| 258 | WRITE(numout,*) |
|---|
| 259 | IF( nsbc == -1 ) WRITE(numout,*) ' ESOPA test All surface boundary conditions' |
|---|
| 260 | IF( nsbc == 0 ) WRITE(numout,*) ' GYRE analytical formulation' |
|---|
| 261 | IF( nsbc == 1 ) WRITE(numout,*) ' analytical formulation' |
|---|
| 262 | IF( nsbc == 2 ) WRITE(numout,*) ' flux formulation' |
|---|
| 263 | IF( nsbc == 3 ) WRITE(numout,*) ' CLIO bulk formulation' |
|---|
| 264 | IF( nsbc == 4 ) WRITE(numout,*) ' CORE bulk formulation' |
|---|
| 265 | IF( nsbc == 5 ) WRITE(numout,*) ' coupled formulation' |
|---|
| 266 | IF( nsbc == 6 ) WRITE(numout,*) ' MFS Bulk formulation' |
|---|
| 267 | ENDIF |
|---|
| 268 | ! |
|---|
| 269 | CALL sbc_ssm_init ! Sea-surface mean fields initialisation |
|---|
| 270 | ! |
|---|
| 271 | IF( ln_ssr ) CALL sbc_ssr_init ! Sea-Surface Restoring initialisation |
|---|
| 272 | ! |
|---|
| 273 | IF( nn_ice == 4 ) CALL cice_sbc_init( nsbc ) ! CICE initialisation |
|---|
| 274 | ! |
|---|
| 275 | END SUBROUTINE sbc_init |
|---|
| 276 | |
|---|
| 277 | |
|---|
| 278 | SUBROUTINE sbc( kt ) |
|---|
| 279 | !!--------------------------------------------------------------------- |
|---|
| 280 | !! *** ROUTINE sbc *** |
|---|
| 281 | !! |
|---|
| 282 | !! ** Purpose : provide at each time-step the ocean surface boundary |
|---|
| 283 | !! condition (momentum, heat and freshwater fluxes) |
|---|
| 284 | !! |
|---|
| 285 | !! ** Method : blah blah to be written ????????? |
|---|
| 286 | !! CAUTION : never mask the surface stress field (tke sbc) |
|---|
| 287 | !! |
|---|
| 288 | !! ** Action : - set the ocean surface boundary condition at before and now |
|---|
| 289 | !! time step, i.e. |
|---|
| 290 | !! utau_b, vtau_b, qns_b, qsr_b, emp_n, sfx_b, qrp_b, erp_b |
|---|
| 291 | !! utau , vtau , qns , qsr , emp , sfx , qrp , erp |
|---|
| 292 | !! - updte the ice fraction : fr_i |
|---|
| 293 | !!---------------------------------------------------------------------- |
|---|
| 294 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 295 | !!--------------------------------------------------------------------- |
|---|
| 296 | ! |
|---|
| 297 | IF( nn_timing == 1 ) CALL timing_start('sbc') |
|---|
| 298 | ! |
|---|
| 299 | ! ! ---------------------------------------- ! |
|---|
| 300 | IF( kt /= nit000 ) THEN ! Swap of forcing fields ! |
|---|
| 301 | ! ! ---------------------------------------- ! |
|---|
| 302 | utau_b(:,:) = utau(:,:) ! Swap the ocean forcing fields |
|---|
| 303 | vtau_b(:,:) = vtau(:,:) ! (except at nit000 where before fields |
|---|
| 304 | qns_b (:,:) = qns (:,:) ! are set at the end of the routine) |
|---|
| 305 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 306 | ! qsr_b (:,:) = qsr (:,:) |
|---|
| 307 | emp_b(:,:) = emp(:,:) |
|---|
| 308 | sfx_b(:,:) = sfx(:,:) |
|---|
| 309 | ENDIF |
|---|
| 310 | ! ! ---------------------------------------- ! |
|---|
| 311 | ! ! forcing field computation ! |
|---|
| 312 | ! ! ---------------------------------------- ! |
|---|
| 313 | ! |
|---|
| 314 | IF( ln_apr_dyn ) CALL sbc_apr( kt ) ! atmospheric pressure provided at kt+0.5*nn_fsbc |
|---|
| 315 | ! (caution called before sbc_ssm) |
|---|
| 316 | ! |
|---|
| 317 | CALL sbc_ssm( kt ) ! ocean sea surface variables (sst_m, sss_m, ssu_m, ssv_m) |
|---|
| 318 | ! ! averaged over nf_sbc time-step |
|---|
| 319 | |
|---|
| 320 | IF (ln_wave) CALL sbc_wave( kt ) |
|---|
| 321 | !== sbc formulation ==! |
|---|
| 322 | |
|---|
| 323 | SELECT CASE( nsbc ) ! Compute ocean surface boundary condition |
|---|
| 324 | ! ! (i.e. utau,vtau, qns, qsr, emp, sfx) |
|---|
| 325 | CASE( 0 ) ; CALL sbc_gyre ( kt ) ! analytical formulation : GYRE configuration |
|---|
| 326 | CASE( 1 ) ; CALL sbc_ana ( kt ) ! analytical formulation : uniform sbc |
|---|
| 327 | CASE( 2 ) ; CALL sbc_flx ( kt ) ! flux formulation |
|---|
| 328 | CASE( 3 ) ; CALL sbc_blk_clio( kt ) ! bulk formulation : CLIO for the ocean |
|---|
| 329 | CASE( 4 ) ; CALL sbc_blk_core( kt ) ! bulk formulation : CORE for the ocean |
|---|
| 330 | CASE( 5 ) ; CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! coupled formulation |
|---|
| 331 | CASE( 6 ) ; CALL sbc_blk_mfs ( kt ) ! bulk formulation : MFS for the ocean |
|---|
| 332 | CASE( -1 ) |
|---|
| 333 | CALL sbc_ana ( kt ) ! ESOPA, test ALL the formulations |
|---|
| 334 | CALL sbc_gyre ( kt ) ! |
|---|
| 335 | CALL sbc_flx ( kt ) ! |
|---|
| 336 | CALL sbc_blk_clio( kt ) ! |
|---|
| 337 | CALL sbc_blk_core( kt ) ! |
|---|
| 338 | CALL sbc_cpl_rcv ( kt, nn_fsbc, nn_ice ) ! |
|---|
| 339 | END SELECT |
|---|
| 340 | IF (ln_wave .AND. ln_tauoc) THEN |
|---|
| 341 | utau(:,:) = utau(:,:)*tauoc_wave(:,:) |
|---|
| 342 | vtau(:,:) = vtau(:,:)*tauoc_wave(:,:) |
|---|
| 343 | taum(:,:) = taum(:,:)*tauoc_wave(:,:) |
|---|
| 344 | ! |
|---|
| 345 | SELECT CASE( nsbc ) |
|---|
| 346 | CASE( 0,1,2,3,5,-1 ) ; |
|---|
| 347 | IF(lwp) WRITE(numout,*) 'WARNING: You are subtracting the wave stress to the ocean. & |
|---|
| 348 | & If not requested select ln_tauoc=.false' |
|---|
| 349 | END SELECT |
|---|
| 350 | ! |
|---|
| 351 | END IF |
|---|
| 352 | ! !== Misc. Options ==! |
|---|
| 353 | |
|---|
| 354 | SELECT CASE( nn_ice ) ! Update heat and freshwater fluxes over sea-ice areas |
|---|
| 355 | CASE( 1 ) ; CALL sbc_ice_if ( kt ) ! Ice-cover climatology ("Ice-if" model) |
|---|
| 356 | CASE( 2 ) ; CALL sbc_ice_lim_2( kt, nsbc ) ! LIM-2 ice model |
|---|
| 357 | CASE( 3 ) ; CALL sbc_ice_lim ( kt, nsbc ) ! LIM-3 ice model |
|---|
| 358 | !is it useful? |
|---|
| 359 | CASE( 4 ) ; CALL sbc_ice_cice ( kt, nsbc ) ! CICE ice model |
|---|
| 360 | END SELECT |
|---|
| 361 | |
|---|
| 362 | IF( ln_icebergs ) CALL icb_stp( kt ) ! compute icebergs |
|---|
| 363 | |
|---|
| 364 | IF( ln_rnf ) CALL sbc_rnf( kt ) ! add runoffs to fresh water fluxes |
|---|
| 365 | |
|---|
| 366 | IF( ln_ssr ) CALL sbc_ssr( kt ) ! add SST/SSS damping term |
|---|
| 367 | |
|---|
| 368 | IF( nn_fwb /= 0 ) CALL sbc_fwb( kt, nn_fwb, nn_fsbc ) ! control the freshwater budget |
|---|
| 369 | |
|---|
| 370 | IF( nn_closea == 1 ) CALL sbc_clo( kt ) ! treatment of closed sea in the model domain |
|---|
| 371 | ! ! (update freshwater fluxes) |
|---|
| 372 | !RBbug do not understand why see ticket 667 |
|---|
| 373 | !clem-bugsal CALL lbc_lnk( emp, 'T', 1. ) |
|---|
| 374 | ! |
|---|
| 375 | IF( kt == nit000 ) THEN ! set the forcing field at nit000 - 1 ! |
|---|
| 376 | ! ! ---------------------------------------- ! |
|---|
| 377 | IF( ln_rstart .AND. & !* Restart: read in restart file |
|---|
| 378 | & iom_varid( numror, 'utau_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 379 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields red in the restart file' |
|---|
| 380 | CALL iom_get( numror, jpdom_autoglo, 'utau_b', utau_b ) ! before i-stress (U-point) |
|---|
| 381 | CALL iom_get( numror, jpdom_autoglo, 'vtau_b', vtau_b ) ! before j-stress (V-point) |
|---|
| 382 | CALL iom_get( numror, jpdom_autoglo, 'qns_b' , qns_b ) ! before non solar heat flux (T-point) |
|---|
| 383 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 384 | ! CALL iom_get( numror, jpdom_autoglo, 'qsr_b' , qsr_b ) ! before solar heat flux (T-point) |
|---|
| 385 | CALL iom_get( numror, jpdom_autoglo, 'emp_b', emp_b ) ! before freshwater flux (T-point) |
|---|
| 386 | ! To ensure restart capability with 3.3x/3.4 restart files !! to be removed in v3.6 |
|---|
| 387 | IF( iom_varid( numror, 'sfx_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 388 | CALL iom_get( numror, jpdom_autoglo, 'sfx_b', sfx_b ) ! before salt flux (T-point) |
|---|
| 389 | ELSE |
|---|
| 390 | sfx_b (:,:) = sfx(:,:) |
|---|
| 391 | ENDIF |
|---|
| 392 | ELSE !* no restart: set from nit000 values |
|---|
| 393 | IF(lwp) WRITE(numout,*) ' nit000-1 surface forcing fields set to nit000' |
|---|
| 394 | utau_b(:,:) = utau(:,:) |
|---|
| 395 | vtau_b(:,:) = vtau(:,:) |
|---|
| 396 | qns_b (:,:) = qns (:,:) |
|---|
| 397 | emp_b (:,:) = emp(:,:) |
|---|
| 398 | sfx_b (:,:) = sfx(:,:) |
|---|
| 399 | ENDIF |
|---|
| 400 | ENDIF |
|---|
| 401 | ! ! ---------------------------------------- ! |
|---|
| 402 | IF( lrst_oce ) THEN ! Write in the ocean restart file ! |
|---|
| 403 | ! ! ---------------------------------------- ! |
|---|
| 404 | IF(lwp) WRITE(numout,*) |
|---|
| 405 | IF(lwp) WRITE(numout,*) 'sbc : ocean surface forcing fields written in ocean restart file ', & |
|---|
| 406 | & 'at it= ', kt,' date= ', ndastp |
|---|
| 407 | IF(lwp) WRITE(numout,*) '~~~~' |
|---|
| 408 | CALL iom_rstput( kt, nitrst, numrow, 'utau_b' , utau ) |
|---|
| 409 | CALL iom_rstput( kt, nitrst, numrow, 'vtau_b' , vtau ) |
|---|
| 410 | CALL iom_rstput( kt, nitrst, numrow, 'qns_b' , qns ) |
|---|
| 411 | ! The 3D heat content due to qsr forcing is treated in traqsr |
|---|
| 412 | ! CALL iom_rstput( kt, nitrst, numrow, 'qsr_b' , qsr ) |
|---|
| 413 | CALL iom_rstput( kt, nitrst, numrow, 'emp_b' , emp ) |
|---|
| 414 | CALL iom_rstput( kt, nitrst, numrow, 'sfx_b' , sfx ) |
|---|
| 415 | ENDIF |
|---|
| 416 | |
|---|
| 417 | ! ! ---------------------------------------- ! |
|---|
| 418 | ! ! Outputs and control print ! |
|---|
| 419 | ! ! ---------------------------------------- ! |
|---|
| 420 | IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN |
|---|
| 421 | CALL iom_put( "empmr" , emp - rnf ) ! upward water flux |
|---|
| 422 | CALL iom_put( "saltflx", sfx ) ! downward salt flux |
|---|
| 423 | ! (includes virtual salt flux beneath ice |
|---|
| 424 | ! in linear free surface case) |
|---|
| 425 | CALL iom_put( "fmmflx", fmmflx ) ! Freezing-melting water flux |
|---|
| 426 | CALL iom_put( "qt" , qns + qsr ) ! total heat flux |
|---|
| 427 | CALL iom_put( "qns" , qns ) ! solar heat flux |
|---|
| 428 | CALL iom_put( "qsr" , qsr ) ! solar heat flux |
|---|
| 429 | IF( nn_ice > 0 ) CALL iom_put( "ice_cover", fr_i ) ! ice fraction |
|---|
| 430 | ENDIF |
|---|
| 431 | ! |
|---|
| 432 | CALL iom_put( "utau", utau ) ! i-wind stress (stress can be updated at |
|---|
| 433 | CALL iom_put( "vtau", vtau ) ! j-wind stress each time step in sea-ice) |
|---|
| 434 | CALL iom_put( "taum", taum ) ! wind stress module |
|---|
| 435 | CALL iom_put( "wspd", wndm ) ! wind speed module |
|---|
| 436 | ! |
|---|
| 437 | IF(ln_ctl) THEN ! print mean trends (used for debugging) |
|---|
| 438 | CALL prt_ctl(tab2d_1=fr_i , clinfo1=' fr_i - : ', mask1=tmask, ovlap=1 ) |
|---|
| 439 | CALL prt_ctl(tab2d_1=(emp-rnf) , clinfo1=' emp-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 440 | CALL prt_ctl(tab2d_1=(sfx-rnf) , clinfo1=' sfx-rnf - : ', mask1=tmask, ovlap=1 ) |
|---|
| 441 | CALL prt_ctl(tab2d_1=qns , clinfo1=' qns - : ', mask1=tmask, ovlap=1 ) |
|---|
| 442 | CALL prt_ctl(tab2d_1=qsr , clinfo1=' qsr - : ', mask1=tmask, ovlap=1 ) |
|---|
| 443 | CALL prt_ctl(tab3d_1=tmask , clinfo1=' tmask - : ', mask1=tmask, ovlap=1, kdim=jpk ) |
|---|
| 444 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_tem), clinfo1=' sst - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 445 | CALL prt_ctl(tab3d_1=tsn(:,:,:,jp_sal), clinfo1=' sss - : ', mask1=tmask, ovlap=1, kdim=1 ) |
|---|
| 446 | CALL prt_ctl(tab2d_1=utau , clinfo1=' utau - : ', mask1=umask, & |
|---|
| 447 | & tab2d_2=vtau , clinfo2=' vtau - : ', mask2=vmask, ovlap=1 ) |
|---|
| 448 | ENDIF |
|---|
| 449 | |
|---|
| 450 | IF( kt == nitend ) CALL sbc_final ! Close down surface module if necessary |
|---|
| 451 | ! |
|---|
| 452 | IF( nn_timing == 1 ) CALL timing_stop('sbc') |
|---|
| 453 | ! |
|---|
| 454 | END SUBROUTINE sbc |
|---|
| 455 | |
|---|
| 456 | |
|---|
| 457 | SUBROUTINE sbc_final |
|---|
| 458 | !!--------------------------------------------------------------------- |
|---|
| 459 | !! *** ROUTINE sbc_final *** |
|---|
| 460 | !! |
|---|
| 461 | !! ** Purpose : Finalize CICE (if used) |
|---|
| 462 | !!--------------------------------------------------------------------- |
|---|
| 463 | ! |
|---|
| 464 | IF( nn_ice == 4 ) CALL cice_sbc_final |
|---|
| 465 | ! |
|---|
| 466 | END SUBROUTINE sbc_final |
|---|
| 467 | |
|---|
| 468 | !!====================================================================== |
|---|
| 469 | END MODULE sbcmod |
|---|
