New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zdfbfr.F90 in branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/ZDF – NEMO

source: branches/2015/dev_merge_2015/NEMOGCM/NEMO/OPA_SRC/ZDF/zdfbfr.F90 @ 6060

Last change on this file since 6060 was 6060, checked in by timgraham, 8 years ago

Merged dev_r5836_noc2_VVL_BY_DEFAULT into branch

  • Property svn:keywords set to Id
File size: 25.0 KB
Line 
1MODULE zdfbfr
2   !!======================================================================
3   !!                       ***  MODULE  zdfbfr  ***
4   !! Ocean physics: Bottom friction
5   !!======================================================================
6   !! History :  OPA  ! 1997-06  (G. Madec, A.-M. Treguier)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.2  ! 2009-09  (A.C.Coward)  Correction to include barotropic contribution
9   !!            3.3  ! 2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
10   !!            3.4  ! 2011-11  (H. Liu) implementation of semi-implicit bottom friction option
11   !!                 ! 2012-06  (H. Liu) implementation of Log Layer bottom friction option
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   zdf_bfr      : update bottom friction coefficient (non-linear bottom friction only)
16   !!   zdf_bfr_init : read in namelist and control the bottom friction parameters.
17   !!----------------------------------------------------------------------
18   USE oce             ! ocean dynamics and tracers variables
19   USE dom_oce         ! ocean space and time domain variables
20   USE zdf_oce         ! ocean vertical physics variables
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! distributed memory computing
24   USE prtctl          ! Print control
25   USE timing          ! Timing
26   USE wrk_nemo        ! Memory Allocation
27   USE phycst, ONLY: vkarmn
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   zdf_bfr         ! called by step.F90
33   PUBLIC   zdf_bfr_init    ! called by nemogcm.F90
34
35   !                                 !!* Namelist nambfr: bottom friction namelist *
36   INTEGER , PUBLIC ::   nn_bfr       ! = 0/1/2/3 type of bottom friction  (PUBLIC for TAM)
37   REAL(wp), PUBLIC ::   rn_bfri1     ! bottom drag coefficient (linear case)  (PUBLIC for TAM)
38   REAL(wp), PUBLIC ::   rn_bfri2     ! bottom drag coefficient (non linear case) (PUBLIC for TAM)
39   REAL(wp), PUBLIC ::   rn_bfri2_max ! Maximum bottom drag coefficient (non linear case and ln_loglayer=T) (PUBLIC for TAM)
40   REAL(wp), PUBLIC ::   rn_bfeb2     ! background bottom turbulent kinetic energy  [m2/s2] (PUBLIC for TAM)
41   REAL(wp), PUBLIC ::   rn_bfrien    ! local factor to enhance coefficient bfri (PUBLIC for TAM)
42   LOGICAL , PUBLIC ::   ln_bfr2d     ! logical switch for 2D enhancement (PUBLIC for TAM)
43   REAL(wp), PUBLIC ::   rn_tfri1     ! top drag coefficient (linear case)  (PUBLIC for TAM)
44   REAL(wp), PUBLIC ::   rn_tfri2     ! top drag coefficient (non linear case) (PUBLIC for TAM)
45   REAL(wp), PUBLIC ::   rn_tfri2_max ! Maximum top drag coefficient (non linear case and ln_loglayer=T) (PUBLIC for TAM)
46   REAL(wp), PUBLIC ::   rn_tfeb2     ! background top turbulent kinetic energy  [m2/s2] (PUBLIC for TAM)
47   REAL(wp), PUBLIC ::   rn_tfrien    ! local factor to enhance coefficient tfri (PUBLIC for TAM)
48   LOGICAL , PUBLIC ::   ln_tfr2d     ! logical switch for 2D enhancement (PUBLIC for TAM)
49
50   LOGICAL , PUBLIC ::   ln_loglayer  ! switch for log layer bfr coeff. (PUBLIC for TAM)
51   REAL(wp), PUBLIC ::   rn_bfrz0     ! bottom roughness for loglayer bfr coeff (PUBLIC for TAM)
52   REAL(wp), PUBLIC ::   rn_tfrz0     ! bottom roughness for loglayer bfr coeff (PUBLIC for TAM)
53   LOGICAL , PUBLIC ::   ln_bfrimp    ! logical switch for implicit bottom friction
54   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:), PUBLIC ::  bfrcoef2d, tfrcoef2d   ! 2D bottom/top drag coefficient (PUBLIC for TAM)
55
56   !! * Substitutions
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/OPA 4.0 , NEMO Consortium (2011)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   INTEGER FUNCTION zdf_bfr_alloc()
66      !!----------------------------------------------------------------------
67      !!                ***  FUNCTION zdf_bfr_alloc  ***
68      !!----------------------------------------------------------------------
69      ALLOCATE( bfrcoef2d(jpi,jpj), tfrcoef2d(jpi,jpj), STAT=zdf_bfr_alloc )
70      !
71      IF( lk_mpp             )   CALL mpp_sum ( zdf_bfr_alloc )
72      IF( zdf_bfr_alloc /= 0 )   CALL ctl_warn('zdf_bfr_alloc: failed to allocate arrays.')
73   END FUNCTION zdf_bfr_alloc
74
75
76   SUBROUTINE zdf_bfr( kt )
77      !!----------------------------------------------------------------------
78      !!                   ***  ROUTINE zdf_bfr  ***
79      !!
80      !! ** Purpose :   compute the bottom friction coefficient.
81      !!
82      !! ** Method  :   Calculate and store part of the momentum trend due
83      !!              to bottom friction following the chosen friction type
84      !!              (free-slip, linear, or quadratic). The component
85      !!              calculated here is multiplied by the bottom velocity in
86      !!              dyn_bfr to provide the trend term.
87      !!                The coefficients are updated at each time step only
88      !!              in the quadratic case.
89      !!
90      !! ** Action  :   bfrua , bfrva   bottom friction coefficients
91      !!----------------------------------------------------------------------
92      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
93      !!
94      INTEGER  ::   ji, jj                       ! dummy loop indices
95      INTEGER  ::   ikbt, ikbu, ikbv             ! local integers
96      REAL(wp) ::   zvu, zuv, zecu, zecv, ztmp   ! temporary scalars
97      REAL(wp), POINTER, DIMENSION(:,:) ::  zbfrt, ztfrt
98      !!----------------------------------------------------------------------
99      !
100      IF( nn_timing == 1 )  CALL timing_start('zdf_bfr')
101      !
102      IF( kt == nit000 .AND. lwp ) THEN
103         WRITE(numout,*)
104         WRITE(numout,*) 'zdf_bfr : Set bottom friction coefficient (non-linear case)'
105         WRITE(numout,*) '~~~~~~~~'
106      ENDIF
107      !
108      IF( nn_bfr == 2 ) THEN                 ! quadratic bottom friction only
109         !
110         CALL wrk_alloc( jpi, jpj, zbfrt, ztfrt )
111
112         IF ( ln_loglayer.AND. .NOT.ln_linssh ) THEN ! "log layer" bottom friction coefficient
113
114            DO jj = 1, jpj
115               DO ji = 1, jpi
116                  ikbt = mbkt(ji,jj)
117!! JC: possible WAD implementation should modify line below if layers vanish
118                  ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
119                  zbfrt(ji,jj) = MAX(bfrcoef2d(ji,jj), ztmp)
120                  zbfrt(ji,jj) = MIN(zbfrt(ji,jj), rn_bfri2_max)
121               END DO
122            END DO
123! (ISF)
124            IF ( ln_isfcav ) THEN
125               DO jj = 1, jpj
126                  DO ji = 1, jpi
127                     ikbt = mikt(ji,jj)
128! JC: possible WAD implementation should modify line below if layers vanish
129                     ztmp = (1.-tmask(ji,jj,1)) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
130                     ztfrt(ji,jj) = MAX(tfrcoef2d(ji,jj), ztmp)
131                     ztfrt(ji,jj) = MIN(ztfrt(ji,jj), rn_tfri2_max)
132                  END DO
133               END DO
134            END IF
135            !   
136         ELSE
137            zbfrt(:,:) = bfrcoef2d(:,:)
138            ztfrt(:,:) = tfrcoef2d(:,:)
139         ENDIF
140
141         DO jj = 2, jpjm1
142            DO ji = 2, jpim1
143               ikbu = mbku(ji,jj)         ! ocean bottom level at u- and v-points
144               ikbv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
145               !
146               zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
147                  &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
148               zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
149                  &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
150               !
151               zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_bfeb2  )
152               zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_bfeb2  )
153               !
154               bfrua(ji,jj) = - 0.5_wp * ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) ) * zecu
155               bfrva(ji,jj) = - 0.5_wp * ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) ) * zecv
156               !
157               ! in case of 2 cell water column, we assume each cell feels the top and bottom friction
158               IF ( ln_isfcav ) THEN
159                  IF ( miku(ji,jj) + 1  >=  mbku(ji,jj) ) THEN
160                     bfrua(ji,jj) = - 0.5_wp * ( ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) )   &
161                                  &            + ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) ) ) &
162                                  &          * zecu * (1._wp - umask(ji,jj,1))
163                  ENDIF
164                  IF( mikv(ji,jj) + 1  >=  mbkv(ji,jj) ) THEN
165                     bfrva(ji,jj) = - 0.5_wp * ( ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) )   &
166                                  &            + ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) ) ) &
167                                  &          * zecv * (1._wp - vmask(ji,jj,1))
168                  ENDIF
169               ENDIF
170            END DO
171         END DO
172         CALL lbc_lnk( bfrua, 'U', 1. )   ;   CALL lbc_lnk( bfrva, 'V', 1. )      ! Lateral boundary condition
173
174         IF( ln_isfcav ) THEN
175            DO jj = 2, jpjm1
176               DO ji = 2, jpim1
177                  ! (ISF) ========================================================================
178                  ikbu = miku(ji,jj)         ! ocean top level at u- and v-points
179                  ikbv = mikv(ji,jj)         ! (1st wet ocean u- and v-points)
180                  !
181                  zvu  = 0.25 * (  vn(ji,jj  ,ikbu) + vn(ji+1,jj  ,ikbu)     &
182                     &           + vn(ji,jj-1,ikbu) + vn(ji+1,jj-1,ikbu)  )
183                  zuv  = 0.25 * (  un(ji,jj  ,ikbv) + un(ji-1,jj  ,ikbv)     &
184                     &           + un(ji,jj+1,ikbv) + un(ji-1,jj+1,ikbv)  )
185              !
186                  zecu = SQRT(  un(ji,jj,ikbu) * un(ji,jj,ikbu) + zvu*zvu + rn_tfeb2 )
187                  zecv = SQRT(  vn(ji,jj,ikbv) * vn(ji,jj,ikbv) + zuv*zuv + rn_tfeb2 )
188              !
189                  tfrua(ji,jj) = - 0.5_wp * ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) ) * zecu * (1._wp - umask(ji,jj,1))
190                  tfrva(ji,jj) = - 0.5_wp * ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) ) * zecv * (1._wp - vmask(ji,jj,1))
191              ! (ISF) END ====================================================================
192              ! in case of 2 cell water column, we assume each cell feels the top and bottom friction
193                  IF ( miku(ji,jj) + 1 .GE. mbku(ji,jj) ) THEN
194                     tfrua(ji,jj) = - 0.5_wp * ( ( ztfrt(ji,jj) + ztfrt(ji+1,jj  ) )   &
195                                  &            + ( zbfrt(ji,jj) + zbfrt(ji+1,jj  ) ) ) &
196                                  &          * zecu * (1._wp - umask(ji,jj,1))
197                  END IF
198                  IF ( mikv(ji,jj) + 1 .GE. mbkv(ji,jj) ) THEN
199                     tfrva(ji,jj) = - 0.5_wp * ( ( ztfrt(ji,jj) + ztfrt(ji  ,jj+1) )   &
200                                  &            + ( zbfrt(ji,jj) + zbfrt(ji  ,jj+1) ) ) &
201                                  &          * zecv * (1._wp - vmask(ji,jj,1))
202                  END IF
203               END DO
204            END DO
205            CALL lbc_lnk( tfrua, 'U', 1. )   ;   CALL lbc_lnk( tfrva, 'V', 1. )      ! Lateral boundary condition
206         END IF
207         !
208         !
209         IF(ln_ctl)   CALL prt_ctl( tab2d_1=bfrua, clinfo1=' bfr  - u: ', mask1=umask,        &
210            &                       tab2d_2=bfrva, clinfo2=       ' v: ', mask2=vmask,ovlap=1 )
211         CALL wrk_dealloc( jpi,jpj,zbfrt, ztfrt )
212      ENDIF
213      !
214      IF( nn_timing == 1 )  CALL timing_stop('zdf_bfr')
215      !
216   END SUBROUTINE zdf_bfr
217
218
219   SUBROUTINE zdf_bfr_init
220      !!----------------------------------------------------------------------
221      !!                  ***  ROUTINE zdf_bfr_init  ***
222      !!
223      !! ** Purpose :   Initialization of the bottom friction
224      !!
225      !! ** Method  :   Read the nambfr namelist and check their consistency
226      !!                called at the first timestep (nit000)
227      !!----------------------------------------------------------------------
228      USE iom   ! I/O module for ehanced bottom friction file
229      !!
230      INTEGER   ::   inum         ! logical unit for enhanced bottom friction file
231      INTEGER   ::   ji, jj       ! dummy loop indexes
232      INTEGER   ::   ikbt, ikbu, ikbv   ! temporary integers
233      INTEGER   ::   ictu, ictv         !    -          -
234      INTEGER   ::   ios
235      REAL(wp)  ::   zminbfr, zmaxbfr   ! temporary scalars
236      REAL(wp)  ::   zmintfr, zmaxtfr   ! temporary scalars
237      REAL(wp)  ::   ztmp, zfru, zfrv   !    -         -
238      !!
239      NAMELIST/nambfr/ nn_bfr, rn_bfri1, rn_bfri2, rn_bfri2_max, rn_bfeb2, rn_bfrz0, ln_bfr2d, &
240                    &          rn_tfri1, rn_tfri2, rn_tfri2_max, rn_tfeb2, rn_tfrz0, ln_tfr2d, &
241                    &  rn_bfrien, rn_tfrien, ln_bfrimp, ln_loglayer
242      !!----------------------------------------------------------------------
243      !
244      IF( nn_timing == 1 )  CALL timing_start('zdf_bfr_init')
245      !
246      !                              !* Allocate zdfbfr arrays
247      IF( zdf_bfr_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'zdf_bfr_init : unable to allocate arrays' )
248      !
249      !                              !* Parameter control and print
250      !
251      REWIND( numnam_ref )              ! Namelist nambfr in reference namelist : Bottom momentum boundary condition
252      READ  ( numnam_ref, nambfr, IOSTAT = ios, ERR = 901)
253901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambfr in reference namelist', lwp )
254
255      REWIND( numnam_cfg )              ! Namelist nambfr in configuration namelist : Bottom momentum boundary condition
256      READ  ( numnam_cfg, nambfr, IOSTAT = ios, ERR = 902 )
257902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nambfr in configuration namelist', lwp )
258      IF(lwm) WRITE ( numond, nambfr )
259      IF(lwp) WRITE(numout,*)
260      IF(lwp) WRITE(numout,*) 'zdf_bfr_init : momentum bottom friction'
261      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
262      IF(lwp) WRITE(numout,*) '   Namelist nam_bfr : set bottom friction parameters'
263      !
264      SELECT CASE (nn_bfr)
265      !
266      CASE( 0 )
267         IF(lwp) WRITE(numout,*) '      free-slip '
268         bfrua(:,:) = 0.e0
269         bfrva(:,:) = 0.e0
270         tfrua(:,:) = 0.e0
271         tfrva(:,:) = 0.e0
272         !
273      CASE( 1 )
274         IF(lwp) WRITE(numout,*) '      linear botton friction'
275         IF(lwp) WRITE(numout,*) '      bottom friction coef.   rn_bfri1  = ', rn_bfri1
276         IF( ln_bfr2d ) THEN
277            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
278            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
279         ENDIF
280         IF ( ln_isfcav ) THEN
281            IF(lwp) WRITE(numout,*) '      top    friction coef.   rn_bfri1  = ', rn_tfri1
282            IF( ln_tfr2d ) THEN
283               IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_tfr2d  = ', ln_tfr2d
284               IF(lwp) WRITE(numout,*) '      coef rn_tfri2 enhancement factor                rn_tfrien  = ',rn_tfrien
285            ENDIF
286         END IF
287         !
288         IF(ln_bfr2d) THEN
289            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
290            CALL iom_open('bfr_coef.nc',inum)
291            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
292            CALL iom_close(inum)
293            bfrcoef2d(:,:) = rn_bfri1 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
294         ELSE
295            bfrcoef2d(:,:) = rn_bfri1  ! initialize bfrcoef2d to the namelist variable
296         ENDIF
297         !
298         bfrua(:,:) = - bfrcoef2d(:,:)
299         bfrva(:,:) = - bfrcoef2d(:,:)
300         !
301         IF ( ln_isfcav ) THEN
302            IF(ln_tfr2d) THEN
303               ! tfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
304               CALL iom_open('tfr_coef.nc',inum)
305               CALL iom_get (inum, jpdom_data, 'tfr_coef',tfrcoef2d,1) ! tfrcoef2d is used as tmp array
306               CALL iom_close(inum)
307               tfrcoef2d(:,:) = rn_tfri1 * ( 1 + rn_tfrien * tfrcoef2d(:,:) )
308            ELSE
309               tfrcoef2d(:,:) = rn_tfri1  ! initialize tfrcoef2d to the namelist variable
310            ENDIF
311            !
312            tfrua(:,:) = - tfrcoef2d(:,:)
313            tfrva(:,:) = - tfrcoef2d(:,:)
314         END IF
315         !
316      CASE( 2 )
317         IF(lwp) WRITE(numout,*) '      quadratic bottom friction'
318         IF(lwp) WRITE(numout,*) '      friction coef.   rn_bfri2  = ', rn_bfri2
319         IF(lwp) WRITE(numout,*) '      Max. coef. (log case)   rn_bfri2_max  = ', rn_bfri2_max
320         IF(lwp) WRITE(numout,*) '      background tke   rn_bfeb2  = ', rn_bfeb2
321         IF(lwp) WRITE(numout,*) '      log formulation   ln_bfr2d = ', ln_loglayer
322         IF(lwp) WRITE(numout,*) '      bottom roughness  rn_bfrz0 [m] = ', rn_bfrz0
323         IF( rn_bfrz0<=0.e0 ) THEN
324            WRITE(ctmp1,*) '      bottom roughness must be strictly positive'
325            CALL ctl_stop( ctmp1 )
326         ENDIF
327         IF( ln_bfr2d ) THEN
328            IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_bfr2d  = ', ln_bfr2d
329            IF(lwp) WRITE(numout,*) '      coef rn_bfri2 enhancement factor                rn_bfrien  = ',rn_bfrien
330         ENDIF
331         IF ( ln_isfcav ) THEN
332            IF(lwp) WRITE(numout,*) '      quadratic top    friction'
333            IF(lwp) WRITE(numout,*) '      friction coef.    rn_tfri2     = ', rn_tfri2
334            IF(lwp) WRITE(numout,*) '      Max. coef. (log case)   rn_tfri2_max  = ', rn_tfri2_max
335            IF(lwp) WRITE(numout,*) '      background tke    rn_tfeb2     = ', rn_tfeb2
336            IF(lwp) WRITE(numout,*) '      log formulation   ln_tfr2d     = ', ln_loglayer
337            IF(lwp) WRITE(numout,*) '      top roughness     rn_tfrz0 [m] = ', rn_tfrz0
338            IF( rn_tfrz0<=0.e0 ) THEN
339               WRITE(ctmp1,*) '      top roughness must be strictly positive'
340               CALL ctl_stop( ctmp1 )
341            ENDIF
342            IF( ln_tfr2d ) THEN
343               IF(lwp) WRITE(numout,*) '      read coef. enhancement distribution from file   ln_tfr2d  = ', ln_tfr2d
344               IF(lwp) WRITE(numout,*) '      coef rn_tfri2 enhancement factor                rn_tfrien  = ',rn_tfrien
345            ENDIF
346         END IF
347         !
348         IF(ln_bfr2d) THEN
349            ! bfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
350            CALL iom_open('bfr_coef.nc',inum)
351            CALL iom_get (inum, jpdom_data, 'bfr_coef',bfrcoef2d,1) ! bfrcoef2d is used as tmp array
352            CALL iom_close(inum)
353            !
354            bfrcoef2d(:,:) = rn_bfri2 * ( 1 + rn_bfrien * bfrcoef2d(:,:) )
355         ELSE
356            bfrcoef2d(:,:) = rn_bfri2  ! initialize bfrcoef2d to the namelist variable
357         ENDIF
358         
359         IF ( ln_isfcav ) THEN
360            IF(ln_tfr2d) THEN
361               ! tfr_coef is a coefficient in [0,1] giving the mask where to apply the bfr enhancement
362               CALL iom_open('tfr_coef.nc',inum)
363               CALL iom_get (inum, jpdom_data, 'tfr_coef',tfrcoef2d,1) ! tfrcoef2d is used as tmp array
364               CALL iom_close(inum)
365               !
366               tfrcoef2d(:,:) = rn_tfri2 * ( 1 + rn_tfrien * tfrcoef2d(:,:) )
367            ELSE
368               tfrcoef2d(:,:) = rn_tfri2  ! initialize tfrcoef2d to the namelist variable
369            ENDIF
370         END IF
371         !
372         IF( ln_loglayer.AND. ln_linssh ) THEN ! set "log layer" bottom friction once for all
373            DO jj = 1, jpj
374               DO ji = 1, jpi
375                  ikbt = mbkt(ji,jj)
376                  ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_bfrz0 ))**2._wp
377                  bfrcoef2d(ji,jj) = MAX(bfrcoef2d(ji,jj), ztmp)
378                  bfrcoef2d(ji,jj) = MIN(bfrcoef2d(ji,jj), rn_bfri2_max)
379               END DO
380            END DO
381            IF ( ln_isfcav ) THEN
382               DO jj = 1, jpj
383                  DO ji = 1, jpi
384                     ikbt = mikt(ji,jj)
385                     ztmp = tmask(ji,jj,ikbt) * ( vkarmn / LOG( 0.5_wp * e3t_n(ji,jj,ikbt) / rn_tfrz0 ))**2._wp
386                     tfrcoef2d(ji,jj) = MAX(tfrcoef2d(ji,jj), ztmp)
387                     tfrcoef2d(ji,jj) = MIN(tfrcoef2d(ji,jj), rn_tfri2_max)
388                  END DO
389               END DO
390            END IF
391         ENDIF
392         !
393      CASE DEFAULT
394         IF(lwp) WRITE(ctmp1,*) '         bad flag value for nn_bfr = ', nn_bfr
395         CALL ctl_stop( ctmp1 )
396         !
397      END SELECT
398      !
399      IF(lwp) WRITE(numout,*) '      implicit bottom friction switch                ln_bfrimp  = ', ln_bfrimp
400      !
401      !                              ! Make sure ln_zdfexp=.false. when use implicit bfr
402      IF( ln_bfrimp .AND. ln_zdfexp ) THEN
403         IF(lwp) THEN
404            WRITE(numout,*)
405            WRITE(numout,*) 'Implicit bottom friction can only be used when ln_zdfexp=.false.'
406            WRITE(numout,*) '         but you set: ln_bfrimp=.true. and ln_zdfexp=.true.!!!!'
407            WRITE(ctmp1,*)  '         set either ln_zdfexp = .false or ln_bfrimp = .false.'
408            CALL ctl_stop( ctmp1 )
409         END IF
410      END IF
411      !
412      ! Basic stability check on bottom friction coefficient
413      !
414      ictu = 0               ! counter for stability criterion breaches at U-pts
415      ictv = 0               ! counter for stability criterion breaches at V-pts
416      zminbfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
417      zmaxbfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
418      zmintfr =  1.e10_wp    ! initialise tracker for minimum of bottom friction coefficient
419      zmaxtfr = -1.e10_wp    ! initialise tracker for maximum of bottom friction coefficient
420      !
421      DO jj = 2, jpjm1
422         DO ji = 2, jpim1
423             ikbu = mbku(ji,jj)       ! deepest ocean level at u- and v-points
424             ikbv = mbkv(ji,jj)
425             zfru = 0.5 * e3u_n(ji,jj,ikbu) / rdt
426             zfrv = 0.5 * e3v_n(ji,jj,ikbv) / rdt
427             IF( ABS( bfrcoef2d(ji,jj) ) > zfru ) THEN
428                IF( ln_ctl ) THEN
429                   WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbu
430                   WRITE(numout,*) 'BFR ', ABS( bfrcoef2d(ji,jj) ), zfru
431                ENDIF
432                ictu = ictu + 1
433             ENDIF
434             IF( ABS( bfrcoef2d(ji,jj) ) > zfrv ) THEN
435                 IF( ln_ctl ) THEN
436                     WRITE(numout,*) 'BFR ', narea, nimpp+ji, njmpp+jj, ikbv
437                     WRITE(numout,*) 'BFR ', bfrcoef2d(ji,jj), zfrv
438                 ENDIF
439                 ictv = ictv + 1
440             ENDIF
441             zminbfr = MIN(  zminbfr, MIN( zfru, ABS( bfrcoef2d(ji,jj) ) )  )
442             zmaxbfr = MAX(  zmaxbfr, MIN( zfrv, ABS( bfrcoef2d(ji,jj) ) )  )
443! (ISF)
444             IF ( ln_isfcav ) THEN
445                ikbu = miku(ji,jj)       ! 1st wet ocean level at u- and v-points
446                ikbv = mikv(ji,jj)
447                zfru = 0.5 * e3u_n(ji,jj,ikbu) / rdt
448                zfrv = 0.5 * e3v_n(ji,jj,ikbv) / rdt
449                IF( ABS( tfrcoef2d(ji,jj) ) > zfru ) THEN
450                   IF( ln_ctl ) THEN
451                      WRITE(numout,*) 'TFR ', narea, nimpp+ji, njmpp+jj, ikbu
452                      WRITE(numout,*) 'TFR ', ABS( tfrcoef2d(ji,jj) ), zfru
453                   ENDIF
454                   ictu = ictu + 1
455                ENDIF
456                IF( ABS( tfrcoef2d(ji,jj) ) > zfrv ) THEN
457                   IF( ln_ctl ) THEN
458                      WRITE(numout,*) 'TFR ', narea, nimpp+ji, njmpp+jj, ikbv
459                      WRITE(numout,*) 'TFR ', tfrcoef2d(ji,jj), zfrv
460                   ENDIF
461                   ictv = ictv + 1
462                ENDIF
463                zmintfr = MIN(  zmintfr, MIN( zfru, ABS( tfrcoef2d(ji,jj) ) )  )
464                zmaxtfr = MAX(  zmaxtfr, MIN( zfrv, ABS( tfrcoef2d(ji,jj) ) )  )
465             END IF
466! END ISF
467         END DO
468      END DO
469      IF( lk_mpp ) THEN
470         CALL mpp_sum( ictu )
471         CALL mpp_sum( ictv )
472         CALL mpp_min( zminbfr )
473         CALL mpp_max( zmaxbfr )
474         IF ( ln_isfcav) CALL mpp_min( zmintfr )
475         IF ( ln_isfcav) CALL mpp_max( zmaxtfr )
476      ENDIF
477      IF( .NOT.ln_bfrimp) THEN
478      IF( lwp .AND. ictu + ictv > 0 ) THEN
479         WRITE(numout,*) ' Bottom/Top friction stability check failed at ', ictu, ' U-points '
480         WRITE(numout,*) ' Bottom/Top friction stability check failed at ', ictv, ' V-points '
481         WRITE(numout,*) ' Bottom friction coefficient now ranges from: ', zminbfr, ' to ', zmaxbfr
482         IF ( ln_isfcav ) WRITE(numout,*) ' Top friction coefficient now ranges from: ', zmintfr, ' to ', zmaxtfr
483         WRITE(numout,*) ' Bottom/Top friction coefficient will be reduced where necessary'
484      ENDIF
485      ENDIF
486      !
487      IF( nn_timing == 1 )  CALL timing_stop('zdf_bfr_init')
488      !
489   END SUBROUTINE zdf_bfr_init
490
491   !!======================================================================
492END MODULE zdfbfr
Note: See TracBrowser for help on using the repository browser.