New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
nemogcm.F90 in branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC – NEMO

source: branches/2015/dev_MetOffice_merge_2015/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 6008

Last change on this file since 6008 was 6008, checked in by mathiot, 8 years ago

MetO_merge_branch: minor change to run SETTE tests

  • Property svn:keywords set to Id
File size: 41.1 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Ocean system   : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5   !!======================================================================
6   !! History :  OPA  ! 1990-10  (C. Levy, G. Madec)  Original code
7   !!            7.0  ! 1991-11  (M. Imbard, C. Levy, G. Madec)
8   !!            7.1  ! 1993-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9   !!                             P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10   !!             -   ! 1992-06  (L.Terray)  coupling implementation
11   !!             -   ! 1993-11  (M.A. Filiberti) IGLOO sea-ice
12   !!            8.0  ! 1996-03  (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13   !!                             P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14   !!            8.1  ! 1997-06  (M. Imbard, G. Madec)
15   !!            8.2  ! 1999-11  (M. Imbard, H. Goosse)  LIM sea-ice model
16   !!                 ! 1999-12  (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols)  OPEN-MP
17   !!                 ! 2000-07  (J-M Molines, M. Imbard)  Open Boundary Conditions  (CLIPPER)
18   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and modules
19   !!             -   ! 2004-06  (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20   !!             -   ! 2004-08  (C. Talandier) New trends organization
21   !!             -   ! 2005-06  (C. Ethe) Add the 1D configuration possibility
22   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
23   !!             -   ! 2006-03  (L. Debreu, C. Mazauric)  Agrif implementation
24   !!             -   ! 2006-04  (G. Madec, R. Benshila)  Step reorganization
25   !!             -   ! 2007-07  (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26   !!            3.2  ! 2009-08  (S. Masson)  open/write in the listing file in mpp
27   !!            3.3  ! 2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28   !!             -   ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
29   !!            3.3.1! 2011-01  (A. R. Porter, STFC Daresbury) dynamical allocation
30   !!            3.4  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE) add nemo_northcomms
31   !!             -   ! 2011-11  (C. Harris) decomposition changes for running with CICE
32   !!            3.6  ! 2012-05  (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
33   !!             -   ! 2013-06  (I. Epicoco, S. Mocavero, CMCC) nemo_northcomms: setup avoiding MPI communication
34   !!             -   ! 2014-12  (G. Madec) remove KPP scheme and cross-land advection (cla)
35   !!----------------------------------------------------------------------
36
37   !!----------------------------------------------------------------------
38   !!   nemo_gcm       : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
39   !!   nemo_init      : initialization of the NEMO system
40   !!   nemo_ctl       : initialisation of the contol print
41   !!   nemo_closefile : close remaining open files
42   !!   nemo_alloc     : dynamical allocation
43   !!   nemo_partition : calculate MPP domain decomposition
44   !!   factorise      : calculate the factors of the no. of MPI processes
45   !!----------------------------------------------------------------------
46   USE step_oce        ! module used in the ocean time stepping module (step.F90)
47   USE domcfg          ! domain configuration               (dom_cfg routine)
48   USE mppini          ! shared/distributed memory setting (mpp_init routine)
49   USE domain          ! domain initialization             (dom_init routine)
50#if defined key_nemocice_decomp
51   USE ice_domain_size, only: nx_global, ny_global
52#endif
53   USE tideini         ! tidal components initialization   (tide_ini routine)
54   USE bdyini          ! open boundary cond. setting       (bdy_init routine)
55   USE bdydta          ! open boundary cond. setting   (bdy_dta_init routine)
56   USE bdytides        ! open boundary cond. setting   (bdytide_init routine)
57   USE istate          ! initial state setting          (istate_init routine)
58   USE ldfdyn          ! lateral viscosity setting      (ldfdyn_init routine)
59   USE ldftra          ! lateral diffusivity setting    (ldftra_init routine)
60   USE zdfini          ! vertical physics setting          (zdf_init routine)
61   USE phycst          ! physical constant                  (par_cst routine)
62   USE trdini          ! dyn/tra trends initialization     (trd_init routine)
63   USE asminc          ! assimilation increments     
64   USE asmbkg          ! writing out state trajectory
65   USE diaptr          ! poleward transports           (dia_ptr_init routine)
66   USE diadct          ! sections transports           (dia_dct_init routine)
67   USE diaobs          ! Observation diagnostics       (dia_obs_init routine)
68   USE diacfl          ! CFL diagnostics               (dia_cfl_init routine)
69   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
70   USE step            ! NEMO time-stepping                 (stp     routine)
71   USE icbini          ! handle bergs, initialisation
72   USE icbstp          ! handle bergs, calving, themodynamics and transport
73   USE cpl_oasis3      ! OASIS3 coupling
74   USE c1d             ! 1D configuration
75   USE step_c1d        ! Time stepping loop for the 1D configuration
76   USE dyndmp          ! Momentum damping
77#if defined key_top
78   USE trcini          ! passive tracer initialisation
79#endif
80   USE lib_mpp         ! distributed memory computing
81   USE diurnal_bulk    ! diurnal bulk SST
82#if defined key_iomput
83   USE xios            ! xIOserver
84#endif
85   USE sbctide, ONLY   : lk_tide
86   USE crsini          ! initialise grid coarsening utility
87   USE lbcnfd , ONLY   : isendto, nsndto, nfsloop, nfeloop   ! Setup of north fold exchanges
88   USE sbc_oce, ONLY   : lk_oasis
89   USE stopar
90   USE stopts
91
92   IMPLICIT NONE
93   PRIVATE
94
95   PUBLIC   nemo_gcm    ! called by model.F90
96   PUBLIC   nemo_init   ! needed by AGRIF
97   PUBLIC   nemo_alloc  ! needed by TAM
98
99   CHARACTER(lc) ::   cform_aaa="( /, 'AAAAAAAA', / ) "     ! flag for output listing
100
101   !!----------------------------------------------------------------------
102   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
103   !! $Id$
104   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
105   !!----------------------------------------------------------------------
106CONTAINS
107
108   SUBROUTINE nemo_gcm
109      !!----------------------------------------------------------------------
110      !!                     ***  ROUTINE nemo_gcm  ***
111      !!
112      !! ** Purpose :   NEMO solves the primitive equations on an orthogonal
113      !!              curvilinear mesh on the sphere.
114      !!
115      !! ** Method  : - model general initialization
116      !!              - launch the time-stepping (stp routine)
117      !!              - finalize the run by closing files and communications
118      !!
119      !! References : Madec, Delecluse, Imbard, and Levy, 1997:  internal report, IPSL.
120      !!              Madec, 2008, internal report, IPSL.
121      !!----------------------------------------------------------------------
122      INTEGER ::   istp       ! time step index
123      !!----------------------------------------------------------------------
124      !
125#if defined key_agrif
126      CALL Agrif_Init_Grids()      ! AGRIF: set the meshes
127#endif
128
129      !                            !-----------------------!
130      CALL nemo_init               !==  Initialisations  ==!
131      !                            !-----------------------!
132#if defined key_agrif
133      CALL Agrif_Declare_Var_dom   ! AGRIF: set the meshes for DOM
134      CALL Agrif_Declare_Var       !  "      "   "   "      "  DYN/TRA
135# if defined key_top
136      CALL Agrif_Declare_Var_top   !  "      "   "   "      "  TOP
137# endif
138# if defined key_lim2
139      CALL Agrif_Declare_Var_lim2  !  "      "   "   "      "  LIM
140# endif
141#endif
142      ! check that all process are still there... If some process have an error,
143      ! they will never enter in step and other processes will wait until the end of the cpu time!
144      IF( lk_mpp )   CALL mpp_max( nstop )
145
146      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
147
148      !                            !-----------------------!
149      !                            !==   time stepping   ==!
150      !                            !-----------------------!
151      istp = nit000
152#if defined key_c1d
153         DO WHILE ( istp <= nitend .AND. nstop == 0 )
154            CALL stp_c1d( istp )
155            istp = istp + 1
156         END DO
157#else
158          IF( lk_asminc ) THEN
159             IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 )    ! Output background fields
160             IF( ln_asmdin ) THEN                        ! Direct initialization
161                IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 )    ! Tracers
162                IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 )    ! Dynamics
163                IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 )    ! SSH
164             ENDIF
165          ENDIF
166
167#if defined key_agrif
168          CALL Agrif_Regrid()
169#endif
170
171         DO WHILE ( istp <= nitend .AND. nstop == 0 )
172#if defined key_agrif
173            CALL stp                         ! AGRIF: time stepping
174#else
175            IF ( .NOT. ln_diurnal_only ) THEN
176               CALL stp( istp )                 ! standard time stepping
177            ELSE
178               CALL stp_diurnal( istp )        ! time step only the diurnal SST
179            ENDIF 
180#endif
181            istp = istp + 1
182            IF( lk_mpp )   CALL mpp_max( nstop )
183         END DO
184#endif
185
186      IF( ln_diaobs   )   CALL dia_obs_wri
187      !
188      IF( ln_icebergs )   CALL icb_end( nitend )
189
190      !                            !------------------------!
191      !                            !==  finalize the run  ==!
192      !                            !------------------------!
193      IF(lwp) WRITE(numout,cform_aaa)   ! Flag AAAAAAA
194      !
195      IF( nstop /= 0 .AND. lwp ) THEN   ! error print
196         WRITE(numout,cform_err)
197         WRITE(numout,*) nstop, ' error have been found'
198      ENDIF
199      !
200#if defined key_agrif
201      IF( .NOT. Agrif_Root() ) THEN
202                         CALL Agrif_ParentGrid_To_ChildGrid()
203         IF( ln_diaobs ) CALL dia_obs_wri
204         IF( nn_timing == 1 )   CALL timing_finalize
205                                CALL Agrif_ChildGrid_To_ParentGrid()
206      ENDIF
207#endif
208      IF( nn_timing == 1 )   CALL timing_finalize
209      !
210      CALL nemo_closefile
211      !
212#if defined key_iomput
213      CALL xios_finalize                  ! end mpp communications with xios
214      IF( lk_oasis )   CALL cpl_finalize  ! end coupling and mpp communications with OASIS
215#else
216      IF( lk_oasis ) THEN
217         CALL cpl_finalize              ! end coupling and mpp communications with OASIS
218      ELSE
219         IF( lk_mpp )   CALL mppstop    ! end mpp communications
220      ENDIF
221#endif
222      !
223   END SUBROUTINE nemo_gcm
224
225
226   SUBROUTINE nemo_init
227      !!----------------------------------------------------------------------
228      !!                     ***  ROUTINE nemo_init  ***
229      !!
230      !! ** Purpose :   initialization of the NEMO GCM
231      !!----------------------------------------------------------------------
232      INTEGER ::   ji            ! dummy loop indices
233      INTEGER ::   ilocal_comm   ! local integer
234      INTEGER ::   ios
235      CHARACTER(len=80), DIMENSION(16) ::   cltxt
236      !
237      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
238         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
239         &             nn_bench, nn_timing, nn_diacfl
240      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
241         &             jpizoom, jpjzoom, jperio, ln_use_jattr
242      !!----------------------------------------------------------------------
243      !
244      cltxt = ''
245      cxios_context = 'nemo'
246      !
247      !                             ! Open reference namelist and configuration namelist files
248      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
249      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
250      !
251      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
252      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
253901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
254
255      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
256      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
257902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
258
259      !
260      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
261      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
262903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
263
264      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
265      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
266904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
267
268! Force values for AGRIF zoom (cf. agrif_user.F90)
269#if defined key_agrif
270   IF( .NOT. Agrif_Root() ) THEN
271      jpiglo  = nbcellsx + 2 + 2*nbghostcells
272      jpjglo  = nbcellsy + 2 + 2*nbghostcells
273      jpi     = ( jpiglo-2*jpreci + (jpni-1+0) ) / jpni + 2*jpreci
274      jpj     = ( jpjglo-2*jprecj + (jpnj-1+0) ) / jpnj + 2*jprecj
275      jpidta  = jpiglo
276      jpjdta  = jpjglo
277      jpizoom = 1
278      jpjzoom = 1
279      nperio  = 0
280      jperio  = 0
281      ln_use_jattr = .false.
282   ENDIF
283#endif
284      !
285      !                             !--------------------------------------------!
286      !                             !  set communicator & select the local node  !
287      !                             !  NB: mynode also opens output.namelist.dyn !
288      !                             !      on unit number numond on first proc   !
289      !                             !--------------------------------------------!
290#if defined key_iomput
291      IF( Agrif_Root() ) THEN
292         IF( lk_oasis ) THEN
293            CALL cpl_init( "oceanx", ilocal_comm )                     ! nemo local communicator given by oasis
294            CALL xios_initialize( "not used",local_comm=ilocal_comm )    ! send nemo communicator to xios
295         ELSE
296            CALL  xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm )    ! nemo local communicator given by xios
297         ENDIF
298      ENDIF
299      ! Nodes selection (control print return in cltxt)
300      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
301#else
302      IF( lk_oasis ) THEN
303         IF( Agrif_Root() ) THEN
304            CALL cpl_init( "oceanx", ilocal_comm )                      ! nemo local communicator given by oasis
305         ENDIF
306         ! Nodes selection (control print return in cltxt)
307         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
308      ELSE
309         ilocal_comm = 0
310         ! Nodes selection (control print return in cltxt)
311         narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
312      ENDIF
313#endif
314      narea = narea + 1                                     ! mynode return the rank of proc (0 --> jpnij -1 )
315
316      lwm = (narea == 1)                                    ! control of output namelists
317      lwp = (narea == 1) .OR. ln_ctl                        ! control of all listing output print
318
319      IF(lwm) THEN
320         ! write merged namelists from earlier to output namelist now that the
321         ! file has been opened in call to mynode. nammpp has already been
322         ! written in mynode (if lk_mpp_mpi)
323         WRITE( numond, namctl )
324         WRITE( numond, namcfg )
325      ENDIF
326
327      ! If dimensions of processor grid weren't specified in the namelist file
328      ! then we calculate them here now that we have our communicator size
329      IF( jpni < 1 .OR. jpnj < 1 ) THEN
330#if   defined key_mpp_mpi
331         IF( Agrif_Root() )   CALL nemo_partition( mppsize )
332#else
333         jpni  = 1
334         jpnj  = 1
335         jpnij = jpni*jpnj
336#endif
337      ENDIF
338
339      ! Calculate domain dimensions given calculated jpni and jpnj
340      ! This used to be done in par_oce.F90 when they were parameters rather than variables
341      IF( Agrif_Root() ) THEN
342#if defined key_nemocice_decomp
343         jpi = ( nx_global+2-2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
344         jpj = ( ny_global+2-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
345#else
346         jpi = ( jpiglo     -2*jpreci + (jpni-1) ) / jpni + 2*jpreci    ! first  dim.
347         jpj = ( jpjglo     -2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj    ! second dim.
348#endif
349      ENDIF         
350         jpk = jpkdta                                             ! third dim
351#if defined key_agrif
352         ! simple trick to use same vertical grid as parent but different number of levels:
353         ! Save maximum number of levels in jpkdta, then define all vertical grids with this number.
354         ! Suppress once vertical online interpolation is ok
355         IF(.NOT.Agrif_Root())   jpkdta = Agrif_Parent( jpkdta )
356#endif
357         jpim1 = jpi-1                                            ! inner domain indices
358         jpjm1 = jpj-1                                            !   "           "
359         jpkm1 = jpk-1                                            !   "           "
360         jpij  = jpi*jpj                                          !  jpi x j
361
362      IF(lwp) THEN                            ! open listing units
363         !
364         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
365         !
366         WRITE(numout,*)
367         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
368         WRITE(numout,*) '                       NEMO team'
369         WRITE(numout,*) '            Ocean General Circulation Model'
370         WRITE(numout,*) '                  version 3.7  (2015) '
371         WRITE(numout,*)
372         WRITE(numout,*)
373         DO ji = 1, SIZE(cltxt)
374            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
375         END DO
376         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
377         !
378      ENDIF
379
380      ! Now we know the dimensions of the grid and numout has been set we can
381      ! allocate arrays
382      CALL nemo_alloc()
383
384      !                             !-------------------------------!
385      !                             !  NEMO general initialization  !
386      !                             !-------------------------------!
387
388      CALL nemo_ctl                          ! Control prints & Benchmark
389
390      !                                      ! Domain decomposition
391      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
392      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
393      ENDIF
394      !
395      IF( nn_timing == 1 )  CALL timing_init
396      !
397      !                                      ! General initialization
398                            CALL     phy_cst    ! Physical constants
399                            CALL     eos_init   ! Equation of state
400      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
401                            CALL     dom_cfg    ! Domain configuration
402                            CALL     dom_init   ! Domain
403      IF( ln_crs        )   CALL     crs_init   ! coarsened grid: domain initialization
404      IF( ln_nnogather )    CALL nemo_northcomms! northfold neighbour lists (must be done after the masks are defined)
405      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
406     
407      CALL diurnal_sst_bulk_init            ! diurnal sst
408      IF ( ln_diurnal ) CALL diurnal_sst_coolskin_init   ! cool skin   
409     
410      ! IF ln_diurnal_only, then we only want a subset of the initialisation routines
411      IF ( ln_diurnal_only ) THEN
412         CALL  istate_init   ! ocean initial state (Dynamics and tracers)
413         CALL     sbc_init   ! Forcings : surface module
414         CALL tra_qsr_init   ! penetrative solar radiation qsr
415         IF( ln_diaobs     ) THEN                  ! Observation & model comparison
416            CALL dia_obs_init            ! Initialize observational data
417            CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
418         ENDIF     
419         !                                     ! Assimilation increments
420         IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
421                 
422         IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
423         RETURN
424      ENDIF
425     
426                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
427
428      !                                      ! external forcing
429!!gm to be added : creation and call of sbc_apr_init
430      IF( lk_tide       )   CALL    tide_init( nit000 )    ! tidal harmonics
431                            CALL     sbc_init   ! surface boundary conditions (including sea-ice)
432!!gm ==>> bdy_init should call bdy_dta_init and bdytide_init  NOT in nemogcm !!!
433      IF( lk_bdy        )   CALL     bdy_init   ! Open boundaries initialisation
434      IF( lk_bdy        )   CALL bdy_dta_init   ! Open boundaries initialisation of external data arrays
435      IF( lk_bdy .AND. lk_tide )   &
436         &                  CALL bdytide_init   ! Open boundaries initialisation of tidal harmonic forcing
437         
438      !                                      ! Ocean physics
439      !                                         ! Vertical physics
440                            CALL     zdf_init      ! namelist read
441                            CALL zdf_bfr_init      ! bottom friction
442      IF( lk_zdfric     )   CALL zdf_ric_init      ! Richardson number dependent Kz
443      IF( lk_zdftke     )   CALL zdf_tke_init      ! TKE closure scheme
444      IF( lk_zdfgls     )   CALL zdf_gls_init      ! GLS closure scheme
445      IF( lk_zdftmx     )   CALL zdf_tmx_init      ! tidal vertical mixing
446      IF( lk_zdfddm     )   CALL zdf_ddm_init      ! double diffusive mixing
447         
448      !                                         ! Lateral physics
449                            CALL ldf_tra_init      ! Lateral ocean tracer physics
450                            CALL ldf_eiv_init      ! eddy induced velocity param.
451                            CALL ldf_dyn_init      ! Lateral ocean momentum physics
452
453      !                                         ! Active tracers
454                            CALL tra_qsr_init      ! penetrative solar radiation qsr
455                            CALL tra_bbc_init      ! bottom heat flux
456      IF( lk_trabbl     )   CALL tra_bbl_init      ! advective (and/or diffusive) bottom boundary layer scheme
457                            CALL tra_dmp_init      ! internal tracer damping
458                            CALL tra_adv_init      ! horizontal & vertical advection
459                            CALL tra_ldf_init      ! lateral mixing
460                            CALL tra_zdf_init      ! vertical mixing and after tracer fields
461
462      !                                         ! Dynamics
463      IF( lk_c1d        )   CALL dyn_dmp_init      ! internal momentum damping
464                            CALL dyn_adv_init      ! advection (vector or flux form)
465                            CALL dyn_vor_init      ! vorticity term including Coriolis
466                            CALL dyn_ldf_init      ! lateral mixing
467                            CALL dyn_hpg_init      ! horizontal gradient of Hydrostatic pressure
468                            CALL dyn_zdf_init      ! vertical diffusion
469                            CALL dyn_spg_init      ! surface pressure gradient
470
471#if defined key_top
472      !                                      ! Passive tracers
473                            CALL     trc_init
474#endif
475      IF( l_ldfslp      )   CALL ldf_slp_init   ! slope of lateral mixing
476
477      !                                      ! Icebergs
478                            CALL icb_init( rdt, nit000)   ! initialise icebergs instance
479
480      !                                      ! Misc. options
481                            CALL sto_par_init   ! Stochastic parametrization
482      IF( ln_sto_eos     )  CALL sto_pts_init   ! RRandom T/S fluctuations
483     
484      !                                      ! Diagnostics
485      IF( lk_floats     )   CALL     flo_init   ! drifting Floats
486                            CALL dia_cfl_init   ! Initialise CFL diagnostics
487      IF( lk_diaar5     )   CALL dia_ar5_init   ! ar5 diag
488                            CALL dia_ptr_init   ! Poleward TRansports initialization
489      IF( lk_diadct     )   CALL dia_dct_init   ! Sections tranports
490                            CALL dia_hsb_init   ! heat content, salt content and volume budgets
491                            CALL     trd_init   ! Mixed-layer/Vorticity/Integral constraints trends
492                            CALL dia_obs_init            ! Initialize observational data
493      IF( ln_diaobs     )   CALL dia_obs( nit000 - 1 )   ! Observation operator for restart
494
495      !                                         ! Assimilation increments
496      IF( lk_asminc     )   CALL asm_inc_init   ! Initialize assimilation increments
497      IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
498      !
499   END SUBROUTINE nemo_init
500
501
502   SUBROUTINE nemo_ctl
503      !!----------------------------------------------------------------------
504      !!                     ***  ROUTINE nemo_ctl  ***
505      !!
506      !! ** Purpose :   control print setting
507      !!
508      !! ** Method  : - print namctl information and check some consistencies
509      !!----------------------------------------------------------------------
510      !
511      IF(lwp) THEN                  ! control print
512         WRITE(numout,*)
513         WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
514         WRITE(numout,*) '~~~~~~~ '
515         WRITE(numout,*) '   Namelist namctl'
516         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
517         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
518         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
519         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
520         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
521         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
522         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
523         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
524         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
525         WRITE(numout,*) '      timing activated    (0/1)       nn_timing  = ', nn_timing
526      ENDIF
527      !
528      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
529      nictls    = nn_ictls
530      nictle    = nn_ictle
531      njctls    = nn_jctls
532      njctle    = nn_jctle
533      isplt     = nn_isplt
534      jsplt     = nn_jsplt
535      nbench    = nn_bench
536
537      IF(lwp) THEN                  ! control print
538         WRITE(numout,*)
539         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
540         WRITE(numout,*) '~~~~~~~ '
541         WRITE(numout,*) '   Namelist namcfg'
542         WRITE(numout,*) '      configuration name                               cp_cfg  = ', TRIM(cp_cfg)
543         WRITE(numout,*) '      configuration zoom name                          cp_cfz  = ', TRIM(cp_cfz)
544         WRITE(numout,*) '      configuration resolution                         jp_cfg  = ', jp_cfg
545         WRITE(numout,*) '      1st lateral dimension ( >= jpiglo )              jpidta  = ', jpidta
546         WRITE(numout,*) '      2nd    "         "    ( >= jpjglo )              jpjdta  = ', jpjdta
547         WRITE(numout,*) '      3nd    "         "                               jpkdta  = ', jpkdta
548         WRITE(numout,*) '      1st dimension of global domain in i              jpiglo  = ', jpiglo
549         WRITE(numout,*) '      2nd    -                  -    in j              jpjglo  = ', jpjglo
550         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
551         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
552         WRITE(numout,*) '      lateral cond. type (between 0 and 6)             jperio  = ', jperio   
553         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
554      ENDIF
555      !                             ! Parameter control
556      !
557      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
558         IF( lk_mpp .AND. jpnij > 1 ) THEN
559            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real split domain
560         ELSE
561            IF( isplt == 1 .AND. jsplt == 1  ) THEN
562               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
563                  &           ' - the print control will be done over the whole domain' )
564            ENDIF
565            ijsplt = isplt * jsplt            ! total number of processors ijsplt
566         ENDIF
567         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
568         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
569         !
570         !                              ! indices used for the SUM control
571         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
572            lsp_area = .FALSE.
573         ELSE                                             ! print control done over a specific  area
574            lsp_area = .TRUE.
575            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
576               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
577               nictls = 1
578            ENDIF
579            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
580               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
581               nictle = jpiglo
582            ENDIF
583            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
584               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
585               njctls = 1
586            ENDIF
587            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
588               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
589               njctle = jpjglo
590            ENDIF
591         ENDIF
592      ENDIF
593      !
594      IF( nbench == 1 ) THEN              ! Benchmark
595         SELECT CASE ( cp_cfg )
596         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
597         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
598            &                                 ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
599         END SELECT
600      ENDIF
601      !
602      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
603         &                                               'f2003 standard. '                              ,  &
604         &                                               'Compile with key_nosignedzero enabled' )
605      !
606   END SUBROUTINE nemo_ctl
607
608
609   SUBROUTINE nemo_closefile
610      !!----------------------------------------------------------------------
611      !!                     ***  ROUTINE nemo_closefile  ***
612      !!
613      !! ** Purpose :   Close the files
614      !!----------------------------------------------------------------------
615      !
616      IF( lk_mpp )   CALL mppsync
617      !
618      CALL iom_close                                 ! close all input/output files managed by iom_*
619      !
620      IF( numstp          /= -1 )   CLOSE( numstp          )   ! time-step file
621      IF( numsol          /= -1 )   CLOSE( numsol          )   ! solver file
622      IF( numnam_ref      /= -1 )   CLOSE( numnam_ref      )   ! oce reference namelist
623      IF( numnam_cfg      /= -1 )   CLOSE( numnam_cfg      )   ! oce configuration namelist
624      IF( lwm.AND.numond  /= -1 )   CLOSE( numond          )   ! oce output namelist
625      IF( numnam_ice_ref  /= -1 )   CLOSE( numnam_ice_ref  )   ! ice reference namelist
626      IF( numnam_ice_cfg  /= -1 )   CLOSE( numnam_ice_cfg  )   ! ice configuration namelist
627      IF( lwm.AND.numoni  /= -1 )   CLOSE( numoni          )   ! ice output namelist
628      IF( numevo_ice      /= -1 )   CLOSE( numevo_ice      )   ! ice variables (temp. evolution)
629      IF( numout          /=  6 )   CLOSE( numout          )   ! standard model output file
630      IF( numdct_vol      /= -1 )   CLOSE( numdct_vol      )   ! volume transports
631      IF( numdct_heat     /= -1 )   CLOSE( numdct_heat     )   ! heat transports
632      IF( numdct_salt     /= -1 )   CLOSE( numdct_salt     )   ! salt transports
633      !
634      numout = 6                                     ! redefine numout in case it is used after this point...
635      !
636   END SUBROUTINE nemo_closefile
637
638
639   SUBROUTINE nemo_alloc
640      !!----------------------------------------------------------------------
641      !!                     ***  ROUTINE nemo_alloc  ***
642      !!
643      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
644      !!
645      !! ** Method  :
646      !!----------------------------------------------------------------------
647      USE diawri    , ONLY: dia_wri_alloc
648      USE dom_oce   , ONLY: dom_oce_alloc
649      USE trc_oce   , ONLY: trc_oce_alloc
650#if defined key_diadct 
651      USE diadct    , ONLY: diadct_alloc 
652#endif 
653#if defined key_bdy
654      USE bdy_oce   , ONLY: bdy_oce_alloc
655#endif
656      !
657      INTEGER :: ierr
658      !!----------------------------------------------------------------------
659      !
660      ierr =        oce_alloc       ()          ! ocean
661      ierr = ierr + dia_wri_alloc   ()
662      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
663      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
664      !
665      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
666      !
667#if defined key_diadct 
668      ierr = ierr + diadct_alloc    ()          !
669#endif 
670#if defined key_bdy
671      ierr = ierr + bdy_oce_alloc   ()          ! bdy masks (incl. initialization)
672#endif
673      !
674      IF( lk_mpp    )   CALL mpp_sum( ierr )
675      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
676      !
677   END SUBROUTINE nemo_alloc
678
679
680   SUBROUTINE nemo_partition( num_pes )
681      !!----------------------------------------------------------------------
682      !!                 ***  ROUTINE nemo_partition  ***
683      !!
684      !! ** Purpose :
685      !!
686      !! ** Method  :
687      !!----------------------------------------------------------------------
688      INTEGER, INTENT(in) ::   num_pes   ! The number of MPI processes we have
689      !
690      INTEGER, PARAMETER :: nfactmax = 20
691      INTEGER :: nfact ! The no. of factors returned
692      INTEGER :: ierr  ! Error flag
693      INTEGER :: ji
694      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
695      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
696      !!----------------------------------------------------------------------
697      !
698      ierr = 0
699      !
700      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
701      !
702      IF( nfact <= 1 ) THEN
703         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
704         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
705         jpnj = 1
706         jpni = num_pes
707      ELSE
708         ! Search through factors for the pair that are closest in value
709         mindiff = 1000000
710         imin    = 1
711         DO ji = 1, nfact-1, 2
712            idiff = ABS( ifact(ji) - ifact(ji+1) )
713            IF( idiff < mindiff ) THEN
714               mindiff = idiff
715               imin = ji
716            ENDIF
717         END DO
718         jpnj = ifact(imin)
719         jpni = ifact(imin + 1)
720      ENDIF
721      !
722      jpnij = jpni*jpnj
723      !
724   END SUBROUTINE nemo_partition
725
726
727   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
728      !!----------------------------------------------------------------------
729      !!                     ***  ROUTINE factorise  ***
730      !!
731      !! ** Purpose :   return the prime factors of n.
732      !!                knfax factors are returned in array kfax which is of
733      !!                maximum dimension kmaxfax.
734      !! ** Method  :
735      !!----------------------------------------------------------------------
736      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
737      INTEGER                    , INTENT(  out) ::   kerr, knfax
738      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
739      !
740      INTEGER :: ifac, jl, inu
741      INTEGER, PARAMETER :: ntest = 14
742      INTEGER, DIMENSION(ntest) ::   ilfax
743      !!----------------------------------------------------------------------
744      !
745      ! lfax contains the set of allowed factors.
746      ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
747      !
748      ! Clear the error flag and initialise output vars
749      kerr  = 0
750      kfax  = 1
751      knfax = 0
752      !
753      ! Find the factors of n.
754      IF( kn == 1 )   GOTO 20
755
756      ! nu holds the unfactorised part of the number.
757      ! knfax holds the number of factors found.
758      ! l points to the allowed factor list.
759      ! ifac holds the current factor.
760      !
761      inu   = kn
762      knfax = 0
763      !
764      DO jl = ntest, 1, -1
765         !
766         ifac = ilfax(jl)
767         IF( ifac > inu )   CYCLE
768
769         ! Test whether the factor will divide.
770
771         IF( MOD(inu,ifac) == 0 ) THEN
772            !
773            knfax = knfax + 1            ! Add the factor to the list
774            IF( knfax > kmaxfax ) THEN
775               kerr = 6
776               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
777               return
778            ENDIF
779            kfax(knfax) = ifac
780            ! Store the other factor that goes with this one
781            knfax = knfax + 1
782            kfax(knfax) = inu / ifac
783            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
784         ENDIF
785         !
786      END DO
787      !
788   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
789      !
790   END SUBROUTINE factorise
791
792#if defined key_mpp_mpi
793
794   SUBROUTINE nemo_northcomms
795      !!----------------------------------------------------------------------
796      !!                     ***  ROUTINE  nemo_northcomms  ***
797      !! ** Purpose :   Setup for north fold exchanges with explicit
798      !!                point-to-point messaging
799      !!
800      !! ** Method :   Initialization of the northern neighbours lists.
801      !!----------------------------------------------------------------------
802      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
803      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
804      !!----------------------------------------------------------------------
805      INTEGER  ::   sxM, dxM, sxT, dxT, jn
806      INTEGER  ::   njmppmax
807      !!----------------------------------------------------------------------
808      !
809      njmppmax = MAXVAL( njmppt )
810      !
811      !initializes the north-fold communication variables
812      isendto(:) = 0
813      nsndto     = 0
814      !
815      !if I am a process in the north
816      IF ( njmpp == njmppmax ) THEN
817          !sxM is the first point (in the global domain) needed to compute the
818          !north-fold for the current process
819          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
820          !dxM is the last point (in the global domain) needed to compute the
821          !north-fold for the current process
822          dxM = jpiglo - nimppt(narea) + 2
823
824          !loop over the other north-fold processes to find the processes
825          !managing the points belonging to the sxT-dxT range
826 
827          DO jn = 1, jpni
828                !sxT is the first point (in the global domain) of the jn
829                !process
830                sxT = nfiimpp(jn, jpnj)
831                !dxT is the last point (in the global domain) of the jn
832                !process
833                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
834                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
835                   nsndto = nsndto + 1
836                     isendto(nsndto) = jn
837                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
838                   nsndto = nsndto + 1
839                     isendto(nsndto) = jn
840                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
841                   nsndto = nsndto + 1
842                     isendto(nsndto) = jn
843                END IF
844          END DO
845          nfsloop = 1
846          nfeloop = nlci
847          DO jn = 2,jpni-1
848           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
849              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
850                 nfsloop = nldi
851              ENDIF
852              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
853                 nfeloop = nlei
854              ENDIF
855           ENDIF
856        END DO
857
858      ENDIF
859      l_north_nogather = .TRUE.
860   END SUBROUTINE nemo_northcomms
861
862#else
863   SUBROUTINE nemo_northcomms      ! Dummy routine
864      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
865   END SUBROUTINE nemo_northcomms
866#endif
867
868   !!======================================================================
869END MODULE nemogcm
870
Note: See TracBrowser for help on using the repository browser.