New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso_crs.F90 @ 6772

Last change on this file since 6772 was 6772, checked in by cbricaud, 8 years ago

clean in coarsening branch
  • Property svn:executable set to *
File size: 15.9 KB
Line 
1MODULE traldf_iso_crs
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  !  1994-08  (G. Madec, M. Imbard)
7   !!            8.0  !  1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO !  2002-08  (G. Madec)  Free form, F90
9   !!            1.0  !  2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  !  2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!----------------------------------------------------------------------
12#if   ( defined key_ldfslp   ||   defined key_esopa ) && defined key_crs
13   !!----------------------------------------------------------------------
14   !!   'key_ldfslp'               slope of the lateral diffusive direction
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal
17   !!                  component of a iso-neutral laplacian operator
18   !!                  and with the vertical part of
19   !!                  the isopycnal or geopotential s-coord. operator
20   !!----------------------------------------------------------------------
21   USE ldfslp_crs          ! iso-neutral slopes
22   USE diaptr          ! poleward transport diagnostics
23   USE in_out_manager  ! I/O manager
24   USE iom             ! I/O library
25#if defined key_diaar5
26   USE phycst          ! physical constants
27   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
28#endif
29   USE wrk_nemo        ! Memory Allocation
30   USE timing          ! Timing
31   USE oce_trc
32   USE iom, ONLY : iom_put,iom_swap
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_iso_crs   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "ldftra_substitute.h90"
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
45   !! $Id: traldf_iso.F90 3294 2012-01-28 16:44:18Z rblod $
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE tra_ldf_iso_crs( kt, kit000, cdtype, pgu, pgv,              &
51      &                                ptb, pta, kjpt, pahtb0 )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf_iso  ***
54      !!
55      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
56      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
57      !!      add it to the general trend of tracer equation.
58      !!
59      !! ** Method  :   The horizontal component of the lateral diffusive trends
60      !!      is provided by a 2nd order operator rotated along neural or geopo-
61      !!      tential surfaces to which an eddy induced advection can be added
62      !!      It is computed using before fields (forward in time) and isopyc-
63      !!      nal or geopotential slopes computed in routine ldfslp.
64      !!
65      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
66      !!      ========    with partial cell update if ln_zps=T.
67      !!
68      !!      2nd part :  horizontal fluxes of the lateral mixing operator
69      !!      ========   
70      !!         zftu = (aht+ahtb0) e2u*e3u/e1u di[ tb ]
71      !!               - aht       e2u*uslp    dk[ mi(mk(tb)) ]
72      !!         zftv = (aht+ahtb0) e1v*e3v/e2v dj[ tb ]
73      !!               - aht       e2u*vslp    dk[ mj(mk(tb)) ]
74      !!      take the horizontal divergence of the fluxes:
75      !!         difft = 1/(e1t*e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
76      !!      Add this trend to the general trend (ta,sa):
77      !!         ta = ta + difft
78      !!
79      !!      3rd part: vertical trends of the lateral mixing operator
80      !!      ========  (excluding the vertical flux proportional to dk[t] )
81      !!      vertical fluxes associated with the rotated lateral mixing:
82      !!         zftw =-aht {  e2t*wslpi di[ mi(mk(tb)) ]
83      !!                     + e1t*wslpj dj[ mj(mk(tb)) ]  }
84      !!      take the horizontal divergence of the fluxes:
85      !!         difft = 1/(e1t*e2t*e3t) dk[ zftw ]
86      !!      Add this trend to the general trend (ta,sa):
87      !!         pta = pta + difft
88      !!
89      !! ** Action :   Update pta arrays with the before rotated diffusion
90      !!----------------------------------------------------------------------
91      !
92      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
93      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
94      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
95      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
96      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
97      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! before and now tracer fields
98      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
99      REAL(wp)                             , INTENT(in   ) ::   pahtb0     ! background diffusion coef
100      !
101      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
102      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3   ! local scalars
103      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4   !   -      -
104      REAL(wp) ::  zcoef0, zbtr, ztra            !   -      -
105#if defined key_diaar5
106      REAL(wp)                         ::   zztmp               ! local scalar
107#endif
108      REAL(wp)                         ::   zmin,zmax
109      REAL(wp), POINTER, DIMENSION(:,:  ) ::  zdkt, zdk1t, z2d
110      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zdit, zdjt, ztfw , zftu,  zftv 
111      !!----------------------------------------------------------------------
112      !
113      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
114      !
115      CALL wrk_alloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
116      CALL wrk_alloc( jpi, jpj, jpk, zdit, zdjt, ztfw , zftu, zftv ) 
117      !
118
119      IF( kt == kit000 )  THEN
120         IF(lwp) WRITE(numout,*)
121         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
122         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
123      ENDIF
124      !
125      !                                                          ! ===========
126      DO jn = 1, kjpt                                            ! tracer loop
127         !                                                       ! ===========
128         !                                               
129         !!----------------------------------------------------------------------
130         !!   I - masked horizontal derivative
131         !!----------------------------------------------------------------------
132         !!bug ajout.... why?   ( 1,jpj,:) and (jpi,1,:) should be sufficient....
133         zdit (1,:,:) = 0.e0     ;     zdit (jpi,:,:) = 0.e0
134         zdjt (1,:,:) = 0.e0     ;     zdjt (jpi,:,:) = 0.e0
135         !!end
136
137         ! Horizontal tracer gradient
138         DO jk = 1, jpkm1
139            DO jj = 1, jpjm1
140               DO ji = 1, fs_jpim1   ! vector opt.
141                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask_crs(ji,jj,jk)
142                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask_crs(ji,jj,jk)
143               END DO
144            END DO
145         END DO
146         IF( ln_zps ) THEN      ! partial steps correction at the last ocean level
147            DO jj = 1, jpjm1
148               DO ji = 1, fs_jpim1   ! vector opt.
149                  zdit(ji,jj,mbku_crs(ji,jj)) = pgu(ji,jj,jn)         
150                  zdjt(ji,jj,mbkv_crs(ji,jj)) = pgv(ji,jj,jn)     
151               END DO
152            END DO
153         ENDIF
154
155         !!----------------------------------------------------------------------
156         !!   II - horizontal trend  (full)
157         !!----------------------------------------------------------------------
158!CDIR PARALLEL DO PRIVATE( zdk1t )
159         !                                                ! ===============
160         DO jk = 1, jpkm1                                 ! Horizontal slab
161            !                                             ! ===============
162            ! 1. Vertical tracer gradient at level jk and jk+1
163            ! ------------------------------------------------
164            ! surface boundary condition: zdkt(jk=1)=zdkt(jk=2)
165            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask_crs(:,:,jk+1)
166            !
167            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)
168            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask_crs(:,:,jk)
169            ENDIF
170
171            ! 2. Horizontal fluxes
172            ! --------------------   
173            DO jj = 1 , jpjm1
174               DO ji = 1, fs_jpim1   ! vector opt.
175                  zabe1 = ( fsahtu(ji,jj,jk) + pahtb0 ) * e2e3u_msk(ji,jj,jk) / e1u_crs(ji,jj)
176                  zabe2 = ( fsahtv(ji,jj,jk) + pahtb0 ) * e1e3v_msk(ji,jj,jk) / e2v_crs(ji,jj)
177
178                  zmsku = 1. / MAX(  tmask_crs(ji+1,jj,jk  ) + tmask_crs(ji,jj,jk+1)   &
179                     &             + tmask_crs(ji+1,jj,jk+1) + tmask_crs(ji,jj,jk  ), 1. )
180                  !
181                  zmskv = 1. / MAX(  tmask_crs(ji,jj+1,jk  ) + tmask_crs(ji,jj,jk+1)   &
182                     &             + tmask_crs(ji,jj+1,jk+1) + tmask_crs(ji,jj,jk  ), 1. )
183                  !
184                  zcof1 = - fsahtu(ji,jj,jk) * e2e3u_msk(ji,jj,jk) * uslp_crs(ji,jj,jk) * zmsku / MAX( 1._wp , fse3u_max_crs(ji,jj,jk))
185                  zcof2 = - fsahtv(ji,jj,jk) * e1e3v_msk(ji,jj,jk) * vslp_crs(ji,jj,jk) * zmskv / MAX( 1._wp , fse3v_max_crs(ji,jj,jk))
186                  !
187                  zftu(ji,jj,jk ) = ( zabe1 * zdit(ji,jj,jk)   &
188                     &              + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
189                     &                         + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask_crs(ji,jj,jk)
190                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
191                     &              + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
192                     &                         + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask_crs(ji,jj,jk)                 
193               END DO
194            END DO
195
196            ! II.4 Second derivative (divergence) and add to the general trend
197            ! ----------------------------------------------------------------
198            DO jj = 2 , jpjm1
199               DO ji = fs_2, fs_jpim1   ! vector opt.
200                  zbtr = r1_bt_crs(ji,jj,jk)
201                  ztra = zbtr * ( zftu(ji,jj,jk) - zftu(ji-1,jj,jk) + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )
202                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
203
204               END DO
205            END DO
206            !                                          ! ===============
207         END DO                                        !   End of slab 
208         !                                             ! ===============
209         !
210         ! "Poleward" diffusive heat or salt transports (T-S case only)
211         IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
212            IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( zftv(:,:,:) )
213            IF( jn == jp_sal)   str_ldf(:) = ptr_sj( zftv(:,:,:) )
214         ENDIF
215 
216#if defined key_diaar5
217         IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
218            z2d(:,:) = 0._wp 
219            zztmp = rau0 * rcp 
220            DO jk = 1, jpkm1
221               DO jj = 2, jpjm1
222                  DO ji = fs_2, fs_jpim1   ! vector opt.
223                     z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
224                  END DO
225               END DO
226            END DO
227            z2d(:,:) = zztmp * z2d(:,:)
228            CALL crs_lbc_lnk( z2d, 'U', -1. )
229         !   CALL crs_iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
230            z2d(:,:) = 0._wp 
231            DO jk = 1, jpkm1
232               DO jj = 2, jpjm1
233                  DO ji = fs_2, fs_jpim1   ! vector opt.
234                     z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
235                  END DO
236               END DO
237            END DO
238            z2d(:,:) = zztmp * z2d(:,:)
239            CALL crs_lbc_lnk( z2d, 'V', -1. )
240            ! CALL crs_iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
241         END IF
242#endif
243
244         !!----------------------------------------------------------------------
245         !!   III - vertical trend of T & S (extra diagonal terms only)
246         !!----------------------------------------------------------------------
247         
248         ! Local constant initialization
249         ! -----------------------------
250         ztfw(1,:,:) = 0.e0     ;     ztfw(jpi,:,:) = 0.e0
251         
252         ! Vertical fluxes
253         ! ---------------
254         
255         ! Surface and bottom vertical fluxes set to zero
256         ztfw(:,:, 1 ) = 0.e0      ;      ztfw(:,:,jpk) = 0.e0
257         
258         ! interior (2=<jk=<jpk-1)
259         DO jk = 2, jpkm1
260            DO jj = 2, jpjm1
261               DO ji = fs_2, fs_jpim1   ! vector opt.
262                  zcoef0 = - fsahtw(ji,jj,jk) * tmask_crs(ji,jj,jk)
263                  !
264                  zmsku = 1./MAX(   umask_crs(ji  ,jj,jk-1) + umask_crs(ji-1,jj,jk)      &
265                     &            + umask_crs(ji-1,jj,jk-1) + umask_crs(ji  ,jj,jk), 1.  )
266                  zmskv = 1./MAX(   vmask_crs(ji,jj  ,jk-1) + vmask_crs(ji,jj-1,jk)      &
267                     &            + vmask_crs(ji,jj-1,jk-1) + vmask_crs(ji,jj  ,jk), 1.  )
268                  !
269                  zcoef3 = zcoef0 * e1e2w_crs(ji,jj,jk) * zmsku * wslpi_crs(ji,jj,jk) / e1t_crs(ji,jj)
270                  zcoef4 = zcoef0 * e1e2w_crs(ji,jj,jk) * zmskv * wslpj_crs(ji,jj,jk) / e2t_crs(ji,jj)
271                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
272                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
273                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
274                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
275               END DO
276            END DO
277         END DO
278         
279         
280         ! I.5 Divergence of vertical fluxes added to the general tracer trend
281         ! -------------------------------------------------------------------
282         DO jk = 1, jpkm1
283            DO jj = 2, jpjm1
284               DO ji = fs_2, fs_jpim1   ! vector opt.
285                  zbtr = r1_bt_crs(ji,jj,jk)
286                  ztra = (  ztfw(ji,jj,jk) - ztfw(ji,jj,jk+1)  ) * zbtr
287                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
288
289               END DO
290            END DO
291         END DO
292         !
293      END DO
294      !
295      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
296      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt, ztfw , zftu, zftv ) 
297      !
298      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
299      !
300   END SUBROUTINE tra_ldf_iso_crs
301
302#else
303   !!----------------------------------------------------------------------
304   !!   default option :   Dummy code   NO rotation of the diffusive tensor
305   !!----------------------------------------------------------------------
306CONTAINS
307   SUBROUTINE tra_ldf_iso_crs( kt, kit000,cdtype, pgu, pgv, ptb, pta, kjpt, pahtb0 )      ! Empty routine
308      INTEGER:: kt, kit000
309      CHARACTER(len=3) ::   cdtype
310      REAL, DIMENSION(:,:,:) ::   pgu, pgv   ! tracer gradient at pstep levels
311      REAL, DIMENSION(:,:,:,:) ::   ptb, pta
312      WRITE(*,*) 'tra_ldf_iso: You should not have seen this print! error?', kt, kit000, cdtype,   &
313         &                       pgu(1,1,1), pgv(1,1,1), ptb(1,1,1,1), pta(1,1,1,1), kjpt, pahtb0
314   END SUBROUTINE tra_ldf_iso_crs
315#endif
316
317   !!==============================================================================
318END MODULE traldf_iso_crs
Note: See TracBrowser for help on using the repository browser.