New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
crsfld.F90 in branches/2015/dev_CMCC_merge_2015/NEMOGCM/NEMO/OPA_SRC/CRS – NEMO

source: branches/2015/dev_CMCC_merge_2015/NEMOGCM/NEMO/OPA_SRC/CRS/crsfld.F90 @ 6051

Last change on this file since 6051 was 6051, checked in by lovato, 8 years ago

Merge branches/2015/dev_r5056_CMCC4_simplification (see ticket #1456)

  • Property svn:keywords set to Id
File size: 11.1 KB
Line 
1MODULE crsfld
2   !!======================================================================
3   !!                     ***  MODULE  crsdfld  ***
4   !!  Ocean coarsening :  coarse ocean fields
5   !!=====================================================================
6   !!   2012-07  (J. Simeon, C. Calone, G. Madec, C. Ethe)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   crs_fld       : create the standard output files for coarse grid and prep
11   !!                       other variables needed to be passed to TOP
12   !!----------------------------------------------------------------------
13   USE crs
14   USE crsdom
15   USE crslbclnk
16   USE oce             ! ocean dynamics and tracers
17   USE dom_oce         ! ocean space and time domain
18   USE sbc_oce         ! Surface boundary condition: ocean fields
19   USE zdf_oce         ! vertical  physics: ocean fields
20   USE ldftra          ! ocean active tracers: lateral diffusivity & EIV coefficients
21   USE zdfddm          ! vertical  physics: double diffusion
22   !
23   USE in_out_manager  ! I/O manager
24   USE iom             !
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE timing          ! preformance summary
27   USE wrk_nemo        ! working array
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   crs_fld                 ! routines called by step.F90
33
34   !! * Substitutions
35#  include "zdfddm_substitute.h90"
36#  include "domzgr_substitute.h90"
37#  include "vectopt_loop_substitute.h90"
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
40   !! $Id$
41   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE crs_fld( kt )
46      !!---------------------------------------------------------------------
47      !!                  ***  ROUTINE crs_fld  ***
48      !!                   
49      !! ** Purpose :   Basic output of coarsened dynamics and tracer fields
50      !!      NETCDF format is used by default
51      !!      1. Accumulate in time the dimensionally-weighted fields
52      !!      2. At time of output, rescale [1] by dimension and time
53      !!         to yield the spatial and temporal average.
54      !!  See. sbcmod.F90
55      !!
56      !! ** Method  : 
57      !!----------------------------------------------------------------------
58      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
59      !
60      INTEGER  ::   ji, jj, jk        ! dummy loop indices
61      REAL(wp) ::   z2dcrsu, z2dcrsv  ! local scalars
62      !
63      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zfse3t, zfse3u, zfse3v, zfse3w   ! 3D workspace for e3
64      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zt, zt_crs
65      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zs, zs_crs 
66      !!----------------------------------------------------------------------
67      !
68      IF( nn_timing == 1 )   CALL timing_start('crs_fld')
69
70      !  Initialize arrays
71      CALL wrk_alloc( jpi,jpj,jpk,   zfse3t, zfse3w )
72      CALL wrk_alloc( jpi,jpj,jpk,   zfse3u, zfse3v )
73      CALL wrk_alloc( jpi,jpj,jpk,   zt    , zs     )
74      !
75      CALL wrk_alloc( jpi_crs, jpj_crs, jpk, zt_crs, zs_crs )
76
77      ! Depth work arrrays
78      zfse3t(:,:,:) = fse3t(:,:,:)
79      zfse3u(:,:,:) = fse3u(:,:,:)
80      zfse3v(:,:,:) = fse3v(:,:,:)
81      zfse3w(:,:,:) = fse3w(:,:,:)
82
83      IF( kt == nit000  ) THEN
84         tsn_crs  (:,:,:,:) = 0._wp    ! temp/sal  array, now
85         un_crs   (:,:,:  ) = 0._wp    ! u-velocity
86         vn_crs   (:,:,:  ) = 0._wp    ! v-velocity
87         wn_crs   (:,:,:  ) = 0._wp    ! w
88         avt_crs  (:,:,:  ) = 0._wp    ! avt
89         hdivn_crs(:,:,:  ) = 0._wp    ! hdiv
90         rke_crs  (:,:,:  ) = 0._wp    ! rke
91         sshn_crs (:,:    ) = 0._wp    ! ssh
92         utau_crs (:,:    ) = 0._wp    ! taux
93         vtau_crs (:,:    ) = 0._wp    ! tauy
94         wndm_crs (:,:    ) = 0._wp    ! wind speed
95         qsr_crs  (:,:    ) = 0._wp    ! qsr
96         emp_crs  (:,:    ) = 0._wp    ! emp
97         emp_b_crs(:,:    ) = 0._wp    ! emp
98         rnf_crs  (:,:    ) = 0._wp    ! runoff
99         fr_i_crs (:,:    ) = 0._wp    ! ice cover
100      ENDIF
101
102      CALL iom_swap( "nemo_crs" )    ! swap on the coarse grid
103
104      ! 2. Coarsen fields at each time step
105      ! --------------------------------------------------------
106
107      !  Temperature
108      zt(:,:,:) = tsn(:,:,:,jp_tem)  ;      zt_crs(:,:,:) = 0._wp
109      CALL crs_dom_ope( zt, 'VOL', 'T', tmask, zt_crs, p_e12=e1e2t, p_e3=zfse3t, psgn=1.0 )
110      tsn_crs(:,:,:,jp_tem) = zt_crs(:,:,:)
111
112      CALL iom_put( "toce", tsn_crs(:,:,:,jp_tem) )    ! temp
113      CALL iom_put( "sst" , tsn_crs(:,:,1,jp_tem) )    ! sst
114
115     
116      !  Salinity
117      zs(:,:,:) = tsn(:,:,:,jp_sal)  ;      zs_crs(:,:,:) = 0._wp
118      CALL crs_dom_ope( zs, 'VOL', 'T', tmask, zs_crs, p_e12=e1e2t, p_e3=zfse3t, psgn=1.0 )
119      tsn_crs(:,:,:,jp_sal) = zt_crs(:,:,:)
120
121      CALL iom_put( "soce" , tsn_crs(:,:,:,jp_sal) )    ! sal
122      CALL iom_put( "sss"  , tsn_crs(:,:,1,jp_sal) )    ! sss
123
124      !  U-velocity
125      CALL crs_dom_ope( un, 'SUM', 'U', umask, un_crs, p_e12=e2u, p_e3=zfse3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
126      !
127      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
128      DO jk = 1, jpkm1
129         DO jj = 2, jpjm1
130            DO ji = 2, jpim1   
131               zt(ji,jj,jk)  = un(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_tem) + tsn(ji+1,jj,jk,jp_tem) ) 
132               zs(ji,jj,jk)  = un(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_sal) + tsn(ji+1,jj,jk,jp_sal) ) 
133            END DO
134         END DO
135      END DO
136      CALL crs_dom_ope( zt, 'SUM', 'U', umask, zt_crs, p_e12=e2u, p_e3=zfse3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
137      CALL crs_dom_ope( zs, 'SUM', 'U', umask, zs_crs, p_e12=e2u, p_e3=zfse3u, p_surf_crs=e2e3u_msk, psgn=-1.0 )
138
139      CALL iom_put( "uoce"  , un_crs )   ! i-current
140      CALL iom_put( "uocet" , zt_crs )   ! uT
141      CALL iom_put( "uoces" , zs_crs )   ! uS
142
143      !  V-velocity
144      CALL crs_dom_ope( vn, 'SUM', 'V', vmask, vn_crs, p_e12=e1v, p_e3=zfse3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
145      !                                                                                 
146      zt(:,:,:) = 0._wp     ;    zs(:,:,:) = 0._wp  ;   zt_crs(:,:,:) = 0._wp   ;    zs_crs(:,:,:) = 0._wp
147      DO jk = 1, jpkm1
148         DO jj = 2, jpjm1
149            DO ji = 2, jpim1   
150               zt(ji,jj,jk)  = vn(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_tem) + tsn(ji,jj+1,jk,jp_tem) ) 
151               zs(ji,jj,jk)  = vn(ji,jj,jk) * 0.5 * ( tsn(ji,jj,jk,jp_sal) + tsn(ji,jj+1,jk,jp_sal) ) 
152            END DO
153         END DO
154      END DO
155      CALL crs_dom_ope( zt, 'SUM', 'V', vmask, zt_crs, p_e12=e1v, p_e3=zfse3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
156      CALL crs_dom_ope( zs, 'SUM', 'V', vmask, zs_crs, p_e12=e1v, p_e3=zfse3v, p_surf_crs=e1e3v_msk, psgn=-1.0 )
157 
158      CALL iom_put( "voce"  , vn_crs )   ! i-current
159      CALL iom_put( "vocet" , zt_crs )   ! vT
160      CALL iom_put( "voces" , zs_crs )   ! vS
161
162     
163      !  Kinetic energy
164      CALL crs_dom_ope( rke, 'VOL', 'T', tmask, rke_crs, p_e12=e1e2t, p_e3=zfse3t, psgn=1.0 )
165      CALL iom_put( "eken", rke_crs )
166
167      !  Horizontal divergence ( following OPA_SRC/DYN/divhor.F90 )
168      DO jk = 1, jpkm1
169         DO ji = 2, jpi_crsm1
170            DO jj = 2, jpj_crsm1
171               IF( tmask_crs(ji,jj,jk ) > 0 ) THEN
172                   z2dcrsu =  ( un_crs(ji  ,jj  ,jk) * crs_surfu_wgt(ji  ,jj  ,jk) ) &
173                      &     - ( un_crs(ji-1,jj  ,jk) * crs_surfu_wgt(ji-1,jj  ,jk) )
174                   z2dcrsv =  ( vn_crs(ji  ,jj  ,jk) * crs_surfv_wgt(ji  ,jj  ,jk) ) &
175                      &     - ( vn_crs(ji  ,jj-1,jk) * crs_surfv_wgt(ji  ,jj-1,jk) )
176                   !
177                   hdivn_crs(ji,jj,jk) = ( z2dcrsu + z2dcrsv ) / crs_volt_wgt(ji,jj,jk) 
178               ENDIF
179            ENDDO
180         ENDDO
181      ENDDO
182      CALL crs_lbc_lnk( hdivn_crs, 'T', 1.0 )
183      !
184      CALL iom_put( "hdiv", hdivn_crs ) 
185
186
187      !  W-velocity
188      IF( ln_crs_wn ) THEN
189         CALL crs_dom_ope( wn, 'SUM', 'W', tmask, wn_crs, p_e12=e1e2t, p_surf_crs=e1e2w_msk, psgn=1.0 )
190       !  CALL crs_dom_ope( wn, 'VOL', 'W', tmask, wn_crs, p_e12=e1e2t, p_e3=zfse3w )
191      ELSE
192        wn_crs(:,:,jpk) = 0._wp
193        DO jk = jpkm1, 1, -1
194           wn_crs(:,:,jk) = wn_crs(:,:,jk+1) - e3t_crs(:,:,jk) * hdivn_crs(:,:,jk)
195        ENDDO
196      ENDIF
197      CALL iom_put( "woce", wn_crs  )   ! vertical velocity
198      !  free memory
199
200      !  avt, avs
201      SELECT CASE ( nn_crs_kz )
202         CASE ( 0 )
203            CALL crs_dom_ope( avt, 'VOL', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=zfse3w, psgn=1.0 )
204         CASE ( 1 )
205            CALL crs_dom_ope( avt, 'MAX', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=zfse3w, psgn=1.0 )
206         CASE ( 2 )
207            CALL crs_dom_ope( avt, 'MIN', 'W', tmask, avt_crs, p_e12=e1e2t, p_e3=zfse3w, psgn=1.0 )
208      END SELECT
209      !
210      CALL iom_put( "avt", avt_crs )   !  Kz
211     
212      !  sbc fields 
213      CALL crs_dom_ope( sshn , 'VOL', 'T', tmask, sshn_crs , p_e12=e1e2t, p_e3=zfse3t         , psgn=1.0 ) 
214      CALL crs_dom_ope( utau , 'SUM', 'U', umask, utau_crs , p_e12=e2u  , p_surf_crs=e2u_crs  , psgn=1.0 )
215      CALL crs_dom_ope( vtau , 'SUM', 'V', vmask, vtau_crs , p_e12=e1v  , p_surf_crs=e1v_crs  , psgn=1.0 )
216      CALL crs_dom_ope( wndm , 'SUM', 'T', tmask, wndm_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
217      CALL crs_dom_ope( rnf  , 'MAX', 'T', tmask, rnf_crs                                     , psgn=1.0 )
218      CALL crs_dom_ope( qsr  , 'SUM', 'T', tmask, qsr_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
219      CALL crs_dom_ope( emp_b, 'SUM', 'T', tmask, emp_b_crs, p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
220      CALL crs_dom_ope( emp  , 'SUM', 'T', tmask, emp_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
221      CALL crs_dom_ope( sfx  , 'SUM', 'T', tmask, sfx_crs  , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
222      CALL crs_dom_ope( fr_i , 'SUM', 'T', tmask, fr_i_crs , p_e12=e1e2t, p_surf_crs=e1e2t_crs, psgn=1.0 )
223
224      CALL iom_put( "ssh"      , sshn_crs )   ! ssh output
225      CALL iom_put( "utau"     , utau_crs )   ! i-tau output
226      CALL iom_put( "vtau"     , vtau_crs )   ! j-tau output
227      CALL iom_put( "wspd"     , wndm_crs )   ! wind speed output
228      CALL iom_put( "runoffs"  , rnf_crs  )   ! runoff output
229      CALL iom_put( "qsr"      , qsr_crs  )   ! qsr output
230      CALL iom_put( "empmr"    , emp_crs  )   ! water flux output
231      CALL iom_put( "saltflx"  , sfx_crs  )   ! salt flux output
232      CALL iom_put( "ice_cover", fr_i_crs )   ! ice cover output
233
234      !  free memory
235      CALL wrk_dealloc( jpi, jpj, jpk, zfse3t, zfse3w )
236      CALL wrk_dealloc( jpi, jpj, jpk, zfse3u, zfse3v )
237      CALL wrk_dealloc( jpi, jpj, jpk, zt, zs       )
238      CALL wrk_dealloc( jpi_crs, jpj_crs, jpk, zt_crs, zs_crs )
239      !
240      CALL iom_swap( "nemo" )     ! return back on high-resolution grid
241      !
242      IF( nn_timing == 1 )   CALL timing_stop('crs_fld')
243      !
244   END SUBROUTINE crs_fld
245
246   !!======================================================================
247END MODULE crsfld
Note: See TracBrowser for help on using the repository browser.