New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2015/dev_CMCC_merge_2015/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_CMCC_merge_2015/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 6051

Last change on this file since 6051 was 6051, checked in by lovato, 8 years ago

Merge branches/2015/dev_r5056_CMCC4_simplification (see ticket #1456)
  • Property svn:keywords set to Id
File size: 15.1 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2010-06  (C. Ethe)   Adapted to passive tracers
8   !!            3.7  !  2014-05  (G. Madec, C. Ethe)  Add 2nd/4th order cases for CEN and FCT schemes
9   !!----------------------------------------------------------------------
10#if defined key_top
11   !!----------------------------------------------------------------------
12   !!   'key_top'                                                TOP models
13   !!----------------------------------------------------------------------
14   !!   trc_adv       : compute ocean tracer advection trend
15   !!   trc_adv_ini   : control the different options of advection scheme
16   !!----------------------------------------------------------------------
17   USE oce_trc        ! ocean dynamics and active tracers
18   USE trc            ! ocean passive tracers variables
19   USE traadv_cen     ! centered scheme           (tra_adv_cen  routine)
20   USE traadv_fct     ! FCT      scheme           (tra_adv_fct  routine)
21   USE traadv_mus     ! MUSCL    scheme           (tra_adv_mus  routine)
22   USE traadv_ubs     ! UBS      scheme           (tra_adv_ubs  routine)
23   USE traadv_qck     ! QUICKEST scheme           (tra_adv_qck  routine)
24   USE traadv_mle     ! ML eddy induced velocity  (tra_adv_mle  routine)
25   USE ldftra         ! lateral diffusion coefficient on tracers
26   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
27   !
28   USE prtctl_trc     ! Print control
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   trc_adv       
34   PUBLIC   trc_adv_ini 
35
36   !                            !!* Namelist namtrc_adv *
37   LOGICAL ::   ln_trcadv_cen    ! centered scheme flag
38   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
39   LOGICAL ::   ln_trcadv_fct    ! FCT scheme flag
40   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
41   INTEGER ::      nn_fct_zts           ! >=1 : 2nd order FCT with vertical sub-timestepping
42   LOGICAL ::   ln_trcadv_mus    ! MUSCL scheme flag
43   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
44   LOGICAL ::   ln_trcadv_ubs    ! UBS scheme flag
45   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
46   LOGICAL ::   ln_trcadv_qck    ! QUICKEST scheme flag
47
48   !                                        ! choices of advection scheme:
49   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
50   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
51   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
52   INTEGER, PARAMETER ::   np_FCT_zts = 3   ! 2nd order FCT scheme with vertical sub-timestepping
53   INTEGER, PARAMETER ::   np_MUS     = 4   ! MUSCL scheme
54   INTEGER, PARAMETER ::   np_UBS     = 5   ! 3rd order Upstream Biased Scheme
55   INTEGER, PARAMETER ::   np_QCK     = 6   ! QUICK scheme
56
57   INTEGER ::              nadv             ! chosen advection scheme
58   !
59   REAL(wp) ::   r2dttrc  ! vertical profile time-step, = 2 rdt
60   !                                                    ! except at nitrrc000 (=rdt) if neuler=0
61
62   !! * Substitutions
63#  include "domzgr_substitute.h90"
64#  include "vectopt_loop_substitute.h90"
65   !!----------------------------------------------------------------------
66   !! NEMO/TOP 3.7 , NEMO Consortium (2015)
67   !! $Id$
68   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
69   !!----------------------------------------------------------------------
70CONTAINS
71
72   SUBROUTINE trc_adv( kt )
73      !!----------------------------------------------------------------------
74      !!                  ***  ROUTINE trc_adv  ***
75      !!
76      !! ** Purpose :   compute the ocean tracer advection trend.
77      !!
78      !! ** Method  : - Update the tracer with the advection term following nadv
79      !!----------------------------------------------------------------------
80      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
81      !
82      INTEGER ::   jk   ! dummy loop index
83      CHARACTER (len=22) ::   charout
84      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn  ! effective velocity
85      !!----------------------------------------------------------------------
86      !
87      IF( nn_timing == 1 )   CALL timing_start('trc_adv')
88      !
89      CALL wrk_alloc( jpi,jpj,jpk,   zun, zvn, zwn )
90      !
91      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
92         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
93      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
94         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
95      ENDIF
96      !                                               !==  effective transport  ==!
97      DO jk = 1, jpkm1
98         zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)                   ! eulerian transport
99         zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
100         zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
101      END DO
102      !
103      IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                 ! add z-tilde and/or vvl corrections
104         zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
105         zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
106      ENDIF
107      !
108      IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   & 
109         &              CALL ldf_eiv_trp( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the eiv transport
110      !
111      IF( ln_mle    )   CALL tra_adv_mle( kt, nittrc000, zun, zvn, zwn, 'TRC' )  ! add the mle transport
112      !
113      zun(:,:,jpk) = 0._wp                                                       ! no transport trough the bottom
114      zvn(:,:,jpk) = 0._wp
115      zwn(:,:,jpk) = 0._wp
116      !
117      !
118      SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
119      !
120      CASE ( np_CEN )                                    ! Centered : 2nd / 4th order
121         CALL tra_adv_cen    ( kt, nittrc000,'TRC',       zun, zvn, zwn     , trn, tra, jptra, nn_cen_h, nn_cen_v )
122      CASE ( np_FCT )                                    ! FCT      : 2nd / 4th order
123         CALL tra_adv_fct    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra, nn_fct_h, nn_fct_v )
124      CASE ( np_FCT_zts )                                ! 2nd order FCT with vertical time-splitting
125         CALL tra_adv_fct_zts( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra        , nn_fct_zts )
126      CASE ( np_MUS )                                    ! MUSCL
127         CALL tra_adv_mus    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb,      tra, jptra        , ln_mus_ups ) 
128      CASE ( np_UBS )                                    ! UBS
129         CALL tra_adv_ubs    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra        , nn_ubs_v   )
130      CASE ( np_QCK )                                    ! QUICKEST
131         CALL tra_adv_qck    ( kt, nittrc000,'TRC', r2dttrc, zun, zvn, zwn, trb, trn, tra, jptra                     )
132      !
133      END SELECT
134      !                 
135      IF( ln_ctl )   THEN                             !== print mean trends (used for debugging)
136         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
137                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
138      END IF
139      !
140      CALL wrk_dealloc( jpi,jpj,jpk,   zun, zvn, zwn )
141      !
142      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
143      !
144   END SUBROUTINE trc_adv
145
146
147   SUBROUTINE trc_adv_ini
148      !!---------------------------------------------------------------------
149      !!                  ***  ROUTINE trc_adv_ini  ***
150      !!               
151      !! ** Purpose : Control the consistency between namelist options for
152      !!              passive tracer advection schemes and set nadv
153      !!----------------------------------------------------------------------
154      INTEGER ::   ioptio
155      INTEGER ::  ios                 ! Local integer output status for namelist read
156      !!
157      NAMELIST/namtrc_adv/ ln_trcadv_cen, nn_cen_h, nn_cen_v,               &   ! CEN
158         &                 ln_trcadv_fct, nn_fct_h, nn_fct_v, nn_fct_zts,   &   ! FCT
159         &                 ln_trcadv_mus,                     ln_mus_ups,   &   ! MUSCL
160         &                 ln_trcadv_ubs,           nn_ubs_v,               &   ! UBS
161         &                 ln_trcadv_qck                                        ! QCK
162      !!----------------------------------------------------------------------
163      !
164      REWIND( numnat_ref )              !  namtrc_adv in reference namelist
165      READ  ( numnat_ref, namtrc_adv, IOSTAT = ios, ERR = 901)
166901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in reference namelist', lwp )
167
168      REWIND( numnat_cfg )              ! namtrc_adv in configuration namelist
169      READ  ( numnat_cfg, namtrc_adv, IOSTAT = ios, ERR = 902 )
170902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_adv in configuration namelist', lwp )
171      IF(lwm) WRITE ( numont, namtrc_adv )
172
173      IF(lwp) THEN                    ! Namelist print
174         WRITE(numout,*)
175         WRITE(numout,*) 'trc_adv_ini : choice/control of the tracer advection scheme'
176         WRITE(numout,*) '~~~~~~~~~~~'
177         WRITE(numout,*) '   Namelist namtrc_adv : chose a advection scheme for tracers'
178         WRITE(numout,*) '      centered scheme                           ln_trcadv_cen = ', ln_trcadv_cen
179         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
180         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
181         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_trcadv_fct = ', ln_trcadv_fct
182         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
183         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
184         WRITE(numout,*) '            2nd order + vertical sub-timestepping  nn_fct_zts = ', nn_fct_zts
185         WRITE(numout,*) '      MUSCL scheme                              ln_trcadv_mus = ', ln_trcadv_mus
186         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
187         WRITE(numout,*) '      UBS scheme                                ln_trcadv_ubs = ', ln_trcadv_ubs
188         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
189         WRITE(numout,*) '      QUICKEST scheme                           ln_trcadv_qck = ', ln_trcadv_qck
190      ENDIF
191      !
192
193      ioptio = 0                       !==  Parameter control  ==!
194      IF( ln_trcadv_cen )   ioptio = ioptio + 1
195      IF( ln_trcadv_fct )   ioptio = ioptio + 1
196      IF( ln_trcadv_mus )   ioptio = ioptio + 1
197      IF( ln_trcadv_ubs )   ioptio = ioptio + 1
198      IF( ln_trcadv_qck )   ioptio = ioptio + 1
199
200      !
201      IF( ioptio == 0 ) THEN
202         nadv = np_NO_adv
203         CALL ctl_warn( 'trc_adv_init: You are running without tracer advection.' )
204      ENDIF
205      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
206      !
207      IF( ln_trcadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &
208                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
209        CALL ctl_stop( 'trc_adv_init: CEN scheme, choose 2nd or 4th order' )
210      ENDIF
211      IF( ln_trcadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &
212                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
213        CALL ctl_stop( 'trc_adv_init: FCT scheme, choose 2nd or 4th order' )
214      ENDIF
215      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 ) THEN
216         IF( nn_fct_h == 4 ) THEN
217            nn_fct_h = 2
218            CALL ctl_stop( 'trc_adv_init: force 2nd order FCT scheme, 4th order does not exist with sub-timestepping' )
219         ENDIF
220         IF( lk_vvl ) THEN
221            CALL ctl_stop( 'trc_adv_init: vertical sub-timestepping not allow in non-linear free surface' )
222         ENDIF
223         IF( nn_fct_zts == 1 )   CALL ctl_warn( 'trc_adv_init: FCT with ONE sub-timestep = FCT without sub-timestep' )
224      ENDIF
225      IF( ln_trcadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN
226        CALL ctl_stop( 'trc_adv_init: UBS scheme, choose 2nd or 4th order' )
227      ENDIF
228      IF( ln_trcadv_ubs .AND. nn_ubs_v == 4 ) THEN
229         CALL ctl_warn( 'trc_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
230      ENDIF
231      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
232         IF(  ln_trcadv_cen .AND. nn_cen_v /= 4    .OR.   &                            ! NO 4th order with ISF
233            & ln_trcadv_fct .AND. nn_fct_v /= 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
234      ENDIF
235      !
236      !                                !==  used advection scheme  ==!
237      !                                      ! set nadv
238      IF( ln_trcadv_cen                      )   nadv = np_CEN
239      IF( ln_trcadv_fct                      )   nadv = np_FCT
240      IF( ln_trcadv_fct .AND. nn_fct_zts > 0 )   nadv = np_FCT_zts
241      IF( ln_trcadv_mus                      )   nadv = np_MUS
242      IF( ln_trcadv_ubs                      )   nadv = np_UBS
243      IF( ln_trcadv_qck                      )   nadv = np_QCK
244      !
245      IF(lwp) THEN                   ! Print the choice
246         WRITE(numout,*)
247         IF( nadv == np_NO_adv  )   WRITE(numout,*) '         NO passive tracer advection'
248         IF( nadv == np_CEN     )   WRITE(numout,*) '         CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
249            &                                                                        ' Vertical   order: ', nn_cen_v
250         IF( nadv == np_FCT     )   WRITE(numout,*) '         FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
251            &                                                                       ' Vertical   order: ', nn_fct_v
252         IF( nadv == np_FCT_zts )   WRITE(numout,*) '         use 2nd order FCT with ', nn_fct_zts,'vertical sub-timestepping'
253         IF( nadv == np_MUS     )   WRITE(numout,*) '         MUSCL    scheme is used'
254         IF( nadv == np_UBS     )   WRITE(numout,*) '         UBS      scheme is used'
255         IF( nadv == np_QCK     )   WRITE(numout,*) '         QUICKEST scheme is used'
256      ENDIF
257      !
258   END SUBROUTINE trc_adv_ini
259   
260#else
261   !!----------------------------------------------------------------------
262   !!   Default option                                         Empty module
263   !!----------------------------------------------------------------------
264CONTAINS
265   SUBROUTINE trc_adv( kt )
266      INTEGER, INTENT(in) :: kt
267      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
268   END SUBROUTINE trc_adv
269#endif
270
271  !!======================================================================
272END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.