New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC – NEMO

Context Navigation

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/OPA_SRC/nemogcm.F90 @ 7795

Last change on this file since 7795 was 7332, checked in by cbricaud, 7 years ago
crs branch cleaning
Property svn:keywords set to `Id`
File size: 40.8 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) LIM sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! 3.4 ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!!----------------------------------------------------------------------
33
34	!!----------------------------------------------------------------------
35	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
36	!! nemo_init : initialization of the NEMO system
37	!! nemo_ctl : initialisation of the contol print
38	!! nemo_closefile : close remaining open files
39	!! nemo_alloc : dynamical allocation
40	!! nemo_partition : calculate MPP domain decomposition
41	!! factorise : calculate the factors of the no. of MPI processes
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module
44	USE cla ! cross land advection (tra_cla routine)
45	USE domcfg ! domain configuration (dom_cfg routine)
46	USE mppini ! shared/distributed memory setting (mpp_init routine)
47	USE domain ! domain initialization (dom_init routine)
48	#if defined key_nemocice_decomp
49	USE ice_domain_size, only: nx_global, ny_global
50	#endif
51	USE tideini ! tidal components initialization (tide_ini routine)
52	USE bdyini ! open boundary cond. setting (bdy_init routine)
53	USE bdydta ! open boundary cond. setting (bdy_dta_init routine)
54	USE bdytides ! open boundary cond. setting (bdytide_init routine)
55	USE istate ! initial state setting (istate_init routine)
56	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
57	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
58	USE ldftra_crs ! lateral diffusivity setting (ldftra_init routine)
59	USE zdfini ! vertical physics setting (zdf_init routine)
60	USE phycst ! physical constant (par_cst routine)
61	USE trdini ! dyn/tra trends initialization (trd_init routine)
62	USE asminc ! assimilation increments
63	USE asmbkg ! writing out state trajectory
64	USE diaptr ! poleward transports (dia_ptr_init routine)
65	USE diadct ! sections transports (dia_dct_init routine)
66	USE diaobs ! Observation diagnostics (dia_obs_init routine)
67	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
68	USE step ! NEMO time-stepping (stp routine)
69	USE icbini ! handle bergs, initialisation
70	USE icbstp ! handle bergs, calving, themodynamics and transport
71	USE cpl_oasis3 ! OASIS3 coupling
72	USE c1d ! 1D configuration
73	USE step_c1d ! Time stepping loop for the 1D configuration
74	USE dyndmp ! Momentum damping
75	#if defined key_top
76	USE trcini ! passive tracer initialisation
77	#endif
78	USE lib_mpp ! distributed memory computing
79	#if defined key_iomput
80	USE xios
81	#endif
82	USE sbctide, ONLY: lk_tide
83	USE crsini ! initialise grid coarsening utility
84	USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
85	!cbr USE trabbl_crs
86	USE sbc_oce, ONLY: lk_oasis
87	USE stopar
88	USE stopts
89
90	IMPLICIT NONE
91	PRIVATE
92
93	PUBLIC nemo_gcm ! called by model.F90
94	PUBLIC nemo_init ! needed by AGRIF
95	PUBLIC nemo_alloc ! needed by TAM
96
97	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
98
99	!!----------------------------------------------------------------------
100	!! NEMO/OPA 4.0 , NEMO Consortium (2011)
101	!! $Id$
102	!! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
103	!!----------------------------------------------------------------------
104	CONTAINS
105
106	SUBROUTINE nemo_gcm
107	!!----------------------------------------------------------------------
108	!! * ROUTINE nemo_gcm *
109	!!
110	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
111	!! curvilinear mesh on the sphere.
112	!!
113	!! ** Method : - model general initialization
114	!! - launch the time-stepping (stp routine)
115	!! - finalize the run by closing files and communications
116	!!
117	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
118	!! Madec, 2008, internal report, IPSL.
119	!!----------------------------------------------------------------------
120	INTEGER :: istp ! time step index
121	CHARACTER(len=30) :: cmd
122	!!----------------------------------------------------------------------
123	!
124	#if defined key_agrif
125	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
126	#endif
127
128	! !-----------------------!
129	CALL nemo_init !== Initialisations ==!
130	! !-----------------------!
131	#if defined key_agrif
132	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
133	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
134	# if defined key_top
135	CALL Agrif_Declare_Var_top ! " " " " " TOP
136	# endif
137	# if defined key_lim2
138	CALL Agrif_Declare_Var_lim2 ! " " " " " LIM
139	# endif
140	#endif
141	! check that all process are still there... If some process have an error,
142	! they will never enter in step and other processes will wait until the end of the cpu time!
143	IF( lk_mpp ) CALL mpp_max( nstop )
144
145	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
146
147	! !-----------------------!
148	! !== time stepping ==!
149	! !-----------------------!
150	istp = nit000
151	#if defined key_c1d
152	DO WHILE ( istp <= nitend .AND. nstop == 0 )
153	CALL stp_c1d( istp )
154	istp = istp + 1
155	END DO
156	#else
157	IF( lk_asminc ) THEN
158	IF( ln_bkgwri ) CALL asm_bkg_wri( nit000 - 1 ) ! Output background fields
159	IF( ln_asmdin ) THEN ! Direct initialization
160	IF( ln_trainc ) CALL tra_asm_inc( nit000 - 1 ) ! Tracers
161	IF( ln_dyninc ) CALL dyn_asm_inc( nit000 - 1 ) ! Dynamics
162	IF( ln_sshinc ) CALL ssh_asm_inc( nit000 - 1 ) ! SSH
163	ENDIF
164	ENDIF
165
166	#if defined key_agrif
167	CALL Agrif_Regrid()
168	#endif
169
170	DO WHILE ( istp <= nitend .AND. nstop == 0 )
171	#if defined key_agrif
172	CALL stp ! AGRIF: time stepping
173	#else
174	CALL stp( istp ) ! standard time stepping
175	#endif
176	istp = istp + 1
177	IF( lk_mpp ) CALL mpp_max( nstop )
178	END DO
179	#endif
180
181	IF( lk_diaobs ) CALL dia_obs_wri
182	!
183	IF( ln_icebergs ) CALL icb_end( nitend )
184
185	! !------------------------!
186	! !== finalize the run ==!
187	! !------------------------!
188	IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA
189	!
190	IF( nstop /= 0 ) THEN ! error print
191	cmd='touch nemo_NOK'
192	CALL system(cmd)
193	WRITE(numout,cform_err)
194	WRITE(numout,*) nstop, ' error have been found'
195	ELSE
196	cmd='touch nemo_OK'
197	CALL system(cmd)
198	ENDIF
199	!
200	#if defined key_agrif
201	IF( .NOT. Agrif_Root() ) THEN
202	CALL Agrif_ParentGrid_To_ChildGrid()
203	IF( lk_diaobs ) CALL dia_obs_wri
204	IF( nn_timing == 1 ) CALL timing_finalize
205	CALL Agrif_ChildGrid_To_ParentGrid()
206	ENDIF
207	#endif
208	IF( nn_timing == 1 ) CALL timing_finalize
209	!
210	CALL nemo_closefile
211	!
212	#if defined key_iomput
213	CALL xios_finalize ! end mpp communications with xios
214	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
215	#else
216	IF( lk_oasis ) THEN
217	CALL cpl_finalize ! end coupling and mpp communications with OASIS
218	ELSE
219	IF( lk_mpp ) CALL mppstop ! end mpp communications
220	ENDIF
221	#endif
222	!
223	END SUBROUTINE nemo_gcm
224
225
226	SUBROUTINE nemo_init
227	!!----------------------------------------------------------------------
228	!! * ROUTINE nemo_init *
229	!!
230	!! ** Purpose : initialization of the NEMO GCM
231	!!----------------------------------------------------------------------
232	INTEGER :: ji ! dummy loop indices
233	INTEGER :: ilocal_comm ! local integer
234	INTEGER :: ios
235	CHARACTER(len=80), DIMENSION(16) :: cltxt
236	!
237	NAMELIST/namctl/ ln_ctl , nn_print, nn_ictls, nn_ictle, &
238	& nn_isplt, nn_jsplt, nn_jctls, nn_jctle, &
239	& nn_bench, nn_timing
240	NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
241	& jpizoom, jpjzoom, jperio, ln_use_jattr
242	!!----------------------------------------------------------------------
243	!
244	cltxt = ''
245	cxios_context = 'nemo'
246	!
247	! ! Open reference namelist and configuration namelist files
248	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
249	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
250	!
251	REWIND( numnam_ref ) ! Namelist namctl in reference namelist : Control prints & Benchmark
252	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
253	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
254
255	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist : Control prints & Benchmark
256	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
257	902 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
258
259	!
260	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist : Control prints & Benchmark
261	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
262	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
263
264	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist : Control prints & Benchmark
265	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
266	904 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
267
268	! Force values for AGRIF zoom (cf. agrif_user.F90)
269	#if defined key_agrif
270	IF( .NOT. Agrif_Root() ) THEN
271	jpiglo = nbcellsx + 2 + 2*nbghostcells
272	jpjglo = nbcellsy + 2 + 2*nbghostcells
273	jpi = ( jpiglo-2jpreci + (jpni-1+0) ) / jpni + 2jpreci
274	jpj = ( jpjglo-2jprecj + (jpnj-1+0) ) / jpnj + 2jprecj
275	jpidta = jpiglo
276	jpjdta = jpjglo
277	jpizoom = 1
278	jpjzoom = 1
279	nperio = 0
280	jperio = 0
281	ln_use_jattr = .false.
282	ENDIF
283	#endif
284	!
285	! !--------------------------------------------!
286	! ! set communicator & select the local node !
287	! ! NB: mynode also opens output.namelist.dyn !
288	! ! on unit number numond on first proc !
289	! !--------------------------------------------!
290	#if defined key_iomput
291	IF( Agrif_Root() ) THEN
292	IF( lk_oasis ) THEN
293	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
294	CALL xios_initialize( "not used",local_comm=ilocal_comm ) ! send nemo communicator to xios
295	ELSE
296	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
297	ENDIF
298	ENDIF
299	! Nodes selection (control print return in cltxt)
300	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
301	#else
302	IF( lk_oasis ) THEN
303	IF( Agrif_Root() ) THEN
304	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
305	ENDIF
306	! Nodes selection (control print return in cltxt)
307	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
308	ELSE
309	ilocal_comm = 0
310	! Nodes selection (control print return in cltxt)
311	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
312	ENDIF
313	#endif
314	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
315
316	lwm = (narea == 1) ! control of output namelists
317	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
318
319	IF(lwm) THEN
320	! write merged namelists from earlier to output namelist now that the
321	! file has been opened in call to mynode. nammpp has already been
322	! written in mynode (if lk_mpp_mpi)
323	WRITE( numond, namctl )
324	WRITE( numond, namcfg )
325	ENDIF
326
327	! If dimensions of processor grid weren't specified in the namelist file
328	! then we calculate them here now that we have our communicator size
329	IF( (jpni < 1) .OR. (jpnj < 1) )THEN
330	#if defined key_mpp_mpi
331	IF( Agrif_Root() ) CALL nemo_partition(mppsize)
332	#else
333	jpni = 1
334	jpnj = 1
335	jpnij = jpni*jpnj
336	#endif
337	END IF
338
339	! Calculate domain dimensions given calculated jpni and jpnj
340	! This used to be done in par_oce.F90 when they were parameters rather
341	! than variables
342	IF( Agrif_Root() ) THEN
343	#if defined key_nemocice_decomp
344	jpi = ( nx_global+2-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
345	jpj = ( ny_global+2-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
346	#else
347	jpi = ( jpiglo-2jpreci + (jpni-1) ) / jpni + 2jpreci ! first dim.
348	jpj = ( jpjglo-2jprecj + (jpnj-1) ) / jpnj + 2jprecj ! second dim.
349	#endif
350	ENDIF
351	jpk = jpkdta ! third dim
352	#if defined key_agrif
353	! simple trick to use same vertical grid as parent
354	! but different number of levels:
355	! Save maximum number of levels in jpkdta, then define all vertical grids
356	! with this number.
357	! Suppress once vertical online interpolation is ok
358	IF(.NOT.Agrif_Root()) jpkdta = Agrif_Parent(jpkdta)
359	#endif
360	jpim1 = jpi-1 ! inner domain indices
361	jpjm1 = jpj-1 ! " "
362	jpkm1 = jpk-1 ! " "
363	jpij = jpi*jpj ! jpi x j
364
365	IF(lwp) THEN ! open listing units
366	!
367	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
368	!
369	WRITE(numout,*)
370	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
371	WRITE(numout,*) ' NEMO team'
372	WRITE(numout,*) ' Ocean General Circulation Model'
373	WRITE(numout,*) ' version 3.6 (2015) '
374	WRITE(numout,*)
375	WRITE(numout,*)
376	DO ji = 1, SIZE(cltxt)
377	IF( TRIM(cltxt(ji)) /= '' ) WRITE(numout,*) cltxt(ji) ! control print of mynode
378	END DO
379	WRITE(numout,cform_aaa) ! Flag AAAAAAA
380	!
381	ENDIF
382
383	! Now we know the dimensions of the grid and numout has been set we can
384	! allocate arrays
385	CALL nemo_alloc()
386
387	! !-------------------------------!
388	! ! NEMO general initialization !
389	! !-------------------------------!
390
391	CALL nemo_ctl ! Control prints & Benchmark
392
393	! ! Domain decomposition
394	IF( jpni*jpnj == jpnij ) THEN ; CALL mpp_init ! standard cutting out
395	ELSE ; CALL mpp_init2 ! eliminate land processors
396	ENDIF
397	!
398	IF( nn_timing == 1 ) CALL timing_init
399	!
400	! ! General initialization
401	CALL phy_cst ! Physical constants
402	CALL eos_init ! Equation of state
403	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
404	CALL dom_cfg ! Domain configuration
405	CALL dom_init ! Domain
406
407	IF( ln_nnogather ) CALL nemo_northcomms ! Initialise the northfold neighbour lists (must be done after the masks are defined)
408
409	IF( ln_ctl ) CALL prt_ctl_init ! Print control
410
411	IF( lk_crs ) CALL crs_init ! Domain initialization of coarsened grid
412
413	CALL istate_init ! ocean initial state (Dynamics and tracers)
414
415	IF( lk_tide ) CALL tide_init( nit000 ) ! Initialisation of the tidal harmonics
416
417	CALL sbc_init ! Forcings : surface module (clem: moved here for bdy purpose)
418
419	IF( lk_bdy ) CALL bdy_init ! Open boundaries initialisation
420	IF( lk_bdy ) CALL bdy_dta_init ! Open boundaries initialisation of external data arrays
421	IF( lk_bdy .AND. lk_tide ) &
422	& CALL bdytide_init ! Open boundaries initialisation of tidal harmonic forcing
423
424	CALL dyn_nept_init ! simplified form of Neptune effect
425	!
426	IF( lk_crs ) CALL eos_init_crs ! Equation of state
427	!
428	! Ocean physics
429	! ! Vertical physics
430	CALL zdf_init ! namelist read
431	CALL zdf_bfr_init ! bottom friction
432	IF( lk_zdfric ) CALL zdf_ric_init ! Richardson number dependent Kz
433	IF( lk_zdftke ) CALL zdf_tke_init ! TKE closure scheme
434	IF( lk_zdfgls ) CALL zdf_gls_init ! GLS closure scheme
435	IF( lk_zdfkpp ) CALL zdf_kpp_init ! KPP closure scheme
436	IF( lk_zdftmx ) CALL zdf_tmx_init ! tidal vertical mixing
437	IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) &
438	& CALL zdf_ddm_init ! double diffusive mixing
439	! ! Lateral physics
440	CALL ldf_tra_init ! Lateral ocean tracer physics
441	CALL ldf_dyn_init ! Lateral ocean momentum physics
442	IF( lk_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
443	!
444	IF( ln_crs_top .AND. lk_ldfslp ) THEN
445	CALL dom_grid_crs
446	CALL ldf_slp_init_crs
447	CALL dom_grid_glo
448	ENDIF
449	! ! Active tracers
450	CALL tra_qsr_init ! penetrative solar radiation qsr
451	CALL tra_bbc_init ! bottom heat flux
452	IF( lk_trabbl ) CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
453	!
454	!cbr IF( ln_crs_top .AND. lk_trabbl ) THEN
455	! CALL dom_grid_crs
456	! CALL tra_bbl_init_crs ! advective (and/or diffusive) bottom boundary layer scheme
457	! CALL dom_grid_glo
458	!ENDIF
459	!
460	CALL tra_dmp_init ! internal damping trends- tracers
461	CALL tra_adv_init ! horizontal & vertical advection
462	CALL tra_ldf_init ! lateral mixing
463	CALL tra_zdf_init ! vertical mixing and after tracer fields
464
465	! ! Dynamics
466	IF( lk_c1d ) CALL dyn_dmp_init ! internal damping trends- momentum
467	CALL dyn_adv_init ! advection (vector or flux form)
468	CALL dyn_vor_init ! vorticity term including Coriolis
469	CALL dyn_ldf_init ! lateral mixing
470	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
471	CALL dyn_zdf_init ! vertical diffusion
472	CALL dyn_spg_init ! surface pressure gradient
473
474	! ! Misc. options
475	IF( nn_cla == 1 .AND. cp_cfg == 'orca' .AND. jp_cfg == 2 ) CALL cla_init ! Cross Land Advection
476	CALL icb_init( rdt, nit000) ! initialise icebergs instance
477	CALL sto_par_init ! Stochastic parametrization
478	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
479
480	#if defined key_top
481	! ! Passive tracers
482	IF( ln_crs_top ) CALL dom_grid_crs
483	CALL trc_init
484	IF( ln_crs_top ) CALL ldf_tra_crs_init
485	IF( ln_crs_top ) CALL dom_grid_glo
486	#endif
487	! ! Diagnostics
488	IF( lk_floats ) CALL flo_init ! drifting Floats
489	IF( lk_diaar5 ) CALL dia_ar5_init ! ar5 diag
490	CALL dia_ptr_init ! Poleward TRansports initialization
491	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
492	CALL dia_hsb_init ! heat content, salt content and volume budgets
493	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
494	IF( lk_diaobs ) THEN ! Observation & model comparison
495	CALL dia_obs_init ! Initialize observational data
496	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
497	ENDIF
498
499	! ! Assimilation increments
500	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
501	IF(lwp) WRITE(numout,*) 'Euler time step switch is ', neuler
502	!
503	END SUBROUTINE nemo_init
504
505
506	SUBROUTINE nemo_ctl
507	!!----------------------------------------------------------------------
508	!! * ROUTINE nemo_ctl *
509	!!
510	!! ** Purpose : control print setting
511	!!
512	!! ** Method : - print namctl information and check some consistencies
513	!!----------------------------------------------------------------------
514	!
515	IF(lwp) THEN ! control print
516	WRITE(numout,*)
517	WRITE(numout,*) 'nemo_ctl: Control prints & Benchmark'
518	WRITE(numout,*) '~~~~~~~ '
519	WRITE(numout,*) ' Namelist namctl'
520	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
521	WRITE(numout,*) ' level of print nn_print = ', nn_print
522	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
523	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
524	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
525	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
526	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
527	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
528	WRITE(numout,*) ' benchmark parameter (0/1) nn_bench = ', nn_bench
529	WRITE(numout,*) ' timing activated (0/1) nn_timing = ', nn_timing
530	ENDIF
531	!
532	nprint = nn_print ! convert DOCTOR namelist names into OLD names
533	nictls = nn_ictls
534	nictle = nn_ictle
535	njctls = nn_jctls
536	njctle = nn_jctle
537	isplt = nn_isplt
538	jsplt = nn_jsplt
539	nbench = nn_bench
540
541	IF(lwp) THEN ! control print
542	WRITE(numout,*)
543	WRITE(numout,*) 'namcfg : configuration initialization through namelist read'
544	WRITE(numout,*) '~~~~~~~ '
545	WRITE(numout,*) ' Namelist namcfg'
546	WRITE(numout,*) ' configuration name cp_cfg = ', TRIM(cp_cfg)
547	WRITE(numout,*) ' configuration zoom name cp_cfz = ', TRIM(cp_cfz)
548	WRITE(numout,*) ' configuration resolution jp_cfg = ', jp_cfg
549	WRITE(numout,*) ' 1st lateral dimension ( >= jpi ) jpidta = ', jpidta
550	WRITE(numout,*) ' 2nd " " ( >= jpj ) jpjdta = ', jpjdta
551	WRITE(numout,*) ' 3nd " " jpkdta = ', jpkdta
552	WRITE(numout,*) ' 1st dimension of global domain in i jpiglo = ', jpiglo
553	WRITE(numout,*) ' 2nd - - in j jpjglo = ', jpjglo
554	WRITE(numout,*) ' left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
555	WRITE(numout,*) ' left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
556	WRITE(numout,*) ' lateral cond. type (between 0 and 6) jperio = ', jperio
557	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
558	ENDIF
559	! ! Parameter control
560	!
561	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
562	IF( lk_mpp .AND. jpnij > 1 ) THEN
563	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
564	ELSE
565	IF( isplt == 1 .AND. jsplt == 1 ) THEN
566	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
567	& ' - the print control will be done over the whole domain' )
568	ENDIF
569	ijsplt = isplt * jsplt ! total number of processors ijsplt
570	ENDIF
571	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
572	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
573	!
574	! ! indices used for the SUM control
575	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
576	lsp_area = .FALSE.
577	ELSE ! print control done over a specific area
578	lsp_area = .TRUE.
579	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
580	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
581	nictls = 1
582	ENDIF
583	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
584	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
585	nictle = jpiglo
586	ENDIF
587	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
588	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
589	njctls = 1
590	ENDIF
591	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
592	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
593	njctle = jpjglo
594	ENDIF
595	ENDIF
596	ENDIF
597	!
598	IF( nbench == 1 ) THEN ! Benchmark
599	SELECT CASE ( cp_cfg )
600	CASE ( 'gyre' ) ; CALL ctl_warn( ' The Benchmark is activated ' )
601	CASE DEFAULT ; CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:', &
602	& ' cp_cfg = "gyre" in namelist &namcfg or set nbench = 0' )
603	END SELECT
604	ENDIF
605	!
606	IF( 1_wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ', &
607	& 'f2003 standard. ' , &
608	& 'Compile with key_nosignedzero enabled' )
609	!
610	END SUBROUTINE nemo_ctl
611
612
613	SUBROUTINE nemo_closefile
614	!!----------------------------------------------------------------------
615	!! * ROUTINE nemo_closefile *
616	!!
617	!! ** Purpose : Close the files
618	!!----------------------------------------------------------------------
619	!
620	IF( lk_mpp ) CALL mppsync
621	!
622	CALL iom_close ! close all input/output files managed by iom_*
623	!
624	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
625	IF( numsol /= -1 ) CLOSE( numsol ) ! solver file
626	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
627	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
628	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
629	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
630	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
631	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
632	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
633	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
634	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
635	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
636	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
637
638	!
639	numout = 6 ! redefine numout in case it is used after this point...
640	!
641	END SUBROUTINE nemo_closefile
642
643
644	SUBROUTINE nemo_alloc
645	!!----------------------------------------------------------------------
646	!! * ROUTINE nemo_alloc *
647	!!
648	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
649	!!
650	!! ** Method :
651	!!----------------------------------------------------------------------
652	USE diawri , ONLY: dia_wri_alloc
653	USE dom_oce , ONLY: dom_oce_alloc
654	USE ldfdyn_oce, ONLY: ldfdyn_oce_alloc
655	USE ldftra_oce, ONLY: ldftra_oce_alloc
656	USE trc_oce , ONLY: trc_oce_alloc
657	USE zdfmxl , ONLY: zdf_mxl_alloc
658	#if defined key_diadct
659	USE diadct , ONLY: diadct_alloc
660	#endif
661	#if defined key_bdy
662	USE bdy_oce , ONLY: bdy_oce_alloc
663	#endif
664	!
665	INTEGER :: ierr
666	!!----------------------------------------------------------------------
667	!
668	ierr = oce_alloc () ! ocean
669	ierr = ierr + dia_wri_alloc ()
670	ierr = ierr + dom_oce_alloc () ! ocean domain
671	ierr = ierr + ldfdyn_oce_alloc() ! ocean lateral physics : dynamics
672	ierr = ierr + ldftra_oce_alloc() ! ocean lateral physics : tracers
673	ierr = ierr + zdf_oce_alloc () ! ocean vertical physics
674	ierr = ierr + zdf_mxl_alloc () ! mixed layer
675	!
676	ierr = ierr + trc_oce_alloc () ! shared TRC / TRA arrays
677	!
678	#if defined key_diadct
679	ierr = ierr + diadct_alloc () !
680	#endif
681	#if defined key_bdy
682	ierr = ierr + bdy_oce_alloc () ! bdy masks (incl. initialization)
683	#endif
684	!
685	IF( lk_mpp ) CALL mpp_sum( ierr )
686	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc : unable to allocate standard ocean arrays' )
687	!
688	END SUBROUTINE nemo_alloc
689
690
691	SUBROUTINE nemo_partition( num_pes )
692	!!----------------------------------------------------------------------
693	!! * ROUTINE nemo_partition *
694	!!
695	!! ** Purpose :
696	!!
697	!! ** Method :
698	!!----------------------------------------------------------------------
699	INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
700	!
701	INTEGER, PARAMETER :: nfactmax = 20
702	INTEGER :: nfact ! The no. of factors returned
703	INTEGER :: ierr ! Error flag
704	INTEGER :: ji
705	INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
706	INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
707	!!----------------------------------------------------------------------
708	!
709	ierr = 0
710	!
711	CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
712	!
713	IF( nfact <= 1 ) THEN
714	WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
715	WRITE (numout, *) ' : using grid of ',num_pes,' x 1'
716	jpnj = 1
717	jpni = num_pes
718	ELSE
719	! Search through factors for the pair that are closest in value
720	mindiff = 1000000
721	imin = 1
722	DO ji = 1, nfact-1, 2
723	idiff = ABS( ifact(ji) - ifact(ji+1) )
724	IF( idiff < mindiff ) THEN
725	mindiff = idiff
726	imin = ji
727	ENDIF
728	END DO
729	jpnj = ifact(imin)
730	jpni = ifact(imin + 1)
731	ENDIF
732	!
733	jpnij = jpni*jpnj
734	!
735	END SUBROUTINE nemo_partition
736
737
738	SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
739	!!----------------------------------------------------------------------
740	!! * ROUTINE factorise *
741	!!
742	!! ** Purpose : return the prime factors of n.
743	!! knfax factors are returned in array kfax which is of
744	!! maximum dimension kmaxfax.
745	!! ** Method :
746	!!----------------------------------------------------------------------
747	INTEGER , INTENT(in ) :: kn, kmaxfax
748	INTEGER , INTENT( out) :: kerr, knfax
749	INTEGER, DIMENSION(kmaxfax), INTENT( out) :: kfax
750	!
751	INTEGER :: ifac, jl, inu
752	INTEGER, PARAMETER :: ntest = 14
753	INTEGER, DIMENSION(ntest) :: ilfax
754	!
755	! ilfax contains the set of allowed factors.
756	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
757	!!----------------------------------------------------------------------
758	! ilfax contains the set of allowed factors.
759	ilfax(:) = (/(2**jl,jl=ntest,1,-1)/)
760
761	! Clear the error flag and initialise output vars
762	kerr = 0
763	kfax = 1
764	knfax = 0
765
766	! Find the factors of n.
767	IF( kn == 1 ) GOTO 20
768
769	! nu holds the unfactorised part of the number.
770	! knfax holds the number of factors found.
771	! l points to the allowed factor list.
772	! ifac holds the current factor.
773
774	inu = kn
775	knfax = 0
776
777	DO jl = ntest, 1, -1
778	!
779	ifac = ilfax(jl)
780	IF( ifac > inu ) CYCLE
781
782	! Test whether the factor will divide.
783
784	IF( MOD(inu,ifac) == 0 ) THEN
785	!
786	knfax = knfax + 1 ! Add the factor to the list
787	IF( knfax > kmaxfax ) THEN
788	kerr = 6
789	write (,) 'FACTOR: insufficient space in factor array ', knfax
790	return
791	ENDIF
792	kfax(knfax) = ifac
793	! Store the other factor that goes with this one
794	knfax = knfax + 1
795	kfax(knfax) = inu / ifac
796	!WRITE (,) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
797	ENDIF
798	!
799	END DO
800
801	20 CONTINUE ! Label 20 is the exit point from the factor search loop.
802	!
803	END SUBROUTINE factorise
804
805	#if defined key_mpp_mpi
806
807	SUBROUTINE nemo_northcomms
808	!!======================================================================
809	!! * ROUTINE nemo_northcomms *
810	!! nemo_northcomms : Setup for north fold exchanges with explicit
811	!! point-to-point messaging
812	!!=====================================================================
813	!!----------------------------------------------------------------------
814	!!
815	!! ** Purpose : Initialization of the northern neighbours lists.
816	!!----------------------------------------------------------------------
817	!! 1.0 ! 2011-10 (A. C. Coward, NOCS & J. Donners, PRACE)
818	!! 2.0 ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S. Mocavero, CMCC)
819	!!----------------------------------------------------------------------
820
821	INTEGER :: sxM, dxM, sxT, dxT, jn
822	INTEGER :: njmppmax
823
824	njmppmax = MAXVAL( njmppt )
825
826	!initializes the north-fold communication variables
827	isendto(:) = 0
828	nsndto = 0
829
830	!if I am a process in the north
831	IF ( njmpp == njmppmax ) THEN
832	!sxM is the first point (in the global domain) needed to compute the
833	!north-fold for the current process
834	sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
835	!dxM is the last point (in the global domain) needed to compute the
836	!north-fold for the current process
837	dxM = jpiglo - nimppt(narea) + 2
838
839	!loop over the other north-fold processes to find the processes
840	!managing the points belonging to the sxT-dxT range
841
842	DO jn = 1, jpni
843	!sxT is the first point (in the global domain) of the jn
844	!process
845	sxT = nfiimpp(jn, jpnj)
846	!dxT is the last point (in the global domain) of the jn
847	!process
848	dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
849	IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
850	nsndto = nsndto + 1
851	isendto(nsndto) = jn
852	ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
853	nsndto = nsndto + 1
854	isendto(nsndto) = jn
855	ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
856	nsndto = nsndto + 1
857	isendto(nsndto) = jn
858	END IF
859	END DO
860	nfsloop = 1
861	nfeloop = nlci
862	DO jn = 2,jpni-1
863	IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
864	IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
865	nfsloop = nldi
866	ENDIF
867	IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
868	nfeloop = nlei
869	ENDIF
870	ENDIF
871	END DO
872
873	ENDIF
874	l_north_nogather = .TRUE.
875	END SUBROUTINE nemo_northcomms
876	#else
877	SUBROUTINE nemo_northcomms ! Dummy routine
878	WRITE(,) 'nemo_northcomms: You should not have seen this print! error?'
879	END SUBROUTINE nemo_northcomms
880	#endif
881
882	!!======================================================================
883	END MODULE nemogcm
884
885

Note: See TracBrowser for help on using the repository browser.

Download in other formats: