New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diahsb.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/DIA/diahsb.F90 @ 5602

Last change on this file since 5602 was 5602, checked in by cbricaud, 9 years ago

merge change from trunk rev 5003 to 5519 ( rev where branche 3.6_stable were created )

  • Property svn:keywords set to Id
File size: 20.1 KB
Line 
1MODULE diahsb
2   !!======================================================================
3   !!                       ***  MODULE  diahsb  ***
4   !! Ocean diagnostics: Heat, salt and volume budgets
5   !!======================================================================
6   !! History :  3.3  ! 2010-09  (M. Leclair)  Original code
7   !!                 ! 2012-10  (C. Rousset)  add iom_put
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   dia_hsb       : Diagnose the conservation of ocean heat and salt contents, and volume
12   !!   dia_hsb_rst   : Read or write DIA file in restart file
13   !!   dia_hsb_init  : Initialization of the conservation diagnostic
14   !!----------------------------------------------------------------------
15   USE oce             ! ocean dynamics and tracers
16   USE dom_oce         ! ocean space and time domain
17   USE phycst          ! physical constants
18   USE sbc_oce         ! surface thermohaline fluxes
19   USE sbcrnf          ! river runoff
20   USE sbcisf          ! ice shelves
21   USE domvvl          ! vertical scale factors
22   USE traqsr          ! penetrative solar radiation
23   USE trabbc          ! bottom boundary condition
24   USE trabbc          ! bottom boundary condition
25   USE bdy_par         ! (for lk_bdy)
26   USE restart         ! ocean restart
27   !
28   USE iom             ! I/O manager
29   USE in_out_manager  ! I/O manager
30   USE lib_fortran     ! glob_sum
31   USE lib_mpp         ! distributed memory computing library
32   USE timing          ! preformance summary
33   USE wrk_nemo        ! work arrays
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   dia_hsb        ! routine called by step.F90
39   PUBLIC   dia_hsb_init   ! routine called by nemogcm.F90
40   PUBLIC   dia_hsb_rst    ! routine called by step.F90
41
42   LOGICAL, PUBLIC ::   ln_diahsb   !: check the heat and salt budgets
43
44   REAL(wp) ::   surf_tot              ! ocean surface
45   REAL(wp) ::   frc_t, frc_s, frc_v   ! global forcing trends
46   REAL(wp) ::   frc_wn_t, frc_wn_s    ! global forcing trends
47   !
48   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   surf          , ssh_ini          !
49   REAL(wp), DIMENSION(:,:)  , ALLOCATABLE ::   ssh_hc_loc_ini, ssh_sc_loc_ini   !
50   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   hc_loc_ini, sc_loc_ini, e3t_ini  !
51
52   !! * Substitutions
53#  include "domzgr_substitute.h90"
54#  include "vectopt_loop_substitute.h90"
55   !!----------------------------------------------------------------------
56   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
57   !! $Id$
58   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
59   !!----------------------------------------------------------------------
60CONTAINS
61
62   SUBROUTINE dia_hsb( kt )
63      !!---------------------------------------------------------------------------
64      !!                  ***  ROUTINE dia_hsb  ***
65      !!     
66      !! ** Purpose: Compute the ocean global heat content, salt content and volume conservation
67      !!
68      !! ** Method : - Compute the deviation of heat content, salt content and volume
69      !!             at the current time step from their values at nit000
70      !!             - Compute the contribution of forcing and remove it from these deviations
71      !!
72      !!---------------------------------------------------------------------------
73      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
74      !
75      INTEGER    ::   ji, jj, jk                  ! dummy loop indice
76      REAL(wp)   ::   zdiff_hc    , zdiff_sc      ! heat and salt content variations
77      REAL(wp)   ::   zdiff_hc1   , zdiff_sc1     !  -         -     -        -
78      REAL(wp)   ::   zdiff_v1    , zdiff_v2      ! volume variation
79      REAL(wp)   ::   zerr_hc1    , zerr_sc1      ! heat and salt content misfit
80      REAL(wp)   ::   zvol_tot                    ! volume
81      REAL(wp)   ::   z_frc_trd_t , z_frc_trd_s   !    -     -
82      REAL(wp)   ::   z_frc_trd_v                 !    -     -
83      REAL(wp)   ::   z_wn_trd_t , z_wn_trd_s     !    -     -
84      REAL(wp)   ::   z_ssh_hc , z_ssh_sc         !    -     -
85      REAL(wp), DIMENSION(:,:), POINTER ::   z2d0, z2d1
86      !!---------------------------------------------------------------------------
87      IF( nn_timing == 1 )   CALL timing_start('dia_hsb')     
88      CALL wrk_alloc( jpi,jpj,   z2d0, z2d1 )
89      !
90      tsn(:,:,:,1) = tsn(:,:,:,1) * tmask(:,:,:) ; tsb(:,:,:,1) = tsb(:,:,:,1) * tmask(:,:,:) ;
91      tsn(:,:,:,2) = tsn(:,:,:,2) * tmask(:,:,:) ; tsb(:,:,:,2) = tsb(:,:,:,2) * tmask(:,:,:) ;
92      ! ------------------------- !
93      ! 1 - Trends due to forcing !
94      ! ------------------------- !
95      z_frc_trd_v = r1_rau0 * glob_sum( - ( emp(:,:) - rnf(:,:) + rdivisf * fwfisf(:,:) ) * surf(:,:) ) ! volume fluxes
96      z_frc_trd_t =           glob_sum( sbc_tsc(:,:,jp_tem) * surf(:,:) )                               ! heat fluxes
97      z_frc_trd_s =           glob_sum( sbc_tsc(:,:,jp_sal) * surf(:,:) )                               ! salt fluxes
98      ! Add runoff    heat & salt input
99      IF( ln_rnf    )   z_frc_trd_t = z_frc_trd_t + glob_sum( rnf_tsc(:,:,jp_tem) * surf(:,:) )
100      IF( ln_rnf_sal)   z_frc_trd_s = z_frc_trd_s + glob_sum( rnf_tsc(:,:,jp_sal) * surf(:,:) )
101      ! Add ice shelf heat & salt input
102      IF( nn_isf .GE. 1 )  THEN
103          z_frc_trd_t = z_frc_trd_t &
104              &   + glob_sum( ( risf_tsc(:,:,jp_tem) - rdivisf * fwfisf(:,:) * (-1.9) * r1_rau0 ) * surf(:,:) )
105          z_frc_trd_s = z_frc_trd_s + (1.0_wp - rdivisf) * glob_sum( risf_tsc(:,:,jp_sal) * surf(:,:) )
106      ENDIF
107
108      ! Add penetrative solar radiation
109      IF( ln_traqsr )   z_frc_trd_t = z_frc_trd_t + r1_rau0_rcp * glob_sum( qsr     (:,:) * surf(:,:) )
110      ! Add geothermal heat flux
111      IF( ln_trabbc )   z_frc_trd_t = z_frc_trd_t +               glob_sum( qgh_trd0(:,:) * surf(:,:) )
112      !
113      IF( .NOT. lk_vvl ) THEN
114         IF ( ln_isfcav ) THEN
115            DO ji=1,jpi
116               DO jj=1,jpj
117                  z2d0(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_tem)
118                  z2d1(ji,jj) = surf(ji,jj) * wn(ji,jj,mikt(ji,jj)) * tsb(ji,jj,mikt(ji,jj),jp_sal)
119               ENDDO
120            ENDDO
121         ELSE
122            z2d0(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_tem)
123            z2d1(:,:) = surf(:,:) * wn(:,:,1) * tsb(:,:,1,jp_sal)
124         END IF
125         z_wn_trd_t = - glob_sum( z2d0 ) 
126         z_wn_trd_s = - glob_sum( z2d1 )
127      ENDIF
128
129      frc_v = frc_v + z_frc_trd_v * rdt
130      frc_t = frc_t + z_frc_trd_t * rdt
131      frc_s = frc_s + z_frc_trd_s * rdt
132      !                                          ! Advection flux through fixed surface (z=0)
133      IF( .NOT. lk_vvl ) THEN
134         frc_wn_t = frc_wn_t + z_wn_trd_t * rdt
135         frc_wn_s = frc_wn_s + z_wn_trd_s * rdt
136      ENDIF
137
138      ! ------------------------ !
139      ! 2 -  Content variations !
140      ! ------------------------ !
141      zdiff_v2 = 0._wp
142      zdiff_hc = 0._wp
143      zdiff_sc = 0._wp
144
145      ! volume variation (calculated with ssh)
146      zdiff_v1 = glob_sum( surf(:,:) * ( sshn(:,:) - ssh_ini(:,:) ) )
147
148      ! heat & salt content variation (associated with ssh)
149      IF( .NOT. lk_vvl ) THEN
150         IF ( ln_isfcav ) THEN
151            DO ji = 1, jpi
152               DO jj = 1, jpj
153                  z2d0(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj) - ssh_hc_loc_ini(ji,jj) ) 
154                  z2d1(ji,jj) = surf(ji,jj) * ( tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj) - ssh_sc_loc_ini(ji,jj) ) 
155               END DO
156            END DO
157         ELSE
158            z2d0(:,:) = surf(:,:) * ( tsn(:,:,1,jp_tem) * sshn(:,:) - ssh_hc_loc_ini(:,:) ) 
159            z2d1(:,:) = surf(:,:) * ( tsn(:,:,1,jp_sal) * sshn(:,:) - ssh_sc_loc_ini(:,:) ) 
160         END IF
161         z_ssh_hc = glob_sum( z2d0 ) 
162         z_ssh_sc = glob_sum( z2d1 ) 
163      ENDIF
164
165      DO jk = 1, jpkm1
166         ! volume variation (calculated with scale factors)
167         zdiff_v2 = zdiff_v2 + glob_sum( surf(:,:) * tmask(:,:,jk) &
168            &                           * ( fse3t_n(:,:,jk) - e3t_ini(:,:,jk) ) )
169         ! heat content variation
170         zdiff_hc = zdiff_hc + glob_sum(  surf(:,:) * tmask(:,:,jk) & 
171            &                           * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_tem) - hc_loc_ini(:,:,jk) ) )
172         ! salt content variation
173         zdiff_sc = zdiff_sc + glob_sum(  surf(:,:) * tmask(:,:,jk)   &
174            &                           * ( fse3t_n(:,:,jk) * tsn(:,:,jk,jp_sal) - sc_loc_ini(:,:,jk) ) )
175      ENDDO
176
177      ! Substract forcing from heat content, salt content and volume variations
178      zdiff_v1 = zdiff_v1 - frc_v
179      IF( lk_vvl )   zdiff_v2 = zdiff_v2 - frc_v
180      zdiff_hc = zdiff_hc - frc_t
181      zdiff_sc = zdiff_sc - frc_s
182      IF( .NOT. lk_vvl ) THEN
183         zdiff_hc1 = zdiff_hc + z_ssh_hc 
184         zdiff_sc1 = zdiff_sc + z_ssh_sc
185         zerr_hc1  = z_ssh_hc - frc_wn_t
186         zerr_sc1  = z_ssh_sc - frc_wn_s
187      ENDIF
188
189      ! ----------------------- !
190      ! 3 - Diagnostics writing !
191      ! ----------------------- !
192      zvol_tot = 0._wp                    ! total ocean volume (calculated with scale factors)
193      DO jk = 1, jpkm1
194         zvol_tot  = zvol_tot + glob_sum( surf(:,:) * tmask(:,:,jk) * fse3t_n(:,:,jk) )
195      END DO
196
197!!gm to be added ?
198!      IF( .NOT. lk_vvl ) THEN            ! fixed volume, add the ssh contribution
199!        zvol_tot = zvol_tot + glob_sum( surf(:,:) * sshn(:,:) )
200!      ENDIF
201!!gm end
202
203
204      IF( lk_vvl ) THEN
205        CALL iom_put( 'bgtemper' , zdiff_hc / zvol_tot )              ! Temperature variation (C)
206        CALL iom_put( 'bgsaline' , zdiff_sc / zvol_tot )              ! Salinity    variation (psu)
207        CALL iom_put( 'bgheatco' , zdiff_hc * 1.e-20 * rau0 * rcp )   ! Heat content variation (1.e20 J)
208        CALL iom_put( 'bgsaltco' , zdiff_sc * 1.e-9    )              ! Salt content variation (psu*km3)
209        CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh variation (km3) 
210        CALL iom_put( 'bgvole3t' , zdiff_v2 * 1.e-9    )              ! volume e3t variation (km3) 
211        CALL iom_put( 'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
212        CALL iom_put( 'bgfrctem' , frc_t / zvol_tot    )              ! hc  - surface forcing (C)
213        CALL iom_put( 'bgfrcsal' , frc_s / zvol_tot    )              ! sc  - surface forcing (psu)
214      ELSE
215        CALL iom_put( 'bgtemper' , zdiff_hc1 / zvol_tot)              ! Heat content variation (C)
216        CALL iom_put( 'bgsaline' , zdiff_sc1 / zvol_tot)              ! Salt content variation (psu)
217        CALL iom_put( 'bgheatco' , zdiff_hc1 * 1.e-20 * rau0 * rcp )  ! Heat content variation (1.e20 J)
218        CALL iom_put( 'bgsaltco' , zdiff_sc1 * 1.e-9    )             ! Salt content variation (psu*km3)
219        CALL iom_put( 'bgvolssh' , zdiff_v1 * 1.e-9    )              ! volume ssh variation (km3) 
220        CALL iom_put( 'bgfrcvol' , frc_v    * 1.e-9    )              ! vol - surface forcing (km3)
221        CALL iom_put( 'bgfrctem' , frc_t / zvol_tot    )              ! hc  - surface forcing (C)
222        CALL iom_put( 'bgfrcsal' , frc_s / zvol_tot    )              ! sc  - surface forcing (psu)
223        CALL iom_put( 'bgmistem' , zerr_hc1 / zvol_tot )              ! hc  - error due to free surface (C)
224        CALL iom_put( 'bgmissal' , zerr_sc1 / zvol_tot )              ! sc  - error due to free surface (psu)
225      ENDIF
226      !
227      IF( lrst_oce )   CALL dia_hsb_rst( kt, 'WRITE' )
228
229      CALL wrk_dealloc( jpi,jpj,   z2d0, z2d1 )
230
231      IF( nn_timing == 1 )   CALL timing_stop('dia_hsb')
232      !
233   END SUBROUTINE dia_hsb
234
235
236   SUBROUTINE dia_hsb_rst( kt, cdrw )
237     !!---------------------------------------------------------------------
238     !!                   ***  ROUTINE limdia_rst  ***
239     !!                     
240     !! ** Purpose :   Read or write DIA file in restart file
241     !!
242     !! ** Method  :   use of IOM library
243     !!----------------------------------------------------------------------
244     INTEGER         , INTENT(in) ::   kt     ! ocean time-step
245     CHARACTER(len=*), INTENT(in) ::   cdrw   ! "READ"/"WRITE" flag
246     !
247     INTEGER ::   ji, jj, jk   ! dummy loop indices
248     INTEGER ::   id1          ! local integers
249     !!----------------------------------------------------------------------
250     !
251     IF( TRIM(cdrw) == 'READ' ) THEN        ! Read/initialise
252        IF( ln_rstart ) THEN                   !* Read the restart file
253           !id1 = iom_varid( numror, 'frc_vol'  , ldstop = .FALSE. )
254           !
255           IF(lwp) WRITE(numout,*) '~~~~~~~'
256           IF(lwp) WRITE(numout,*) ' dia_hsb_rst at it= ', kt,' date= ', ndastp
257           IF(lwp) WRITE(numout,*) '~~~~~~~'
258           CALL iom_get( numror, 'frc_v', frc_v )
259           CALL iom_get( numror, 'frc_t', frc_t )
260           CALL iom_get( numror, 'frc_s', frc_s )
261           IF( .NOT. lk_vvl ) THEN
262              CALL iom_get( numror, 'frc_wn_t', frc_wn_t )
263              CALL iom_get( numror, 'frc_wn_s', frc_wn_s )
264           ENDIF
265           CALL iom_get( numror, jpdom_autoglo, 'ssh_ini', ssh_ini )
266           CALL iom_get( numror, jpdom_autoglo, 'e3t_ini', e3t_ini )
267           CALL iom_get( numror, jpdom_autoglo, 'hc_loc_ini', hc_loc_ini )
268           CALL iom_get( numror, jpdom_autoglo, 'sc_loc_ini', sc_loc_ini )
269           IF( .NOT. lk_vvl ) THEN
270              CALL iom_get( numror, jpdom_autoglo, 'ssh_hc_loc_ini', ssh_hc_loc_ini )
271              CALL iom_get( numror, jpdom_autoglo, 'ssh_sc_loc_ini', ssh_sc_loc_ini )
272           ENDIF
273       ELSE
274          IF(lwp) WRITE(numout,*) '~~~~~~~'
275          IF(lwp) WRITE(numout,*) ' dia_hsb at initial state '
276          IF(lwp) WRITE(numout,*) '~~~~~~~'
277          ssh_ini(:,:) = sshn(:,:)                                       ! initial ssh
278          DO jk = 1, jpk
279             e3t_ini   (:,:,jk) = fse3t_n(:,:,jk)                        ! initial vertical scale factors
280             hc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_tem) * fse3t_n(:,:,jk)   ! initial heat content
281             sc_loc_ini(:,:,jk) = tsn(:,:,jk,jp_sal) * fse3t_n(:,:,jk)   ! initial salt content
282          END DO
283          frc_v = 0._wp                                           ! volume       trend due to forcing
284          frc_t = 0._wp                                           ! heat content   -    -   -    -   
285          frc_s = 0._wp                                           ! salt content   -    -   -    -       
286          IF( .NOT. lk_vvl ) THEN
287             IF ( ln_isfcav ) THEN
288                DO ji=1,jpi
289                   DO jj=1,jpj
290                      ssh_hc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_tem) * sshn(ji,jj)   ! initial heat content in ssh
291                      ssh_sc_loc_ini(ji,jj) = tsn(ji,jj,mikt(ji,jj),jp_sal) * sshn(ji,jj)   ! initial salt content in ssh
292                   ENDDO
293                ENDDO
294             ELSE
295                ssh_hc_loc_ini(:,:) = tsn(:,:,1,jp_tem) * sshn(:,:)   ! initial heat content in ssh
296                ssh_sc_loc_ini(:,:) = tsn(:,:,1,jp_sal) * sshn(:,:)   ! initial salt content in ssh
297             END IF
298             frc_wn_t = 0._wp                                       ! initial heat content misfit due to free surface
299             frc_wn_s = 0._wp                                       ! initial salt content misfit due to free surface
300          ENDIF
301       ENDIF
302
303     ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN   ! Create restart file
304        !                                   ! -------------------
305        IF(lwp) WRITE(numout,*) '~~~~~~~'
306        IF(lwp) WRITE(numout,*) ' dia_hsb_rst at it= ', kt,' date= ', ndastp
307        IF(lwp) WRITE(numout,*) '~~~~~~~'
308
309        CALL iom_rstput( kt, nitrst, numrow, 'frc_v'   , frc_v     )
310        CALL iom_rstput( kt, nitrst, numrow, 'frc_t'   , frc_t     )
311        CALL iom_rstput( kt, nitrst, numrow, 'frc_s'   , frc_s     )
312        IF( .NOT. lk_vvl ) THEN
313           CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_t', frc_wn_t )
314           CALL iom_rstput( kt, nitrst, numrow, 'frc_wn_s', frc_wn_s )
315        ENDIF
316        CALL iom_rstput( kt, nitrst, numrow, 'ssh_ini', ssh_ini )
317        CALL iom_rstput( kt, nitrst, numrow, 'e3t_ini', e3t_ini )
318        CALL iom_rstput( kt, nitrst, numrow, 'hc_loc_ini', hc_loc_ini )
319        CALL iom_rstput( kt, nitrst, numrow, 'sc_loc_ini', sc_loc_ini )
320        IF( .NOT. lk_vvl ) THEN
321           CALL iom_rstput( kt, nitrst, numrow, 'ssh_hc_loc_ini', ssh_hc_loc_ini )
322           CALL iom_rstput( kt, nitrst, numrow, 'ssh_sc_loc_ini', ssh_sc_loc_ini )
323        ENDIF
324        !
325     ENDIF
326     !
327   END SUBROUTINE dia_hsb_rst
328
329
330   SUBROUTINE dia_hsb_init
331      !!---------------------------------------------------------------------------
332      !!                  ***  ROUTINE dia_hsb  ***
333      !!     
334      !! ** Purpose: Initialization for the heat salt volume budgets
335      !!
336      !! ** Method : Compute initial heat content, salt content and volume
337      !!
338      !! ** Action : - Compute initial heat content, salt content and volume
339      !!             - Initialize forcing trends
340      !!             - Compute coefficients for conversion
341      !!---------------------------------------------------------------------------
342      INTEGER ::   jk       ! dummy loop indice
343      INTEGER ::   ierror   ! local integer
344      INTEGER ::   ios
345      !
346      NAMELIST/namhsb/ ln_diahsb
347      !!----------------------------------------------------------------------
348
349      IF(lwp) THEN
350         WRITE(numout,*)
351         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
352         WRITE(numout,*) '~~~~~~~~ '
353      ENDIF
354
355      REWIND( numnam_ref )              ! Namelist namhsb in reference namelist
356      READ  ( numnam_ref, namhsb, IOSTAT = ios, ERR = 901)
357901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in reference namelist', lwp )
358
359      REWIND( numnam_cfg )              ! Namelist namhsb in configuration namelist
360      READ  ( numnam_cfg, namhsb, IOSTAT = ios, ERR = 902 )
361902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namhsb in configuration namelist', lwp )
362      IF(lwm) WRITE ( numond, namhsb )
363
364      !
365      IF(lwp) THEN                   ! Control print
366         WRITE(numout,*)
367         WRITE(numout,*) 'dia_hsb_init : check the heat and salt budgets'
368         WRITE(numout,*) '~~~~~~~~~~~~'
369         WRITE(numout,*) '   Namelist namhsb : set hsb parameters'
370         WRITE(numout,*) '      Switch for hsb diagnostic (T) or not (F)  ln_diahsb  = ', ln_diahsb
371         WRITE(numout,*)
372      ENDIF
373
374      IF( .NOT. ln_diahsb )   RETURN
375         !      IF( .NOT. lk_mpp_rep ) &
376         !        CALL ctl_stop (' Your global mpp_sum if performed in single precision - 64 bits -', &
377         !             &         ' whereas the global sum to be precise must be done in double precision ',&
378         !             &         ' please add key_mpp_rep')
379
380      ! ------------------- !
381      ! 1 - Allocate memory !
382      ! ------------------- !
383      ALLOCATE( hc_loc_ini(jpi,jpj,jpk), sc_loc_ini(jpi,jpj,jpk), &
384         &      e3t_ini(jpi,jpj,jpk), surf(jpi,jpj),  ssh_ini(jpi,jpj), STAT=ierror )
385      IF( ierror > 0 ) THEN
386         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
387      ENDIF
388
389      IF(.NOT. lk_vvl ) ALLOCATE( ssh_hc_loc_ini(jpi,jpj), ssh_sc_loc_ini(jpi,jpj),STAT=ierror )
390      IF( ierror > 0 ) THEN
391         CALL ctl_stop( 'dia_hsb: unable to allocate hc_loc_ini' )   ;   RETURN
392      ENDIF
393
394      ! ----------------------------------------------- !
395      ! 2 - Time independant variables and file opening !
396      ! ----------------------------------------------- !
397      IF(lwp) WRITE(numout,*) "dia_hsb: heat salt volume budgets activated"
398      IF(lwp) WRITE(numout,*) '~~~~~~~'
399      surf(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)      ! masked surface grid cell area
400      surf_tot  = glob_sum( surf(:,:) )                                       ! total ocean surface area
401
402      IF( lk_bdy ) CALL ctl_warn( 'dia_hsb does not take open boundary fluxes into account' )         
403      !
404      ! ---------------------------------- !
405      ! 4 - initial conservation variables !
406      ! ---------------------------------- !
407      CALL dia_hsb_rst( nit000, 'READ' )  !* read or initialize all required files
408      !
409   END SUBROUTINE dia_hsb_init
410
411   !!======================================================================
412END MODULE diahsb
Note: See TracBrowser for help on using the repository browser.