| 1 | MODULE step |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE step *** |
|---|
| 4 | !! Time-stepping : manager of the ocean, tracer and ice time stepping |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1991-03 (G. Madec) Original code |
|---|
| 7 | !! - ! 1991-11 (G. Madec) |
|---|
| 8 | !! - ! 1992-06 (M. Imbard) add a first output record |
|---|
| 9 | !! - ! 1996-04 (G. Madec) introduction of dynspg |
|---|
| 10 | !! - ! 1996-04 (M.A. Foujols) introduction of passive tracer |
|---|
| 11 | !! 8.0 ! 1997-06 (G. Madec) new architecture of call |
|---|
| 12 | !! 8.2 ! 1997-06 (G. Madec, M. Imbard, G. Roullet) free surface |
|---|
| 13 | !! - ! 1999-02 (G. Madec, N. Grima) hpg implicit |
|---|
| 14 | !! - ! 2000-07 (J-M Molines, M. Imbard) Open Bondary Conditions |
|---|
| 15 | !! NEMO 1.0 ! 2002-06 (G. Madec) free form, suppress macro-tasking |
|---|
| 16 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 17 | !! - ! 2005-01 (C. Ethe) Add the KPP closure scheme |
|---|
| 18 | !! - ! 2005-11 (G. Madec) Reorganisation of tra and dyn calls |
|---|
| 19 | !! - ! 2006-01 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 20 | !! - ! 2006-07 (S. Masson) restart using iom |
|---|
| 21 | !! 3.2 ! 2009-02 (G. Madec, R. Benshila) reintroduicing z*-coordinate |
|---|
| 22 | !! - ! 2009-06 (S. Masson, G. Madec) TKE restart compatible with key_cpl |
|---|
| 23 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 24 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA |
|---|
| 25 | !! 3.4 ! 2011-04 (G. Madec, C. Ethe) Merge of dtatem and dtasal |
|---|
| 26 | !! ! 2012-07 (J. Simeon, G. Madec, C. Ethe) Online coarsening of outputs |
|---|
| 27 | !! 3.7 ! 2014-04 (F. Roquet, G. Madec) New equations of state |
|---|
| 28 | !!---------------------------------------------------------------------- |
|---|
| 29 | |
|---|
| 30 | !!---------------------------------------------------------------------- |
|---|
| 31 | !! stp : OPA system time-stepping |
|---|
| 32 | !!---------------------------------------------------------------------- |
|---|
| 33 | USE step_oce ! time stepping definition modules |
|---|
| 34 | USE iom |
|---|
| 35 | USE crs |
|---|
| 36 | |
|---|
| 37 | IMPLICIT NONE |
|---|
| 38 | PRIVATE |
|---|
| 39 | |
|---|
| 40 | PUBLIC stp ! called by opa.F90 |
|---|
| 41 | |
|---|
| 42 | !! * Substitutions |
|---|
| 43 | # include "domzgr_substitute.h90" |
|---|
| 44 | !!gm # include "zdfddm_substitute.h90" |
|---|
| 45 | !!---------------------------------------------------------------------- |
|---|
| 46 | !! NEMO/OPA 3.7 , NEMO Consortium (2014) |
|---|
| 47 | !! $Id$ |
|---|
| 48 | !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt) |
|---|
| 49 | !!---------------------------------------------------------------------- |
|---|
| 50 | CONTAINS |
|---|
| 51 | |
|---|
| 52 | #if defined key_agrif |
|---|
| 53 | SUBROUTINE stp( ) |
|---|
| 54 | INTEGER :: kstp ! ocean time-step index |
|---|
| 55 | #else |
|---|
| 56 | SUBROUTINE stp( kstp ) |
|---|
| 57 | INTEGER, INTENT(in) :: kstp ! ocean time-step index |
|---|
| 58 | #endif |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | !! *** ROUTINE stp *** |
|---|
| 61 | !! |
|---|
| 62 | !! ** Purpose : - Time stepping of OPA (momentum and active tracer eqs.) |
|---|
| 63 | !! - Time stepping of LIM (dynamic and thermodynamic eqs.) |
|---|
| 64 | !! - Tme stepping of TRC (passive tracer eqs.) |
|---|
| 65 | !! |
|---|
| 66 | !! ** Method : -1- Update forcings and data |
|---|
| 67 | !! -2- Update ocean physics |
|---|
| 68 | !! -3- Compute the t and s trends |
|---|
| 69 | !! -4- Update t and s |
|---|
| 70 | !! -5- Compute the momentum trends |
|---|
| 71 | !! -6- Update the horizontal velocity |
|---|
| 72 | !! -7- Compute the diagnostics variables (rd,N2, div,cur,w) |
|---|
| 73 | !! -8- Outputs and diagnostics |
|---|
| 74 | !!---------------------------------------------------------------------- |
|---|
| 75 | INTEGER :: jk ! dummy loop indice |
|---|
| 76 | INTEGER :: indic ! error indicator if < 0 |
|---|
| 77 | INTEGER :: kcall ! optional integer argument (dom_vvl_sf_nxt) |
|---|
| 78 | !! --------------------------------------------------------------------- |
|---|
| 79 | |
|---|
| 80 | #if defined key_agrif |
|---|
| 81 | kstp = nit000 + Agrif_Nb_Step() |
|---|
| 82 | ! IF ( Agrif_Root() .and. lwp) Write(*,*) '---' |
|---|
| 83 | ! IF (lwp) Write(*,*) 'Grid Number',Agrif_Fixed(),' time step ',kstp |
|---|
| 84 | IF ( kstp == (nit000 + 1) ) lk_agrif_fstep = .FALSE. |
|---|
| 85 | # if defined key_iomput |
|---|
| 86 | IF( Agrif_Nbstepint() == 0 ) CALL iom_swap( "nemo" ) |
|---|
| 87 | # endif |
|---|
| 88 | #endif |
|---|
| 89 | indic = 0 ! reset to no error condition |
|---|
| 90 | IF( kstp == nit000 ) THEN |
|---|
| 91 | CALL iom_init( "nemo" ) ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS) |
|---|
| 92 | IF( ln_crs ) CALL iom_init( "nemo_crs" ) ! initialize context for coarse grid |
|---|
| 93 | ENDIF |
|---|
| 94 | |
|---|
| 95 | IF( kstp /= nit000 ) CALL day( kstp ) ! Calendar (day was already called at nit000 in day_init) |
|---|
| 96 | CALL iom_setkt( kstp - nit000 + 1, "nemo" ) ! say to iom that we are at time step kstp |
|---|
| 97 | IF( ln_crs ) CALL iom_setkt( kstp - nit000 + 1, "nemo_crs" ) ! say to iom that we are at time step kstp |
|---|
| 98 | |
|---|
| 99 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 100 | ! Update data, open boundaries, surface boundary condition (including sea-ice) |
|---|
| 101 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 102 | IF( lk_tide ) CALL sbc_tide( kstp ) |
|---|
| 103 | IF( lk_bdy ) CALL bdy_dta ( kstp, time_offset=+1 ) ! update dynamic & tracer data at open boundaries |
|---|
| 104 | |
|---|
| 105 | CALL sbc ( kstp ) ! Sea Boundary Condition (including sea-ice) |
|---|
| 106 | ! clem: moved here for bdy ice purpose |
|---|
| 107 | |
|---|
| 108 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 109 | ! Ocean physics update (ua, va, tsa used as workspace) |
|---|
| 110 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 111 | ! THERMODYNAMICS |
|---|
| 112 | !cbr not used CALL eos_rab( tsb, rab_b ) ! before local thermal/haline expension ratio at T-points |
|---|
| 113 | !cbr not used CALL eos_rab( tsn, rab_n ) ! now local thermal/haline expension ratio at T-points |
|---|
| 114 | CALL bn2 ( tsb, rab_b, rn2b ) ! before Brunt-Vaisala frequency |
|---|
| 115 | CALL bn2 ( tsn, rab_n, rn2 ) ! now Brunt-Vaisala frequency |
|---|
| 116 | ! |
|---|
| 117 | ! VERTICAL PHYSICS |
|---|
| 118 | CALL zdf_bfr( kstp ) ! bottom friction (if quadratic) |
|---|
| 119 | ! ! Vertical eddy viscosity and diffusivity coefficients |
|---|
| 120 | IF( lk_zdfric ) CALL zdf_ric( kstp ) ! Richardson number dependent Kz |
|---|
| 121 | IF( lk_zdftke ) CALL zdf_tke( kstp ) ! TKE closure scheme for Kz |
|---|
| 122 | IF( lk_zdfgls ) CALL zdf_gls( kstp ) ! GLS closure scheme for Kz |
|---|
| 123 | IF( lk_zdfkpp ) CALL zdf_kpp( kstp ) ! KPP closure scheme for Kz |
|---|
| 124 | IF( lk_zdfcst ) THEN ! Constant Kz (reset avt, avm[uv] to the background value) |
|---|
| 125 | avt (:,:,:) = rn_avt0 * tmask(:,:,:) |
|---|
| 126 | avmu(:,:,:) = rn_avm0 * umask(:,:,:) |
|---|
| 127 | avmv(:,:,:) = rn_avm0 * vmask(:,:,:) |
|---|
| 128 | ENDIF |
|---|
| 129 | IF( ln_rnf_mouth ) THEN ! increase diffusivity at rivers mouths |
|---|
| 130 | DO jk = 2, nkrnf ; avt(:,:,jk) = avt(:,:,jk) + 2.e0 * rn_avt_rnf * rnfmsk(:,:) * tmask(:,:,jk) ; END DO |
|---|
| 131 | ENDIF |
|---|
| 132 | IF( ln_zdfevd ) CALL zdf_evd( kstp ) ! enhanced vertical eddy diffusivity |
|---|
| 133 | |
|---|
| 134 | IF( lk_zdftmx ) CALL zdf_tmx( kstp ) ! tidal vertical mixing |
|---|
| 135 | |
|---|
| 136 | IF( lk_zdfddm .AND. .NOT. lk_zdfkpp ) & |
|---|
| 137 | & CALL zdf_ddm( kstp ) ! double diffusive mixing |
|---|
| 138 | |
|---|
| 139 | CALL zdf_mxl( kstp ) ! mixed layer depth |
|---|
| 140 | |
|---|
| 141 | ! write TKE or GLS information in the restart file |
|---|
| 142 | IF( lrst_oce .AND. lk_zdftke ) CALL tke_rst( kstp, 'WRITE' ) |
|---|
| 143 | IF( lrst_oce .AND. lk_zdfgls ) CALL gls_rst( kstp, 'WRITE' ) |
|---|
| 144 | ! |
|---|
| 145 | ! LATERAL PHYSICS |
|---|
| 146 | ! |
|---|
| 147 | IF( lk_ldfslp ) THEN ! slope of lateral mixing |
|---|
| 148 | CALL eos( tsb, rhd, gdept_0(:,:,:) ) ! before in situ density |
|---|
| 149 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsb, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 150 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 151 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 152 | IF( ln_traldf_grif ) THEN ! before slope for Griffies operator |
|---|
| 153 | CALL ldf_slp_grif( kstp ) |
|---|
| 154 | ELSE |
|---|
| 155 | CALL iom_put("rabt",rab_n(:,:,:,jp_tem)) |
|---|
| 156 | CALL iom_put("rabs",rab_n(:,:,:,jp_sal)) |
|---|
| 157 | CALL iom_put("rhd",rhd) |
|---|
| 158 | CALL iom_put("rn2b",rn2b) |
|---|
| 159 | CALL ldf_slp( kstp, rhd, rn2b ) ! before slope for Madec operator |
|---|
| 160 | ENDIF |
|---|
| 161 | ENDIF |
|---|
| 162 | #if defined key_traldf_c2d |
|---|
| 163 | IF( lk_traldf_eiv ) CALL ldf_eiv( kstp ) ! eddy induced velocity coefficient |
|---|
| 164 | #endif |
|---|
| 165 | #if defined key_traldf_c3d && key_traldf_smag |
|---|
| 166 | CALL ldf_tra_smag( kstp ) ! eddy induced velocity coefficient |
|---|
| 167 | # endif |
|---|
| 168 | #if defined key_dynldf_c3d && key_dynldf_smag |
|---|
| 169 | CALL ldf_dyn_smag( kstp ) ! eddy induced velocity coefficient |
|---|
| 170 | # endif |
|---|
| 171 | |
|---|
| 172 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 173 | ! Ocean dynamics : hdiv, rot, ssh, e3, wn |
|---|
| 174 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 175 | CALL ssh_nxt ( kstp ) ! after ssh (includes call to div_cur) |
|---|
| 176 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp ) ! after vertical scale factors |
|---|
| 177 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 178 | |
|---|
| 179 | IF( lk_dynspg_ts ) THEN |
|---|
| 180 | ! In case the time splitting case, update almost all momentum trends here: |
|---|
| 181 | ! Note that the computation of vertical velocity above, hence "after" sea level |
|---|
| 182 | ! is necessary to compute momentum advection for the rhs of barotropic loop: |
|---|
| 183 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 184 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 185 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 186 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 187 | |
|---|
| 188 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 189 | va(:,:,:) = 0.e0 |
|---|
| 190 | IF( ln_asmiau .AND. & |
|---|
| 191 | & ln_dyninc ) CALL dyn_asm_inc ( kstp ) ! apply dynamics assimilation increment |
|---|
| 192 | IF( ln_neptsimp ) CALL dyn_nept_cor ( kstp ) ! subtract Neptune velocities (simplified) |
|---|
| 193 | IF( lk_bdy ) CALL bdy_dyn3d_dmp( kstp ) ! bdy damping trends |
|---|
| 194 | CALL dyn_adv ( kstp ) ! advection (vector or flux form) |
|---|
| 195 | CALL dyn_vor ( kstp ) ! vorticity term including Coriolis |
|---|
| 196 | CALL dyn_ldf ( kstp ) ! lateral mixing |
|---|
| 197 | IF( ln_neptsimp ) CALL dyn_nept_cor ( kstp ) ! add Neptune velocities (simplified) |
|---|
| 198 | #if defined key_agrif |
|---|
| 199 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momentum sponge |
|---|
| 200 | #endif |
|---|
| 201 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 202 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 203 | |
|---|
| 204 | ua_sv(:,:,:) = ua(:,:,:) ! Save trends (barotropic trend has been fully updated at this stage) |
|---|
| 205 | va_sv(:,:,:) = va(:,:,:) |
|---|
| 206 | |
|---|
| 207 | CALL div_cur( kstp ) ! Horizontal divergence & Relative vorticity (2nd call in time-split case) |
|---|
| 208 | IF( lk_vvl ) CALL dom_vvl_sf_nxt( kstp, kcall=2 ) ! after vertical scale factors (update depth average component) |
|---|
| 209 | CALL wzv ( kstp ) ! now cross-level velocity |
|---|
| 210 | ENDIF |
|---|
| 211 | |
|---|
| 212 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 213 | ! diagnostics and outputs (ua, va, tsa used as workspace) |
|---|
| 214 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 215 | IF( lk_floats ) CALL flo_stp( kstp ) ! drifting Floats |
|---|
| 216 | IF( lk_diahth ) CALL dia_hth( kstp ) ! Thermocline depth (20 degres isotherm depth) |
|---|
| 217 | IF( .NOT. lk_cpl ) CALL dia_fwb( kstp ) ! Fresh water budget diagnostics |
|---|
| 218 | IF( ln_diaptr ) CALL dia_ptr( kstp ) ! Poleward TRansports diagnostics |
|---|
| 219 | IF( lk_diadct ) CALL dia_dct( kstp ) ! Transports |
|---|
| 220 | IF( lk_diaar5 ) CALL dia_ar5( kstp ) ! ar5 diag |
|---|
| 221 | IF( lk_diaharm ) CALL dia_harm( kstp ) ! Tidal harmonic analysis |
|---|
| 222 | CALL dia_wri( kstp ) ! ocean model: outputs |
|---|
| 223 | ! |
|---|
| 224 | IF( ln_crs ) CALL crs_fld( kstp ) ! ocean model: online field coarsening & output |
|---|
| 225 | |
|---|
| 226 | |
|---|
| 227 | #if defined key_top |
|---|
| 228 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 229 | ! Passive Tracer Model |
|---|
| 230 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 231 | IF( ln_crs ) THEN |
|---|
| 232 | CALL dom_grid_crs |
|---|
| 233 | |
|---|
| 234 | CALL eos_rab_crs( tsn_crs, rab_crs_n ) ! now local thermal/haline expension ratio at T-points |
|---|
| 235 | CALL bn2_crs ( tsn_crs, rab_crs_n, rb2_crs ) ! now Brunt-Vaisala frequency |
|---|
| 236 | CALL eos_crs ( tsn_crs, rhd_crs, rhop_crs, gdept_crs(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 237 | |
|---|
| 238 | IF( ln_zps ) CALL zps_hde_crs( kstp, jpts, tsb_crs, gtsu_crs, gtsv_crs, rhd_crs, gru_crs, grv_crs ) |
|---|
| 239 | |
|---|
| 240 | IF( lk_ldfslp .AND. .NOT. ln_traldf_grif ) & |
|---|
| 241 | CALL ldf_slp_crs( kstp, rhd_crs, rb2_crs ) |
|---|
| 242 | CALL dom_grid_glo |
|---|
| 243 | |
|---|
| 244 | ENDIF |
|---|
| 245 | CALL zdf_mxl_crs(kstp) |
|---|
| 246 | |
|---|
| 247 | IF( ln_crs_top ) CALL dom_grid_crs |
|---|
| 248 | |
|---|
| 249 | CALL trc_stp( kstp ) ! time-stepping |
|---|
| 250 | |
|---|
| 251 | IF( ln_crs_top ) CALL dom_grid_glo |
|---|
| 252 | #endif |
|---|
| 253 | |
|---|
| 254 | |
|---|
| 255 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 256 | ! Active tracers (ua, va used as workspace) |
|---|
| 257 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 258 | tsa(:,:,:,:) = 0.e0 ! set tracer trends to zero |
|---|
| 259 | |
|---|
| 260 | IF( ln_asmiau .AND. & |
|---|
| 261 | & ln_trainc ) CALL tra_asm_inc( kstp ) ! apply tracer assimilation increment |
|---|
| 262 | CALL tra_sbc ( kstp ) ! surface boundary condition |
|---|
| 263 | IF( ln_traqsr ) CALL tra_qsr ( kstp ) ! penetrative solar radiation qsr |
|---|
| 264 | IF( ln_trabbc ) CALL tra_bbc ( kstp ) ! bottom heat flux |
|---|
| 265 | IF( lk_trabbl ) CALL tra_bbl ( kstp ) ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 266 | IF( ln_tradmp ) CALL tra_dmp ( kstp ) ! internal damping trends |
|---|
| 267 | IF( lk_bdy ) CALL bdy_tra_dmp( kstp ) ! bdy damping trends |
|---|
| 268 | CALL tra_adv ( kstp ) ! horizontal & vertical advection |
|---|
| 269 | IF( lk_zdfkpp ) CALL tra_kpp ( kstp ) ! KPP non-local tracer fluxes |
|---|
| 270 | CALL tra_ldf ( kstp ) ! lateral mixing |
|---|
| 271 | #if defined key_agrif |
|---|
| 272 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_tra ! tracers sponge |
|---|
| 273 | #endif |
|---|
| 274 | CALL tra_zdf ( kstp ) ! vertical mixing and after tracer fields |
|---|
| 275 | |
|---|
| 276 | IF( ln_dynhpg_imp ) THEN ! semi-implicit hpg (time stepping then eos) |
|---|
| 277 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 278 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 279 | CALL eos ( tsa, rhd, rhop, fsdept_n(:,:,:) ) ! Time-filtered in situ density for hpg computation |
|---|
| 280 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsa, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 281 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 282 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 283 | ELSE ! centered hpg (eos then time stepping) |
|---|
| 284 | IF ( .NOT. lk_dynspg_ts ) THEN ! eos already called in time-split case |
|---|
| 285 | CALL eos ( tsn, rhd, rhop, fsdept_n(:,:,:) ) ! now in situ density for hpg computation |
|---|
| 286 | IF( ln_zps ) CALL zps_hde( kstp, jpts, tsn, gtsu, gtsv, & ! Partial steps: before horizontal gradient |
|---|
| 287 | & rhd, gru , grv , aru , arv , gzu , gzv , ge3ru , ge3rv , & ! |
|---|
| 288 | & gtui, gtvi, grui, grvi, arui, arvi, gzui, gzvi, ge3rui, ge3rvi ) ! of t, s, rd at the last ocean level |
|---|
| 289 | ENDIF |
|---|
| 290 | IF( ln_zdfnpc ) CALL tra_npc( kstp ) ! update after fields by non-penetrative convection |
|---|
| 291 | CALL tra_nxt( kstp ) ! tracer fields at next time step |
|---|
| 292 | ENDIF |
|---|
| 293 | |
|---|
| 294 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 295 | ! Dynamics (tsa used as workspace) |
|---|
| 296 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 297 | IF( lk_dynspg_ts ) THEN |
|---|
| 298 | ! revert to previously computed momentum tendencies |
|---|
| 299 | ! (not using ua, va as temporary arrays during tracers' update could avoid that) |
|---|
| 300 | ua(:,:,:) = ua_sv(:,:,:) |
|---|
| 301 | va(:,:,:) = va_sv(:,:,:) |
|---|
| 302 | ! Revert now divergence and rotational to previously computed ones |
|---|
| 303 | !(needed because of the time swap in div_cur, at the beginning of each time step) |
|---|
| 304 | hdivn(:,:,:) = hdivb(:,:,:) |
|---|
| 305 | rotn(:,:,:) = rotb(:,:,:) |
|---|
| 306 | |
|---|
| 307 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 308 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 309 | ELSE |
|---|
| 310 | ua(:,:,:) = 0.e0 ! set dynamics trends to zero |
|---|
| 311 | va(:,:,:) = 0.e0 |
|---|
| 312 | |
|---|
| 313 | IF( ln_asmiau .AND. & |
|---|
| 314 | & ln_dyninc ) CALL dyn_asm_inc( kstp ) ! apply dynamics assimilation increment |
|---|
| 315 | IF( ln_bkgwri ) CALL asm_bkg_wri( kstp ) ! output background fields |
|---|
| 316 | IF( ln_neptsimp ) CALL dyn_nept_cor( kstp ) ! subtract Neptune velocities (simplified) |
|---|
| 317 | IF( lk_bdy ) CALL bdy_dyn3d_dmp(kstp ) ! bdy damping trends |
|---|
| 318 | CALL dyn_adv( kstp ) ! advection (vector or flux form) |
|---|
| 319 | CALL dyn_vor( kstp ) ! vorticity term including Coriolis |
|---|
| 320 | CALL dyn_ldf( kstp ) ! lateral mixing |
|---|
| 321 | IF( ln_neptsimp ) CALL dyn_nept_cor( kstp ) ! add Neptune velocities (simplified) |
|---|
| 322 | #if defined key_agrif |
|---|
| 323 | IF(.NOT. Agrif_Root()) CALL Agrif_Sponge_dyn ! momemtum sponge |
|---|
| 324 | #endif |
|---|
| 325 | CALL dyn_hpg( kstp ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 326 | CALL dyn_bfr( kstp ) ! bottom friction |
|---|
| 327 | CALL dyn_zdf( kstp ) ! vertical diffusion |
|---|
| 328 | CALL dyn_spg( kstp, indic ) ! surface pressure gradient |
|---|
| 329 | ENDIF |
|---|
| 330 | CALL dyn_nxt( kstp ) ! lateral velocity at next time step |
|---|
| 331 | |
|---|
| 332 | CALL ssh_swp( kstp ) ! swap of sea surface height |
|---|
| 333 | IF( lk_vvl ) CALL dom_vvl_sf_swp( kstp ) ! swap of vertical scale factors |
|---|
| 334 | |
|---|
| 335 | IF( ln_diahsb ) CALL dia_hsb( kstp ) ! - ML - global conservation diagnostics |
|---|
| 336 | IF( lk_diaobs ) CALL dia_obs( kstp ) ! obs-minus-model (assimilation) diagnostics (call after dynamics update) |
|---|
| 337 | |
|---|
| 338 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 339 | ! Control and restarts |
|---|
| 340 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 341 | CALL stp_ctl( kstp, indic ) |
|---|
| 342 | IF( indic < 0 ) THEN |
|---|
| 343 | CALL ctl_stop( 'step: indic < 0' ) |
|---|
| 344 | CALL dia_wri_state( 'output.abort', kstp ) |
|---|
| 345 | ENDIF |
|---|
| 346 | IF( kstp == nit000 ) THEN |
|---|
| 347 | CALL iom_close( numror ) ! close input ocean restart file |
|---|
| 348 | IF(lwm) CALL FLUSH ( numond ) ! flush output namelist oce |
|---|
| 349 | IF(lwm) CALL FLUSH ( numoni ) ! flush output namelist ice |
|---|
| 350 | ENDIF |
|---|
| 351 | IF( lrst_oce ) CALL rst_write ( kstp ) ! write output ocean restart file |
|---|
| 352 | |
|---|
| 353 | !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> |
|---|
| 354 | ! Coupled mode |
|---|
| 355 | !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< |
|---|
| 356 | IF( lk_cpl ) CALL sbc_cpl_snd( kstp ) ! coupled mode : field exchanges |
|---|
| 357 | ! |
|---|
| 358 | #if defined key_iomput |
|---|
| 359 | IF( kstp == nitend .OR. indic < 0 ) THEN |
|---|
| 360 | CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF |
|---|
| 361 | IF( ln_crs ) CALL iom_context_finalize( "nemo_crs" ) ! |
|---|
| 362 | ENDIF |
|---|
| 363 | #endif |
|---|
| 364 | ! |
|---|
| 365 | IF( nn_timing == 1 .AND. kstp == nit000 ) CALL timing_reset |
|---|
| 366 | ! |
|---|
| 367 | END SUBROUTINE stp |
|---|
| 368 | |
|---|
| 369 | !!====================================================================== |
|---|
| 370 | END MODULE step |
|---|
