New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 7217

Last change on this file since 7217 was 7217, checked in by cbricaud, 7 years ago
CRS branch: code cleaning
Property svn:keywords set to `Id`
File size: 40.2 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!!----------------------------------------------------------------------
33
34	!!----------------------------------------------------------------------
35	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36	!! nemo_init : initialization of the NEMO system
37	!! nemo_ctl : initialisation of the contol print
38	!! nemo_closefile : close remaining open files
39	!! nemo_alloc : dynamical allocation
40	!! nemo_partition : calculate MPP domain decomposition
41	!! factorise : calculate the factors of the no. of MPI processes
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdyini ! open boundary cond. setting (bdy_init routine)
53	USE bdydta ! open boundary cond. setting (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. setting (bdytide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE ldftra_crs ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdini ! dyn/tra trends initialization (trd_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	USE cpl_oasis3 ! OASIS3 coupling
72	USE c1d ! 1D configuration
73	USE step_c1d ! Time stepping loop for the 1D configuration
74	USE dyndmp ! Momentum damping
75	#if defined key_top
76	USE trcini ! passive tracer initialisation
77	#endif
78	USE lib_mpp ! distributed memory computing
79	#if defined key_iomput
80	USE xios
81	#endif
82	USE sbctide, ONLY: lk_tide
83	USE crsini ! initialise grid coarsening utility
84	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
85	USE trabbl_crs
86	USE sbc_oce, ONLY: lk_oasis
87	USE stopar
88	USE stopts
89
90	IMPLICIT NONE
91	PRIVATE
92
93	PUBLIC nemo_gcm ! called by model.F90
94	PUBLIC nemo_init ! needed by AGRIF
95	PUBLIC nemo_alloc ! needed by TAM
96
97	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
98
99	!!----------------------------------------------------------------------
100	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
101	!! $Id$
102	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
103	!!----------------------------------------------------------------------
104	CONTAINS
105
106	SUBROUTINE nemo_gcm
107	!!----------------------------------------------------------------------
108	!! * ROUTINE nemo_gcm *
109	!!
110	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
111	!! curvilinear mesh on the sphere.
112	!!
113	!! ** Method : - model general initialization
114	!! - launch the time-stepping (stp routine)
115	!! - finalize the run by closing files and communications
116	!!
117	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
118	!! Madec, 2008, internal report, IPSL.
119	!!----------------------------------------------------------------------
120	INTEGER :: istp ! time step index
121	CHARACTER(len=30) :: cmd
122	!!----------------------------------------------------------------------
123	!
124	#if defined key_agrif
125	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
126	#endif
127
128	! !-----------------------!
129	CALL nemo_init !== Initialisations ==!
130	! !-----------------------!
131	#if defined key_agrif
132	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
133	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
134	# if defined key_top
135	CALL Agrif_Declare_Var_top ! " " " " " TOP
136	# endif
137	# if defined key_lim2
138	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
139	# endif
140	#endif
141	! check that all process are still there... If some process have an error,
142	! they will never enter in step and other processes will wait until the end of the cpu time!
143	IF( lk_mpp ) CALL mpp_max( nstop )
144
145	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
146
147	! !-----------------------!
148	! !== time stepping ==!
149	! !-----------------------!
150	istp = nit000
151	#if defined key_c1d
152	DO WHILE ( istp <= nitend .AND. nstop == 0 )
153	CALL stp_c1d( istp )
154	istp = istp + 1
155	END DO
156	#else
157	IF( lk_asminc ) THEN
158	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
159	IF( ln_asmdin ) THEN ! Direct initialization
160	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
161	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
162	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
163	ENDIF
164	ENDIF
165
166	DO WHILE ( istp <= nitend .AND. nstop == 0 )
167	#if defined key_agrif
168	CALL Agrif_Step( stp ) ! AGRIF: time stepping
169	#else
170	CALL stp( istp ) ! standard time stepping
171	#endif
172	istp = istp + 1
173	IF( lk_mpp ) CALL mpp_max( nstop )
174	END DO
175	#endif
176
177	IF( lk_diaobs ) CALL dia_obs_wri
178	!
179	IF( ln_icebergs ) CALL icb_end( nitend )
180
181	! !------------------------!
182	! !== finalize the run ==!
183	! !------------------------!
184	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
185	!
186	IF( nstop /= 0 ) THEN ! error print
187	cmd='touch nemo_NOK'
188	CALL system(cmd)
189	WRITE(numout,cform_err)
190	WRITE(numout,*) nstop, ' error have been found'
191	ELSE
192	cmd='touch nemo_OK'
193	CALL system(cmd)
194	ENDIF
195	!
196	#if defined key_agrif
197	CALL Agrif_ParentGrid_To_ChildGrid()
198	IF( lk_diaobs ) CALL dia_obs_wri
199	IF( nn_timing == 1 ) CALL timing_finalize
200	CALL Agrif_ChildGrid_To_ParentGrid()
201	#endif
202	IF( nn_timing == 1 ) CALL timing_finalize
203	!
204	CALL nemo_closefile
205	!
206	#if defined key_iomput
207	CALL xios_finalize ! end mpp communications with xios
208	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
209	#else
210	IF( lk_oasis ) THEN
211	CALL cpl_finalize ! end coupling and mpp communications with OASIS
212	ELSE
213	IF( lk_mpp ) CALL mppstop ! end mpp communications
214	ENDIF
215	#endif
216	!
217	END SUBROUTINE nemo_gcm
218
219
220	SUBROUTINE nemo_init
221	!!----------------------------------------------------------------------
222	!! * ROUTINE nemo_init *
223	!!
224	!! ** Purpose : initialization of the NEMO GCM
225	!!----------------------------------------------------------------------
226	INTEGER :: ji ! dummy loop indices
227	INTEGER :: ilocal_comm ! local integer
228	INTEGER :: ios
229	CHARACTER(len=80), DIMENSION(16) :: cltxt
230	!
231	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
232	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
233	& nn_bench, nn_timing
234	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
235	& jpizoom, jpjzoom, jperio, ln_use_jattr
236	!!----------------------------------------------------------------------
237	!
238	cltxt = ''
239	cxios_context = 'nemo'
240	!
241	! ! Open reference namelist and configuration namelist files
242	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
243	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
244	!
245	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
246	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
247	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
248
249	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
250	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
251	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
252
253	!
254	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
255	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
256	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
257
258	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
259	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
260	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
261
262	! Force values for AGRIF zoom (cf. agrif_user.F90)
263	#if defined key_agrif
264	IF( .NOT. Agrif_Root() ) THEN
265	jpiglo = nbcellsx + 2 + 2*nbghostcells
266	jpjglo = nbcellsy + 2 + 2*nbghostcells
267	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
268	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
269	jpidta = jpiglo
270	jpjdta = jpjglo
271	jpizoom = 1
272	jpjzoom = 1
273	nperio = 0
274	jperio = 0
275	ln_use_jattr = .false.
276	ENDIF
277	#endif
278	!
279	! !--------------------------------------------!
280	! ! set communicator & select the local node !
281	! ! NB: mynode also opens output.namelist.dyn !
282	! ! on unit number numond on first proc !
283	! !--------------------------------------------!
284	#if defined key_iomput
285	IF( Agrif_Root() ) THEN
286	IF( lk_oasis ) THEN
287	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
288	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
289	ELSE
290	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
291	ENDIF
292	ENDIF
293	! Nodes selection (control print return in cltxt)
294	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
295	#else
296	IF( lk_oasis ) THEN
297	IF( Agrif_Root() ) THEN
298	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
299	ENDIF
300	! Nodes selection (control print return in cltxt)
301	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
302	ELSE
303	ilocal_comm = 0
304	! Nodes selection (control print return in cltxt)
305	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
306	ENDIF
307	#endif
308	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
309
310	lwm = (narea == 1) ! control of output namelists
311	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
312
313	IF(lwm) THEN
314	! write merged namelists from earlier to output namelist now that the
315	! file has been opened in call to mynode. nammpp has already been
316	! written in mynode (if lk_mpp_mpi)
317	WRITE( numond, namctl )
318	WRITE( numond, namcfg )
319	ENDIF
320
321	! If dimensions of processor grid weren't specified in the namelist file
322	! then we calculate them here now that we have our communicator size
323	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
324	#if defined key_mpp_mpi
325	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
326	#else
327	jpni = 1
328	jpnj = 1
329	jpnij = jpni*jpnj
330	#endif
331	END IF
332
333	! Calculate domain dimensions given calculated jpni and jpnj
334	! This used to be done in par_oce.F90 when they were parameters rather
335	! than variables
336	IF( Agrif_Root() ) THEN
337	#if defined key_nemocice_decomp
338	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
339	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
340	#else
341	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
342	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
343	#endif
344	ENDIF
345	jpk = jpkdta ! third dim
346	jpim1 = jpi-1 ! inner domain indices
347	jpjm1 = jpj-1 ! " "
348	jpkm1 = jpk-1 ! " "
349	jpij = jpi*jpj ! jpi x j
350
351	IF(lwp) THEN ! open listing units
352	!
353	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
354	!
355	WRITE(numout,*)
356	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
357	WRITE(numout,*) ' NEMO team'
358	WRITE(numout,*) ' Ocean General Circulation Model'
359	WRITE(numout,*) ' version 3.6 (2015) '
360	WRITE(numout,*)
361	WRITE(numout,*)
362	DO ji = 1, SIZE(cltxt)
363	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
364	END DO
365	WRITE(numout,cform_aaa) ! Flag AAAAAAA
366	!
367	ENDIF
368
369	! Now we know the dimensions of the grid and numout has been set we can
370	! allocate arrays
371	CALL nemo_alloc()
372
373	! !-------------------------------!
374	! ! NEMO general initialization !
375	! !-------------------------------!
376
377	CALL nemo_ctl ! Control prints & Benchmark
378
379	! ! Domain decomposition
380	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
381	ELSE ; CALL mpp_init2 ! eliminate land processors
382	ENDIF
383	!
384	IF( nn_timing == 1 ) CALL timing_init
385	!
386	! ! General initialization
387	CALL phy_cst ! Physical constants
388	CALL eos_init ! Equation of state
389	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
390	CALL dom_cfg ! Domain configuration
391	CALL dom_init ! Domain
392
393	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
394
395	IF( ln_ctl ) CALL prt_ctl_init ! Print control
396
397	IF( lk_crs ) CALL crs_init ! Domain initialization of coarsened grid
398
399	CALL istate_init ! ocean initial state (Dynamics and tracers)
400
401	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
402
403	CALL sbc_init ! Forcings : surface module (clem: moved here for bdy purpose)
404
405	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
406	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
407	IF( lk_bdy .AND. lk_tide ) &
408	& CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
409
410	CALL dyn_nept_init ! simplified form of Neptune effect
411	!
412	IF( lk_crs ) CALL eos_init_crs ! Equation of state
413	!
414	! Ocean physics
415	! ! Vertical physics
416	CALL zdf_init ! namelist read
417	CALL zdf_bfr_init ! bottom friction
418	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
419	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
420	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
421	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
422	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
423	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
424	& CALL zdf_ddm_init ! double diffusive mixing
425	! ! Lateral physics
426	CALL ldf_tra_init ! Lateral ocean tracer physics
427	CALL ldf_dyn_init ! Lateral ocean momentum physics
428	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
429	!
430	IF( ln_crs_top .AND. lk_ldfslp ) THEN
431	CALL dom_grid_crs
432	CALL ldf_slp_init_crs
433	CALL dom_grid_glo
434	ENDIF
435	! ! Active tracers
436	CALL tra_qsr_init ! penetrative solar radiation qsr
437	CALL tra_bbc_init ! bottom heat flux
438	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
439	!
440	IF( ln_crs_top .AND. lk_trabbl ) THEN
441	CALL dom_grid_crs
442	CALL tra_bbl_init_crs ! advective (and/or diffusive) bottom boundary layer scheme
443	CALL dom_grid_glo
444	ENDIF
445	!
446	CALL tra_dmp_init ! internal damping trends- tracers
447	CALL tra_adv_init ! horizontal & vertical advection
448	CALL tra_ldf_init ! lateral mixing
449	CALL tra_zdf_init ! vertical mixing and after tracer fields
450
451	! ! Dynamics
452	IF( lk_c1d ) CALL dyn_dmp_init ! internal damping trends- momentum
453	CALL dyn_adv_init ! advection (vector or flux form)
454	CALL dyn_vor_init ! vorticity term including Coriolis
455	CALL dyn_ldf_init ! lateral mixing
456	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
457	CALL dyn_zdf_init ! vertical diffusion
458	CALL dyn_spg_init ! surface pressure gradient
459
460	! ! Misc. options
461	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
462	CALL icb_init( rdt, nit000) ! initialise icebergs instance
463	CALL sto_par_init ! Stochastic parametrization
464	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
465
466	#if defined key_top
467	! ! Passive tracers
468	IF( ln_crs_top ) CALL dom_grid_crs
469	CALL trc_init
470	CALL ldf_tra_crs_init
471	IF( ln_crs_top ) CALL dom_grid_glo
472	#endif
473	! ! Diagnostics
474	IF( lk_floats ) CALL flo_init ! drifting Floats
475	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
476	CALL dia_ptr_init ! Poleward TRansports initialization
477	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
478	CALL dia_hsb_init ! heat content, salt content and volume budgets
479	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
480	IF( lk_diaobs ) THEN ! Observation & model comparison
481	CALL dia_obs_init ! Initialize observational data
482	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
483	ENDIF
484
485	! ! Assimilation increments
486	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
487	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
488	!
489	END SUBROUTINE nemo_init
490
491
492	SUBROUTINE nemo_ctl
493	!!----------------------------------------------------------------------
494	!! * ROUTINE nemo_ctl *
495	!!
496	!! ** Purpose : control print setting
497	!!
498	!! ** Method : - print namctl information and check some consistencies
499	!!----------------------------------------------------------------------
500	!
501	IF(lwp) THEN ! control print
502	WRITE(numout,*)
503	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
504	WRITE(numout,*) '~~~~~~~ '
505	WRITE(numout,*) ' Namelist namctl'
506	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
507	WRITE(numout,*) ' level of print nn_print = ', nn_print
508	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
509	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
510	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
511	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
512	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
513	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
514	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
515	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
516	ENDIF
517	!
518	nprint = nn_print ! convert DOCTOR namelist names into OLD names
519	nictls = nn_ictls
520	nictle = nn_ictle
521	njctls = nn_jctls
522	njctle = nn_jctle
523	isplt = nn_isplt
524	jsplt = nn_jsplt
525	nbench = nn_bench
526
527	IF(lwp) THEN ! control print
528	WRITE(numout,*)
529	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
530	WRITE(numout,*) '~~~~~~~ '
531	WRITE(numout,*) ' Namelist namcfg'
532	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
533	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
534	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
535	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
536	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
537	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
538	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
539	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
540	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
541	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
542	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
543	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
544	ENDIF
545	! ! Parameter control
546	!
547	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
548	IF( lk_mpp .AND. jpnij > 1 ) THEN
549	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
550	ELSE
551	IF( isplt == 1 .AND. jsplt == 1 ) THEN
552	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
553	& ' - the print control will be done over the whole domain' )
554	ENDIF
555	ijsplt = isplt * jsplt ! total number of processors ijsplt
556	ENDIF
557	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
558	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
559	!
560	! ! indices used for the SUM control
561	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
562	lsp_area = .FALSE.
563	ELSE ! print control done over a specific area
564	lsp_area = .TRUE.
565	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
566	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
567	nictls = 1
568	ENDIF
569	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
570	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
571	nictle = jpiglo
572	ENDIF
573	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
574	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
575	njctls = 1
576	ENDIF
577	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
578	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
579	njctle = jpjglo
580	ENDIF
581	ENDIF
582	ENDIF
583	!
584	IF( nbench == 1 ) THEN ! Benchmark
585	SELECT CASE ( cp_cfg )
586	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
587	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
588	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
589	END SELECT
590	ENDIF
591	!
592	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
593	& 'f2003 standard. ' , &
594	& 'Compile with key_nosignedzero enabled' )
595	!
596	END SUBROUTINE nemo_ctl
597
598
599	SUBROUTINE nemo_closefile
600	!!----------------------------------------------------------------------
601	!! * ROUTINE nemo_closefile *
602	!!
603	!! ** Purpose : Close the files
604	!!----------------------------------------------------------------------
605	!
606	IF( lk_mpp ) CALL mppsync
607	!
608	CALL iom_close ! close all input/output files managed by iom_*
609	!
610	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
611	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
612	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
613	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
614	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
615	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
616	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
617	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
618	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
619	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
620	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
621	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
622	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
623
624	!
625	numout = 6 ! redefine numout in case it is used after this point...
626	!
627	END SUBROUTINE nemo_closefile
628
629
630	SUBROUTINE nemo_alloc
631	!!----------------------------------------------------------------------
632	!! * ROUTINE nemo_alloc *
633	!!
634	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
635	!!
636	!! ** Method :
637	!!----------------------------------------------------------------------
638	USE diawri , ONLY: dia_wri_alloc
639	USE dom_oce , ONLY: dom_oce_alloc
640	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
641	USE ldftra_oce, ONLY: ldftra_oce_alloc
642	USE trc_oce , ONLY: trc_oce_alloc
643	#if defined key_diadct
644	USE diadct , ONLY: diadct_alloc
645	#endif
646	#if defined key_bdy
647	USE bdy_oce , ONLY: bdy_oce_alloc
648	#endif
649	!
650	INTEGER :: ierr
651	!!----------------------------------------------------------------------
652	!
653	ierr = oce_alloc () ! ocean
654	ierr = ierr + dia_wri_alloc ()
655	ierr = ierr + dom_oce_alloc () ! ocean domain
656	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
657	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
658	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
659	!
660	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
661	!
662	#if defined key_diadct
663	ierr = ierr + diadct_alloc () !
664	#endif
665	#if defined key_bdy
666	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
667	#endif
668	!
669	IF( lk_mpp ) CALL mpp_sum( ierr )
670	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
671	!
672	END SUBROUTINE nemo_alloc
673
674
675	SUBROUTINE nemo_partition( num_pes )
676	!!----------------------------------------------------------------------
677	!! * ROUTINE nemo_partition *
678	!!
679	!! ** Purpose :
680	!!
681	!! ** Method :
682	!!----------------------------------------------------------------------
683	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
684	!
685	INTEGER, PARAMETER :: nfactmax = 20
686	INTEGER :: nfact ! The no. of factors returned
687	INTEGER :: ierr ! Error flag
688	INTEGER :: ji
689	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
690	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
691	!!----------------------------------------------------------------------
692	!
693	ierr = 0
694	!
695	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
696	!
697	IF( nfact <= 1 ) THEN
698	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
699	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
700	jpnj = 1
701	jpni = num_pes
702	ELSE
703	! Search through factors for the pair that are closest in value
704	mindiff = 1000000
705	imin = 1
706	DO ji = 1, nfact-1, 2
707	idiff = ABS( ifact(ji) - ifact(ji+1) )
708	IF( idiff < mindiff ) THEN
709	mindiff = idiff
710	imin = ji
711	ENDIF
712	END DO
713	jpnj = ifact(imin)
714	jpni = ifact(imin + 1)
715	ENDIF
716	!
717	jpnij = jpni*jpnj
718	!
719	END SUBROUTINE nemo_partition
720
721
722	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
723	!!----------------------------------------------------------------------
724	!! * ROUTINE factorise *
725	!!
726	!! ** Purpose : return the prime factors of n.
727	!! knfax factors are returned in array kfax which is of
728	!! maximum dimension kmaxfax.
729	!! ** Method :
730	!!----------------------------------------------------------------------
731	INTEGER , INTENT(in ) :: kn, kmaxfax
732	INTEGER , INTENT( out) :: kerr, knfax
733	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
734	!
735	INTEGER :: ifac, jl, inu
736	INTEGER, PARAMETER :: ntest = 14
737	INTEGER :: ilfax(ntest)
738	!
739	! lfax contains the set of allowed factors.
740	data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256, &
741	& 128, 64, 32, 16, 8, 4, 2 /
742	!!----------------------------------------------------------------------
743
744	! Clear the error flag and initialise output vars
745	kerr = 0
746	kfax = 1
747	knfax = 0
748
749	! Find the factors of n.
750	IF( kn == 1 ) GOTO 20
751
752	! nu holds the unfactorised part of the number.
753	! knfax holds the number of factors found.
754	! l points to the allowed factor list.
755	! ifac holds the current factor.
756
757	inu = kn
758	knfax = 0
759
760	DO jl = ntest, 1, -1
761	!
762	ifac = ilfax(jl)
763	IF( ifac > inu ) CYCLE
764
765	! Test whether the factor will divide.
766
767	IF( MOD(inu,ifac) == 0 ) THEN
768	!
769	knfax = knfax + 1 ! Add the factor to the list
770	IF( knfax > kmaxfax ) THEN
771	kerr = 6
772	write (,) 'FACTOR: insufficient space in factor array ', knfax
773	return
774	ENDIF
775	kfax(knfax) = ifac
776	! Store the other factor that goes with this one
777	knfax = knfax + 1
778	kfax(knfax) = inu / ifac
779	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
780	ENDIF
781	!
782	END DO
783
784	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
785	!
786	END SUBROUTINE factorise
787
788	#if defined key_mpp_mpi
789
790	SUBROUTINE nemo_northcomms
791	!!======================================================================
792	!! * ROUTINE nemo_northcomms *
793	!! nemo_northcomms : Setup for north fold exchanges with explicit
794	!! point-to-point messaging
795	!!=====================================================================
796	!!----------------------------------------------------------------------
797	!!
798	!! ** Purpose : Initialization of the northern neighbours lists.
799	!!----------------------------------------------------------------------
800	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
801	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
802	!!----------------------------------------------------------------------
803
804	INTEGER :: sxM, dxM, sxT, dxT, jn
805	INTEGER :: njmppmax
806
807	njmppmax = MAXVAL( njmppt )
808
809	!initializes the north-fold communication variables
810	isendto(:) = 0
811	nsndto = 0
812
813	!if I am a process in the north
814	IF ( njmpp == njmppmax ) THEN
815	!sxM is the first point (in the global domain) needed to compute the
816	!north-fold for the current process
817	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
818	!dxM is the last point (in the global domain) needed to compute the
819	!north-fold for the current process
820	dxM = jpiglo - nimppt(narea) + 2
821
822	!loop over the other north-fold processes to find the processes
823	!managing the points belonging to the sxT-dxT range
824
825	DO jn = 1, jpni
826	!sxT is the first point (in the global domain) of the jn
827	!process
828	sxT = nfiimpp(jn, jpnj)
829	!dxT is the last point (in the global domain) of the jn
830	!process
831	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
832	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
833	nsndto = nsndto + 1
834	isendto(nsndto) = jn
835	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
836	nsndto = nsndto + 1
837	isendto(nsndto) = jn
838	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
839	nsndto = nsndto + 1
840	isendto(nsndto) = jn
841	END IF
842	END DO
843	nfsloop = 1
844	nfeloop = nlci
845	DO jn = 2,jpni-1
846	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
847	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
848	nfsloop = nldi
849	ENDIF
850	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
851	nfeloop = nlei
852	ENDIF
853	ENDIF
854	END DO
855
856	ENDIF
857	l_north_nogather = .TRUE.
858	END SUBROUTINE nemo_northcomms
859	#else
860	SUBROUTINE nemo_northcomms ! Dummy routine
861	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
862	END SUBROUTINE nemo_northcomms
863	#endif
864
865	!!======================================================================
866	END MODULE nemogcm
867
868

Note: See TracBrowser for help on using the repository browser.

Download in other formats: