New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 6069

Last change on this file since 6069 was 6069, checked in by timgraham, 8 years ago

Merge of dev_MetOffice_merge_2015 into branch (only NEMO directory for now).
  • Property svn:keywords set to Id
File size: 63.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47   USE iom
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                 !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL , PUBLIC ::   ln_hpg_zco   !: z-coordinate - full steps
57   LOGICAL , PUBLIC ::   ln_hpg_zps   !: z-coordinate - partial steps (interpolation)
58   LOGICAL , PUBLIC ::   ln_hpg_sco   !: s-coordinate (standard jacobian formulation)
59   LOGICAL , PUBLIC ::   ln_hpg_djc   !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL , PUBLIC ::   ln_hpg_prj   !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL , PUBLIC ::   ln_hpg_isf   !: s-coordinate similar to sco modify for isf
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE dyn_hpg( kt )
75      !!---------------------------------------------------------------------
76      !!                  ***  ROUTINE dyn_hpg  ***
77      !!
78      !! ** Method  :   Call the hydrostatic pressure gradient routine
79      !!              using the scheme defined in the namelist
80      !!
81      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83      !!----------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
89      !
90      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
91         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
92         ztrdu(:,:,:) = ua(:,:,:)
93         ztrdv(:,:,:) = va(:,:,:)
94      ENDIF
95      !
96      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
97      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
98      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
99      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
100      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
101      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
102      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
103      END SELECT
104      !
105      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
110      ENDIF
111      !
112      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
113         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
114      !
115      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
116      !
117   END SUBROUTINE dyn_hpg
118
119
120   SUBROUTINE dyn_hpg_init
121      !!----------------------------------------------------------------------
122      !!                 ***  ROUTINE dyn_hpg_init  ***
123      !!
124      !! ** Purpose :   initializations for the hydrostatic pressure gradient
125      !!              computation and consistency control
126      !!
127      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
128      !!      with the type of vertical coordinate used (zco, zps, sco)
129      !!----------------------------------------------------------------------
130      INTEGER ::   ioptio = 0      ! temporary integer
131      INTEGER ::   ios             ! Local integer output status for namelist read
132      !!
133      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
134      REAL(wp) ::   znad
135      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
136      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
138      !!
139      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
140         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
141      !!----------------------------------------------------------------------
142      !
143      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
144      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
145901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
146      !
147      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
148      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
149902   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
150      IF(lwm) WRITE ( numond, namdyn_hpg )
151      !
152      IF(lwp) THEN                   ! Control print
153         WRITE(numout,*)
154         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
155         WRITE(numout,*) '~~~~~~~~~~~~'
156         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
157         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
158         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
159         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
161         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
162         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
163      ENDIF
164      !
165      IF( ln_hpg_djc )   &
166         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
167                           & currently disabled (bugs under investigation). Please select &
168                           & either  ln_hpg_sco or  ln_hpg_prj instead')
169      !
170      IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )        &
171         &   CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
172         &                 '   the standard jacobian formulation hpg_sco    or '    , &
173         &                 '   the pressure jacobian formulation hpg_prj'            )
174
175      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
176         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
177      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
178         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
179      !
180      !                               ! Set nhpg from ln_hpg_... flags
181      IF( ln_hpg_zco )   nhpg = 0
182      IF( ln_hpg_zps )   nhpg = 1
183      IF( ln_hpg_sco )   nhpg = 2
184      IF( ln_hpg_djc )   nhpg = 3
185      IF( ln_hpg_prj )   nhpg = 4
186      IF( ln_hpg_isf )   nhpg = 5
187      !
188      !                               ! Consistency check
189      ioptio = 0
190      IF( ln_hpg_zco )   ioptio = ioptio + 1
191      IF( ln_hpg_zps )   ioptio = ioptio + 1
192      IF( ln_hpg_sco )   ioptio = ioptio + 1
193      IF( ln_hpg_djc )   ioptio = ioptio + 1
194      IF( ln_hpg_prj )   ioptio = ioptio + 1
195      IF( ln_hpg_isf )   ioptio = ioptio + 1
196      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
197      !
198      ! initialisation of ice shelf load
199      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
200      IF (       ln_isfcav ) THEN
201         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
202         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
203         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
204         !
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
207         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
208
209         ! To use density and not density anomaly
210         znad=1._wp
211         
212         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
213         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
214
215         ! compute density of the water displaced by the ice shelf
216         DO jk = 1, jpk
217            CALL eos(ztstop(:,:,:),fsdept_n(:,:,jk),zrhd(:,:,jk))
218         END DO
219     
220         ! compute rhd at the ice/oce interface (ice shelf side)
221         CALL eos(ztstop,risfdep,zrhdtop_isf)
222
223         ! Surface value + ice shelf gradient
224         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
225         ! divided by 2 later
226         ziceload = 0._wp
227         DO jj = 1, jpj
228            DO ji = 1, jpi
229               ikt=mikt(ji,jj)
230               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
231               DO jk=2,ikt-1
232                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
233                     &                              * (1._wp - tmask(ji,jj,jk))
234               END DO
235               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
236                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
237            END DO
238         END DO
239         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
240
241         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
242         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
243         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
244      END IF
245      !
246   END SUBROUTINE dyn_hpg_init
247
248
249   SUBROUTINE hpg_zco( kt )
250      !!---------------------------------------------------------------------
251      !!                  ***  ROUTINE hpg_zco  ***
252      !!
253      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
254      !!      The now hydrostatic pressure gradient at a given level, jk,
255      !!      is computed by taking the vertical integral of the in-situ
256      !!      density gradient along the model level from the suface to that
257      !!      level:    zhpi = grav .....
258      !!                zhpj = grav .....
259      !!      add it to the general momentum trend (ua,va).
260      !!            ua = ua - 1/e1u * zhpi
261      !!            va = va - 1/e2v * zhpj
262      !!
263      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
264      !!----------------------------------------------------------------------
265      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
266      !
267      INTEGER  ::   ji, jj, jk       ! dummy loop indices
268      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
269      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
270      !!----------------------------------------------------------------------
271      !
272      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
273      !
274      IF( kt == nit000 ) THEN
275         IF(lwp) WRITE(numout,*)
276         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
277         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
278      ENDIF
279
280      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
281
282      ! Surface value
283      DO jj = 2, jpjm1
284         DO ji = fs_2, fs_jpim1   ! vector opt.
285            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
286            ! hydrostatic pressure gradient
287            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
288            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
289            ! add to the general momentum trend
290            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
291            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
292         END DO
293      END DO
294
295      !
296      ! interior value (2=<jk=<jpkm1)
297      DO jk = 2, jpkm1
298         DO jj = 2, jpjm1
299            DO ji = fs_2, fs_jpim1   ! vector opt.
300               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
301               ! hydrostatic pressure gradient
302               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
303                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )    &
304                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
305
306               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
307                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )    &
308                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
309               ! add to the general momentum trend
310               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
311               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
312            END DO
313         END DO
314      END DO
315      !
316      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
317      !
318   END SUBROUTINE hpg_zco
319
320
321   SUBROUTINE hpg_zps( kt )
322      !!---------------------------------------------------------------------
323      !!                 ***  ROUTINE hpg_zps  ***
324      !!
325      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
326      !!
327      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
328      !!----------------------------------------------------------------------
329      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
330      !!
331      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
332      INTEGER  ::   iku, ikv                         ! temporary integers
333      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
334      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
335      !!----------------------------------------------------------------------
336      !
337      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zhpj )
338      !
339      IF( kt == nit000 ) THEN
340         IF(lwp) WRITE(numout,*)
341         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
342         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
343      ENDIF
344
345      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
346!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
347
348      ! Local constant initialization
349      zcoef0 = - grav * 0.5_wp
350
351      !  Surface value (also valid in partial step case)
352      DO jj = 2, jpjm1
353         DO ji = fs_2, fs_jpim1   ! vector opt.
354            zcoef1 = zcoef0 * e3w_n(ji,jj,1)
355            ! hydrostatic pressure gradient
356            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
357            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
358            ! add to the general momentum trend
359            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
360            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
361         END DO
362      END DO
363
364      ! interior value (2=<jk=<jpkm1)
365      DO jk = 2, jpkm1
366         DO jj = 2, jpjm1
367            DO ji = fs_2, fs_jpim1   ! vector opt.
368               zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
369               ! hydrostatic pressure gradient
370               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
371                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
372                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) * r1_e1u(ji,jj)
373
374               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
375                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
376                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) * r1_e2v(ji,jj)
377               ! add to the general momentum trend
378               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
379               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
380            END DO
381         END DO
382      END DO
383
384      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
385      DO jj = 2, jpjm1
386         DO ji = 2, jpim1
387            iku = mbku(ji,jj)
388            ikv = mbkv(ji,jj)
389            zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj  ,iku) )
390            zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji  ,jj+1,ikv) )
391            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
392               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
393               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
394                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
395               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
396            ENDIF
397            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
398               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
399               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
400                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
401               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
402            ENDIF
403         END DO
404      END DO
405      !
406      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zhpj )
407      !
408   END SUBROUTINE hpg_zps
409
410
411   SUBROUTINE hpg_sco( kt )
412      !!---------------------------------------------------------------------
413      !!                  ***  ROUTINE hpg_sco  ***
414      !!
415      !! ** Method  :   s-coordinate case. Jacobian scheme.
416      !!      The now hydrostatic pressure gradient at a given level, jk,
417      !!      is computed by taking the vertical integral of the in-situ
418      !!      density gradient along the model level from the suface to that
419      !!      level. s-coordinates (ln_sco): a corrective term is added
420      !!      to the horizontal pressure gradient :
421      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
422      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
423      !!      add it to the general momentum trend (ua,va).
424      !!         ua = ua - 1/e1u * zhpi
425      !!         va = va - 1/e2v * zhpj
426      !!
427      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
428      !!----------------------------------------------------------------------
429      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
430      !!
431      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
432      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
433      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
434      !!----------------------------------------------------------------------
435      !
436      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
437      !
438      IF( kt == nit000 ) THEN
439         IF(lwp) WRITE(numout,*)
440         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
441         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
442      ENDIF
443      !
444      zcoef0 = - grav * 0.5_wp
445      IF ( ln_linssh ) THEN   ;   znad = 0._wp         ! Fixed    volume: density anomaly
446      ELSE                    ;   znad = 1._wp         ! Variable volume: density
447      ENDIF
448      !
449      ! Surface value
450      DO jj = 2, jpjm1
451         DO ji = fs_2, fs_jpim1   ! vector opt.
452            ! hydrostatic pressure gradient along s-surfaces
453            zhpi(ji,jj,1) = zcoef0 * (  e3w_n(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )    &
454               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e1u(ji,jj)
455            zhpj(ji,jj,1) = zcoef0 * (  e3w_n(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )    &
456               &                      - e3w_n(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) )  ) * r1_e2v(ji,jj)
457            ! s-coordinate pressure gradient correction
458            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
459               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
460            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
461               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
462            ! add to the general momentum trend
463            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
464            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
465         END DO
466      END DO
467
468      ! interior value (2=<jk=<jpkm1)
469      DO jk = 2, jpkm1
470         DO jj = 2, jpjm1
471            DO ji = fs_2, fs_jpim1   ! vector opt.
472               ! hydrostatic pressure gradient along s-surfaces
473               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj)   &
474                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
475                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
476               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj)   &
477                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
478                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
479               ! s-coordinate pressure gradient correction
480               zuap = -zcoef0 * ( rhd    (ji+1,jj  ,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
481                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
482               zvap = -zcoef0 * ( rhd    (ji  ,jj+1,jk) + rhd    (ji,jj,jk) + 2._wp * znad )   &
483                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
484               ! add to the general momentum trend
485               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
486               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
487            END DO
488         END DO
489      END DO
490      !
491      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
492      !
493   END SUBROUTINE hpg_sco
494
495
496   SUBROUTINE hpg_isf( kt )
497      !!---------------------------------------------------------------------
498      !!                  ***  ROUTINE hpg_isf  ***
499      !!
500      !! ** Method  :   s-coordinate case. Jacobian scheme.
501      !!      The now hydrostatic pressure gradient at a given level, jk,
502      !!      is computed by taking the vertical integral of the in-situ
503      !!      density gradient along the model level from the suface to that
504      !!      level. s-coordinates (ln_sco): a corrective term is added
505      !!      to the horizontal pressure gradient :
506      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
507      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
508      !!      add it to the general momentum trend (ua,va).
509      !!         ua = ua - 1/e1u * zhpi
510      !!         va = va - 1/e2v * zhpj
511      !!      iceload is added and partial cell case are added to the top and bottom
512      !!     
513      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
514      !!----------------------------------------------------------------------
515      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
516      !!
517      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
518      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
519      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
520      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
521      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce
522      !!----------------------------------------------------------------------
523      !
524      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
525      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
526      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce )
527      !
528      ! Local constant initialization
529      zcoef0 = - grav * 0.5_wp
530 
531      ! To use density and not density anomaly
532      znad=1._wp
533
534      ! iniitialised to 0. zhpi zhpi
535      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
536
537      ! compute rhd at the ice/oce interface (ocean side)
538      ! usefull to reduce residual current in the test case ISOMIP with no melting
539      DO ji=1,jpi
540        DO jj=1,jpj
541          ikt=mikt(ji,jj)
542          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
543          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
544        END DO
545      END DO
546      CALL eos( ztstop, risfdep, zrhdtop_oce )
547
548!==================================================================================     
549!===== Compute surface value =====================================================
550!==================================================================================
551      DO jj = 2, jpjm1
552         DO ji = fs_2, fs_jpim1   ! vector opt.
553            ikt    = mikt(ji,jj)
554            iktp1i = mikt(ji+1,jj)
555            iktp1j = mikt(ji,jj+1)
556            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
557            ! we assume ISF is in isostatic equilibrium
558            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i)                                    &
559               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
560               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         &
561               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
562               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
563            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j)                                    &
564               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
565               &                                  - 0.5_wp * e3w_n(ji,jj,ikt)                                         & 
566               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
567               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
568            ! s-coordinate pressure gradient correction (=0 if z coordinate)
569            zuap = -zcoef0 * ( rhd    (ji+1,jj,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
570               &           * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
571            zvap = -zcoef0 * ( rhd    (ji,jj+1,1) + rhd    (ji,jj,1) + 2._wp * znad )   &
572               &           * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
573            ! add to the general momentum trend
574            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
575            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
576         END DO
577      END DO
578!==================================================================================     
579!===== Compute interior value =====================================================
580!==================================================================================
581      ! interior value (2=<jk=<jpkm1)
582      DO jk = 2, jpkm1
583         DO jj = 2, jpjm1
584            DO ji = fs_2, fs_jpim1   ! vector opt.
585               ! hydrostatic pressure gradient along s-surfaces
586               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
587                  &           * (  e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
588                  &              - e3w_n(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
589               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
590                  &           * (  e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
591                  &              - e3w_n(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
592               ! s-coordinate pressure gradient correction
593               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
594                  &           * ( gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
595               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
596                  &           * ( gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
597               ! add to the general momentum trend
598               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
599               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
600            END DO
601         END DO
602      END DO
603     !
604      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
605      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
606      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce )
607      !
608   END SUBROUTINE hpg_isf
609
610
611   SUBROUTINE hpg_djc( kt )
612      !!---------------------------------------------------------------------
613      !!                  ***  ROUTINE hpg_djc  ***
614      !!
615      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
616      !!
617      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
618      !!----------------------------------------------------------------------
619      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
620      !!
621      INTEGER  ::   ji, jj, jk          ! dummy loop indices
622      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
623      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
624      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
625      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
626      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
627      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
628      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
629      !!----------------------------------------------------------------------
630      !
631      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
632      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
633      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
634      !
635
636      IF( kt == nit000 ) THEN
637         IF(lwp) WRITE(numout,*)
638         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
639         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
640      ENDIF
641
642      ! Local constant initialization
643      zcoef0 = - grav * 0.5_wp
644      z1_10  = 1._wp / 10._wp
645      z1_12  = 1._wp / 12._wp
646
647      !----------------------------------------------------------------------------------------
648      !  compute and store in provisional arrays elementary vertical and horizontal differences
649      !----------------------------------------------------------------------------------------
650
651!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
652
653      DO jk = 2, jpkm1
654         DO jj = 2, jpjm1
655            DO ji = fs_2, fs_jpim1   ! vector opt.
656               drhoz(ji,jj,jk) = rhd    (ji  ,jj  ,jk) - rhd    (ji,jj,jk-1)
657               dzz  (ji,jj,jk) = gde3w_n(ji  ,jj  ,jk) - gde3w_n(ji,jj,jk-1)
658               drhox(ji,jj,jk) = rhd    (ji+1,jj  ,jk) - rhd    (ji,jj,jk  )
659               dzx  (ji,jj,jk) = gde3w_n(ji+1,jj  ,jk) - gde3w_n(ji,jj,jk  )
660               drhoy(ji,jj,jk) = rhd    (ji  ,jj+1,jk) - rhd    (ji,jj,jk  )
661               dzy  (ji,jj,jk) = gde3w_n(ji  ,jj+1,jk) - gde3w_n(ji,jj,jk  )
662            END DO
663         END DO
664      END DO
665
666      !-------------------------------------------------------------------------
667      ! compute harmonic averages using eq. 5.18
668      !-------------------------------------------------------------------------
669      zep = 1.e-15
670
671!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
672!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
673
674      DO jk = 2, jpkm1
675         DO jj = 2, jpjm1
676            DO ji = fs_2, fs_jpim1   ! vector opt.
677               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
678
679               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
680               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
681
682               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
683               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
684
685               IF( cffw > zep) THEN
686                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
687                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
688               ELSE
689                  drhow(ji,jj,jk) = 0._wp
690               ENDIF
691
692               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
693                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
694
695               IF( cffu > zep ) THEN
696                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
697                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
698               ELSE
699                  drhou(ji,jj,jk ) = 0._wp
700               ENDIF
701
702               IF( cffx > zep ) THEN
703                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
704                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
705               ELSE
706                  dzu(ji,jj,jk) = 0._wp
707               ENDIF
708
709               IF( cffv > zep ) THEN
710                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
711                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
712               ELSE
713                  drhov(ji,jj,jk) = 0._wp
714               ENDIF
715
716               IF( cffy > zep ) THEN
717                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
718                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
719               ELSE
720                  dzv(ji,jj,jk) = 0._wp
721               ENDIF
722
723            END DO
724         END DO
725      END DO
726
727      !----------------------------------------------------------------------------------
728      ! apply boundary conditions at top and bottom using 5.36-5.37
729      !----------------------------------------------------------------------------------
730      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
731      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
732      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
733
734      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
735      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
736      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
737
738
739      !--------------------------------------------------------------
740      ! Upper half of top-most grid box, compute and store
741      !-------------------------------------------------------------
742
743!!bug gm   :  e3w-gde3w = 0.5*e3w  ....  and gde3w(2)-gde3w(1)=e3w(2) ....   to be verified
744!          true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
745
746      DO jj = 2, jpjm1
747         DO ji = fs_2, fs_jpim1   ! vector opt.
748            rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) )               &
749               &                   * (  rhd(ji,jj,1)                                     &
750               &                     + 0.5_wp * ( rhd    (ji,jj,2) - rhd    (ji,jj,1) )  &
751               &                              * ( e3w_n  (ji,jj,1) - gde3w_n(ji,jj,1) )  &
752               &                              / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) )  )
753         END DO
754      END DO
755
756!!bug gm    : here also, simplification is possible
757!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
758
759      DO jk = 2, jpkm1
760         DO jj = 2, jpjm1
761            DO ji = fs_2, fs_jpim1   ! vector opt.
762
763               rho_k(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj,jk) + rhd    (ji,jj,jk-1) )                                   &
764                  &                     * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) )                                   &
765                  &            - grav * z1_10 * (                                                                   &
766                  &     ( drhow  (ji,jj,jk) - drhow  (ji,jj,jk-1) )                                                     &
767                  &   * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
768                  &   - ( dzw    (ji,jj,jk) - dzw    (ji,jj,jk-1) )                                                     &
769                  &   * ( rhd    (ji,jj,jk) - rhd    (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
770                  &                             )
771
772               rho_i(ji,jj,jk) = zcoef0 * ( rhd    (ji+1,jj,jk) + rhd    (ji,jj,jk) )                                   &
773                  &                     * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) )                                   &
774                  &            - grav* z1_10 * (                                                                    &
775                  &     ( drhou  (ji+1,jj,jk) - drhou  (ji,jj,jk) )                                                     &
776                  &   * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
777                  &   - ( dzu    (ji+1,jj,jk) - dzu    (ji,jj,jk) )                                                     &
778                  &   * ( rhd    (ji+1,jj,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
779                  &                            )
780
781               rho_j(ji,jj,jk) = zcoef0 * ( rhd    (ji,jj+1,jk) + rhd    (ji,jj,jk) )                                 &
782                  &                     * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) )                                   &
783                  &            - grav* z1_10 * (                                                                    &
784                  &     ( drhov  (ji,jj+1,jk) - drhov  (ji,jj,jk) )                                                     &
785                  &   * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
786                  &   - ( dzv    (ji,jj+1,jk) - dzv    (ji,jj,jk) )                                                     &
787                  &   * ( rhd    (ji,jj+1,jk) - rhd    (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
788                  &                            )
789
790            END DO
791         END DO
792      END DO
793      CALL lbc_lnk(rho_k,'W',1.)
794      CALL lbc_lnk(rho_i,'U',1.)
795      CALL lbc_lnk(rho_j,'V',1.)
796
797
798      ! ---------------
799      !  Surface value
800      ! ---------------
801      DO jj = 2, jpjm1
802         DO ji = fs_2, fs_jpim1   ! vector opt.
803            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
804            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
805            ! add to the general momentum trend
806            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
807            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
808         END DO
809      END DO
810
811      ! ----------------
812      !  interior value   (2=<jk=<jpkm1)
813      ! ----------------
814      DO jk = 2, jpkm1
815         DO jj = 2, jpjm1
816            DO ji = fs_2, fs_jpim1   ! vector opt.
817               ! hydrostatic pressure gradient along s-surfaces
818               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
819                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
820                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) * r1_e1u(ji,jj)
821               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
822                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
823                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) * r1_e2v(ji,jj)
824               ! add to the general momentum trend
825               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
826               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
827            END DO
828         END DO
829      END DO
830      !
831      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
832      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
833      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
834      !
835   END SUBROUTINE hpg_djc
836
837
838   SUBROUTINE hpg_prj( kt )
839      !!---------------------------------------------------------------------
840      !!                  ***  ROUTINE hpg_prj  ***
841      !!
842      !! ** Method  :   s-coordinate case.
843      !!      A Pressure-Jacobian horizontal pressure gradient method
844      !!      based on the constrained cubic-spline interpolation for
845      !!      all vertical coordinate systems
846      !!
847      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
848      !!----------------------------------------------------------------------
849      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
850      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
851      !!
852      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
853      REAL(wp) ::   zcoef0, znad                    ! local scalars
854      !
855      !! The local variables for the correction term
856      INTEGER  :: jk1, jis, jid, jjs, jjd
857      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
858      REAL(wp) :: zrhdt1
859      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
860      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
861      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
862      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
863      !!----------------------------------------------------------------------
864      !
865      CALL wrk_alloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
866      CALL wrk_alloc( jpi,jpj,jpk,   zdept, zrhh )
867      CALL wrk_alloc( jpi,jpj,       zsshu_n, zsshv_n )
868      !
869      IF( kt == nit000 ) THEN
870         IF(lwp) WRITE(numout,*)
871         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
872         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
873      ENDIF
874
875      ! Local constant initialization
876      zcoef0 = - grav
877      znad = 1._wp
878      IF( ln_linssh )   znad = 0._wp
879
880      ! Clean 3-D work arrays
881      zhpi(:,:,:) = 0._wp
882      zrhh(:,:,:) = rhd(:,:,:)
883
884      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
885      DO jj = 1, jpj
886        DO ji = 1, jpi
887          jk = mbathy(ji,jj)
888          IF(     jk <=  0   ) THEN   ;   zrhh(ji,jj,    :   ) = 0._wp
889          ELSEIF( jk ==  1   ) THEN   ;   zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
890          ELSEIF( jk < jpkm1 ) THEN
891             DO jkk = jk+1, jpk
892                zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk  ), gde3w_n(ji,jj,jkk-1),   &
893                   &                      gde3w_n(ji,jj,jkk-2), rhd    (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
894             END DO
895          ENDIF
896        END DO
897      END DO
898
899      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
900      DO jj = 1, jpj
901         DO ji = 1, jpi
902            zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
903         END DO
904      END DO
905
906      DO jk = 2, jpk
907         DO jj = 1, jpj
908            DO ji = 1, jpi
909               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
910            END DO
911         END DO
912      END DO
913
914      fsp(:,:,:) = zrhh (:,:,:)
915      xsp(:,:,:) = zdept(:,:,:)
916
917      ! Construct the vertical density profile with the
918      ! constrained cubic spline interpolation
919      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
920      CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
921
922      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
923      DO jj = 2, jpj
924        DO ji = 2, jpi
925          zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1),  &
926             &                                              csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
927
928          ! assuming linear profile across the top half surface layer
929          zhpi(ji,jj,1) =  0.5_wp * e3w_n(ji,jj,1) * zrhdt1
930        END DO
931      END DO
932
933      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
934      DO jk = 2, jpkm1
935        DO jj = 2, jpj
936          DO ji = 2, jpi
937            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                                  &
938               &             integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk),   &
939               &                           asp  (ji,jj,jk-1), bsp  (ji,jj,jk-1), &
940               &                           csp  (ji,jj,jk-1), dsp  (ji,jj,jk-1)  )
941          END DO
942        END DO
943      END DO
944
945      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
946
947      ! Prepare zsshu_n and zsshv_n
948      DO jj = 2, jpjm1
949        DO ji = 2, jpim1
950!!gm BUG ?    if it is ssh at u- & v-point then it should be:
951!          zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
952!                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
953!          zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
954!                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
955!!gm not this:
956          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
957                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
958          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
959                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
960        END DO
961      END DO
962
963      DO jj = 2, jpjm1
964        DO ji = 2, jpim1
965          zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad) 
966          zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
967        END DO
968      END DO
969
970      DO jk = 2, jpkm1
971        DO jj = 2, jpjm1
972          DO ji = 2, jpim1
973            zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
974            zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
975          END DO
976        END DO
977      END DO
978
979      DO jk = 1, jpkm1
980        DO jj = 2, jpjm1
981          DO ji = 2, jpim1
982            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
983            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
984          END DO
985        END DO
986      END DO
987
988      DO jk = 1, jpkm1
989        DO jj = 2, jpjm1
990          DO ji = 2, jpim1
991            zu(ji,jj,jk) = MIN(  zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
992            zu(ji,jj,jk) = MAX(  zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) )  )
993            zv(ji,jj,jk) = MIN(  zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
994            zv(ji,jj,jk) = MAX(  zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) )  )
995          END DO
996        END DO
997      END DO
998
999
1000      DO jk = 1, jpkm1
1001        DO jj = 2, jpjm1
1002          DO ji = 2, jpim1
1003            zpwes = 0._wp; zpwed = 0._wp
1004            zpnss = 0._wp; zpnsd = 0._wp
1005            zuijk = zu(ji,jj,jk)
1006            zvijk = zv(ji,jj,jk)
1007
1008            !!!!!     for u equation
1009            IF( jk <= mbku(ji,jj) ) THEN
1010               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1011                 jis = ji + 1; jid = ji
1012               ELSE
1013                 jis = ji;     jid = ji +1
1014               ENDIF
1015
1016               ! integrate the pressure on the shallow side
1017               jk1 = jk
1018               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1019                 IF( jk1 == mbku(ji,jj) ) THEN
1020                   zuijk = -zdept(jis,jj,jk1)
1021                   EXIT
1022                 ENDIF
1023                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1024                 zpwes = zpwes +                                    &
1025                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1026                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1027                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1028                 jk1 = jk1 + 1
1029               END DO
1030
1031               ! integrate the pressure on the deep side
1032               jk1 = jk
1033               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1034                 IF( jk1 == 1 ) THEN
1035                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1036                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1037                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1038                                                     dsp(jid,jj,1)) * zdeps
1039                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1040                   EXIT
1041                 ENDIF
1042                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1043                 zpwed = zpwed +                                        &
1044                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1045                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1046                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1047                 jk1 = jk1 - 1
1048               END DO
1049
1050               ! update the momentum trends in u direction
1051
1052               zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1053               IF( .NOT.ln_linssh ) THEN
1054                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1055                    &    ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1056                ELSE
1057                 zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1058               ENDIF
1059!!gm  Since umask(ji,:,:) = tmask(ji,:,:) * tmask(ji+1,:,:)  by definition
1060!!gm      in the line below only * umask(ji,jj,jk)  is needed !!
1061               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1062            ENDIF
1063
1064            !!!!!     for v equation
1065            IF( jk <= mbkv(ji,jj) ) THEN
1066               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1067                 jjs = jj + 1; jjd = jj
1068               ELSE
1069                 jjs = jj    ; jjd = jj + 1
1070               ENDIF
1071
1072               ! integrate the pressure on the shallow side
1073               jk1 = jk
1074               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1075                 IF( jk1 == mbkv(ji,jj) ) THEN
1076                   zvijk = -zdept(ji,jjs,jk1)
1077                   EXIT
1078                 ENDIF
1079                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1080                 zpnss = zpnss +                                      &
1081                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1082                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1083                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1084                 jk1 = jk1 + 1
1085               END DO
1086
1087               ! integrate the pressure on the deep side
1088               jk1 = jk
1089               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1090                 IF( jk1 == 1 ) THEN
1091                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1092                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1093                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1094                                                     dsp(ji,jjd,1) ) * zdeps
1095                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1096                   EXIT
1097                 ENDIF
1098                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1099                 zpnsd = zpnsd +                                        &
1100                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1101                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1102                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1103                 jk1 = jk1 - 1
1104               END DO
1105
1106
1107               ! update the momentum trends in v direction
1108
1109               zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1110               IF( .NOT.ln_linssh ) THEN
1111                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1112                          ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1113               ELSE
1114                  zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1115               ENDIF
1116!!gm  Since vmask(:,jj,:) = tmask(:,jj,:) * tmask(:,jj+1,:)  by definition
1117!!gm      in the line below only * vmask(ji,jj,jk)  is needed !!
1118               va(ji,jj,jk) = va(ji,jj,jk) + ( zdpdy1 + zdpdy2 ) * vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1119            ENDIF
1120               !
1121            END DO
1122         END DO
1123      END DO
1124      !
1125      CALL wrk_dealloc( jpi,jpj,jpk,   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1126      CALL wrk_dealloc( jpi,jpj,jpk,   zdept, zrhh )
1127      CALL wrk_dealloc( jpi,jpj,       zsshu_n, zsshv_n )
1128      !
1129   END SUBROUTINE hpg_prj
1130
1131
1132   SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1133      !!----------------------------------------------------------------------
1134      !!                 ***  ROUTINE cspline  ***
1135      !!
1136      !! ** Purpose :   constrained cubic spline interpolation
1137      !!
1138      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1139      !!
1140      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1141      !!----------------------------------------------------------------------
1142      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   fsp, xsp           ! value and coordinate
1143      REAL(wp), DIMENSION(:,:,:), INTENT(  out) ::   asp, bsp, csp, dsp ! coefficients of the interpoated function
1144      INTEGER                   , INTENT(in   ) ::   polynomial_type    ! 1: cubic spline   ;   2: Linear
1145      !
1146      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1147      INTEGER  ::   jpi, jpj, jpkm1
1148      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1149      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1150      REAL(wp) ::   zdf(size(fsp,3))
1151      !!----------------------------------------------------------------------
1152      !
1153!!gm  WHAT !!!!!   THIS IS VERY DANGEROUS !!!!! 
1154      jpi   = size(fsp,1)
1155      jpj   = size(fsp,2)
1156      jpkm1 = size(fsp,3) - 1
1157      !
1158      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1159         DO ji = 1, jpi
1160            DO jj = 1, jpj
1161           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1162           !    DO jk = 2, jpkm1-1
1163           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1164           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1165           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1166           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1167           !
1168           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1169           !
1170           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1171           !           zdf(jk) = 0._wp
1172           !       ELSE
1173           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1174           !       ENDIF
1175           !    END DO
1176
1177           !!Simply geometric average
1178               DO jk = 2, jpkm1-1
1179                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1180                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1181
1182                  IF(zdf1 * zdf2 <= 0._wp) THEN
1183                     zdf(jk) = 0._wp
1184                  ELSE
1185                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1186                  ENDIF
1187               END DO
1188
1189               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1190                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) )           -  0.5_wp * zdf(2)
1191               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1192                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1193
1194               DO jk = 1, jpkm1 - 1
1195                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1196                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1197                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1198                 zddf1  = -2._wp * ztmp1 + ztmp2
1199                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1200                 zddf2  =  2._wp * ztmp1 - ztmp2
1201
1202                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1203                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1204                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1205                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1206                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1207                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1208                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1209                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1210                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1211               END DO
1212            END DO
1213         END DO
1214
1215      ELSEIF ( polynomial_type == 2 ) THEN     ! Linear
1216         DO ji = 1, jpi
1217            DO jj = 1, jpj
1218               DO jk = 1, jpkm1-1
1219                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1220                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1221
1222                  dsp(ji,jj,jk) = 0._wp
1223                  csp(ji,jj,jk) = 0._wp
1224                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1225                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1226               END DO
1227            END DO
1228         END DO
1229
1230      ELSE
1231           CALL ctl_stop( 'invalid polynomial type in cspline' )
1232      ENDIF
1233
1234   END SUBROUTINE cspline
1235
1236
1237   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1238      !!----------------------------------------------------------------------
1239      !!                 ***  ROUTINE interp1  ***
1240      !!
1241      !! ** Purpose :   1-d linear interpolation
1242      !!
1243      !! ** Method  :   interpolation is straight forward
1244      !!                extrapolation is also permitted (no value limit)
1245      !!----------------------------------------------------------------------
1246      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1247      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1248      REAL(wp)             ::  zdeltx
1249      !!----------------------------------------------------------------------
1250      !
1251      zdeltx = xr - xl
1252      IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1253         f = 0.5_wp * (fl + fr)
1254      ELSE
1255         f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1256      ENDIF
1257      !
1258   END FUNCTION interp1
1259
1260
1261   FUNCTION interp2( x, a, b, c, d )  RESULT(f)
1262      !!----------------------------------------------------------------------
1263      !!                 ***  ROUTINE interp1  ***
1264      !!
1265      !! ** Purpose :   1-d constrained cubic spline interpolation
1266      !!
1267      !! ** Method  :  cubic spline interpolation
1268      !!
1269      !!----------------------------------------------------------------------
1270      REAL(wp), INTENT(in) ::  x, a, b, c, d
1271      REAL(wp)             ::  f ! value from the interpolation
1272      !!----------------------------------------------------------------------
1273      !
1274      f = a + x* ( b + x * ( c + d * x ) )
1275      !
1276   END FUNCTION interp2
1277
1278
1279   FUNCTION interp3( x, a, b, c, d )  RESULT(f)
1280      !!----------------------------------------------------------------------
1281      !!                 ***  ROUTINE interp1  ***
1282      !!
1283      !! ** Purpose :   Calculate the first order of deriavtive of
1284      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1285      !!
1286      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1287      !!
1288      !!----------------------------------------------------------------------
1289      REAL(wp), INTENT(in) ::  x, a, b, c, d
1290      REAL(wp)             ::  f ! value from the interpolation
1291      !!----------------------------------------------------------------------
1292      !
1293      f = b + x * ( 2._wp * c + 3._wp * d * x)
1294      !
1295   END FUNCTION interp3
1296
1297
1298   FUNCTION integ_spline( xl, xr, a, b, c, d )  RESULT(f)
1299      !!----------------------------------------------------------------------
1300      !!                 ***  ROUTINE interp1  ***
1301      !!
1302      !! ** Purpose :   1-d constrained cubic spline integration
1303      !!
1304      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1305      !!
1306      !!----------------------------------------------------------------------
1307      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1308      REAL(wp)             ::  za1, za2, za3
1309      REAL(wp)             ::  f                   ! integration result
1310      !!----------------------------------------------------------------------
1311      !
1312      za1 = 0.5_wp * b
1313      za2 = c / 3.0_wp
1314      za3 = 0.25_wp * d
1315      !
1316      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1317         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1318      !
1319   END FUNCTION integ_spline
1320
1321   !!======================================================================
1322END MODULE dynhpg
1323
Note: See TracBrowser for help on using the repository browser.