| 1 | MODULE trasbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trasbc *** |
|---|
| 4 | !! Ocean active tracers: surface boundary condition |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! - ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.6 ! 2014-11 (P. Mathiot) isf melting forcing |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_sbc : update the tracer trend at ocean surface |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and active tracers |
|---|
| 18 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 19 | USE dom_oce ! ocean space domain variables |
|---|
| 20 | USE phycst ! physical constant |
|---|
| 21 | USE eosbn2 ! Equation Of State |
|---|
| 22 | USE sbcmod ! ln_rnf |
|---|
| 23 | USE sbcrnf ! River runoff |
|---|
| 24 | USE sbcisf ! Ice shelf |
|---|
| 25 | USE traqsr ! solar radiation penetration |
|---|
| 26 | USE trd_oce ! trends: ocean variables |
|---|
| 27 | USE trdtra ! trends manager: tracers |
|---|
| 28 | ! |
|---|
| 29 | USE in_out_manager ! I/O manager |
|---|
| 30 | USE prtctl ! Print control |
|---|
| 31 | USE iom ! xIOS server |
|---|
| 32 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 33 | USE wrk_nemo ! Memory Allocation |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC tra_sbc ! routine called by step.F90 |
|---|
| 40 | |
|---|
| 41 | !! * Substitutions |
|---|
| 42 | # include "vectopt_loop_substitute.h90" |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 45 | !! $Id$ |
|---|
| 46 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | CONTAINS |
|---|
| 49 | |
|---|
| 50 | SUBROUTINE tra_sbc ( kt ) |
|---|
| 51 | !!---------------------------------------------------------------------- |
|---|
| 52 | !! *** ROUTINE tra_sbc *** |
|---|
| 53 | !! |
|---|
| 54 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 55 | !! (flux through the interface, concentration/dilution effect) |
|---|
| 56 | !! and add it to the general trend of tracer equations. |
|---|
| 57 | !! |
|---|
| 58 | !! ** Method : The (air+ice)-sea flux has two components: |
|---|
| 59 | !! (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface); |
|---|
| 60 | !! (2) Fwe , tracer carried with the water that is exchanged with air+ice. |
|---|
| 61 | !! The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe, |
|---|
| 62 | !! they are simply added to the tracer trend (tsa). |
|---|
| 63 | !! In linear free surface case (ln_linssh=T), the volume of the |
|---|
| 64 | !! ocean does not change with the water exchanges at the (air+ice)-sea |
|---|
| 65 | !! interface. Therefore another term has to be added, to mimic the |
|---|
| 66 | !! concentration/dilution effect associated with water exchanges. |
|---|
| 67 | !! |
|---|
| 68 | !! ** Action : - Update tsa with the surface boundary condition trend |
|---|
| 69 | !! - send trends to trdtra module for further diagnostics(l_trdtra=T) |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 72 | ! |
|---|
| 73 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 74 | INTEGER :: ikt, ikb ! local integers |
|---|
| 75 | REAL(wp) :: zfact, z1_e3t, zdep ! local scalar |
|---|
| 76 | REAL(wp) :: zalpha, zhk ! - - |
|---|
| 77 | REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdt, ztrds |
|---|
| 78 | !!---------------------------------------------------------------------- |
|---|
| 79 | ! |
|---|
| 80 | IF( nn_timing == 1 ) CALL timing_start('tra_sbc') |
|---|
| 81 | ! |
|---|
| 82 | IF( kt == nit000 ) THEN |
|---|
| 83 | IF(lwp) WRITE(numout,*) |
|---|
| 84 | IF(lwp) WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition' |
|---|
| 85 | IF(lwp) WRITE(numout,*) '~~~~~~~ ' |
|---|
| 86 | ENDIF |
|---|
| 87 | ! |
|---|
| 88 | IF( l_trdtra ) THEN !* Save ta and sa trends |
|---|
| 89 | CALL wrk_alloc( jpi, jpj, jpk, ztrdt, ztrds ) |
|---|
| 90 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 91 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) |
|---|
| 92 | ENDIF |
|---|
| 93 | ! |
|---|
| 94 | !!gm This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist) |
|---|
| 95 | IF( .NOT.ln_traqsr ) THEN ! no solar radiation penetration |
|---|
| 96 | qns(:,:) = qns(:,:) + qsr(:,:) ! total heat flux in qns |
|---|
| 97 | qsr(:,:) = 0._wp ! qsr set to zero |
|---|
| 98 | ENDIF |
|---|
| 99 | |
|---|
| 100 | !---------------------------------------- |
|---|
| 101 | ! EMP, SFX and QNS effects |
|---|
| 102 | !---------------------------------------- |
|---|
| 103 | ! !== Set before sbc tracer content fields ==! |
|---|
| 104 | IF( kt == nit000 ) THEN !* 1st time-step |
|---|
| 105 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 106 | & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 107 | IF(lwp) WRITE(numout,*) ' nit000-1 sbc tracer content field read in the restart file' |
|---|
| 108 | zfact = 0.5_wp |
|---|
| 109 | CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem) ) ! before heat content sbc trend |
|---|
| 110 | CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal) ) ! before salt content sbc trend |
|---|
| 111 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 112 | zfact = 1._wp |
|---|
| 113 | sbc_tsc_b(:,:,:) = 0._wp |
|---|
| 114 | ENDIF |
|---|
| 115 | ELSE !* other time-steps: swap of forcing fields |
|---|
| 116 | zfact = 0.5_wp |
|---|
| 117 | sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:) |
|---|
| 118 | ENDIF |
|---|
| 119 | ! !== Now sbc tracer content fields ==! |
|---|
| 120 | DO jj = 2, jpj |
|---|
| 121 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 122 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 123 | sbc_tsc(ji,jj,jp_sal) = r1_rau0 * sfx(ji,jj) ! salt flux due to freezing/melting |
|---|
| 124 | END DO |
|---|
| 125 | END DO |
|---|
| 126 | IF( ln_linssh ) THEN !* linear free surface |
|---|
| 127 | DO jj = 2, jpj !==>> add concentration/dilution effect due to constant volume cell |
|---|
| 128 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 129 | sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem) |
|---|
| 130 | sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal) |
|---|
| 131 | END DO |
|---|
| 132 | END DO !==>> output c./d. term |
|---|
| 133 | IF( iom_use('emp_x_sst') ) CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) ) |
|---|
| 134 | IF( iom_use('emp_x_sss') ) CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) ) |
|---|
| 135 | ENDIF |
|---|
| 136 | ! |
|---|
| 137 | DO jn = 1, jpts !== update tracer trend ==! |
|---|
| 138 | DO jj = 2, jpj |
|---|
| 139 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 140 | tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1) |
|---|
| 141 | END DO |
|---|
| 142 | END DO |
|---|
| 143 | END DO |
|---|
| 144 | ! |
|---|
| 145 | IF( lrst_oce ) THEN !== write sbc_tsc in the ocean restart file ==! |
|---|
| 146 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem) ) |
|---|
| 147 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal) ) |
|---|
| 148 | ENDIF |
|---|
| 149 | ! |
|---|
| 150 | !---------------------------------------- |
|---|
| 151 | ! Ice Shelf effects (ISF) |
|---|
| 152 | ! tbl treated as in Losh (2008) JGR |
|---|
| 153 | !---------------------------------------- |
|---|
| 154 | ! |
|---|
| 155 | !!gm BUG ? Why no differences between non-linear and linear free surface ? |
|---|
| 156 | !!gm probably taken into account in r1_hisf_tbl : to be verified |
|---|
| 157 | ! |
|---|
| 158 | IF( nn_isf > 0 ) THEN |
|---|
| 159 | zfact = 0.5_wp |
|---|
| 160 | DO jj = 2, jpj |
|---|
| 161 | DO ji = fs_2, fs_jpim1 |
|---|
| 162 | ! |
|---|
| 163 | ikt = misfkt(ji,jj) |
|---|
| 164 | ikb = misfkb(ji,jj) |
|---|
| 165 | ! |
|---|
| 166 | ! level fully include in the ice shelf boundary layer |
|---|
| 167 | ! if isfdiv, we have to remove heat flux due to inflow at 0oC (as in rnf when you add rnf at sst) |
|---|
| 168 | ! sign - because fwf sign of evapo (rnf sign of precip) |
|---|
| 169 | DO jk = ikt, ikb - 1 |
|---|
| 170 | ! compute tfreez for the temperature correction (we add water at freezing temperature) |
|---|
| 171 | ! compute trend |
|---|
| 172 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 173 | & + zfact * (risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem)) * r1_hisf_tbl(ji,jj) |
|---|
| 174 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 175 | & + zfact * (risf_tsc_b(ji,jj,jp_sal) + risf_tsc(ji,jj,jp_sal)) * r1_hisf_tbl(ji,jj) |
|---|
| 176 | END DO |
|---|
| 177 | |
|---|
| 178 | ! level partially include in ice shelf boundary layer |
|---|
| 179 | ! compute tfreez for the temperature correction (we add water at freezing temperature) |
|---|
| 180 | ! compute trend |
|---|
| 181 | tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem) & |
|---|
| 182 | & + zfact * (risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem)) * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) |
|---|
| 183 | tsa(ji,jj,ikb,jp_sal) = tsa(ji,jj,ikb,jp_sal) & |
|---|
| 184 | & + zfact * (risf_tsc_b(ji,jj,jp_sal) + risf_tsc(ji,jj,jp_sal)) * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) |
|---|
| 185 | END DO |
|---|
| 186 | END DO |
|---|
| 187 | IF( lrst_oce ) THEN |
|---|
| 188 | CALL iom_rstput( kt, nitrst, numrow, 'fwf_isf_b', fwfisf (:,:) ) |
|---|
| 189 | CALL iom_rstput( kt, nitrst, numrow, 'isf_hc_b' , risf_tsc(:,:,jp_tem) ) |
|---|
| 190 | CALL iom_rstput( kt, nitrst, numrow, 'isf_sc_b' , risf_tsc(:,:,jp_sal) ) |
|---|
| 191 | ENDIF |
|---|
| 192 | END IF |
|---|
| 193 | ! |
|---|
| 194 | !---------------------------------------- |
|---|
| 195 | ! River Runoff effects |
|---|
| 196 | !---------------------------------------- |
|---|
| 197 | ! |
|---|
| 198 | IF( ln_rnf ) THEN ! input of heat and salt due to river runoff |
|---|
| 199 | zfact = 0.5_wp |
|---|
| 200 | DO jj = 2, jpj |
|---|
| 201 | DO ji = fs_2, fs_jpim1 |
|---|
| 202 | IF( rnf(ji,jj) /= 0._wp ) THEN |
|---|
| 203 | zdep = zfact / h_rnf(ji,jj) |
|---|
| 204 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 205 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 206 | & + ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep |
|---|
| 207 | IF( ln_rnf_sal ) tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 208 | & + ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep |
|---|
| 209 | END DO |
|---|
| 210 | ENDIF |
|---|
| 211 | END DO |
|---|
| 212 | END DO |
|---|
| 213 | ENDIF |
|---|
| 214 | ! |
|---|
| 215 | IF( l_trdtra ) THEN ! send trends for further diagnostics |
|---|
| 216 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 217 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:) |
|---|
| 218 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt ) |
|---|
| 219 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds ) |
|---|
| 220 | CALL wrk_dealloc( jpi, jpj, jpk, ztrdt, ztrds ) |
|---|
| 221 | ENDIF |
|---|
| 222 | ! |
|---|
| 223 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc - Ta: ', mask1=tmask, & |
|---|
| 224 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
|---|
| 225 | ! |
|---|
| 226 | IF( nn_timing == 1 ) CALL timing_stop('tra_sbc') |
|---|
| 227 | ! |
|---|
| 228 | END SUBROUTINE tra_sbc |
|---|
| 229 | |
|---|
| 230 | !!====================================================================== |
|---|
| 231 | END MODULE trasbc |
|---|
