New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_tvd_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd_crs.F90 @ 6101

Last change on this file since 6101 was 6101, checked in by cbricaud, 8 years ago

correction of bugs from last update and improvments for CRS
  • Property svn:executable set to *
File size: 18.1 KB
Line 
1MODULE traadv_tvd_crs
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd  : update the tracer trend with the horizontal
20   !!                  and vertical advection trends using a TVD scheme
21   !!   nonosc       : compute monotonic tracer fluxes by a nonoscillatory
22   !!                  algorithm
23   !!----------------------------------------------------------------------
24   USE oce             ! ocean dynamics and active tracers
25   USE dom_oce , ONLY : lk_vvl
26   USE trd_oce         ! tracers trends
27   USE trdtra          ! tracers trends
28   USE in_out_manager  ! I/O manager
29   USE dynspg_oce      ! choice/control of key cpp for surface pressure gradient
30   USE lib_mpp         ! MPP library
31   USE lbclnk          ! ocean lateral boundary condition (or mpp link)
32   USE diaptr          ! poleward transport diagnostics
33   USE trc_oce         ! share passive tracers/Ocean variables
34   USE wrk_nemo        ! Memory Allocation
35   USE timing          ! Timing
36   USE crs
37   USE crslbclnk
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   tra_adv_tvd_crs    ! routine called by step.F90
43
44   LOGICAL ::   l_trd   ! flag to compute trends
45
46   !! * Substitutions
47#  include "domzgr_substitute.h90"
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
51   !! $Id: traadv_tvd.F90 3294 2012-01-28 16:44:18Z rblod $
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE tra_adv_tvd_crs ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
57      &                                       ptb, ptn, pta, kjpt )
58      !!----------------------------------------------------------------------
59      !!                  ***  ROUTINE tra_adv_tvd  ***
60      !!
61      !! **  Purpose :   Compute the now trend due to total advection of
62      !!       tracers and add it to the general trend of tracer equations
63      !!
64      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
65      !!       corrected flux (monotonic correction)
66      !!       note: - this advection scheme needs a leap-frog time scheme
67      !!
68      !! ** Action : - update (pta) with the now advective tracer trends
69      !!             - save the trends
70      !!----------------------------------------------------------------------
71      !cbr ça fait des trucs bizarres USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
72      !
73      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
74      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
75      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
76      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
77      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
78      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
81      !
82      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz,zwx,zwy
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88
89      INTEGER  ::   iji, ijj, ijk           ! dummy loop indices 
90      REAL(wp) ::   zmin,zmax
91      !!----------------------------------------------------------------------
92      !
93      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
94      !
95      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zwx, zwy )
96      !
97      IF( kt == kit000 )  THEN
98         IF(lwp) WRITE(numout,*)
99         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
100         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
101         !
102         l_trd = .FALSE.
103         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
104
105         IF(lwp) WRITE(numout,*)"jpi jpj jpkm1 ",jpi,jpj,jpkm1
106      ENDIF
107      !
108      IF( l_trd )  THEN
109         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
110         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
111      ENDIF
112      !
113      zwi(:,:,:) = 0.e0
114      !
115      !                                                          ! ===========
116      DO jn = 1, kjpt                                            ! tracer loop
117         !                                                       ! ===========
118         ! 1. Bottom value : flux set to zero
119         ! ----------------------------------
120         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
121         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
122
123         ! 2. upstream advection with initial mass fluxes & intermediate update
124         ! --------------------------------------------------------------------
125
126         ! upstream tracer flux in the i and j direction
127         DO jk = 1, jpkm1
128            DO jj = 1, jpjm1
129               DO ji = 1, fs_jpim1   ! vector opt.
130                  ! upstream scheme
131                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
132                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
133                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
134                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
135                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
136                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
137               END DO
138            END DO
139         END DO
140         ! upstream tracer flux in the k direction
141         ! Surface value
142         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0.e0                         ! volume variable
143         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
144         ENDIF
145         ! Interior value
146         DO jk = 2, jpkm1
147            DO jj = 1, jpj
148               DO ji = 1, jpi
149                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
150                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
151                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
152               END DO
153            END DO
154         END DO
155         ! total advective trend
156         DO jk = 1, jpkm1
157            z2dtt = p2dt(jk)
158            DO jj = 2, jpjm1
159               DO ji = fs_2, fs_jpim1   ! vector opt.
160                  zbtr = r1_bt_crs(ji,jj,jk) 
161                  ! total intermediate advective trends
162                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
163                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
164                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
165                  ! update and guess with monotonic sheme
166                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
167                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask_crs(ji,jj,jk)
168               END DO
169            END DO
170         END DO
171         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
172         CALL crs_lbc_lnk( zwi, 'T', 1. ) 
173
174         !                                 ! trend diagnostics (contribution of upstream fluxes)
175         IF( l_trd )  THEN 
176            ! store intermediate advective trends
177            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
178         END IF
179         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
180         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
181           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) )
182           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) )
183         ENDIF
184
185         ! 3. antidiffusive flux : high order minus low order
186         ! --------------------------------------------------
187         ! antidiffusive flux on i and j
188         DO jk = 1, jpkm1
189            DO jj = 1, jpjm1
190               DO ji = 1, fs_jpim1   ! vector opt.
191                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
192                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
193               END DO
194            END DO
195         END DO
196         ! antidiffusive flux on k
197         zwz(:,:,1) = 0.e0         ! Surface value
198         !
199         DO jk = 2, jpkm1          ! Interior value
200            DO jj = 1, jpj
201               DO ji = 1, jpi
202                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
203               END DO
204            END DO
205         END DO
206         CALL crs_lbc_lnk( zwx, 'U', -1. )   ;   CALL crs_lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
207         CALL crs_lbc_lnk( zwz, 'W',  1. )
208
209         ! 4. monotonicity algorithm
210         ! -------------------------
211         CALL nonosc_crs( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
212
213         ! 5. final trend with corrected fluxes
214         ! ------------------------------------
215         DO jk = 1, jpkm1
216            DO jj = 2, jpjm1
217               DO ji = fs_2, fs_jpim1   ! vector opt. 
218                  zbtr = r1_bt_crs(ji,jj,jk)
219                  ! total advective trends
220                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
221                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
222                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
223                  ! add them to the general tracer trends
224                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
225
226
227               END DO
228            END DO
229         END DO
230
231         !                                 ! trend diagnostics (contribution of upstream fluxes)
232         IF( l_trd )  THEN
233            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
234            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
235            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
236           
237            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
238            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
239            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
240         END IF
241         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
242         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN 
243           IF( jn == jp_tem )  htr_adv(:) = ptr_sj( zwy(:,:,:) ) + htr_adv(:)
244           IF( jn == jp_sal )  str_adv(:) = ptr_sj( zwy(:,:,:) ) + str_adv(:)
245         ENDIF
246         !
247      END DO
248      !
249                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz , zwx, zwy )
250      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
251      !
252      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
253      !
254   END SUBROUTINE tra_adv_tvd_crs
255
256
257   SUBROUTINE nonosc_crs( pbef, paa, pbb, pcc, paft, p2dt )
258      !!---------------------------------------------------------------------
259      !!                    ***  ROUTINE nonosc  ***
260      !!     
261      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
262      !!       scheme and the before field by a nonoscillatory algorithm
263      !!
264      !! **  Method  :   ... ???
265      !!       warning : pbef and paft must be masked, but the boundaries
266      !!       conditions on the fluxes are not necessary zalezak (1979)
267      !!       drange (1995) multi-dimensional forward-in-time and upstream-
268      !!       in-space based differencing for fluid
269      !!----------------------------------------------------------------------
270      !
271      !!----------------------------------------------------------------------
272      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
273      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
274      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
275      !
276      INTEGER ::   ji, jj, jk   ! dummy loop indices
277      INTEGER ::   ikm1         ! local integer
278      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
279      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
280      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
281      !!----------------------------------------------------------------------
282      !
283      IF( nn_timing == 1 )  CALL timing_start('nonosc')
284      !
285      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
286      !
287
288      zbig  = 1.e+40_wp
289      zrtrn = 1.e-15_wp
290      zbetup(:,:,jpk) = 0._wp   ;   zbetdo(:,:,jpk) = 0._wp
291
292
293      ! Search local extrema
294      ! --------------------
295      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
296      zbup = MAX( pbef * tmask_crs - zbig * ( 1.e0 - tmask_crs ),   &
297         &        paft * tmask_crs - zbig * ( 1.e0 - tmask_crs )  )
298      zbdo = MIN( pbef * tmask_crs + zbig * ( 1.e0 - tmask_crs ),   &
299         &        paft * tmask_crs + zbig * ( 1.e0 - tmask_crs )  )
300
301      DO jk = 1, jpkm1
302         ikm1 = MAX(jk-1,1)
303         z2dtt = p2dt(jk)
304         DO jj = 2, jpjm1
305            DO ji = fs_2, fs_jpim1   ! vector opt.
306
307               ! search maximum in neighbourhood
308               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
309                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
310                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
311                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
312
313               ! search minimum in neighbourhood
314               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
315                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
316                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
317                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
318
319               ! positive part of the flux
320               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
321                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
322                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
323
324               ! negative part of the flux
325               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
326                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
327                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
328
329               ! up & down beta terms
330               zbt = bt_crs(ji,jj,jk) / z2dtt
331               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
332               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
333            END DO
334         END DO
335      END DO
336      CALL crs_lbc_lnk( zbetup, 'T', 1. )   ;   CALL crs_lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
337
338      ! 3. monotonic flux in the i & j direction (paa & pbb)
339      ! ----------------------------------------
340      DO jk = 1, jpkm1
341         DO jj = 2, jpjm1
342            DO ji = fs_2, fs_jpim1   ! vector opt.
343               zau = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
344               zbu = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
345               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
346               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1.e0 - zcu) * zbu )
347
348               zav = MIN( 1.e0, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
349               zbv = MIN( 1.e0, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
350               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
351               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1.e0 - zcv) * zbv )
352
353      ! monotonic flux in the k direction, i.e. pcc
354      ! -------------------------------------------
355               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
356               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
357               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
358               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1.e0 - zc) * zb )
359            END DO
360         END DO
361      END DO
362
363      CALL crs_lbc_lnk( paa, 'U', -1. )   ;   CALL crs_lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
364      !
365      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
366      !
367      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
368      !
369   END SUBROUTINE nonosc_crs
370
371   !!======================================================================
372END MODULE traadv_tvd_crs
Note: See TracBrowser for help on using the repository browser.