New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
closea.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/DOM – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/DOM/closea.F90 @ 7256

Last change on this file since 7256 was 7256, checked in by cbricaud, 7 years ago

phaze NEMO routines in CRS branch with nemo_v3_6_STABLE branch at rev 7213 (09-09-2016) (merge -r 5519:7213 )

  • Property svn:keywords set to Id
File size: 21.8 KB
Line 
1MODULE closea
2   !!======================================================================
3   !!                       ***  MODULE  closea  ***
4   !! Closed Seas  : specific treatments associated with closed seas
5   !!======================================================================
6   !! History :   8.2  !  00-05  (O. Marti)  Original code
7   !!             8.5  !  02-06  (E. Durand, G. Madec)  F90
8   !!             9.0  !  06-07  (G. Madec)  add clo_rnf, clo_ups, clo_bat
9   !!        NEMO 3.4  !  03-12  (P.G. Fogli) sbc_clo bug fix & mpp reproducibility
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   dom_clo    : modification of the ocean domain for closed seas cases
14   !!   sbc_clo    : Special handling of closed seas
15   !!   clo_rnf    : set close sea outflows as river mouths (see sbcrnf)
16   !!   clo_ups    : set mixed centered/upstream scheme in closed sea (see traadv_cen2)
17   !!   clo_bat    : set to zero a field over closed sea (see domzrg)
18   !!----------------------------------------------------------------------
19   USE oce             ! dynamics and tracers
20   USE dom_oce         ! ocean space and time domain
21   USE phycst          ! physical constants
22   USE in_out_manager  ! I/O manager
23   USE sbc_oce         ! ocean surface boundary conditions
24   USE lib_fortran,    ONLY: glob_sum, DDPDD
25   USE lbclnk          ! lateral boundary condition - MPP exchanges
26   USE lib_mpp         ! MPP library
27   USE timing
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC dom_clo      ! routine called by domain module
33   PUBLIC sbc_clo      ! routine called by step module
34   PUBLIC clo_rnf      ! routine called by sbcrnf module
35   PUBLIC clo_ups      ! routine called in traadv_cen2(_jki) module
36   PUBLIC clo_bat      ! routine called in domzgr module
37
38   INTEGER, PUBLIC, PARAMETER          ::   jpncs   = 4      !: number of closed sea
39   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncstt            !: Type of closed sea
40   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncsi1, ncsj1     !: south-west closed sea limits (i,j)
41   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncsi2, ncsj2     !: north-east closed sea limits (i,j)
42   INTEGER, PUBLIC, DIMENSION(jpncs)   ::   ncsnr            !: number of point where run-off pours
43   INTEGER, PUBLIC, DIMENSION(jpncs,4) ::   ncsir, ncsjr     !: Location of runoff
44
45   REAL(wp), DIMENSION (jpncs+1)       ::   surf             ! closed sea surface
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE dom_clo
57      !!---------------------------------------------------------------------
58      !!                  ***  ROUTINE dom_clo  ***
59      !!       
60      !! ** Purpose :   Closed sea domain initialization
61      !!
62      !! ** Method  :   if a closed sea is located only in a model grid point
63      !!                just the thermodynamic processes are applied.
64      !!
65      !! ** Action  :   ncsi1(), ncsj1() : south-west closed sea limits (i,j)
66      !!                ncsi2(), ncsj2() : north-east Closed sea limits (i,j)
67      !!                ncsir(), ncsjr() : Location of runoff
68      !!                ncsnr            : number of point where run-off pours
69      !!                ncstt            : Type of closed sea
70      !!                                   =0 spread over the world ocean
71      !!                                   =2 put at location runoff
72      !!----------------------------------------------------------------------
73      INTEGER ::   jc            ! dummy loop indices
74      INTEGER :: isrow           ! local index
75      !!----------------------------------------------------------------------
76     
77      IF(lwp) WRITE(numout,*)
78      IF(lwp) WRITE(numout,*)'dom_clo : closed seas '
79      IF(lwp) WRITE(numout,*)'~~~~~~~'
80
81      ! initial values
82      ncsnr(:) = 1  ;  ncsi1(:) = 1  ;  ncsi2(:) = 1  ;  ncsir(:,:) = 1
83      ncstt(:) = 0  ;  ncsj1(:) = 1  ;  ncsj2(:) = 1  ;  ncsjr(:,:) = 1
84
85      ! set the closed seas (in data domain indices)
86      ! -------------------
87
88      IF( cp_cfg == "orca" ) THEN
89         !
90         SELECT CASE ( jp_cfg )
91         !                                           ! =======================
92         CASE ( 1 )                                  ! ORCA_R1 configuration
93            !                                        ! =======================
94            ! This dirty section will be suppressed by simplification process:
95            ! all this will come back in input files
96            ! Currently these hard-wired indices relate to configuration with
97            ! extend grid (jpjglo=332)
98            isrow = 332 - jpjglo
99            !
100            ncsnr(1)   = 1    ; ncstt(1)   = 0           ! Caspian Sea
101            ncsi1(1)   = 332  ; ncsj1(1)   = 243 - isrow
102            ncsi2(1)   = 344  ; ncsj2(1)   = 275 - isrow
103            ncsir(1,1) = 1    ; ncsjr(1,1) = 1
104            !                                       
105            !                                        ! =======================
106         CASE ( 2 )                                  !  ORCA_R2 configuration
107            !                                        ! =======================
108            !                                            ! Caspian Sea
109            ncsnr(1)   =   1  ;  ncstt(1)   =   0           ! spread over the globe
110            ncsi1(1)   =  11  ;  ncsj1(1)   = 103
111            ncsi2(1)   =  17  ;  ncsj2(1)   = 112
112            ncsir(1,1) =   1  ;  ncsjr(1,1) =   1 
113            !                                            ! Great North American Lakes
114            ncsnr(2)   =   1  ;  ncstt(2)   =   2           ! put at St Laurent mouth
115            ncsi1(2)   =  97  ;  ncsj1(2)   = 107
116            ncsi2(2)   = 103  ;  ncsj2(2)   = 111
117            ncsir(2,1) = 110  ;  ncsjr(2,1) = 111           
118            !                                            ! Black Sea (crossed by the cyclic boundary condition)
119            ncsnr(3:4) =   4  ;  ncstt(3:4) =   2           ! put in Med Sea (north of Aegean Sea)
120            ncsir(3:4,1) = 171;  ncsjr(3:4,1) = 106         !
121            ncsir(3:4,2) = 170;  ncsjr(3:4,2) = 106 
122            ncsir(3:4,3) = 171;  ncsjr(3:4,3) = 105 
123            ncsir(3:4,4) = 170;  ncsjr(3:4,4) = 105 
124            ncsi1(3)   = 174  ;  ncsj1(3)   = 107           ! 1 : west part of the Black Sea     
125            ncsi2(3)   = 181  ;  ncsj2(3)   = 112           !            (ie west of the cyclic b.c.)
126            ncsi1(4)   =   2  ;  ncsj1(4)   = 107           ! 2 : east part of the Black Sea
127            ncsi2(4)   =   6  ;  ncsj2(4)   = 112           !           (ie east of the cyclic b.c.)
128             
129         
130
131            !                                        ! =======================
132         CASE ( 4 )                                  !  ORCA_R4 configuration
133            !                                        ! =======================
134            !                                            ! Caspian Sea
135            ncsnr(1)   =  1  ;  ncstt(1)   =  0 
136            ncsi1(1)   =  4  ;  ncsj1(1)   = 53 
137            ncsi2(1)   =  4  ;  ncsj2(1)   = 56
138            ncsir(1,1) =  1  ;  ncsjr(1,1) =  1
139            !                                            ! Great North American Lakes
140            ncsnr(2)   =  1  ;  ncstt(2)   =  2 
141            ncsi1(2)   = 49  ;  ncsj1(2)   = 55
142            ncsi2(2)   = 51  ;  ncsj2(2)   = 56
143            ncsir(2,1) = 57  ;  ncsjr(2,1) = 55
144            !                                            ! Black Sea
145            ncsnr(3)   =  4  ;  ncstt(3)   =  2 
146            ncsi1(3)   = 88  ;  ncsj1(3)   = 55 
147            ncsi2(3)   = 91  ;  ncsj2(3)   = 56
148            ncsir(3,1) = 86  ;  ncsjr(3,1) = 53
149            ncsir(3,2) = 87  ;  ncsjr(3,2) = 53 
150            ncsir(3,3) = 86  ;  ncsjr(3,3) = 52 
151            ncsir(3,4) = 87  ;  ncsjr(3,4) = 52
152            !                                            ! Baltic Sea
153            ncsnr(4)   =  1  ;  ncstt(4)   =  2
154            ncsi1(4)   = 75  ;  ncsj1(4)   = 59
155            ncsi2(4)   = 76  ;  ncsj2(4)   = 61
156            ncsir(4,1) = 84  ;  ncsjr(4,1) = 59 
157            !                                        ! =======================
158         CASE ( 025 )                                ! ORCA_R025 configuration
159            !                                        ! =======================
160            isrow = 1207 - jpjglo                    !  eORCA025 R025 - Using full isf­extended 
161                                                     !  domain for reference. - Adjust j­indices
162            ncsnr(1)   = 1    ; ncstt(1)   = 0               ! Caspian + Aral sea
163            ncsi1(1)   = 1330 ; ncsj1(1)   = 831 - isrow
164            ncsi2(1)   = 1400 ; ncsj2(1)   = 981 - isrow
165            ncsir(1,1) = 1    ; ncsjr(1,1) = 1
166            !                                       
167            ncsnr(2)   = 1    ; ncstt(2)   = 0               ! Azov Sea
168            ncsi1(2)   = 1284 ; ncsj1(2)   = 908 - isrow
169            ncsi2(2)   = 1304 ; ncsj2(2)   = 933 - isrow
170            ncsir(2,1) = 1    ; ncsjr(2,1) = 1
171            !
172            ncsnr(3)   = 1    ; ncstt(3)   = 0               ! Great Lakes
173            ncsi1(3)   = 775  ; ncsj1(3)   = 866 - isrow
174            ncsi2(3)   = 848  ; ncsj2(3)   = 931 - isrow
175            ncsir(3,1) = 1    ; ncsjr(3,1) = 1
176            !   
177            ncsnr(4)   = 1    ; ncstt(4)   = 0               ! Lake Victoria
178            ncsi1(4)   = 1270 ; ncsj1(4)   = 661 - isrow
179            ncsi2(4)   = 1295 ; ncsj2(4)   = 696 - isrow
180            ncsir(4,1) = 1    ; ncsjr(4,1) = 1
181            !       
182            !
183         END SELECT
184         !
185      ENDIF
186
187      ! convert the position in local domain indices
188      ! --------------------------------------------
189      DO jc = 1, jpncs
190         ncsi1(jc)   = mi0( ncsi1(jc) )
191         ncsj1(jc)   = mj0( ncsj1(jc) )
192
193         ncsi2(jc)   = mi1( ncsi2(jc) )   
194         ncsj2(jc)   = mj1( ncsj2(jc) ) 
195      END DO
196      !
197   END SUBROUTINE dom_clo
198
199
200   SUBROUTINE sbc_clo( kt )
201      !!---------------------------------------------------------------------
202      !!                  ***  ROUTINE sbc_clo  ***
203      !!                   
204      !! ** Purpose :   Special handling of closed seas
205      !!
206      !! ** Method  :   Water flux is forced to zero over closed sea
207      !!      Excess is shared between remaining ocean, or
208      !!      put as run-off in open ocean.
209      !!
210      !! ** Action  :   emp updated surface freshwater fluxes and associated heat content at kt
211      !!----------------------------------------------------------------------
212      INTEGER, INTENT(in) ::   kt   ! ocean model time step
213      !
214      INTEGER             ::   ji, jj, jc, jn   ! dummy loop indices
215      REAL(wp), PARAMETER ::   rsmall = 1.e-20_wp    ! Closed sea correction epsilon
216      REAL(wp)            ::   zze2, ztmp, zcorr     !
217      REAL(wp)            ::   zcoef, zcoef1         !
218      COMPLEX(wp)         ::   ctmp 
219      REAL(wp), DIMENSION(jpncs) ::   zfwf   ! 1D workspace
220      !!----------------------------------------------------------------------
221      !
222      IF( nn_timing == 1 )  CALL timing_start('sbc_clo')
223      !                                                   !------------------!
224      IF( kt == nit000 ) THEN                             !  Initialisation  !
225         !                                                !------------------!
226         IF(lwp) WRITE(numout,*)
227         IF(lwp) WRITE(numout,*)'sbc_clo : closed seas '
228         IF(lwp) WRITE(numout,*)'~~~~~~~'
229
230         surf(:) = 0.e0_wp
231         !
232         surf(jpncs+1) = glob_sum( e1e2t(:,:) )   ! surface of the global ocean
233         !
234         !                                        ! surface of closed seas
235         IF( lk_mpp_rep ) THEN                         ! MPP reproductible calculation
236            DO jc = 1, jpncs
237               ctmp = CMPLX( 0.e0, 0.e0, wp )
238               DO jj = ncsj1(jc), ncsj2(jc)
239                  DO ji = ncsi1(jc), ncsi2(jc)
240                     ztmp = e1e2t(ji,jj) * tmask_i(ji,jj)
241                     CALL DDPDD( CMPLX( ztmp, 0.e0, wp ), ctmp )
242                  END DO
243               END DO
244               IF( lk_mpp )   CALL mpp_sum( ctmp )
245               surf(jc) = REAL(ctmp,wp)
246            END DO
247         ELSE                                          ! Standard calculation           
248            DO jc = 1, jpncs
249               DO jj = ncsj1(jc), ncsj2(jc)
250                  DO ji = ncsi1(jc), ncsi2(jc)
251                     surf(jc) = surf(jc) + e1e2t(ji,jj) * tmask_i(ji,jj)      ! surface of closed seas
252                  END DO
253               END DO
254            END DO
255            IF( lk_mpp )   CALL mpp_sum ( surf, jpncs )       ! mpp: sum over all the global domain
256         ENDIF
257
258         IF(lwp) WRITE(numout,*)'     Closed sea surfaces'
259         DO jc = 1, jpncs
260            IF(lwp)WRITE(numout,FMT='(1I3,4I4,5X,F16.2)') jc, ncsi1(jc), ncsi2(jc), ncsj1(jc), ncsj2(jc), surf(jc)
261         END DO
262
263         ! jpncs+1 : surface of sea, closed seas excluded
264         DO jc = 1, jpncs
265            surf(jpncs+1) = surf(jpncs+1) - surf(jc)
266         END DO           
267         !
268      ENDIF
269      !                                                   !--------------------!
270      !                                                   !  update emp        !
271      zfwf = 0.e0_wp                                      !--------------------!
272      IF( lk_mpp_rep ) THEN                         ! MPP reproductible calculation
273         DO jc = 1, jpncs
274            ctmp = CMPLX( 0.e0, 0.e0, wp )
275            DO jj = ncsj1(jc), ncsj2(jc)
276               DO ji = ncsi1(jc), ncsi2(jc)
277                  ztmp = e1e2t(ji,jj) * ( emp(ji,jj)-rnf(ji,jj) ) * tmask_i(ji,jj)
278                  CALL DDPDD( CMPLX( ztmp, 0.e0, wp ), ctmp )
279               END DO 
280            END DO
281            IF( lk_mpp )   CALL mpp_sum( ctmp )
282            zfwf(jc) = REAL(ctmp,wp)
283         END DO
284      ELSE                                          ! Standard calculation           
285         DO jc = 1, jpncs
286            DO jj = ncsj1(jc), ncsj2(jc)
287               DO ji = ncsi1(jc), ncsi2(jc)
288                  zfwf(jc) = zfwf(jc) + e1e2t(ji,jj) * ( emp(ji,jj)-rnf(ji,jj) ) * tmask_i(ji,jj) 
289               END DO 
290            END DO
291         END DO
292         IF( lk_mpp )   CALL mpp_sum ( zfwf(:) , jpncs )       ! mpp: sum over all the global domain
293      ENDIF
294
295      IF( cp_cfg == "orca" .AND. jp_cfg == 2 ) THEN      ! Black Sea case for ORCA_R2 configuration
296         zze2    = ( zfwf(3) + zfwf(4) ) * 0.5_wp
297         zfwf(3) = zze2
298         zfwf(4) = zze2
299      ENDIF
300
301      zcorr = 0._wp
302
303      DO jc = 1, jpncs
304         !
305         ! The following if avoids the redistribution of the round off
306         IF ( ABS(zfwf(jc) / surf(jpncs+1) ) > rsmall) THEN
307            !
308            IF( ncstt(jc) == 0 ) THEN           ! water/evap excess is shared by all open ocean
309               zcoef    = zfwf(jc) / surf(jpncs+1)
310               zcoef1   = rcp * zcoef
311               emp(:,:) = emp(:,:) + zcoef
312               qns(:,:) = qns(:,:) - zcoef1 * sst_m(:,:)
313               ! accumulate closed seas correction
314               zcorr    = zcorr    + zcoef
315               !
316            ELSEIF( ncstt(jc) == 1 ) THEN       ! Excess water in open sea, at outflow location, excess evap shared
317               IF ( zfwf(jc) <= 0.e0_wp ) THEN
318                   DO jn = 1, ncsnr(jc)
319                     ji = mi0(ncsir(jc,jn))
320                     jj = mj0(ncsjr(jc,jn)) ! Location of outflow in open ocean
321                     IF (      ji > 1 .AND. ji < jpi   &
322                         .AND. jj > 1 .AND. jj < jpj ) THEN
323                         zcoef      = zfwf(jc) / ( REAL(ncsnr(jc)) * e1e2t(ji,jj) )
324                         zcoef1     = rcp * zcoef
325                         emp(ji,jj) = emp(ji,jj) + zcoef
326                         qns(ji,jj) = qns(ji,jj) - zcoef1 * sst_m(ji,jj)
327                     ENDIF
328                   END DO
329               ELSE
330                   zcoef    = zfwf(jc) / surf(jpncs+1)
331                   zcoef1   = rcp * zcoef
332                   emp(:,:) = emp(:,:) + zcoef
333                   qns(:,:) = qns(:,:) - zcoef1 * sst_m(:,:)
334                   ! accumulate closed seas correction
335                   zcorr    = zcorr    + zcoef
336               ENDIF
337            ELSEIF( ncstt(jc) == 2 ) THEN       ! Excess e-p-r (either sign) goes to open ocean, at outflow location
338               DO jn = 1, ncsnr(jc)
339                  ji = mi0(ncsir(jc,jn))
340                  jj = mj0(ncsjr(jc,jn)) ! Location of outflow in open ocean
341                  IF(      ji > 1 .AND. ji < jpi    &
342                     .AND. jj > 1 .AND. jj < jpj ) THEN
343                     zcoef      = zfwf(jc) / ( REAL(ncsnr(jc)) *  e1e2t(ji,jj) )
344                     zcoef1     = rcp * zcoef
345                     emp(ji,jj) = emp(ji,jj) + zcoef
346                     qns(ji,jj) = qns(ji,jj) - zcoef1 * sst_m(ji,jj)
347                  ENDIF
348               END DO
349            ENDIF 
350            !
351            DO jj = ncsj1(jc), ncsj2(jc)
352               DO ji = ncsi1(jc), ncsi2(jc)
353                  zcoef      = zfwf(jc) / surf(jc)
354                  zcoef1     = rcp * zcoef
355                  emp(ji,jj) = emp(ji,jj) - zcoef
356                  qns(ji,jj) = qns(ji,jj) + zcoef1 * sst_m(ji,jj)
357               END DO 
358            END DO 
359            !
360         END IF
361      END DO
362
363      IF ( ABS(zcorr) > rsmall ) THEN      ! remove the global correction from the closed seas
364         DO jc = 1, jpncs                  ! only if it is large enough
365            DO jj = ncsj1(jc), ncsj2(jc)
366               DO ji = ncsi1(jc), ncsi2(jc)
367                  emp(ji,jj) = emp(ji,jj) - zcorr
368                  qns(ji,jj) = qns(ji,jj) + rcp * zcorr * sst_m(ji,jj)
369               END DO 
370             END DO
371          END DO
372      ENDIF
373      !
374      emp (:,:) = emp (:,:) * tmask(:,:,1)
375      !
376      CALL lbc_lnk( emp , 'T', 1._wp )
377      !
378      IF( nn_timing == 1 )  CALL timing_stop('sbc_clo')
379      !
380   END SUBROUTINE sbc_clo
381
382
383   SUBROUTINE clo_rnf( p_rnfmsk )
384      !!---------------------------------------------------------------------
385      !!                  ***  ROUTINE sbc_rnf  ***
386      !!                   
387      !! ** Purpose :   allow the treatment of closed sea outflow grid-points
388      !!                to be the same as river mouth grid-points
389      !!
390      !! ** Method  :   set to 1 the runoff mask (mskrnf, see sbcrnf module)
391      !!                at the closed sea outflow grid-point.
392      !!
393      !! ** Action  :   update (p_)mskrnf (set 1 at closed sea outflow)
394      !!----------------------------------------------------------------------
395      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   p_rnfmsk   ! river runoff mask (rnfmsk array)
396      !
397      INTEGER  ::   jc, jn, ji, jj      ! dummy loop indices
398      !!----------------------------------------------------------------------
399      !
400      DO jc = 1, jpncs
401         IF( ncstt(jc) >= 1 ) THEN            ! runoff mask set to 1 at closed sea outflows
402             DO jn = 1, 4
403                DO jj =    mj0( ncsjr(jc,jn) ), mj1( ncsjr(jc,jn) )
404                   DO ji = mi0( ncsir(jc,jn) ), mi1( ncsir(jc,jn) )
405                      p_rnfmsk(ji,jj) = MAX( p_rnfmsk(ji,jj), 1.0_wp )
406                   END DO
407                END DO
408            END DO
409         ENDIF
410      END DO 
411      !
412   END SUBROUTINE clo_rnf
413
414   
415   SUBROUTINE clo_ups( p_upsmsk )
416      !!---------------------------------------------------------------------
417      !!                  ***  ROUTINE sbc_rnf  ***
418      !!                   
419      !! ** Purpose :   allow the treatment of closed sea outflow grid-points
420      !!                to be the same as river mouth grid-points
421      !!
422      !! ** Method  :   set to 0.5 the upstream mask (upsmsk, see traadv_cen2
423      !!                module) over the closed seas.
424      !!
425      !! ** Action  :   update (p_)upsmsk (set 0.5 over closed seas)
426      !!----------------------------------------------------------------------
427      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   p_upsmsk   ! upstream mask (upsmsk array)
428      !
429      INTEGER  ::   jc, ji, jj      ! dummy loop indices
430      !!----------------------------------------------------------------------
431      !
432      DO jc = 1, jpncs
433         DO jj = ncsj1(jc), ncsj2(jc)
434            DO ji = ncsi1(jc), ncsi2(jc)
435               p_upsmsk(ji,jj) = 0.5_wp         ! mixed upstream/centered scheme over closed seas
436            END DO
437         END DO
438       END DO 
439       !
440   END SUBROUTINE clo_ups
441   
442     
443   SUBROUTINE clo_bat( pbat, kbat )
444      !!---------------------------------------------------------------------
445      !!                  ***  ROUTINE clo_bat  ***
446      !!                   
447      !! ** Purpose :   suppress closed sea from the domain
448      !!
449      !! ** Method  :   set to 0 the meter and level bathymetry (given in
450      !!                arguments) over the closed seas.
451      !!
452      !! ** Action  :   set pbat=0 and kbat=0 over closed seas
453      !!----------------------------------------------------------------------
454      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   pbat   ! bathymetry in meters (bathy array)
455      INTEGER , DIMENSION(jpi,jpj), INTENT(inout) ::   kbat   ! bathymetry in levels (mbathy array)
456      !
457      INTEGER  ::   jc, ji, jj      ! dummy loop indices
458      !!----------------------------------------------------------------------
459      !
460      DO jc = 1, jpncs
461         DO jj = ncsj1(jc), ncsj2(jc)
462            DO ji = ncsi1(jc), ncsi2(jc)
463               pbat(ji,jj) = 0._wp   
464               kbat(ji,jj) = 0   
465            END DO
466         END DO
467       END DO 
468       !
469   END SUBROUTINE clo_bat
470
471   !!======================================================================
472END MODULE closea
473
Note: See TracBrowser for help on using the repository browser.