New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydyn.F90 in branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/BDY – NEMO

source: branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/BDY/bdydyn.F90 @ 6060

Last change on this file since 6060 was 6060, checked in by timgraham, 8 years ago

Merged dev_r5836_noc2_VVL_BY_DEFAULT into branch

  • Property svn:keywords set to Id
File size: 6.3 KB
Line 
1MODULE bdydyn
2   !!======================================================================
3   !!                       ***  MODULE  bdydyn  ***
4   !! Unstructured Open Boundary Cond. :   Apply boundary conditions to velocities
5   !!======================================================================
6   !! History :  1.0  !  2005-02  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-07  (D. Storkey) Move Flather implementation to separate routine.
8   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
9   !!            3.2  !  2008-04  (R. Benshila) consider velocity instead of transport
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!----------------------------------------------------------------------
14#if defined key_bdy 
15   !!----------------------------------------------------------------------
16   !!   'key_bdy' :                    Unstructured Open Boundary Condition
17   !!----------------------------------------------------------------------
18   !!   bdy_dyn        : split velocities into barotropic and baroclinic parts
19   !!                    and call bdy_dyn2d and bdy_dyn3d to apply boundary
20   !!                    conditions
21   !!----------------------------------------------------------------------
22   USE wrk_nemo        ! Memory Allocation
23   USE timing          ! Timing
24   USE oce             ! ocean dynamics and tracers
25   USE dom_oce         ! ocean space and time domain
26   USE bdy_oce         ! ocean open boundary conditions
27   USE bdydyn2d        ! open boundary conditions for barotropic solution
28   USE bdydyn3d        ! open boundary conditions for baroclinic velocities
29   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
30   USE in_out_manager  !
31   USE domvvl          ! variable volume
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   bdy_dyn    ! routine called in dyn_nxt
37
38   !!----------------------------------------------------------------------
39   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
40   !! $Id$
41   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
42   !!----------------------------------------------------------------------
43CONTAINS
44
45   SUBROUTINE bdy_dyn( kt, dyn3d_only )
46      !!----------------------------------------------------------------------
47      !!                  ***  SUBROUTINE bdy_dyn  ***
48      !!
49      !! ** Purpose : - Wrapper routine for bdy_dyn2d and bdy_dyn3d.
50      !!
51      !!----------------------------------------------------------------------
52      INTEGER, INTENT(in)           ::   kt           ! Main time step counter
53      LOGICAL, INTENT(in), OPTIONAL ::   dyn3d_only   ! T => only update baroclinic velocities
54      !
55      INTEGER ::   jk, ii, ij, ib_bdy, ib, igrd     ! Loop counter
56      LOGICAL ::   ll_dyn2d, ll_dyn3d, ll_orlanski
57      REAL(wp), POINTER, DIMENSION(:,:) :: pua2d, pva2d     ! after barotropic velocities
58      !!----------------------------------------------------------------------
59      !
60      IF( nn_timing == 1 )   CALL timing_start('bdy_dyn')
61      !
62      ll_dyn2d = .true.
63      ll_dyn3d = .true.
64      !
65      IF( PRESENT(dyn3d_only) ) THEN
66         IF( dyn3d_only )   ll_dyn2d = .false.
67      ENDIF
68      !
69      ll_orlanski = .false.
70      DO ib_bdy = 1, nb_bdy
71         IF ( cn_dyn2d(ib_bdy) == 'orlanski' .OR. cn_dyn2d(ib_bdy) == 'orlanski_npo' &
72     &   .OR. cn_dyn3d(ib_bdy) == 'orlanski' .OR. cn_dyn3d(ib_bdy) == 'orlanski_npo')   ll_orlanski = .true.
73      END DO
74
75      !-------------------------------------------------------
76      ! Set pointers
77      !-------------------------------------------------------
78
79      CALL wrk_alloc( jpi,jpj,   pua2d, pva2d ) 
80
81      !-------------------------------------------------------
82      ! Split velocities into barotropic and baroclinic parts
83      !-------------------------------------------------------
84
85      !                          ! "After" velocities:
86      pua2d(:,:) = 0._wp
87      pva2d(:,:) = 0._wp     
88      DO jk = 1, jpkm1
89         pua2d(:,:) = pua2d(:,:) + e3u_a(:,:,jk) * ua(:,:,jk) * umask(:,:,jk)
90         pva2d(:,:) = pva2d(:,:) + e3v_a(:,:,jk) * va(:,:,jk) * vmask(:,:,jk)
91      END DO
92      pua2d(:,:) = pua2d(:,:) * r1_hu_a(:,:)
93      pva2d(:,:) = pva2d(:,:) * r1_hv_a(:,:)
94
95      DO jk = 1 , jpkm1
96         ua(:,:,jk) = ( ua(:,:,jk) - pua2d(:,:) ) * umask(:,:,jk)
97         va(:,:,jk) = ( va(:,:,jk) - pva2d(:,:) ) * vmask(:,:,jk)
98      END DO
99
100
101      IF( ll_orlanski ) THEN     ! "Before" velocities (Orlanski condition only)
102         DO jk = 1 , jpkm1
103            ub(:,:,jk) = ( ub(:,:,jk) - ub_b(:,:) ) * umask(:,:,jk)
104            vb(:,:,jk) = ( vb(:,:,jk) - vb_b(:,:) ) * vmask(:,:,jk)
105         END DO
106      ENDIF
107
108      !-------------------------------------------------------
109      ! Apply boundary conditions to barotropic and baroclinic
110      ! parts separately
111      !-------------------------------------------------------
112
113      IF( ll_dyn2d )   CALL bdy_dyn2d( kt, pua2d, pva2d, ub_b, vb_b, r1_hu_a(:,:), r1_hv_a(:,:), ssha )
114
115      IF( ll_dyn3d )   CALL bdy_dyn3d( kt )
116
117      !-------------------------------------------------------
118      ! Recombine velocities
119      !-------------------------------------------------------
120      !
121      DO jk = 1 , jpkm1
122         ua(:,:,jk) = ( ua(:,:,jk) + pua2d(:,:) ) * umask(:,:,jk)
123         va(:,:,jk) = ( va(:,:,jk) + pva2d(:,:) ) * vmask(:,:,jk)
124      END DO
125      !
126      IF ( ll_orlanski ) THEN
127         DO jk = 1 , jpkm1
128            ub(:,:,jk) = ( ub(:,:,jk) + ub_b(:,:) ) * umask(:,:,jk)
129            vb(:,:,jk) = ( vb(:,:,jk) + vb_b(:,:) ) * vmask(:,:,jk)
130         END DO
131      END IF
132      !
133      CALL wrk_dealloc( jpi,jpj,  pua2d, pva2d ) 
134      !
135      IF( nn_timing == 1 )   CALL timing_stop('bdy_dyn')
136      !
137   END SUBROUTINE bdy_dyn
138
139#else
140   !!----------------------------------------------------------------------
141   !!   Dummy module                   NO Unstruct Open Boundary Conditions
142   !!----------------------------------------------------------------------
143CONTAINS
144   SUBROUTINE bdy_dyn( kt )      ! Empty routine
145      WRITE(*,*) 'bdy_dyn: You should not have seen this print! error?', kt
146   END SUBROUTINE bdy_dyn
147#endif
148
149   !!======================================================================
150END MODULE bdydyn
Note: See TracBrowser for help on using the repository browser.