New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trczdf.F90 in branches/2015/dev_CMCC_merge_2015/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_CMCC_merge_2015/NEMOGCM/NEMO/TOP_SRC/TRP/trczdf.F90 @ 6051

Last change on this file since 6051 was 6051, checked in by lovato, 8 years ago

Merge branches/2015/dev_r5056_CMCC4_simplification (see ticket #1456)
  • Property svn:keywords set to Id
File size: 8.4 KB
Line 
1MODULE trczdf
2   !!==============================================================================
3   !!                 ***  MODULE  trczdf  ***
4   !! Ocean Passive tracers : vertical diffusive trends
5   !!=====================================================================
6   !! History :  9.0  ! 2005-11 (G. Madec)  Original code
7   !!       NEMO 3.0  ! 2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_zdf      : update the tracer trend with the lateral diffusion
14   !!   trc_zdf_ini  : initialization, namelist read, and parameters control
15   !!----------------------------------------------------------------------
16   USE trc           ! ocean passive tracers variables
17   USE oce_trc       ! ocean dynamics and active tracers
18   USE trd_oce       ! trends: ocean variables
19   USE trazdf_exp    ! vertical diffusion: explicit (tra_zdf_exp     routine)
20   USE trazdf_imp    ! vertical diffusion: implicit (tra_zdf_imp     routine)
21   USE trcldf        ! passive tracers: lateral diffusion
22   USE trdtra        ! trends manager: tracers
23   USE prtctl_trc    ! Print control
24
25   IMPLICIT NONE
26   PRIVATE
27
28   PUBLIC   trc_zdf         ! called by step.F90
29   PUBLIC   trc_zdf_ini     ! called by nemogcm.F90
30   
31   !                                        !!** Vertical diffusion (nam_trczdf) **
32   LOGICAL , PUBLIC ::   ln_trczdf_exp       !: explicit vertical diffusion scheme flag
33   INTEGER , PUBLIC ::   nn_trczdf_exp       !: number of sub-time step (explicit time stepping)
34
35   INTEGER ::   nzdf = 0               ! type vertical diffusion algorithm used
36      !                                ! defined from ln_zdf...  namlist logicals)
37   REAL(wp) ::  r2dttrc   ! vertical profile time-step, = 2 rdt
38      !                   ! except at nittrc000 (=rdt) if neuler=0
39
40   !! * Substitutions
41#  include "domzgr_substitute.h90"
42#  include "zdfddm_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 3.7 , NEMO Consortium (2015)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE trc_zdf( kt )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE trc_zdf  ***
54      !!
55      !! ** Purpose :   compute the vertical ocean tracer physics.
56      !!---------------------------------------------------------------------
57      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
58      !
59      INTEGER               ::  jk, jn
60      CHARACTER (len=22)    :: charout
61      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   ztrtrd   ! 4D workspace
62      !!---------------------------------------------------------------------
63      !
64      IF( nn_timing == 1 )  CALL timing_start('trc_zdf')
65      !
66      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
67         r2dttrc =  rdttrc           ! = rdttrc (use or restarting with Euler time stepping)
68      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
69         r2dttrc = 2. * rdttrc       ! = 2 rdttrc (leapfrog)
70      ENDIF
71
72      IF( l_trdtrc )  THEN
73         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrtrd )
74         ztrtrd(:,:,:,:)  = tra(:,:,:,:)
75      ENDIF
76
77      SELECT CASE ( nzdf )                       ! compute lateral mixing trend and add it to the general trend
78      CASE ( 0 ) ;  CALL tra_zdf_exp( kt, nittrc000, 'TRC', r2dttrc, nn_trczdf_exp, trb, tra, jptra )    !   explicit scheme
79      CASE ( 1 ) ;  CALL tra_zdf_imp( kt, nittrc000, 'TRC', r2dttrc,                trb, tra, jptra )    !   implicit scheme         
80      END SELECT
81
82      IF( l_trdtrc )   THEN                      ! save the vertical diffusive trends for further diagnostics
83         DO jn = 1, jptra
84            DO jk = 1, jpkm1
85               ztrtrd(:,:,jk,jn) = ( ( tra(:,:,jk,jn) - trb(:,:,jk,jn) ) / r2dttrc ) - ztrtrd(:,:,jk,jn)
86            END DO
87            CALL trd_tra( kt, 'TRC', jn, jptra_zdf, ztrtrd(:,:,:,jn) )
88         END DO
89         CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrtrd )
90      ENDIF
91      !                                          ! print mean trends (used for debugging)
92      IF( ln_ctl )   THEN
93         WRITE(charout, FMT="('zdf ')") ;  CALL prt_ctl_trc_info(charout)
94                                           CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
95      END IF
96      !
97      IF( nn_timing == 1 )  CALL timing_stop('trc_zdf')
98      !
99   END SUBROUTINE trc_zdf
100
101
102   SUBROUTINE trc_zdf_ini
103      !!----------------------------------------------------------------------
104      !!                 ***  ROUTINE trc_zdf_ini  ***
105      !!
106      !! ** Purpose :   Choose the vertical mixing scheme
107      !!
108      !! ** Method  :   Set nzdf from ln_zdfexp
109      !!      nzdf = 0   explicit (time-splitting) scheme (ln_trczdf_exp=T)
110      !!           = 1   implicit (euler backward) scheme (ln_trczdf_exp=F)
111      !!      NB: The implicit scheme is required when using :
112      !!             - rotated lateral mixing operator
113      !!             - TKE, GLS vertical mixing scheme
114      !!----------------------------------------------------------------------
115      INTEGER ::  ios                 ! Local integer output status for namelist read
116      !!
117      NAMELIST/namtrc_zdf/ ln_trczdf_exp  , nn_trczdf_exp
118      !!----------------------------------------------------------------------
119      !
120      REWIND( numnat_ref )             ! namtrc_zdf in reference namelist
121      READ  ( numnat_ref, namtrc_zdf, IOSTAT = ios, ERR = 905)
122905   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_zdf in reference namelist', lwp )
123      !
124      REWIND( numnat_cfg )             ! namtrc_zdf in configuration namelist
125      READ  ( numnat_cfg, namtrc_zdf, IOSTAT = ios, ERR = 906 )
126906   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namtrc_zdf in configuration namelist', lwp )
127      IF(lwm) WRITE ( numont, namtrc_zdf )
128      !
129      IF(lwp) THEN                     ! Control print
130         WRITE(numout,*)
131         WRITE(numout,*) '   Namelist namtrc_zdf : set vertical diffusion  parameters'
132         WRITE(numout,*) '      time splitting / backward scheme ln_trczdf_exp = ', ln_trczdf_exp
133         WRITE(numout,*) '      number of time step              nn_trczdf_exp = ', nn_trczdf_exp
134      ENDIF
135
136      !                                ! Define the vertical tracer physics scheme
137      IF( ln_trczdf_exp ) THEN   ;   nzdf = 0     ! explicit scheme
138      ELSE                       ;   nzdf = 1     ! implicit scheme
139      ENDIF
140
141      !                                ! Force implicit schemes
142      IF( ln_trcldf_iso              )   nzdf = 1      ! iso-neutral lateral physics
143      IF( ln_trcldf_hor .AND. ln_sco )   nzdf = 1      ! horizontal lateral physics in s-coordinate
144#if defined key_zdftke || defined key_zdfgls 
145                                         nzdf = 1      ! TKE or GLS physics       
146#endif
147      IF( ln_trczdf_exp .AND. nzdf == 1 )  & 
148         CALL ctl_stop( 'trc_zdf : If using the rotated lateral mixing operator or TKE, GLS vertical scheme ', &
149            &           '          the implicit scheme is required, set ln_trczdf_exp = .false.' )
150
151      IF(lwp) THEN
152         WRITE(numout,*)
153         WRITE(numout,*) 'trc:zdf_ctl : vertical passive tracer physics scheme'
154         WRITE(numout,*) '~~~~~~~~~~~'
155         IF( nzdf ==  0 )   WRITE(numout,*) '              Explicit time-splitting scheme'
156         IF( nzdf ==  1 )   WRITE(numout,*) '              Implicit (euler backward) scheme'
157      ENDIF
158      !
159   END SUBROUTINE trc_zdf_ini
160   
161#else
162   !!----------------------------------------------------------------------
163   !!   Default option                                         Empty module
164   !!----------------------------------------------------------------------
165CONTAINS
166   SUBROUTINE trc_zdf( kt )
167      INTEGER, INTENT(in) :: kt 
168      WRITE(*,*) 'trc_zdf: You should not have seen this print! error?', kt
169   END SUBROUTINE trc_zdf
170#endif
171   !!==============================================================================
172END MODULE trczdf
Note: See TracBrowser for help on using the repository browser.