New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde_crs.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde_crs.F90 @ 6772

Last change on this file since 6772 was 6772, checked in by cbricaud, 8 years ago

clean in coarsening branch

  • Property svn:executable set to *
File size: 11.0 KB
Line 
1MODULE zpshde_crs
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!======================================================================
11   
12   !!----------------------------------------------------------------------
13   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
14   !!                   ocean level (Z-coord. with Partial Steps)
15   !!----------------------------------------------------------------------
16   USE oce             ! ocean: dynamics and tracers variables
17   USE dom_oce         ! domain: ocean variables
18   USE phycst          ! physical constants
19   USE eosbn2_crs          ! ocean equation of state
20   USE in_out_manager  ! I/O manager
21   USE crslbclnk          ! lateral boundary conditions (or mpp link)
22   USE lib_mpp         ! MPP library
23   USE wrk_nemo        ! Memory allocation
24   USE timing          ! Timing
25   USE crs
26   
27
28   IMPLICIT NONE
29   PRIVATE
30
31   PUBLIC   zps_hde_crs    ! routine called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id: zpshde.F90 3294 2012-01-28 16:44:18Z rblod $
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde_crs( kt, kjpt, pta, pgtu, pgtv,   &
44                                 prd, pgru, pgrv    )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE zps_hde  ***
47      !!                   
48      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
49      !!      at u- and v-points with a linear interpolation for z-coordinate
50      !!      with partial steps.
51      !!
52      !! ** Method  :   In z-coord with partial steps, scale factors on last
53      !!      levels are different for each grid point, so that T, S and rd
54      !!      points are not at the same depth as in z-coord. To have horizontal
55      !!      gradients again, we interpolate T and S at the good depth :
56      !!      Linear interpolation of T, S   
57      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
58      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
59      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
60      !!         This formulation computes the two cases:
61      !!                 CASE 1                   CASE 2 
62      !!         k-1  ___ ___________   k-1   ___ ___________
63      !!                    Ti  T~                  T~  Ti+1
64      !!                  _____                        _____
65      !!         k        |   |Ti+1     k           Ti |   |
66      !!                  |   |____                ____|   |
67      !!              ___ |   |   |           ___  |   |   |
68      !!                 
69      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
70      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
71      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
72      !!          or
73      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
74      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
75      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
76      !!          Idem for di(s) and dj(s)         
77      !!
78      !!      For rho, we call eos_insitu_2d which will compute rd~(t~,s~) at
79      !!      the good depth zh from interpolated T and S for the different
80      !!      formulation of the equation of state (eos).
81      !!      Gradient formulation for rho :
82      !!          di(rho) = rd~ - rd(i,j,k) or rd(i+1,j,k) - rd~
83      !!
84      !! ** Action  : - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
85      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
86      !!----------------------------------------------------------------------
87      !
88      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
89      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
90      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
91      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
92      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
93      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad. of prd at u- & v-pts
94      !
95      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
96      INTEGER  ::   iku, ikv, ikum1, ikvm1   ! partial step level (ocean bottom level) at u- and v-points
97      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv  ! temporary scalars
98      REAL(wp), ALLOCATABLE, DIMENSION(:,:  ) ::  zri, zrj, zhi, zhj
99      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::  zti, zte    ! interpolated value of tracer
100
101      !!----------------------------------------------------------------------
102      !
103      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_crs')
104      !
105      ALLOCATE( zri(jpi_crs,jpj_crs) , zrj(jpi_crs,jpj_crs), zte(jpi_crs ,jpj_crs ,kjpt), &
106         &      zhi(jpi_crs,jpj_crs) , zhj(jpi_crs,jpj_crs), zti(jpi_crs ,jpj_crs ,kjpt))
107      !
108      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
109         !
110         DO jj = 1, jpjm1
111            DO ji = 1, jpim1
112
113               iku = mbku_crs(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
114               ikv = mbkv_crs(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
115               ze3wu = e3w_max_0_crs(ji+1,jj  ,iku) - e3w_max_0_crs(ji,jj,iku)
116               ze3wv = e3w_max_0_crs(ji  ,jj+1,ikv) - e3w_max_0_crs(ji,jj,ikv)
117               !
118               ! i- direction
119               IF( ze3wu >= 0._wp ) THEN      ! case 1
120#if defined key_vvl
121                  zmaxu =  ze3wu / e3w_max_n_crs(ji+1,jj,iku) 
122#else
123                  zmaxu =  ze3wu / e3w_max_0_crs(ji+1,jj,iku) 
124#endif
125                  ! interpolated values of tracers
126                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
127                  ! gradient of  tracers
128                  pgtu(ji,jj,jn) = umask_crs(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
129               ELSE                           ! case 2
130#if defined key_vvl
131                  zmaxu = -ze3wu / e3w_max_n_crs(ji,jj,iku)
132#else
133                  zmaxu = -ze3wu / e3w_max_0_crs(ji,jj,iku)
134#endif
135                  ! interpolated values of tracers
136                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
137                  ! gradient of tracers
138                  pgtu(ji,jj,jn) = umask_crs(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
139               ENDIF
140               !
141               ! j- direction
142               IF( ze3wv >= 0._wp ) THEN      ! case 1
143#if defined key_vvl
144                  zmaxv =  ze3wv / e3w_max_n_crs(ji,jj+1,ikv)
145#else
146                  zmaxv =  ze3wv / e3w_max_0_crs(ji,jj+1,ikv)
147#endif
148                  ! interpolated values of tracers
149                  zte(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
150                  ! gradient of tracers
151                  pgtv(ji,jj,jn) = vmask_crs(ji,jj,1) * ( zte(ji,jj,jn) - pta(ji,jj,ikv,jn) )
152               ELSE                           ! case 2
153#if defined key_vvl
154                  zmaxv =  -ze3wv / e3w_max_n_crs(ji,jj,ikv)
155#else
156                  zmaxv =  -ze3wv / e3w_max_0_crs(ji,jj,ikv)
157#endif
158                  ! interpolated values of tracers
159                  zte(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
160                  ! gradient of tracers
161                  pgtv(ji,jj,jn) = vmask_crs(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - zte(ji,jj,jn) )
162               ENDIF
163
164            END DO
165         END DO
166         CALL crs_lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL crs_lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
167         !
168      END DO
169
170      ! horizontal derivative of density anomalies (rd)
171      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
172         DO jj = 1, jpjm1
173            DO ji = 1, jpim1
174
175               iku = mbku_crs(ji,jj)
176               ikv = mbkv_crs(ji,jj)
177               ze3wu  = e3w_0_crs(ji+1,jj  ,iku) - e3w_0_crs(ji,jj,iku)
178               ze3wv  = e3w_0_crs(ji  ,jj+1,ikv) - e3w_0_crs(ji,jj,ikv)
179               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept_crs(ji  ,jj,iku)     ! i-direction: case 1
180               ELSE                        ;   zhi(ji,jj) = fsdept_crs(ji+1,jj,iku)     ! -     -      case 2
181               ENDIF
182               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept_crs(ji,jj  ,ikv)     ! j-direction: case 1
183               ELSE                        ;   zhj(ji,jj) = fsdept_crs(ji,jj+1,ikv)     ! -     -      case 2
184               ENDIF
185
186            END DO
187         END DO
188         CALL eos_crs( zti, zhi, zri ) 
189         CALL eos_crs( zte, zhj, zrj )
190
191         ! Gradient of density at the last level
192         DO jj = 1, jpjm1
193            DO ji = 1, jpim1
194               iku = mbku_crs(ji,jj)
195               ikv = mbkv_crs(ji,jj)
196                ze3wu  = e3w_0_crs(ji+1,jj  ,iku) - e3w_0_crs(ji,jj,iku)
197                ze3wv  = e3w_0_crs(ji  ,jj+1,ikv) - e3w_0_crs(ji,jj,ikv)
198               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask_crs(ji,jj,1) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
199               ELSE                        ;   pgru(ji,jj) = umask_crs(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
200               ENDIF
201               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask_crs(ji,jj,1) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
202               ELSE                        ;   pgrv(ji,jj) = vmask_crs(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
203               ENDIF
204
205            END DO
206         END DO
207
208         CALL crs_lbc_lnk( pgru , 'U', -1. )   ;   CALL crs_lbc_lnk( pgrv , 'V', -1. )   ! Lateral boundary conditions
209         !
210      END IF
211      !
212      DEALLOCATE( zri , zrj, zte, zhi, zhj, zti)
213      !
214      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde_crs')
215      !
216   END SUBROUTINE zps_hde_crs
217
218   !!======================================================================
219END MODULE zpshde_crs
Note: See TracBrowser for help on using the repository browser.