New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2014/dev_r5134_UKMO4_CF_compliance/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2014/dev_r5134_UKMO4_CF_compliance/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5350

Last change on this file since 5350 was 5350, checked in by hadcv, 9 years ago

Update to head of the trunk (r5344).

  • Property svn:keywords set to Id
File size: 17.2 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   defined key_ldfslp   ||   defined key_esopa
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and active tracers
22   USE dom_oce         ! ocean space and time domain
23   USE trc_oce         ! share passive tracers/Ocean variables
24   USE zdf_oce         ! ocean vertical physics
25   USE ldftra_oce      ! ocean active tracers: lateral physics
26   USE ldfslp          ! iso-neutral slopes
27   USE diaptr          ! poleward transport diagnostics
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O library
30   USE phycst          ! physical constants
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32   USE wrk_nemo        ! Memory Allocation
33   USE timing          ! Timing
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   tra_ldf_iso   ! routine called by step.F90
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "ldftra_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pgu, pgv,              &
52      &                                pgui, pgvi,                    &
53      &                                ptb, pta, kjpt, pahtb0 )
54      !!----------------------------------------------------------------------
55      !!                  ***  ROUTINE tra_ldf_iso  ***
56      !!
57      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
58      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
59      !!      add it to the general trend of tracer equation.
60      !!
61      !! ** Method  :   The horizontal component of the lateral diffusive trends
62      !!      is provided by a 2nd order operator rotated along neural or geopo-
63      !!      tential surfaces to which an eddy induced advection can be added
64      !!      It is computed using before fields (forward in time) and isopyc-
65      !!      nal or geopotential slopes computed in routine ldfslp.
66      !!
67      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
68      !!      ========    with partial cell update if ln_zps=T.
69      !!
70      !!      2nd part :  horizontal fluxes of the lateral mixing operator
71      !!      ========   
72      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
73      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
74      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
75      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
76      !!      take the horizontal divergence of the fluxes:
77      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
78      !!      Add this trend to the general trend (ta,sa):
79      !!         ta = ta + difft
80      !!
81      !!      3rd part: vertical trends of the lateral mixing operator
82      !!      ========  (excluding the vertical flux proportional to dk[t] )
83      !!      vertical fluxes associated with the rotated lateral mixing:
84      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
85      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
86      !!      take the horizontal divergence of the fluxes:
87      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
88      !!      Add this trend to the general trend (ta,sa):
89      !!         pta = pta + difft
90      !!
91      !! ** Action :   Update pta arrays with the before rotated diffusion
92      !!----------------------------------------------------------------------
93      USE oce     , ONLY:   zftu => ua       , zftv  => va         ! (ua,va) used as workspace
94      !
95      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
96      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
97      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
98      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
99      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv    ! tracer gradient at pstep levels
100      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgui, pgvi   ! tracer gradient at pstep levels
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
104      !
105      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
106      INTEGER  ::  ikt
107      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
108      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
109      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
110      REAL(wp), POINTER, DIMENSION(:,:  ) ::  z2d
111      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdkt, zdk1t, zdit, zdjt, ztfw 
112      !!----------------------------------------------------------------------
113      !
114      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
115      !
116      CALL wrk_alloc( jpi, jpj,      z2d ) 
117      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw, zdkt, zdk1t ) 
118      !
119
120      IF( kt == kit000 )  THEN
121         IF(lwp) WRITE(numout,*)
122         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
123         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
124      ENDIF
125      !
126      !                                                          ! ===========
127      DO jn = 1, kjpt                                            ! tracer loop
128         !                                                       ! ===========
129         !                                               
130         !!----------------------------------------------------------------------
131         !!   I - masked horizontal derivative
132         !!----------------------------------------------------------------------
133         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
134         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
135         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
136         !!end
137
138         ! Horizontal tracer gradient
139         DO jk = 1, jpkm1
140            DO jj = 1, jpjm1
141               DO ji = 1, fs_jpim1   ! vector opt.
142                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
143                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
144               END DO
145            END DO
146         END DO
147
148         ! partial cell correction
149         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
150            DO jj = 1, jpjm1
151               DO ji = 1, fs_jpim1   ! vector opt.
152! IF useless if zpshde defines pgu everywhere
153                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
154                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
155               END DO
156            END DO
157         ENDIF
158         IF( ln_zps .AND. ln_isfcav ) THEN      ! partial steps correction at the first wet level beneath a cavity
159            DO jj = 1, jpjm1
160               DO ji = 1, fs_jpim1   ! vector opt.
161                  IF (miku(ji,jj) > 1) zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
162                  IF (mikv(ji,jj) > 1) zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
163               END DO
164            END DO
165         END IF
166
167         !!----------------------------------------------------------------------
168         !!   II - horizontal trend  (full)
169         !!----------------------------------------------------------------------
170!!!!!!!!!!CDIR PARALLEL DO PRIVATE( zdk1t )
171            ! 1. Vertical tracer gradient at level jk and jk+1
172            ! ------------------------------------------------
173         !
174         ! interior value
175         DO jk = 2, jpkm1               
176            DO jj = 1, jpj
177               DO ji = 1, jpi   ! vector opt.
178                  zdk1t(ji,jj,jk) = ( ptb(ji,jj,jk,jn  ) - ptb(ji,jj,jk+1,jn) ) * wmask(ji,jj,jk+1)
179                  !
180                  zdkt(ji,jj,jk)  = ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn  ) ) * wmask(ji,jj,jk)
181               END DO
182            END DO
183         END DO
184         ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
185         zdk1t(:,:,1) = ( ptb(:,:,1,jn  ) - ptb(:,:,2,jn) ) * wmask(:,:,2)
186         zdkt (:,:,1) = zdk1t(:,:,1)
187         IF ( ln_isfcav ) THEN
188            DO jj = 1, jpj
189               DO ji = 1, jpi   ! vector opt.
190                  ikt = mikt(ji,jj) ! surface level
191                  zdk1t(ji,jj,ikt) = ( ptb(ji,jj,ikt,jn  ) - ptb(ji,jj,ikt+1,jn) ) * wmask(ji,jj,ikt+1)
192                  zdkt (ji,jj,ikt) = zdk1t(ji,jj,ikt)
193               END DO
194            END DO
195         END IF
196
197         ! 2. Horizontal fluxes
198         ! --------------------   
199         DO jk = 1, jpkm1
200            DO jj = 1 , jpjm1
201               DO ji = 1, fs_jpim1   ! vector opt.
202                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * re2u_e1u(ji,jj) * fse3u_n(ji,jj,jk)
203                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * re1v_e2v(ji,jj) * fse3v_n(ji,jj,jk)
204                  !
205                  zmsku = 1. / MAX(  tmask(ji+1,jj,jk  ) + tmask(ji,jj,jk+1)   &
206                     &             + tmask(ji+1,jj,jk+1) + tmask(ji,jj,jk  ), 1. )
207                  !
208                  zmskv = 1. / MAX(  tmask(ji,jj+1,jk  ) + tmask(ji,jj,jk+1)   &
209                     &             + tmask(ji,jj+1,jk+1) + tmask(ji,jj,jk  ), 1. )
210                  !
211                  zcof1 = - fsahtu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
212                  zcof2 = - fsahtv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
213                  !
214                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
215                     &              + zcof1 * (  zdkt (ji+1,jj,jk) + zdk1t(ji,jj,jk)      &
216                     &                         + zdk1t(ji+1,jj,jk) + zdkt (ji,jj,jk)  )  ) * umask(ji,jj,jk)
217                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
218                     &              + zcof2 * (  zdkt (ji,jj+1,jk) + zdk1t(ji,jj,jk)      &
219                     &                         + zdk1t(ji,jj+1,jk) + zdkt (ji,jj,jk)  )  ) * vmask(ji,jj,jk)                 
220               END DO
221            END DO
222
223            ! II.4 Second derivative (divergence) and add to the general trend
224            ! ----------------------------------------------------------------
225            DO jj = 2 , jpjm1
226               DO ji = fs_2, fs_jpim1   ! vector opt.
227                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
228                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
229                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
230               END DO
231            END DO
232            !                                          ! ===============
233         END DO                                        !   End of slab 
234         !                                             ! ===============
235         !
236         ! "Poleward" diffusive heat or salt transports (T-S case only)
237         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
238            ! note sign is reversed to give down-gradient diffusive transports (#1043)
239            IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
240            IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
241         ENDIF
242 
243         IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
244           !
245           IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
246               z2d(:,:) = 0._wp 
247               DO jk = 1, jpkm1
248                  DO jj = 2, jpjm1
249                     DO ji = fs_2, fs_jpim1   ! vector opt.
250                        z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
251                     END DO
252                  END DO
253               END DO
254               z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
255               CALL lbc_lnk( z2d, 'U', -1. )
256               CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
257               !
258               z2d(:,:) = 0._wp 
259               DO jk = 1, jpkm1
260                  DO jj = 2, jpjm1
261                     DO ji = fs_2, fs_jpim1   ! vector opt.
262                        z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
263                     END DO
264                  END DO
265               END DO
266               z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
267               CALL lbc_lnk( z2d, 'V', -1. )
268               CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
269            END IF
270            !
271         ENDIF
272
273         !!----------------------------------------------------------------------
274         !!   III - vertical trend of T & S (extra diagonal terms only)
275         !!----------------------------------------------------------------------
276         
277         ! Local constant initialization
278         ! -----------------------------
279         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
280         
281         ! Vertical fluxes
282         ! ---------------
283         
284         ! Surface and bottom vertical fluxes set to zero
285         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
286         
287         ! interior (2=<jk=<jpk-1)
288         DO jk = 2, jpkm1
289            DO jj = 2, jpjm1
290               DO ji = fs_2, fs_jpim1   ! vector opt.
291                  zcoef0 = - fsahtw(ji,jj,jk) * wmask(ji,jj,jk)
292                  !
293                  zmsku = 1./MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)      &
294                     &            + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk), 1.  )
295                  zmskv = 1./MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)      &
296                     &            + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk), 1.  )
297                  !
298                  zcoef3 = zcoef0 * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)
299                  zcoef4 = zcoef0 * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
300                  !
301                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
302                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
303                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
304                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
305               END DO
306            END DO
307         END DO
308         
309         
310         ! I.5 Divergence of vertical fluxes added to the general tracer trend
311         ! -------------------------------------------------------------------
312         DO jk = 1, jpkm1
313            DO jj = 2, jpjm1
314               DO ji = fs_2, fs_jpim1   ! vector opt.
315                  zbtr = 1.0 / ( e12t(ji,jj) * fse3t_n(ji,jj,jk) )
316                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
317                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
318               END DO
319            END DO
320         END DO
321         !
322      END DO
323      !
324      CALL wrk_dealloc( jpi, jpj, z2d ) 
325      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw, zdkt, zdk1t ) 
326      !
327      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
328      !
329   END SUBROUTINE tra_ldf_iso
330
331#else
332   !!----------------------------------------------------------------------
333   !!   default option :   Dummy code   NO rotation of the diffusive tensor
334   !!----------------------------------------------------------------------
335CONTAINS
336   SUBROUTINE tra_ldf_iso( kt, kit000,cdtype, pgu, pgv, pgui, pgvi, ptb, pta, kjpt, pahtb0 )      ! Empty routine
337      INTEGER:: kt, kit000
338      CHARACTER(len=3) ::   cdtype
339      REAL, DIMENSION(:,:,:) ::   pgu, pgv, pgui, pgvi    ! tracer gradient at pstep levels
340      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
341      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
342         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
343   END SUBROUTINE tra_ldf_iso
344#endif
345
346   !!==============================================================================
347END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.