New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in branches/2014/dev_r5134_UKMO4_CF_compliance/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2014/dev_r5134_UKMO4_CF_compliance/NEMOGCM/NEMO/OPA_SRC/step.F90 @ 5350

Last change on this file since 5350 was 5350, checked in by hadcv, 9 years ago

Update to head of the trunk (r5344).

  • Property svn:keywords set to Id
File size: 23.4 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping    : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!                 !  2012-07  (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs
27   !!            3.7  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!----------------------------------------------------------------------
29
30   !!----------------------------------------------------------------------
31   !!   stp             : OPA system time-stepping
32   !!----------------------------------------------------------------------
33   USE step_oce         ! time stepping definition modules
34   USE iom
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   stp   ! called by opa.F90
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43!!gm   #  include "zdfddm_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.7 , NEMO Consortium (2014)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51#if defined key_agrif
52   SUBROUTINE stp( )
53      INTEGER             ::   kstp   ! ocean time-step index
54#else
55   SUBROUTINE stp( kstp )
56      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
57#endif
58      !!----------------------------------------------------------------------
59      !!                     ***  ROUTINE stp  ***
60      !!
61      !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.)
62      !!              - Time stepping of LIM (dynamic and thermodynamic eqs.)
63      !!              - Tme stepping  of TRC (passive tracer eqs.)
64      !!
65      !! ** Method  : -1- Update forcings and data
66      !!              -2- Update ocean physics
67      !!              -3- Compute the t and s trends
68      !!              -4- Update t and s
69      !!              -5- Compute the momentum trends
70      !!              -6- Update the horizontal velocity
71      !!              -7- Compute the diagnostics variables (rd,N2, div,cur,w)
72      !!              -8- Outputs and diagnostics
73      !!----------------------------------------------------------------------
74      INTEGER ::   jk       ! dummy loop indice
75      INTEGER ::   indic    ! error indicator if < 0
76      INTEGER ::   kcall    ! optional integer argument (dom_vvl_sf_nxt)
77      !! ---------------------------------------------------------------------
78
79#if defined key_agrif
80      kstp = nit000 + Agrif_Nb_Step()
81!      IF ( Agrif_Root() .and. lwp) Write(*,*) '---'
82!      IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp
83      IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE.
84# if defined key_iomput
85      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( "nemo" )
86# endif
87#endif
88                             indic = 0           ! reset to no error condition
89      IF( kstp == nit000 ) THEN
90                      CALL iom_init( "nemo" )      ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
91         IF( ln_crs ) CALL iom_init( "nemo_crs" )  ! initialize context for coarse grid
92      ENDIF
93
94      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
95                             CALL iom_setkt( kstp - nit000 + 1, "nemo"     )   ! say to iom that we are at time step kstp
96      IF( ln_crs     )       CALL iom_setkt( kstp - nit000 + 1, "nemo_crs" )   ! say to iom that we are at time step kstp
97
98      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
99      ! Update data, open boundaries, surface boundary condition (including sea-ice)
100      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
101      IF( lk_tide    )   CALL sbc_tide( kstp )
102      IF( lk_bdy     )   CALL bdy_dta ( kstp, time_offset=+1 )   ! update dynamic & tracer data at open boundaries
103
104                         CALL sbc    ( kstp )         ! Sea Boundary Condition (including sea-ice)
105                                                      ! clem: moved here for bdy ice purpose
106
107      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
108      ! Update stochastic parameters and random T/S fluctuations
109      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
110                        CALL sto_par( kstp )          ! Stochastic parameters
111
112      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
113      ! Ocean physics update                (ua, va, tsa used as workspace)
114      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
115      !  THERMODYNAMICS
116                         CALL eos_rab( tsb, rab_b )       ! before local thermal/haline expension ratio at T-points
117                         CALL eos_rab( tsn, rab_n )       ! now    local thermal/haline expension ratio at T-points
118                         CALL bn2    ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency
119                         CALL bn2    ( tsn, rab_n, rn2  ) ! now    Brunt-Vaisala frequency
120      !
121      !  VERTICAL PHYSICS
122                         CALL zdf_bfr( kstp )         ! bottom friction (if quadratic)
123      !                                               ! Vertical eddy viscosity and diffusivity coefficients
124      IF( lk_zdfric  )   CALL zdf_ric( kstp )            ! Richardson number dependent Kz
125      IF( lk_zdftke  )   CALL zdf_tke( kstp )            ! TKE closure scheme for Kz
126      IF( lk_zdfgls  )   CALL zdf_gls( kstp )            ! GLS closure scheme for Kz
127      IF( lk_zdfkpp  )   CALL zdf_kpp( kstp )            ! KPP closure scheme for Kz
128      IF( lk_zdfcst  ) THEN                              ! Constant Kz (reset avt, avm[uv] to the background value)
129         avt (:,:,:) = rn_avt0 * wmask (:,:,:)
130         avmu(:,:,:) = rn_avm0 * wumask(:,:,:)
131         avmv(:,:,:) = rn_avm0 * wvmask(:,:,:)
132      ENDIF
133      IF( ln_rnf_mouth ) THEN                         ! increase diffusivity at rivers mouths
134         DO jk = 2, nkrnf   ;   avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk)   ;   END DO
135      ENDIF
136      IF( ln_zdfevd  )   CALL zdf_evd( kstp )         ! enhanced vertical eddy diffusivity
137
138      IF( lk_zdftmx  )   CALL zdf_tmx( kstp )         ! tidal vertical mixing
139
140      IF( lk_zdfddm .AND. .NOT. lk_zdfkpp )   &
141         &               CALL zdf_ddm( kstp )         ! double diffusive mixing
142
143                         CALL zdf_mxl( kstp )         ! mixed layer depth
144
145                                                      ! write TKE or GLS information in the restart file
146      IF( lrst_oce .AND. lk_zdftke )   CALL tke_rst( kstp, 'WRITE' )
147      IF( lrst_oce .AND. lk_zdfgls )   CALL gls_rst( kstp, 'WRITE' )
148      !
149      !  LATERAL  PHYSICS
150      !
151      IF( lk_ldfslp ) THEN                            ! slope of lateral mixing
152         IF(ln_sto_eos ) CALL sto_pts( tsn )          ! Random T/S fluctuations
153                         CALL eos( tsb, rhd, gdept_0(:,:,:) )               ! before in situ density
154         IF( ln_zps .AND. .NOT. ln_isfcav)                               &
155            &            CALL zps_hde    ( kstp, jpts, tsb, gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
156            &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
157         IF( ln_zps .AND.       ln_isfcav)                               &
158            &            CALL zps_hde_isf( kstp, jpts, tsb, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
159            &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
160            &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the first ocean level
161         IF( ln_traldf_grif ) THEN                           ! before slope for Griffies operator
162                         CALL ldf_slp_grif( kstp )
163         ELSE
164                         CALL ldf_slp( kstp, rhd, rn2b )     ! before slope for Madec operator
165         ENDIF
166      ENDIF
167#if defined key_traldf_c2d
168      IF( lk_traldf_eiv )   CALL ldf_eiv( kstp )      ! eddy induced velocity coefficient
169#endif
170#if defined key_traldf_c3d && key_traldf_smag
171                          CALL ldf_tra_smag( kstp )      ! eddy induced velocity coefficient
172#  endif
173#if defined key_dynldf_c3d && key_dynldf_smag
174                          CALL ldf_dyn_smag( kstp )      ! eddy induced velocity coefficient
175#  endif
176
177      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
178      !  Ocean dynamics : hdiv, rot, ssh, e3, wn
179      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
180                         CALL ssh_nxt       ( kstp )  ! after ssh (includes call to div_cur)
181      IF( lk_vvl     )   CALL dom_vvl_sf_nxt( kstp )  ! after vertical scale factors
182                         CALL wzv           ( kstp )  ! now cross-level velocity
183
184      IF( lk_dynspg_ts ) THEN 
185          ! In case the time splitting case, update almost all momentum trends here:
186          ! Note that the computation of vertical velocity above, hence "after" sea level
187          ! is necessary to compute momentum advection for the rhs of barotropic loop:
188            IF(ln_sto_eos ) CALL sto_pts( tsn )                             ! Random T/S fluctuations
189                            CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation
190            IF( ln_zps .AND. .NOT. ln_isfcav)                               &
191               &            CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
192               &                                          rhd, gru , grv    )  ! of t, s, rd at the last ocean level
193            IF( ln_zps .AND.       ln_isfcav)                               &
194               &            CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
195               &                                          rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
196               &                                   gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
197
198                                  ua(:,:,:) = 0.e0             ! set dynamics trends to zero
199                                  va(:,:,:) = 0.e0
200          IF(  ln_asmiau .AND. &
201             & ln_dyninc       )  CALL dyn_asm_inc  ( kstp )   ! apply dynamics assimilation increment
202          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! subtract Neptune velocities (simplified)
203          IF( lk_bdy           )  CALL bdy_dyn3d_dmp( kstp )   ! bdy damping trends
204                                  CALL dyn_adv      ( kstp )   ! advection (vector or flux form)
205                                  CALL dyn_vor      ( kstp )   ! vorticity term including Coriolis
206                                  CALL dyn_ldf      ( kstp )   ! lateral mixing
207          IF( ln_neptsimp )       CALL dyn_nept_cor ( kstp )   ! add Neptune velocities (simplified)
208#if defined key_agrif
209          IF(.NOT. Agrif_Root())  CALL Agrif_Sponge_dyn        ! momentum sponge
210#endif
211                                  CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
212                                  CALL dyn_spg( kstp, indic )  ! surface pressure gradient
213
214                                  ua_sv(:,:,:) = ua(:,:,:)     ! Save trends (barotropic trend has been fully updated at this stage)
215                                  va_sv(:,:,:) = va(:,:,:)
216
217                                  CALL div_cur( kstp )         ! Horizontal divergence & Relative vorticity (2nd call in time-split case)
218          IF( lk_vvl     )        CALL dom_vvl_sf_nxt( kstp, kcall=2 )  ! after vertical scale factors (update depth average component)
219                                  CALL wzv           ( kstp )  ! now cross-level velocity
220      ENDIF
221
222      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
223      ! diagnostics and outputs             (ua, va, tsa used as workspace)
224      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
225      IF( lk_floats  )      CALL flo_stp( kstp )         ! drifting Floats
226      IF( lk_diahth  )      CALL dia_hth( kstp )         ! Thermocline depth (20 degres isotherm depth)
227      IF( .NOT. lk_cpl )    CALL dia_fwb( kstp )         ! Fresh water budget diagnostics
228      IF( lk_diadct  )      CALL dia_dct( kstp )         ! Transports
229      IF( lk_diaar5  )      CALL dia_ar5( kstp )         ! ar5 diag
230      IF( lk_diaharm )      CALL dia_harm( kstp )        ! Tidal harmonic analysis
231                            CALL dia_wri( kstp )         ! ocean model: outputs
232      !
233      IF( ln_crs     )      CALL crs_fld( kstp )         ! ocean model: online field coarsening & output
234
235#if defined key_top
236      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
237      ! Passive Tracer Model
238      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
239                         CALL trc_stp( kstp )         ! time-stepping
240#endif
241
242
243      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
244      ! Active tracers                              (ua, va used as workspace)
245      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
246                             tsa(:,:,:,:) = 0.e0            ! set tracer trends to zero
247
248      IF(  ln_asmiau .AND. &
249         & ln_trainc     )   CALL tra_asm_inc( kstp )       ! apply tracer assimilation increment
250                             CALL tra_sbc    ( kstp )       ! surface boundary condition
251      IF( ln_traqsr      )   CALL tra_qsr    ( kstp )       ! penetrative solar radiation qsr
252      IF( ln_trabbc      )   CALL tra_bbc    ( kstp )       ! bottom heat flux
253      IF( lk_trabbl      )   CALL tra_bbl    ( kstp )       ! advective (and/or diffusive) bottom boundary layer scheme
254      IF( ln_tradmp      )   CALL tra_dmp    ( kstp )       ! internal damping trends
255      IF( lk_bdy         )   CALL bdy_tra_dmp( kstp )       ! bdy damping trends
256                             CALL tra_adv    ( kstp )       ! horizontal & vertical advection
257      IF( lk_zdfkpp      )   CALL tra_kpp    ( kstp )       ! KPP non-local tracer fluxes
258                             CALL tra_ldf    ( kstp )       ! lateral mixing
259
260      IF( ln_diaptr      )   CALL dia_ptr                   ! Poleward adv/ldf TRansports diagnostics
261
262#if defined key_agrif
263      IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra          ! tracers sponge
264#endif
265                             CALL tra_zdf    ( kstp )       ! vertical mixing and after tracer fields
266
267      IF( ln_dynhpg_imp  ) THEN                             ! semi-implicit hpg (time stepping then eos)
268         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
269                             CALL tra_nxt( kstp )                ! tracer fields at next time step
270            IF( ln_sto_eos ) CALL sto_pts( tsn )                 ! Random T/S fluctuations
271                             CALL eos    ( tsa, rhd, rhop, fsdept_n(:,:,:) )  ! Time-filtered in situ density for hpg computation
272            IF( ln_zps .AND. .NOT. ln_isfcav)                                &
273               &             CALL zps_hde    ( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
274               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
275            IF( ln_zps .AND.       ln_isfcav)                                &
276               &             CALL zps_hde_isf( kstp, jpts, tsa, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
277               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
278               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
279      ELSE                                                  ! centered hpg  (eos then time stepping)
280         IF ( .NOT. lk_dynspg_ts ) THEN                     ! eos already called in time-split case
281            IF( ln_sto_eos ) CALL sto_pts( tsn )    ! Random T/S fluctuations
282                             CALL eos    ( tsn, rhd, rhop, fsdept_n(:,:,:) )  ! now in situ density for hpg computation
283         IF( ln_zps .AND. .NOT. ln_isfcav)                                   &
284               &             CALL zps_hde    ( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps: before horizontal gradient
285               &                                           rhd, gru , grv    )  ! of t, s, rd at the last ocean level
286         IF( ln_zps .AND.       ln_isfcav)                                   & 
287               &             CALL zps_hde_isf( kstp, jpts, tsn, gtsu, gtsv,  &    ! Partial steps for top cell (ISF)
288               &                                           rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv ,   &
289               &                                    gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi    ) ! of t, s, rd at the last ocean level
290         ENDIF
291         IF( ln_zdfnpc   )   CALL tra_npc( kstp )                ! update after fields by non-penetrative convection
292                             CALL tra_nxt( kstp )                ! tracer fields at next time step
293      ENDIF
294
295      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
296      ! Dynamics                                    (tsa used as workspace)
297      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
298      IF( lk_dynspg_ts   )  THEN
299                                                             ! revert to previously computed momentum tendencies
300                                                             ! (not using ua, va as temporary arrays during tracers' update could avoid that)
301                               ua(:,:,:) = ua_sv(:,:,:)
302                               va(:,:,:) = va_sv(:,:,:)
303                                                             ! Revert now divergence and rotational to previously computed ones
304                                                             !(needed because of the time swap in div_cur, at the beginning of each time step)
305                               hdivn(:,:,:) = hdivb(:,:,:)
306                               rotn(:,:,:)  = rotb(:,:,:) 
307
308                               CALL dyn_bfr( kstp )         ! bottom friction
309                               CALL dyn_zdf( kstp )         ! vertical diffusion
310      ELSE
311                               ua(:,:,:) = 0.e0             ! set dynamics trends to zero
312                               va(:,:,:) = 0.e0
313
314        IF(  ln_asmiau .AND. &
315           & ln_dyninc      )  CALL dyn_asm_inc( kstp )     ! apply dynamics assimilation increment
316        IF( ln_bkgwri )        CALL asm_bkg_wri( kstp )     ! output background fields
317        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! subtract Neptune velocities (simplified)
318        IF( lk_bdy          )  CALL bdy_dyn3d_dmp(kstp )    ! bdy damping trends
319                               CALL dyn_adv( kstp )         ! advection (vector or flux form)
320                               CALL dyn_vor( kstp )         ! vorticity term including Coriolis
321                               CALL dyn_ldf( kstp )         ! lateral mixing
322        IF( ln_neptsimp )      CALL dyn_nept_cor( kstp )    ! add Neptune velocities (simplified)
323#if defined key_agrif
324        IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn        ! momemtum sponge
325#endif
326                               CALL dyn_hpg( kstp )         ! horizontal gradient of Hydrostatic pressure
327                               CALL dyn_bfr( kstp )         ! bottom friction
328                               CALL dyn_zdf( kstp )         ! vertical diffusion
329                               CALL dyn_spg( kstp, indic )  ! surface pressure gradient
330      ENDIF
331                               CALL dyn_nxt( kstp )         ! lateral velocity at next time step
332
333                               CALL ssh_swp( kstp )         ! swap of sea surface height
334      IF( lk_vvl           )   CALL dom_vvl_sf_swp( kstp )  ! swap of vertical scale factors
335
336      IF( ln_diahsb        )   CALL dia_hsb( kstp )         ! - ML - global conservation diagnostics
337      IF( lk_diaobs  )         CALL dia_obs( kstp )         ! obs-minus-model (assimilation) diagnostics (call after dynamics update)
338
339      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
340      ! Control and restarts
341      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
342                               CALL stp_ctl( kstp, indic )
343      IF( indic < 0        )   THEN
344                               CALL ctl_stop( 'step: indic < 0' )
345                               CALL dia_wri_state( 'output.abort', kstp )
346      ENDIF
347      IF( kstp == nit000   )   THEN
348                 CALL iom_close( numror )     ! close input  ocean restart file
349         IF(lwm) CALL FLUSH    ( numond )     ! flush output namelist oce
350         IF( lwm.AND.numoni /= -1 ) CALL FLUSH    ( numoni )     ! flush output namelist ice
351      ENDIF
352      IF( lrst_oce         )   CALL rst_write    ( kstp )   ! write output ocean restart file
353
354      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
355      ! Coupled mode
356      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
357      IF( lk_cpl           )   CALL sbc_cpl_snd( kstp )     ! coupled mode : field exchanges
358      !
359#if defined key_iomput
360      IF( kstp == nitend .OR. indic < 0 ) THEN
361                      CALL iom_context_finalize( "nemo"     ) ! needed for XIOS+AGRIF
362         IF( ln_crs ) CALL iom_context_finalize( "nemo_crs" ) !
363      ENDIF
364#endif
365      !
366      IF( nn_timing == 1 .AND.  kstp == nit000  )   CALL timing_reset
367      !
368   END SUBROUTINE stp
369
370   !!======================================================================
371END MODULE step
Note: See TracBrowser for help on using the repository browser.