New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
eosbn2_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/eosbn2_crs.F90 @ 5105

Last change on this file since 5105 was 5105, checked in by cbricaud, 9 years ago

bug correction

  • Property svn:executable set to *
File size: 40.3 KB
Line 
1MODULE eosbn2_crs
2   !!==============================================================================
3   !!                       ***  MODULE  eosbn2  ***
4   !! Ocean diagnostic variable : equation of state - in situ and potential density
5   !!                                               - Brunt-Vaisala frequency
6   !!==============================================================================
7   !! History :  OPA  ! 1989-03  (O. Marti)  Original code
8   !!            6.0  ! 1994-07  (G. Madec, M. Imbard)  add bn2
9   !!            6.0  ! 1994-08  (G. Madec)  Add Jackett & McDougall eos
10   !!            7.0  ! 1996-01  (G. Madec)  statement function for e3
11   !!            8.1  ! 1997-07  (G. Madec)  density instead of volumic mass
12   !!             -   ! 1999-02  (G. Madec, N. Grima) semi-implicit pressure gradient
13   !!            8.2  ! 2001-09  (M. Ben Jelloul)  bugfix on linear eos
14   !!   NEMO     1.0  ! 2002-10  (G. Madec)  add eos_init
15   !!             -   ! 2002-11  (G. Madec, A. Bozec)  partial step, eos_insitu_2d
16   !!             -   ! 2003-08  (G. Madec)  F90, free form
17   !!            3.0  ! 2006-08  (G. Madec)  add tfreez function
18   !!            3.3  ! 2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
19   !!             -   ! 2010-10  (G. Nurser, G. Madec)  add eos_alpbet used in ldfslp
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   eos            : generic interface of the equation of state
24   !!   eos_insitu     : Compute the in situ density
25   !!   eos_insitu_pot : Compute the insitu and surface referenced potential
26   !!                    volumic mass
27   !!   eos_insitu_2d  : Compute the in situ density for 2d fields
28   !!   eos_bn2        : Compute the Brunt-Vaisala frequency
29   !!   eos_alpbet     : calculates the in situ thermal/haline expansion ratio
30   !!   tfreez         : Compute the surface freezing temperature
31   !!   eos_init       : set eos parameters (namelist)
32   !!----------------------------------------------------------------------
33   USE dom_oce         ! ocean space and time domain
34   USE phycst          ! physical constants
35   USE zdfddm          ! vertical physics: double diffusion
36   USE in_out_manager  ! I/O manager
37   USE lib_mpp         ! MPP library
38   USE prtctl          ! Print control
39   USE wrk_nemo        ! Memory Allocation
40   USE timing          ! Timing
41   USE crs
42
43   IMPLICIT NONE
44   PRIVATE
45
46   !                   !! * Interface
47   INTERFACE eos_crs
48      MODULE PROCEDURE eos_insitu_crs, eos_insitu_pot_crs, eos_insitu_2d_crs
49   END INTERFACE
50   INTERFACE bn2_crs
51      MODULE PROCEDURE eos_bn2_crs
52   END INTERFACE
53
54   PUBLIC   eos_crs        ! called by step, istate, tranpc and zpsgrd modules
55   PUBLIC   eos_init_crs   ! called by istate module
56   PUBLIC   bn2_crs        ! called by step module
57   PUBLIC   eos_alpbet_crs ! called by ldfslp module
58   PUBLIC   tfreez_crs     ! called by sbcice_... modules
59
60   !                                          !!* Namelist (nameos) *
61   INTEGER , PUBLIC ::   nn_eos   = 0         !: = 0/1/2 type of eq. of state and Brunt-Vaisala frequ.
62   REAL(wp), PUBLIC ::   rn_alpha = 2.0e-4_wp !: thermal expension coeff. (linear equation of state)
63   REAL(wp), PUBLIC ::   rn_beta  = 7.7e-4_wp !: saline  expension coeff. (linear equation of state)
64
65   REAL(wp), PUBLIC ::   ralpbet_crs              !: alpha / beta ratio
66
67   !! * Substitutions
68#  include "domzgr_substitute.h90"
69#  include "vectopt_loop_substitute.h90"
70   !!----------------------------------------------------------------------
71   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
72   !! $Id: eosbn2.F90 3294 2012-01-28 16:44:18Z rblod $
73   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE eos_insitu_crs( pts, prd )
78      !!----------------------------------------------------------------------
79      !!                   ***  ROUTINE eos_insitu  ***
80      !!
81      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
82      !!       potential temperature and salinity using an equation of state
83      !!       defined through the namelist parameter nn_eos.
84      !!
85      !! ** Method  :   3 cases:
86      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
87      !!         the in situ density is computed directly as a function of
88      !!         potential temperature relative to the surface (the opa t
89      !!         variable), salt and pressure (assuming no pressure variation
90      !!         along geopotential surfaces, i.e. the pressure p in decibars
91      !!         is approximated by the depth in meters.
92      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
93      !!         with pressure                      p        decibars
94      !!              potential temperature         t        deg celsius
95      !!              salinity                      s        psu
96      !!              reference volumic mass        rau0     kg/m**3
97      !!              in situ volumic mass          rho      kg/m**3
98      !!              in situ density anomalie      prd      no units
99      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
100      !!          t = 40 deg celcius, s=40 psu
101      !!      nn_eos = 1 : linear equation of state function of temperature only
102      !!              prd(t) = 0.0285 - rn_alpha * t
103      !!      nn_eos = 2 : linear equation of state function of temperature and
104      !!               salinity
105      !!              prd(t,s) = rn_beta * s - rn_alpha * tn - 1.
106      !!      Note that no boundary condition problem occurs in this routine
107      !!      as pts are defined over the whole domain.
108      !!
109      !! ** Action  :   compute prd , the in situ density (no units)
110      !!
111      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
112      !!----------------------------------------------------------------------
113      !!
114      REAL(wp), DIMENSION(:,:,:,:), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
115      !                                                      ! 2 : salinity               [psu]
116      REAL(wp), DIMENSION(:,:,:)  , INTENT(  out) ::   prd   ! in situ density            [-]
117      !!
118      INTEGER  ::   ji, jj, jk           ! dummy loop indices
119      REAL(wp) ::   zt , zs , zh , zsr   ! local scalars
120      REAL(wp) ::   zr1, zr2, zr3, zr4   !   -      -
121      REAL(wp) ::   zrhop, ze, zbw, zb   !   -      -
122      REAL(wp) ::   zd , zc , zaw, za    !   -      -
123      REAL(wp) ::   zb1, za1, zkw, zk0   !   -      -
124      REAL(wp) ::   zrau0r               !   -      -
125      REAL(wp), POINTER, DIMENSION(:,:,:) :: zws
126      !!----------------------------------------------------------------------
127
128      !
129      IF( nn_timing == 1 ) CALL timing_start('eos')
130      !
131      CALL wrk_alloc( jpi, jpj, jpk, zws )
132      !
133      SELECT CASE( nn_eos )
134      !
135      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
136         zrau0r = 1.e0 / rau0
137!CDIR NOVERRCHK
138         zws(:,:,:) = SQRT( ABS( pts(:,:,:,jp_sal) ) )
139         !
140         DO jk = 1, jpkm1
141            DO jj = 1, jpj
142               DO ji = 1, jpi
143                  zt = pts   (ji,jj,jk,jp_tem)
144                  zs = pts   (ji,jj,jk,jp_sal)
145                  zh = gdept_crs(ji,jj,jk)        ! depth
146                  zsr= zws   (ji,jj,jk)        ! square root salinity
147                  !
148                  ! compute volumic mass pure water at atm pressure
149                  zr1= ( ( ( ( 6.536332e-9_wp  *zt - 1.120083e-6_wp )*zt + 1.001685e-4_wp )*zt   &
150                     &        -9.095290e-3_wp )*zt + 6.793952e-2_wp )*zt +  999.842594_wp
151                  ! seawater volumic mass atm pressure
152                  zr2= ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp ) *zt+7.6438e-5_wp ) *zt        &
153                     &                      -4.0899e-3_wp ) *zt+0.824493_wp
154                  zr3= ( -1.6546e-6_wp*zt+1.0227e-4_wp )    *zt-5.72466e-3_wp
155                  zr4= 4.8314e-4_wp
156                  !
157                  ! potential volumic mass (reference to the surface)
158                  zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
159                  !
160                  ! add the compression terms
161                  ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
162                  zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
163                  zb = zbw + ze * zs
164                  !
165                  zd = -2.042967e-2_wp
166                  zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
167                  zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt - 4.721788_wp
168                  za = ( zd*zsr + zc ) *zs + zaw
169                  !
170                  zb1=   (-0.1909078_wp*zt+7.390729_wp )        *zt-55.87545_wp
171                  za1= ( ( 2.326469e-3_wp*zt+1.553190_wp)       *zt-65.00517_wp ) *zt+1044.077_wp
172                  zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp ) *zt-30.41638_wp ) *zt + 2098.925_wp ) *zt+190925.6_wp
173                  zk0= ( zb1*zsr + za1 )*zs + zkw
174                  !
175                  ! masked in situ density anomaly
176                  prd(ji,jj,jk) = (  zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  )    &
177                     &             - rau0  ) * zrau0r * tmask_crs(ji,jj,jk)
178               END DO
179            END DO
180         END DO
181         !
182      CASE( 1 )                !==  Linear formulation function of temperature only  ==!
183         DO jk = 1, jpkm1
184            prd(:,:,jk) = ( 0.0285_wp - rn_alpha * pts(:,:,jk,jp_tem) ) * tmask_crs(:,:,jk)
185         END DO
186         !
187      CASE( 2 )                !==  Linear formulation function of temperature and salinity  ==!
188         DO jk = 1, jpkm1
189            prd(:,:,jk) = ( rn_beta  * pts(:,:,jk,jp_sal) - rn_alpha * pts(:,:,jk,jp_tem) ) * tmask_crs(:,:,jk)
190         END DO
191         !
192      END SELECT
193      !
194    !  IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos  : ', ovlap=1, kdim=jpk )
195      !
196      CALL wrk_dealloc( jpi, jpj, jpk, zws )
197      !
198      IF( nn_timing == 1 ) CALL timing_stop('eos')
199      !
200   END SUBROUTINE eos_insitu_crs
201
202
203   SUBROUTINE eos_insitu_pot_crs( pts, prd, prhop )
204      !!----------------------------------------------------------------------
205      !!                  ***  ROUTINE eos_insitu_pot  ***
206      !!
207      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) and the
208      !!      potential volumic mass (Kg/m3) from potential temperature and
209      !!      salinity fields using an equation of state defined through the
210      !!     namelist parameter nn_eos.
211      !!
212      !! ** Method  :
213      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
214      !!         the in situ density is computed directly as a function of
215      !!         potential temperature relative to the surface (the opa t
216      !!         variable), salt and pressure (assuming no pressure variation
217      !!         along geopotential surfaces, i.e. the pressure p in decibars
218      !!         is approximated by the depth in meters.
219      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
220      !!              rhop(t,s)  = rho(t,s,0)
221      !!         with pressure                      p        decibars
222      !!              potential temperature         t        deg celsius
223      !!              salinity                      s        psu
224      !!              reference volumic mass        rau0     kg/m**3
225      !!              in situ volumic mass          rho      kg/m**3
226      !!              in situ density anomalie      prd      no units
227      !!
228      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
229      !!          t = 40 deg celcius, s=40 psu
230      !!
231      !!      nn_eos = 1 : linear equation of state function of temperature only
232      !!              prd(t) = ( rho(t) - rau0 ) / rau0 = 0.028 - rn_alpha * t
233      !!              rhop(t,s)  = rho(t,s)
234      !!
235      !!      nn_eos = 2 : linear equation of state function of temperature and
236      !!               salinity
237      !!              prd(t,s) = ( rho(t,s) - rau0 ) / rau0
238      !!                       = rn_beta * s - rn_alpha * tn - 1.
239      !!              rhop(t,s)  = rho(t,s)
240      !!      Note that no boundary condition problem occurs in this routine
241      !!      as (tn,sn) or (ta,sa) are defined over the whole domain.
242      !!
243      !! ** Action  : - prd  , the in situ density (no units)
244      !!              - prhop, the potential volumic mass (Kg/m3)
245      !!
246      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
247      !!                Brown and Campana, Mon. Weather Rev., 1978
248      !!----------------------------------------------------------------------
249      !!
250      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts    ! 1 : potential temperature  [Celcius]
251      !                                                                ! 2 : salinity               [psu]
252      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prd    ! in situ density            [-]
253      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(  out) ::   prhop  ! potential density (surface referenced)
254      !
255      INTEGER  ::   ji, jj, jk   ! dummy loop indices
256      REAL(wp) ::   zt, zs, zh, zsr, zr1, zr2, zr3, zr4, zrhop, ze, zbw   ! local scalars
257      REAL(wp) ::   zb, zd, zc, zaw, za, zb1, za1, zkw, zk0, zrau0r       !   -      -
258      REAL(wp), POINTER, DIMENSION(:,:,:) :: zws
259      !!----------------------------------------------------------------------
260      !
261      IF( nn_timing == 1 ) CALL timing_start('eos-p')
262      !
263      CALL wrk_alloc( jpi, jpj, jpk, zws )
264      !
265      SELECT CASE ( nn_eos )
266      !
267      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
268         zrau0r = 1.e0 / rau0
269!CDIR NOVERRCHK
270         zws(:,:,:) = SQRT( ABS( pts(:,:,:,jp_sal) ) )
271         !
272         DO jk = 1, jpkm1
273            DO jj = 1, jpj
274               DO ji = 1, jpi
275                  zt = pts   (ji,jj,jk,jp_tem)
276                  zs = pts   (ji,jj,jk,jp_sal)
277                  zh = gdept_crs(ji,jj,jk)        ! depth
278                  zsr= zws   (ji,jj,jk)        ! square root salinity
279                  !
280                  ! compute volumic mass pure water at atm pressure
281                  zr1= ( ( ( ( 6.536332e-9_wp*zt-1.120083e-6_wp )*zt+1.001685e-4_wp )*zt   &
282                     &                          -9.095290e-3_wp )*zt+6.793952e-2_wp )*zt+999.842594_wp
283                  ! seawater volumic mass atm pressure
284                  zr2= ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp ) *zt+7.6438e-5_wp ) *zt   &
285                     &                                         -4.0899e-3_wp ) *zt+0.824493_wp
286                  zr3= ( -1.6546e-6_wp*zt+1.0227e-4_wp )    *zt-5.72466e-3_wp
287                  zr4= 4.8314e-4_wp
288                  !
289                  ! potential volumic mass (reference to the surface)
290                  zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
291                  !
292                  ! save potential volumic mass
293                  prhop(ji,jj,jk) = zrhop * tmask_crs(ji,jj,jk)
294                  !
295                  ! add the compression terms
296                  ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
297                  zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
298                  zb = zbw + ze * zs
299                  !
300                  zd = -2.042967e-2_wp
301                  zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
302                  zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt - 4.721788_wp
303                  za = ( zd*zsr + zc ) *zs + zaw
304                  !
305                  zb1=   (  -0.1909078_wp  *zt+7.390729_wp    ) *zt-55.87545_wp
306                  za1= ( (   2.326469e-3_wp*zt+1.553190_wp    ) *zt-65.00517_wp ) *zt + 1044.077_wp
307                  zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp ) *zt-30.41638_wp ) *zt + 2098.925_wp ) *zt+190925.6_wp
308                  zk0= ( zb1*zsr + za1 )*zs + zkw
309                  !
310                  ! masked in situ density anomaly
311                  prd(ji,jj,jk) = (  zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  )    &
312                     &             - rau0  ) * zrau0r * tmask_crs(ji,jj,jk)
313               END DO
314            END DO
315         END DO
316         !
317      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
318         DO jk = 1, jpkm1
319            prd  (:,:,jk) = ( 0.0285_wp - rn_alpha * pts(:,:,jk,jp_tem) )        * tmask_crs(:,:,jk)
320            prhop(:,:,jk) = ( 1.e0_wp   +            prd (:,:,jk)       ) * rau0 * tmask_crs(:,:,jk)
321         END DO
322         !
323      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
324         DO jk = 1, jpkm1
325            prd  (:,:,jk) = ( rn_beta  * pts(:,:,jk,jp_sal) - rn_alpha * pts(:,:,jk,jp_tem) )        * tmask_crs(:,:,jk)
326            prhop(:,:,jk) = ( 1.e0_wp  + prd (:,:,jk) )                                       * rau0 * tmask_crs(:,:,jk)
327         END DO
328         !
329      END SELECT
330      !
331   !   IF(ln_ctl)   CALL prt_ctl( tab3d_1=prd, clinfo1=' eos-p: ', tab3d_2=prhop, clinfo2=' pot : ', ovlap=1, kdim=jpk )
332      !
333      CALL wrk_dealloc( jpi, jpj, jpk, zws )
334      !
335      IF( nn_timing == 1 ) CALL timing_stop('eos-p')
336      !
337   END SUBROUTINE eos_insitu_pot_crs
338
339
340   SUBROUTINE eos_insitu_2d_crs( pts, pdep, prd )
341      !!----------------------------------------------------------------------
342      !!                  ***  ROUTINE eos_insitu_2d  ***
343      !!
344      !! ** Purpose :   Compute the in situ density (ratio rho/rau0) from
345      !!      potential temperature and salinity using an equation of state
346      !!      defined through the namelist parameter nn_eos. * 2D field case
347      !!
348      !! ** Method :
349      !!      nn_eos = 0 : Jackett and McDougall (1994) equation of state.
350      !!         the in situ density is computed directly as a function of
351      !!         potential temperature relative to the surface (the opa t
352      !!         variable), salt and pressure (assuming no pressure variation
353      !!         along geopotential surfaces, i.e. the pressure p in decibars
354      !!         is approximated by the depth in meters.
355      !!              prd(t,s,p) = ( rho(t,s,p) - rau0 ) / rau0
356      !!         with pressure                      p        decibars
357      !!              potential temperature         t        deg celsius
358      !!              salinity                      s        psu
359      !!              reference volumic mass        rau0     kg/m**3
360      !!              in situ volumic mass          rho      kg/m**3
361      !!              in situ density anomalie      prd      no units
362      !!         Check value: rho = 1060.93298 kg/m**3 for p=10000 dbar,
363      !!          t = 40 deg celcius, s=40 psu
364      !!      nn_eos = 1 : linear equation of state function of temperature only
365      !!              prd(t) = 0.0285 - rn_alpha * t
366      !!      nn_eos = 2 : linear equation of state function of temperature and
367      !!               salinity
368      !!              prd(t,s) = rn_beta * s - rn_alpha * tn - 1.
369      !!      Note that no boundary condition problem occurs in this routine
370      !!      as pts are defined over the whole domain.
371      !!
372      !! ** Action  : - prd , the in situ density (no units)
373      !!
374      !! References :   Jackett and McDougall, J. Atmos. Ocean. Tech., 1994
375      !!----------------------------------------------------------------------
376      !!
377      REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
378      !                                                           ! 2 : salinity               [psu]
379      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(in   ) ::   pdep  ! depth                  [m]
380      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(  out) ::   prd   ! in situ density
381      !!
382      INTEGER  ::   ji, jj                    ! dummy loop indices
383      REAL(wp) ::   zt, zs, zh, zsr, zr1, zr2, zr3, zr4, zrhop, ze, zbw   ! temporary scalars
384      REAL(wp) ::   zb, zd, zc, zaw, za, zb1, za1, zkw, zk0, zmask        !    -         -
385      REAL(wp), POINTER, DIMENSION(:,:) :: zws
386      !!----------------------------------------------------------------------
387      !
388!WRITE(numout,*) ' pts1 ' ,  pts(:,:,1)
389!WRITE(numout,*) ' pts2 ' ,  pts(:,:,2)
390!WRITE(numout,*) ' jpi ' ,  jpi
391!WRITE(numout,*) ' fs_jpim1 ' ,  fs_jpim1
392!WRITE(numout,*) ' dim ' ,  size(pts,1)
393      IF( nn_timing == 1 ) CALL timing_start('eos2d')
394      !
395      CALL wrk_alloc( jpi, jpj, zws )
396      !
397
398      prd(:,:) = 0._wp
399
400      SELECT CASE( nn_eos )
401      !
402      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
403      !
404!CDIR NOVERRCHK
405         DO jj = 1, jpjm1
406!CDIR NOVERRCHK
407            DO ji = 1, fs_jpim1   ! vector opt.
408               zws(ji,jj) = SQRT( ABS( pts(ji,jj,jp_sal) ) )
409            END DO
410         END DO
411         DO jj = 1, jpjm1
412            DO ji = 1, fs_jpim1   ! vector opt.
413               zmask = tmask_crs(ji,jj,1)          ! land/sea bottom mask = surf. mask
414               zt    = pts  (ji,jj,jp_tem)            ! interpolated T
415               zs    = pts  (ji,jj,jp_sal)            ! interpolated S
416               zsr   = zws  (ji,jj)            ! square root of interpolated S
417               zh    = pdep (ji,jj)            ! depth at the partial step level
418               !
419               ! compute volumic mass pure water at atm pressure
420               zr1 = ( ( ( ( 6.536332e-9_wp*zt-1.120083e-6_wp )*zt+1.001685e-4_wp )*zt   &
421                  &                        -9.095290e-3_wp )*zt+6.793952e-2_wp )*zt+999.842594_wp
422               ! seawater volumic mass atm pressure
423               zr2 = ( ( ( 5.3875e-9_wp*zt-8.2467e-7_wp )*zt+7.6438e-5_wp ) *zt   &
424                  &                                   -4.0899e-3_wp ) *zt+0.824493_wp
425               zr3 = ( -1.6546e-6_wp*zt+1.0227e-4_wp ) *zt-5.72466e-3_wp
426               zr4 = 4.8314e-4_wp
427               !
428               ! potential volumic mass (reference to the surface)
429               zrhop= ( zr4*zs + zr3*zsr + zr2 ) *zs + zr1
430               !
431               ! add the compression terms
432               ze = ( -3.508914e-8_wp*zt-1.248266e-8_wp ) *zt-2.595994e-6_wp
433               zbw= (  1.296821e-6_wp*zt-5.782165e-9_wp ) *zt+1.045941e-4_wp
434               zb = zbw + ze * zs
435               !
436               zd =    -2.042967e-2_wp
437               zc =   (-7.267926e-5_wp*zt+2.598241e-3_wp ) *zt+0.1571896_wp
438               zaw= ( ( 5.939910e-6_wp*zt+2.512549e-3_wp ) *zt-0.1028859_wp ) *zt -4.721788_wp
439               za = ( zd*zsr + zc ) *zs + zaw
440               !
441               zb1=     (-0.1909078_wp  *zt+7.390729_wp      ) *zt-55.87545_wp
442               za1=   ( ( 2.326469e-3_wp*zt+1.553190_wp      ) *zt-65.00517_wp ) *zt+1044.077_wp
443               zkw= ( ( (-1.361629e-4_wp*zt-1.852732e-2_wp   ) *zt-30.41638_wp ) *zt   &
444                  &                             +2098.925_wp ) *zt+190925.6_wp
445               zk0= ( zb1*zsr + za1 )*zs + zkw
446               !
447               ! masked in situ density anomaly
448               prd(ji,jj) = ( zrhop / (  1.0_wp - zh / ( zk0 - zh * ( za - zh * zb ) )  ) - rau0 ) / rau0 * zmask
449            END DO
450         END DO
451         !
452      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
453         DO jj = 1, jpjm1
454            DO ji = 1, fs_jpim1   ! vector opt.
455               prd(ji,jj) = ( 0.0285_wp - rn_alpha * pts(ji,jj,jp_tem) ) * tmask_crs(ji,jj,1)
456            END DO
457         END DO
458         !
459      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
460         DO jj = 1, jpjm1
461            DO ji = 1, fs_jpim1   ! vector opt.
462               prd(ji,jj) = ( rn_beta * pts(ji,jj,jp_sal) - rn_alpha * pts(ji,jj,jp_tem) ) * tmask_crs(ji,jj,1)
463            END DO
464         END DO
465         !
466      END SELECT
467!WRITE(numout,*) ' prd ' ,  prd(:,:)
468!WRITE(numout,*) ' zws ' ,  zws(:,:)
469!WRITE(numout,*) ' pdep ' ,  pdep(:,:)
470
471
472
473!     IF(ln_ctl)   CALL prt_ctl( tab2d_1=prd, clinfo1=' eos2d: ' )
474      !
475      CALL wrk_dealloc( jpi, jpj, zws )
476      !
477      IF( nn_timing == 1 ) CALL timing_stop('eos2d')
478      !
479   END SUBROUTINE eos_insitu_2d_crs
480
481
482   SUBROUTINE eos_bn2_crs( pts, pn2 )
483      !!----------------------------------------------------------------------
484      !!                  ***  ROUTINE eos_bn2  ***
485      !!
486      !! ** Purpose :   Compute the local Brunt-Vaisala frequency at the time-
487      !!      step of the input arguments
488      !!
489      !! ** Method :
490      !!       * nn_eos = 0  : UNESCO sea water properties
491      !!         The brunt-vaisala frequency is computed using the polynomial
492      !!      polynomial expression of McDougall (1987):
493      !!            N^2 = grav * beta * ( alpha/beta*dk[ t ] - dk[ s ] )/e3w
494      !!      If lk_zdfddm=T, the heat/salt buoyancy flux ratio Rrau is
495      !!      computed and used in zdfddm module :
496      !!              Rrau = alpha/beta * ( dk[ t ] / dk[ s ] )
497      !!       * nn_eos = 1  : linear equation of state (temperature only)
498      !!            N^2 = grav * rn_alpha * dk[ t ]/e3w
499      !!       * nn_eos = 2  : linear equation of state (temperature & salinity)
500      !!            N^2 = grav * (rn_alpha * dk[ t ] - rn_beta * dk[ s ] ) / e3w
501      !!      The use of potential density to compute N^2 introduces e r r o r
502      !!      in the sign of N^2 at great depths. We recommand the use of
503      !!      nn_eos = 0, except for academical studies.
504      !!        Macro-tasked on horizontal slab (jk-loop)
505      !!      N.B. N^2 is set to zero at the first level (JK=1) in inidtr
506      !!      and is never used at this level.
507      !!
508      !! ** Action  : - pn2 : the brunt-vaisala frequency
509      !!
510      !! References :   McDougall, J. Phys. Oceanogr., 17, 1950-1964, 1987.
511      !!----------------------------------------------------------------------
512      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts   ! 1 : potential temperature  [Celcius]
513      !                                                               ! 2 : salinity               [psu]
514      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   pn2   ! Brunt-Vaisala frequency    [s-1]
515      !!
516      INTEGER  ::   ji, jj, jk   ! dummy loop indices
517      REAL(wp) ::   zgde3w, zt, zs, zh, zalbet, zbeta   ! local scalars
518#if defined key_zdfddm
519      REAL(wp) ::   zds   ! local scalars
520#endif
521      !!----------------------------------------------------------------------
522
523      !
524      IF( nn_timing == 1 ) CALL timing_start('bn2')
525      !
526      ! pn2 : interior points only (2=< jk =< jpkm1 )
527      ! --------------------------
528      !
529      SELECT CASE( nn_eos )
530      !
531      CASE( 0 )                !==  Jackett and McDougall (1994) formulation  ==!
532         DO jk = 2, jpkm1
533            DO jj = 1, jpj
534               DO ji = 1, jpi
535                  zgde3w = grav / e3w_max_crs(ji,jj,jk)
536                  zt = 0.5 * ( pts(ji,jj,jk,jp_tem) + pts(ji,jj,jk-1,jp_tem) )         ! potential temperature at w-pt
537                  zs = 0.5 * ( pts(ji,jj,jk,jp_sal) + pts(ji,jj,jk-1,jp_sal) ) - 35.0  ! salinity anomaly (s-35) at w-pt
538                  zh = gdepw_crs(ji,jj,jk)                                                ! depth in meters  at w-point
539                  !
540                  zalbet = ( ( ( - 0.255019e-07_wp * zt + 0.298357e-05_wp ) * zt   &   ! ratio alpha/beta
541                     &                                  - 0.203814e-03_wp ) * zt   &
542                     &                                  + 0.170907e-01_wp ) * zt   &
543                     &   +         0.665157e-01_wp                                 &
544                     &   +     ( - 0.678662e-05_wp * zs                            &
545                     &           - 0.846960e-04_wp * zt + 0.378110e-02_wp ) * zs   &
546                     &   +   ( ( - 0.302285e-13_wp * zh                            &
547                     &           - 0.251520e-11_wp * zs                            &
548                     &           + 0.512857e-12_wp * zt * zt              ) * zh   &
549                     &           - 0.164759e-06_wp * zs                            &
550                     &        +(   0.791325e-08_wp * zt - 0.933746e-06_wp ) * zt   &
551                     &                                  + 0.380374e-04_wp ) * zh
552                     !
553                  zbeta  = ( ( -0.415613e-09_wp * zt + 0.555579e-07_wp ) * zt      &   ! beta
554                     &                               - 0.301985e-05_wp ) * zt      &
555                     &   +       0.785567e-03_wp                                   &
556                     &   + (     0.515032e-08_wp * zs                              &
557                     &         + 0.788212e-08_wp * zt - 0.356603e-06_wp ) * zs     &
558                     &   + ( (   0.121551e-17_wp * zh                              &
559                     &         - 0.602281e-15_wp * zs                              &
560                     &         - 0.175379e-14_wp * zt + 0.176621e-12_wp ) * zh     &
561                     &                                + 0.408195e-10_wp   * zs     &
562                     &     + ( - 0.213127e-11_wp * zt + 0.192867e-09_wp ) * zt     &
563                     &                                - 0.121555e-07_wp ) * zh
564                     !
565                  !cbr zgde3w: divide by 0
566                  !pn2(ji,jj,jk) = zgde3w * zbeta * tmask_crs(ji,jj,jk)           &   ! N^2
567                  !   &          * ( zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) )   &
568                  !   &                     - ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) )
569                  pn2(ji,jj,jk) = zbeta * tmask_crs(ji,jj,jk)           &   ! N^2
570                     &          * ( zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) )   &
571                     &                     - ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) ) )
572                  IF( e3w_max_crs(ji,jj,jk) .NE. 0._wp ) pn2(ji,jj,jk) = zgde3w * e3w_max_crs(ji,jj,jk)
573
574#if defined key_zdfddm
575                  !                                                         !!bug **** caution a traiter zds=dk[S]= 0 !!!!
576                  zds = ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) )                    ! Rrau = (alpha / beta) (dk[t] / dk[s])
577                  IF ( ABS( zds) <= 1.e-20_wp ) zds = 1.e-20_wp
578                  rrau(ji,jj,jk) = zalbet * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) / zds
579#endif
580               END DO
581            END DO
582         END DO
583         !
584      CASE( 1 )                !==  Linear formulation = F( temperature )  ==!
585         DO jk = 2, jpkm1
586            pn2(:,:,jk) = grav * rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) ) / e3w_max_crs(:,:,jk) * tmask_crs(:,:,jk)
587         END DO
588         !
589      CASE( 2 )                !==  Linear formulation = F( temperature , salinity )  ==!
590         DO jk = 2, jpkm1
591            !cbr: bug divide by 0.
592            !pn2(:,:,jk) = grav * (  rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) )      &
593            !   &                  - rn_beta  * ( pts(:,:,jk-1,jp_sal) - pts(:,:,jk,jp_sal) )  )   &
594            !   &               / e3w_max_crs(:,:,jk) * tmask_crs(:,:,jk)
595            pn2(:,:,jk) = grav * (  rn_alpha * ( pts(:,:,jk-1,jp_tem) - pts(:,:,jk,jp_tem) )      &
596               &                  - rn_beta  * ( pts(:,:,jk-1,jp_sal) - pts(:,:,jk,jp_sal) )  )   &
597               &               * tmask_crs(:,:,jk)
598            DO jj = 1, jpj
599               DO ji = 1, jpi
600                  IF( e3w_max_crs(ji,jj,jk) .NE. 0._wp ) pn2(ji,jj,jk) = pn2(ji,jj,jk) / e3w_max_crs(ji,jj,jk)
601               ENDDO
602            ENDDO
603         END DO
604#if defined key_zdfddm
605         DO jk = 2, jpkm1                                 ! Rrau = (alpha / beta) (dk[t] / dk[s])
606            DO jj = 1, jpj
607               DO ji = 1, jpi
608                  zds = ( pts(ji,jj,jk-1,jp_sal) - pts(ji,jj,jk,jp_sal) )
609                  IF ( ABS( zds ) <= 1.e-20_wp ) zds = 1.e-20_wp
610                  rrau(ji,jj,jk) = ralpbet_crs * ( pts(ji,jj,jk-1,jp_tem) - pts(ji,jj,jk,jp_tem) ) / zds
611               END DO
612            END DO
613         END DO
614#endif
615      END SELECT
616
617  !    IF(ln_ctl)   CALL prt_ctl( tab3d_1=pn2, clinfo1=' bn2  : ', ovlap=1, kdim=jpk )
618#if defined key_zdfddm
619  !    IF(ln_ctl)   CALL prt_ctl( tab3d_1=rrau, clinfo1=' rrau : ', ovlap=1, kdim=jpk )
620#endif
621      !
622      IF( nn_timing == 1 ) CALL timing_stop('bn2')
623      !
624   END SUBROUTINE eos_bn2_crs
625
626
627   SUBROUTINE eos_alpbet_crs( pts, palpbet, beta0 )
628      !!----------------------------------------------------------------------
629      !!                 ***  ROUTINE eos_alpbet  ***
630      !!
631      !! ** Purpose :   Calculates the in situ thermal/haline expansion ratio at T-points
632      !!
633      !! ** Method  :   calculates alpha / beta ratio at T-points
634      !!       * nn_eos = 0  : UNESCO sea water properties
635      !!                       The alpha/beta ratio is returned as 3-D array palpbet using the polynomial
636      !!                       polynomial expression of McDougall (1987).
637      !!                       Scalar beta0 is returned = 1.
638      !!       * nn_eos = 1  : linear equation of state (temperature only)
639      !!                       The ratio is undefined, so we return alpha as palpbet
640      !!                       Scalar beta0 is returned = 0.
641      !!       * nn_eos = 2  : linear equation of state (temperature & salinity)
642      !!                       The alpha/beta ratio is returned as ralpbet
643      !!                       Scalar beta0 is returned = 1.
644      !!
645      !! ** Action  : - palpbet : thermal/haline expansion ratio at T-points
646      !!            :   beta0   : 1. or 0.
647      !!----------------------------------------------------------------------
648      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts), INTENT(in   ) ::   pts       ! pot. temperature & salinity
649      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(  out) ::   palpbet   ! thermal/haline expansion ratio
650      REAL(wp),                              INTENT(  out) ::   beta0     ! set = 1 except with case 1 eos, rho=rho(T)
651      !!
652      INTEGER  ::   ji, jj, jk   ! dummy loop indices
653      REAL(wp) ::   zt, zs, zh   ! local scalars
654      !!----------------------------------------------------------------------
655      !
656      IF( nn_timing == 1 ) CALL timing_start('eos_alpbet')
657      !
658      SELECT CASE ( nn_eos )
659      !
660      CASE ( 0 )               ! Jackett and McDougall (1994) formulation
661         DO jk = 1, jpk
662            DO jj = 1, jpj
663               DO ji = 1, jpi
664                  zt = pts(ji,jj,jk,jp_tem)           ! potential temperature
665                  zs = pts(ji,jj,jk,jp_sal) - 35._wp  ! salinity anomaly (s-35)
666                  zh = fsdept(ji,jj,jk)               ! depth in meters
667                  !
668                  palpbet(ji,jj,jk) =                                              &
669                     &     ( ( ( - 0.255019e-07_wp * zt + 0.298357e-05_wp ) * zt   &
670                     &                                  - 0.203814e-03_wp ) * zt   &
671                     &                                  + 0.170907e-01_wp ) * zt   &
672                     &   + 0.665157e-01_wp                                         &
673                     &   +     ( - 0.678662e-05_wp * zs                            &
674                     &           - 0.846960e-04_wp * zt + 0.378110e-02_wp ) * zs   &
675                     &   +   ( ( - 0.302285e-13_wp * zh                            &
676                     &           - 0.251520e-11_wp * zs                            &
677                     &           + 0.512857e-12_wp * zt * zt              ) * zh   &
678                     &           - 0.164759e-06_wp * zs                            &
679                     &        +(   0.791325e-08_wp * zt - 0.933746e-06_wp ) * zt   &
680                     &                                  + 0.380374e-04_wp ) * zh
681               END DO
682            END DO
683         END DO
684         beta0 = 1._wp
685         !
686      CASE ( 1 )              !==  Linear formulation = F( temperature )  ==!
687         palpbet(:,:,:) = rn_alpha
688         beta0 = 0._wp
689         !
690      CASE ( 2 )              !==  Linear formulation = F( temperature , salinity )  ==!
691         palpbet(:,:,:) = ralpbet_crs
692         beta0 = 1._wp
693         !
694      CASE DEFAULT
695         IF(lwp) WRITE(numout,cform_err)
696         IF(lwp) WRITE(numout,*) '          bad flag value for nn_eos = ', nn_eos
697         nstop = nstop + 1
698         !
699      END SELECT
700      !
701      IF( nn_timing == 1 ) CALL timing_stop('eos_alpbet')
702      !
703   END SUBROUTINE eos_alpbet_crs
704
705
706   FUNCTION tfreez_crs( psal ) RESULT( ptf )
707      !!----------------------------------------------------------------------
708      !!                 ***  ROUTINE eos_init  ***
709      !!
710      !! ** Purpose :   Compute the sea surface freezing temperature [Celcius]
711      !!
712      !! ** Method  :   UNESCO freezing point at the surface (pressure = 0???)
713      !!       freezing point [Celcius]=(-.0575+1.710523e-3*sqrt(abs(s))-2.154996e-4*s)*s-7.53e-4*p
714      !!       checkvalue: tf= -2.588567 Celsius for s=40.0psu, p=500. decibars
715      !!
716      !! Reference  :   UNESCO tech. papers in the marine science no. 28. 1978
717      !!----------------------------------------------------------------------
718      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   psal   ! salinity             [psu]
719      ! Leave result array automatic rather than making explicitly allocated
720      REAL(wp), DIMENSION(jpi,jpj)                ::   ptf    ! freezing temperature [Celcius]
721      !!----------------------------------------------------------------------
722      !
723      ptf(:,:) = ( - 0.0575_wp + 1.710523e-3_wp * SQRT( psal(:,:) )   &
724         &                     - 2.154996e-4_wp *       psal(:,:)   ) * psal(:,:)
725      !
726   END FUNCTION tfreez_crs
727
728
729   SUBROUTINE eos_init_crs
730      !!----------------------------------------------------------------------
731      !!                 ***  ROUTINE eos_init  ***
732      !!
733      !! ** Purpose :   initializations for the equation of state
734      !!
735      !! ** Method  :   Read the namelist nameos and control the parameters
736      !!----------------------------------------------------------------------
737      INTEGER ::   ios   ! Local integer output status for namelist read
738      !!
739      NAMELIST/nameos/ nn_eos, rn_alpha, rn_beta
740      !!----------------------------------------------------------------------
741      !
742      REWIND( numnam_ref )           
743      READ  ( numnam_ref, nameos, IOSTAT = ios, ERR = 901)
744901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nameos in reference namelist', lwp )
745
746      REWIND( numnam_cfg )   
747      READ  ( numnam_cfg, nameos, IOSTAT = ios, ERR = 902 )
748902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nameos in configuration namelist', lwp )
749      IF(lwm) WRITE ( numond, nameos )
750
751      !
752      IF(lwp) THEN                ! Control print
753         WRITE(numout,*)
754         WRITE(numout,*) 'eos_init : equation of state'
755         WRITE(numout,*) '~~~~~~~~'
756         WRITE(numout,*) '          Namelist nameos : set eos parameters'
757         WRITE(numout,*) '             flag for eq. of state and N^2  nn_eos   = ', nn_eos
758         WRITE(numout,*) '             thermal exp. coef. (linear)    rn_alpha = ', rn_alpha
759         WRITE(numout,*) '             saline  exp. coef. (linear)    rn_beta  = ', rn_beta
760      ENDIF
761      !
762      SELECT CASE( nn_eos )         ! check option
763      !
764      CASE( 0 )                        !==  Jackett and McDougall (1994) formulation  ==!
765         IF(lwp) WRITE(numout,*)
766         IF(lwp) WRITE(numout,*) '          use of Jackett & McDougall (1994) equation of state and'
767         IF(lwp) WRITE(numout,*) '                 McDougall (1987) Brunt-Vaisala frequency'
768         !
769      CASE( 1 )                        !==  Linear formulation = F( temperature )  ==!
770         IF(lwp) WRITE(numout,*)
771         IF(lwp) WRITE(numout,*) '          use of linear eos rho(T) = rau0 * ( 1.0285 - rn_alpha * T )'
772         IF( lk_zdfddm ) CALL ctl_stop( '          double diffusive mixing parameterization requires',   &
773              &                         ' that T and S are used as state variables' )
774         !
775      CASE( 2 )                        !==  Linear formulation = F( temperature , salinity )  ==!
776         ralpbet_crs = rn_alpha / rn_beta
777         IF(lwp) WRITE(numout,*)
778         IF(lwp) WRITE(numout,*) '          use of linear eos rho(T,S) = rau0 * ( rn_beta * S - rn_alpha * T )'
779         !
780      CASE DEFAULT                     !==  ERROR in nn_eos  ==!
781         WRITE(ctmp1,*) '          bad flag value for nn_eos = ', nn_eos
782         CALL ctl_stop( ctmp1 )
783         !
784      END SELECT
785      !
786   END SUBROUTINE eos_init_crs
787
788   !!======================================================================
789END MODULE eosbn2_crs
Note: See TracBrowser for help on using the repository browser.