New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd_crs.F90 @ 7795

Last change on this file since 7795 was 7795, checked in by cbricaud, 7 years ago

code cleaning and correct bug for wn computing in vvl case

  • Property svn:executable set to *
File size: 18.2 KB
RevLine 
[5105]1MODULE traadv_tvd_crs
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce , ONLY : lk_vvl
[5601]26   USE trd_oce         ! tracers trends
[5105]27   USE trdtra          ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp         ! MPP library
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36   USE crs
37   USE crslbclnk
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv_tvd_crs    ! routine called by step.F90
43
44   LOGICAL ::   l_trd   ! flag to compute trends
45
46   !! * Substitutions
47#  include "domzgr_substitute.h90"
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id: traadv_tvd.F90 3294 2012-01-28 16:44:18Z rblod $
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_tvd_crs ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
57      &                                       ptb, ptn, pta, kjpt )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_tvd  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of
62      !!       tracers and add it to the general trend of tracer equations
63      !!
64      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
65      !!       corrected flux (monotonic correction)
66      !!       note: - this advection scheme needs a leap-frog time scheme
67      !!
68      !! ** Action : - update (pta) with the now advective tracer trends
69      !!             - save the trends
70      !!----------------------------------------------------------------------
71      !cbr ça fait des trucs bizarres USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
72      !
73      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
75      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
76      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
77      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
78      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
81      !
82      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz,zwx,zwy
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88
89      INTEGER  ::   iji, ijj, ijk           ! dummy loop indices 
90      REAL(wp) ::   zmin,zmax
91      !!----------------------------------------------------------------------
92      !
[6772]93
[5105]94      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
95      !
96      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zwx, zwy )
97      !
98      IF( kt == kit000 )  THEN
99         IF(lwp) WRITE(numout,*)
100         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
101         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
102         !
103         l_trd = .FALSE.
104         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
105
106         IF(lwp) WRITE(numout,*)"jpi jpj jpkm1 ",jpi,jpj,jpkm1
107      ENDIF
108      !
109      IF( l_trd )  THEN
110         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
111         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
112      ENDIF
113      !
114      zwi(:,:,:) = 0.e0
115      !
116      !                                                          ! ===========
117      DO jn = 1, kjpt                                            ! tracer loop
118         !                                                       ! ===========
119         ! 1. Bottom value : flux set to zero
120         ! ----------------------------------
121         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
122         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
123
124         ! 2. upstream advection with initial mass fluxes & intermediate update
125         ! --------------------------------------------------------------------
126
127         ! upstream tracer flux in the i and j direction
128         DO jk = 1, jpkm1
[6772]129            DO jj = 2, jpj_crs-1
130               DO ji = 2, jpi_crs-1
[5105]131                  ! upstream scheme
132                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
133                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
134                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
135                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
136                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
137                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
138               END DO
139            END DO
140         END DO
[6772]141         CALL crs_lbc_lnk( zwx, 'U', -1._wp ) 
142         CALL crs_lbc_lnk( zwy, 'V', -1._wp ) 
[5105]143         ! upstream tracer flux in the k direction
144         ! Surface value
145         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
[7795]146         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
[5105]147         ENDIF
148         ! Interior value
149         DO jk = 2, jpkm1
[6772]150            DO jj = 2,  jpj_crs-1
151               DO ji = nldi_crs, nlei_crs
[5105]152                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
153                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
154                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
155               END DO
156            END DO
157         END DO
[6772]158         CALL crs_lbc_lnk( zwz, 'T', 1. ) 
159
[5105]160         ! total advective trend
161         DO jk = 1, jpkm1
162            z2dtt = p2dt(jk)
[6772]163            DO jj = 2, jpj_crs-1
164               DO ji = 2, jpi_crs-1
[5105]165                  zbtr = r1_bt_crs(ji,jj,jk) 
166                  ! total intermediate advective trends
167                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
168                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
169                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
[6772]170
[5105]171                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
172                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask_crs(ji,jj,jk)
173               END DO
174            END DO
175         END DO
[6772]176 
[5105]177         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
178         CALL crs_lbc_lnk( zwi, 'T', 1. ) 
179
180         !                                 ! trend diagnostics (contribution of upstream fluxes)
181         IF( l_trd )  THEN 
182            ! store intermediate advective trends
183            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
184         END IF
185         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[6101]186         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
187           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
188           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
[5105]189         ENDIF
190
191         ! 3. antidiffusive flux : high order minus low order
192         ! --------------------------------------------------
193         ! antidiffusive flux on i and j
194         DO jk = 1, jpkm1
[6772]195            DO jj = 2, jpj_crs-1
196               DO ji = 2, jpi_crs-1
[5105]197                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
198                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
199               END DO
200            END DO
201         END DO
202         ! antidiffusive flux on k
203         zwz(:,:,1) = 0.e0         ! Surface value
204         !
205         DO jk = 2, jpkm1          ! Interior value
[6772]206            DO jj = 2, jpj_crs-1
207               DO ji = 2, jpi_crs-1
[5105]208                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
209               END DO
210            END DO
[6772]211        END DO
[5105]212         CALL crs_lbc_lnk( zwx, 'U', -1. )   ;   CALL crs_lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
213         CALL crs_lbc_lnk( zwz, 'W',  1. )
214
215         ! 4. monotonicity algorithm
216         ! -------------------------
217         CALL nonosc_crs( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
218
219         ! 5. final trend with corrected fluxes
220         ! ------------------------------------
221         DO jk = 1, jpkm1
[6772]222            DO jj = 2, jpj_crs-1
223               DO ji = 2, jpi_crs-1
[5105]224                  zbtr = r1_bt_crs(ji,jj,jk)
225                  ! total advective trends
226                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
227                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
228                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
229                  ! add them to the general tracer trends
230                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
231
232
233               END DO
234            END DO
235         END DO
236
237         !                                 ! trend diagnostics (contribution of upstream fluxes)
238         IF( l_trd )  THEN
239            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
240            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
241            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
242           
[5601]243            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
244            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
245            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
[5105]246         END IF
247         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
[6101]248         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
249           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
250           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
[5105]251         ENDIF
252         !
253      END DO
254      !
[6772]255
[5105]256                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz , zwx, zwy )
257      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
258      !
259      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
260      !
261   END SUBROUTINE tra_adv_tvd_crs
262
263
264   SUBROUTINE nonosc_crs( pbef, paa, pbb, pcc, paft, p2dt )
265      !!---------------------------------------------------------------------
266      !!                    ***  ROUTINE nonosc  ***
267      !!     
268      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
269      !!       scheme and the before field by a nonoscillatory algorithm
270      !!
271      !! **  Method  :   ... ???
272      !!       warning : pbef and paft must be masked, but the boundaries
273      !!       conditions on the fluxes are not necessary zalezak (1979)
274      !!       drange (1995) multi-dimensional forward-in-time and upstream-
275      !!       in-space based differencing for fluid
276      !!----------------------------------------------------------------------
277      !
278      !!----------------------------------------------------------------------
279      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
280      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
281      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
282      !
283      INTEGER ::   ji, jj, jk   ! dummy loop indices
284      INTEGER ::   ikm1         ! local integer
285      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
286      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
287      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
288      !!----------------------------------------------------------------------
289      !
290      IF( nn_timing == 1 )  CALL timing_start('nonosc')
291      !
292      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
293      !
294
295      zbig  = 1.e+40_wp
296      zrtrn = 1.e-15_wp
297      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
298
299
300      ! Search local extrema
301      ! --------------------
302      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
303      zbup = MAX( pbef * tmask_crs - zbig * ( 1.e0 - tmask_crs ),   &
304         &        paft * tmask_crs - zbig * ( 1.e0 - tmask_crs )  )
305      zbdo = MIN( pbef * tmask_crs + zbig * ( 1.e0 - tmask_crs ),   &
306         &        paft * tmask_crs + zbig * ( 1.e0 - tmask_crs )  )
307
308      DO jk = 1, jpkm1
309         ikm1 = MAX(jk-1,1)
310         z2dtt = p2dt(jk)
[6772]311         DO jj = 2, jpj_crs-1
312            DO ji = 2, jpi_crs-1
[5105]313
314               ! search maximum in neighbourhood
315               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
316                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
317                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
318                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
319
320               ! search minimum in neighbourhood
321               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
322                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
323                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
324                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
325
326               ! positive part of the flux
327               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
328                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
329                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
330
331               ! negative part of the flux
332               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
333                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
334                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
335
336               ! up & down beta terms
337               zbt = bt_crs(ji,jj,jk) / z2dtt
338               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
339               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
340            END DO
341         END DO
342      END DO
343      CALL crs_lbc_lnk( zbetup, 'T', 1. )   ;   CALL crs_lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
344
345      ! 3. monotonic flux in the i & j direction (paa & pbb)
346      ! ----------------------------------------
347      DO jk = 1, jpkm1
[6772]348         DO jj = 2, jpj_crs-1
349            DO ji = 2, jpi_crs-1
[5105]350               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
351               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
352               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
353               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
354
355               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
356               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
357               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
358               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
359
360      ! monotonic flux in the k direction, i.e. pcc
361      ! -------------------------------------------
362               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
363               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
364               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
365               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
366            END DO
367         END DO
368      END DO
369
370      CALL crs_lbc_lnk( paa, 'U', -1. )   ;   CALL crs_lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
371      !
372      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
373      !
374      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
375      !
376   END SUBROUTINE nonosc_crs
377
378   !!======================================================================
379END MODULE traadv_tvd_crs
Note: See TracBrowser for help on using the repository browser.