New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in branches/2014/dev_r5134_UKMO4_CF_compliance/NEMOGCM/NEMO/OPA_SRC/IOM – NEMO

source: branches/2014/dev_r5134_UKMO4_CF_compliance/NEMOGCM/NEMO/OPA_SRC/IOM/restart.F90 @ 5350

Last change on this file since 5350 was 5350, checked in by hadcv, 9 years ago

Update to head of the trunk (r5344).

  • Property svn:keywords set to Id
File size: 14.5 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   rst_opn    : open the ocean restart file
15   !!   rst_write  : write the ocean restart file
16   !!   rst_read   : read the ocean restart file
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers
19   USE dom_oce         ! ocean space and time domain
20   USE phycst          ! physical constants
21   USE in_out_manager  ! I/O manager
22   USE iom             ! I/O module
23   USE eosbn2          ! equation of state            (eos bn2 routine)
24   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
25   USE divcur          ! hor. divergence and curl      (div & cur routines)
26   USE sbc_ice, ONLY : lk_lim3
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   rst_opn         ! routine called by step module
32   PUBLIC   rst_write       ! routine called by step module
33   PUBLIC   rst_read        ! routine called by istate module
34   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
35
36   !! * Substitutions
37#  include "domzgr_substitute.h90"
38#  include "vectopt_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
41   !! $Id$
42   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE rst_opn( kt )
47      !!---------------------------------------------------------------------
48      !!                   ***  ROUTINE rst_opn  ***
49      !!                     
50      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
51      !!              + open the restart when we are one time step before nitrst
52      !!                   - restart header is defined when kt = nitrst-1
53      !!                   - restart data  are written when kt = nitrst
54      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
55      !!----------------------------------------------------------------------
56      INTEGER, INTENT(in) ::   kt     ! ocean time-step
57      !!
58      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
59      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
60      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
61      !!----------------------------------------------------------------------
62      !
63      IF( kt == nit000 ) THEN   ! default definitions
64         lrst_oce = .FALSE.   
65         IF( ln_rst_list ) THEN
66            nrst_lst = 1
67            nitrst = nstocklist( nrst_lst )
68         ELSE
69            nitrst = nitend
70         ENDIF
71      ENDIF
72
73      ! frequency-based restart dumping (nn_stock)
74      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nstock ) == 0 ) THEN   
75         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
76         nitrst = kt + nstock - 1                  ! define the next value of nitrst for restart writing
77         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
78      ENDIF
79      ! to get better performances with NetCDF format:
80      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
81      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
82      IF( kt == nitrst - 1 .OR. nstock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
83         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
84            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
85            IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
86            ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
87            ENDIF
88            ! create the file
89            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
90            clpath = TRIM(cn_ocerst_outdir)
91            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
92            IF(lwp) THEN
93               WRITE(numout,*)
94               SELECT CASE ( jprstlib )
95               CASE ( jprstdimg )   ;   WRITE(numout,*)                            &
96                   '             open ocean restart binary file: ',TRIM(clpath)//clname
97               CASE DEFAULT         ;   WRITE(numout,*)                            &
98                   '             open ocean restart NetCDF file: ',TRIM(clpath)//clname
99               END SELECT
100               IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
101               IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
102               ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
103               ENDIF
104            ENDIF
105            !
106            CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE., kiolib = jprstlib )
107            lrst_oce = .TRUE.
108         ENDIF
109      ENDIF
110      !
111   END SUBROUTINE rst_opn
112
113
114   SUBROUTINE rst_write( kt )
115      !!---------------------------------------------------------------------
116      !!                   ***  ROUTINE rstwrite  ***
117      !!                     
118      !! ** Purpose :   Write restart fields in the format corresponding to jprstlib
119      !!
120      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
121      !!              file, save fields which are necessary for restart
122      !!----------------------------------------------------------------------
123      INTEGER, INTENT(in) ::   kt   ! ocean time-step
124      !!----------------------------------------------------------------------
125
126                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       )   ! dynamics time step
127                     CALL iom_rstput( kt, nitrst, numrow, 'rdttra1', rdttra(1) )   ! surface tracer time step
128
129                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub        )     ! before fields
130                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb        )
131                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem) )
132                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal) )
133                     CALL iom_rstput( kt, nitrst, numrow, 'rotb'   , rotb      )
134                     CALL iom_rstput( kt, nitrst, numrow, 'hdivb'  , hdivb     )
135                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb      )
136                     !
137      IF( lk_lim3 )  CALL iom_rstput( kt, nitrst, numrow, 'fse3t_b', fse3t_b(:,:,:) )
138                     !
139                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un        )     ! now fields
140                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn        )
141                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem) )
142                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal) )
143                     CALL iom_rstput( kt, nitrst, numrow, 'rotn'   , rotn      )
144                     CALL iom_rstput( kt, nitrst, numrow, 'hdivn'  , hdivn     )
145                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn      )
146                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop      )
147#if defined key_zdfkpp
148                     CALL iom_rstput( kt, nitrst, numrow, 'rhd'    , rhd       )
149#endif
150                  IF( lk_lim3 ) THEN
151                     CALL iom_rstput( kt, nitrst, numrow, 'fraqsr_1lev'  , fraqsr_1lev     ) !clem modif
152                  ENDIF
153      IF( kt == nitrst ) THEN
154         CALL iom_close( numrow )     ! close the restart file (only at last time step)
155!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
156!!gm  not sure what to do here   ===>>>  ask to Sebastian
157         lrst_oce = .FALSE.
158            IF( ln_rst_list ) THEN
159               nrst_lst = MIN(nrst_lst + 1, SIZE(nstocklist,1))
160               nitrst = nstocklist( nrst_lst )
161            ENDIF
162            lrst_oce = .FALSE.
163      ENDIF
164      !
165   END SUBROUTINE rst_write
166
167
168   SUBROUTINE rst_read_open
169      !!----------------------------------------------------------------------
170      !!                   ***  ROUTINE rst_read_open  ***
171      !!
172      !! ** Purpose :   Open read files for restart (format fixed by jprstlib )
173      !!
174      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
175      !!                the file has already been opened
176      !!----------------------------------------------------------------------
177      INTEGER        ::   jlibalt = jprstlib
178      LOGICAL        ::   llok
179      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
180      !!----------------------------------------------------------------------
181      !
182      IF( numror <= 0 ) THEN
183         IF(lwp) THEN                                             ! Contol prints
184            WRITE(numout,*)
185            SELECT CASE ( jprstlib )
186            CASE ( jpnf90    )   ;   WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
187            CASE ( jprstdimg )   ;   WRITE(numout,*) 'rst_read : read oce binary restart file'
188            END SELECT
189            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
190            WRITE(numout,*) '~~~~~~~~'
191         ENDIF
192
193         clpath = TRIM(cn_ocerst_indir)
194         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
195         IF ( jprstlib == jprstdimg ) THEN
196           ! eventually read netcdf file (monobloc)  for restarting on different number of processors
197           ! if {cn_ocerst_in}.nc exists, then set jlibalt to jpnf90
198           INQUIRE( FILE = TRIM(cn_ocerst_indir)//'/'//TRIM(cn_ocerst_in)//'.nc', EXIST = llok )
199           IF ( llok ) THEN ; jlibalt = jpnf90  ; ELSE ; jlibalt = jprstlib ; ENDIF
200         ENDIF
201         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror, kiolib = jlibalt )
202      ENDIF
203   END SUBROUTINE rst_read_open
204
205   SUBROUTINE rst_read
206      !!----------------------------------------------------------------------
207      !!                   ***  ROUTINE rst_read  ***
208      !!
209      !! ** Purpose :   Read files for restart (format fixed by jprstlib )
210      !!
211      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
212      !!----------------------------------------------------------------------
213      REAL(wp) ::   zrdt, zrdttra1
214      INTEGER  ::   jk
215      LOGICAL  ::   llok
216      !!----------------------------------------------------------------------
217
218      CALL rst_read_open           ! open restart for reading (if not already opened)
219
220      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
221      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
222         CALL iom_get( numror, 'rdt', zrdt )
223         IF( zrdt /= rdt )   neuler = 0
224      ENDIF
225      IF( iom_varid( numror, 'rdttra1', ldstop = .FALSE. ) > 0 )   THEN
226         CALL iom_get( numror, 'rdttra1', zrdttra1 )
227         IF( zrdttra1 /= rdttra(1) )   neuler = 0
228      ENDIF
229      !
230      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
231         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub      )   ! before fields
232         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb      )
233         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem) )
234         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal) )
235         CALL iom_get( numror, jpdom_autoglo, 'rotb'   , rotb    )
236         CALL iom_get( numror, jpdom_autoglo, 'hdivb'  , hdivb   )
237         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb    )
238         IF( lk_lim3 )   CALL iom_get( numror, jpdom_autoglo, 'fse3t_b', fse3t_b(:,:,:) )
239      ELSE
240         neuler = 0
241      ENDIF
242      !
243      CALL iom_get( numror, jpdom_autoglo, 'un'     , un      )   ! now    fields
244      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn      )
245      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem) )
246      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal) )
247      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn    )
248      IF( iom_varid( numror, 'rotn', ldstop = .FALSE. ) > 0 ) THEN
249         CALL iom_get( numror, jpdom_autoglo, 'rotn'   , rotn    )
250         CALL iom_get( numror, jpdom_autoglo, 'hdivn'  , hdivn   )
251      ELSE
252         CALL div_cur( 0 )                              ! Horizontal divergence & Relative vorticity
253      ENDIF
254      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
255         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop    )   ! now    potential density
256      ELSE
257         CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )   
258      ENDIF
259#if defined key_zdfkpp
260      IF( iom_varid( numror, 'rhd', ldstop = .FALSE. ) > 0 ) THEN
261         CALL iom_get( numror, jpdom_autoglo, 'rhd'    , rhd     )   ! now    in situ density anomaly
262      ELSE
263         CALL eos( tsn, rhd, fsdept_n(:,:,:) )   ! compute rhd
264      ENDIF
265#endif
266      !
267      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
268         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
269         ub   (:,:,:)   = un   (:,:,:)
270         vb   (:,:,:)   = vn   (:,:,:)
271         rotb (:,:,:)   = rotn (:,:,:)
272         hdivb(:,:,:)   = hdivn(:,:,:)
273         sshb (:,:)     = sshn (:,:)
274
275         IF( lk_vvl ) THEN
276            DO jk = 1, jpk
277               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
278            END DO
279         ENDIF
280
281         IF( lk_lim3 .AND. .NOT. lk_vvl ) THEN
282            DO jk = 1, jpk
283               fse3t_b(:,:,jk) = fse3t_n(:,:,jk)
284            END DO
285         ENDIF
286
287      ENDIF
288      !
289      IF( lk_lim3 ) THEN
290         CALL iom_get( numror, jpdom_autoglo, 'fraqsr_1lev' , fraqsr_1lev )
291      ENDIF
292      !
293   END SUBROUTINE rst_read
294
295   !!=====================================================================
296END MODULE restart
Note: See TracBrowser for help on using the repository browser.