New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zprod.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/TOP_SRC/PISCES/P4Z/p4zprod.F90 @ 7256

Last change on this file since 7256 was 7256, checked in by cbricaud, 7 years ago

phaze NEMO routines in CRS branch with nemo_v3_6_STABLE branch at rev 7213 (09-09-2016) (merge -r 5519:7213 )

File size: 30.1 KB
Line 
1MODULE p4zprod
2   !!======================================================================
3   !!                         ***  MODULE p4zprod  ***
4   !! TOP :  Growth Rate of the two phytoplanktons groups
5   !!======================================================================
6   !! History :   1.0  !  2004     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-05  (O. Aumont, C. Ethe) New parameterization of light limitation
9   !!----------------------------------------------------------------------
10#if defined key_pisces
11   !!----------------------------------------------------------------------
12   !!   'key_pisces'                                       PISCES bio-model
13   !!----------------------------------------------------------------------
14   !!   p4z_prod       :   Compute the growth Rate of the two phytoplanktons groups
15   !!   p4z_prod_init  :   Initialization of the parameters for growth
16   !!   p4z_prod_alloc :   Allocate variables for growth
17   !!----------------------------------------------------------------------
18   USE oce_trc         !  shared variables between ocean and passive tracers
19   USE trc             !  passive tracers common variables
20   USE sms_pisces      !  PISCES Source Minus Sink variables
21   USE p4zopt          !  optical model
22   USE p4zlim          !  Co-limitations of differents nutrients
23   USE prtctl_trc      !  print control for debugging
24   USE iom             !  I/O manager
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   p4z_prod         ! called in p4zbio.F90
30   PUBLIC   p4z_prod_init    ! called in trcsms_pisces.F90
31   PUBLIC   p4z_prod_alloc
32
33   !! * Shared module variables
34   LOGICAL , PUBLIC ::  ln_newprod      !:
35   REAL(wp), PUBLIC ::  pislope         !:
36   REAL(wp), PUBLIC ::  pislope2        !:
37   REAL(wp), PUBLIC ::  xadap           !:
38   REAL(wp), PUBLIC ::  excret          !:
39   REAL(wp), PUBLIC ::  excret2         !:
40   REAL(wp), PUBLIC ::  bresp           !:
41   REAL(wp), PUBLIC ::  chlcnm          !:
42   REAL(wp), PUBLIC ::  chlcdm          !:
43   REAL(wp), PUBLIC ::  chlcmin         !:
44   REAL(wp), PUBLIC ::  fecnm           !:
45   REAL(wp), PUBLIC ::  fecdm           !:
46   REAL(wp), PUBLIC ::  grosip          !:
47
48   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   prmax    !: optimal production = f(temperature)
49   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotan   !: proxy of N quota in Nanophyto
50   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   quotad   !: proxy of N quota in diatomee
51   
52   REAL(wp) :: r1_rday                !: 1 / rday
53   REAL(wp) :: texcret                !: 1 - excret
54   REAL(wp) :: texcret2               !: 1 - excret2       
55
56
57   !!* Substitution
58#  include "top_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
61   !! $Id: p4zprod.F90 3160 2011-11-20 14:27:18Z cetlod $
62   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66   SUBROUTINE p4z_prod( kt , knt )
67      !!---------------------------------------------------------------------
68      !!                     ***  ROUTINE p4z_prod  ***
69      !!
70      !! ** Purpose :   Compute the phytoplankton production depending on
71      !!              light, temperature and nutrient availability
72      !!
73      !! ** Method  : - ???
74      !!---------------------------------------------------------------------
75      !
76      INTEGER, INTENT(in) :: kt, knt
77      !
78      INTEGER  ::   ji, jj, jk
79      REAL(wp) ::   zsilfac, znanotot, zdiattot, zconctemp, zconctemp2
80      REAL(wp) ::   zratio, zmax, zsilim, ztn, zadap
81      REAL(wp) ::   zlim, zsilfac2, zsiborn, zprod, zproreg, zproreg2
82      REAL(wp) ::   zmxltst, zmxlday, zmaxday
83      REAL(wp) ::   zpislopen  , zpislope2n
84      REAL(wp) ::   zrum, zcodel, zargu, zval
85      REAL(wp) ::   zfact
86      CHARACTER (len=25) :: charout
87      REAL(wp), POINTER, DIMENSION(:,:  ) :: zmixnano, zmixdiat, zstrn, zw2d
88      REAL(wp), POINTER, DIMENSION(:,:,:) :: zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt, zw3d   
89      REAL(wp), POINTER, DIMENSION(:,:,:) :: zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd
90      !!---------------------------------------------------------------------
91      !
92      IF( nn_timing == 1 )  CALL timing_start('p4z_prod')
93      !
94      !  Allocate temporary workspace
95      CALL wrk_alloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
96      CALL wrk_alloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
97      CALL wrk_alloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
98      !
99      zprorca (:,:,:) = 0._wp
100      zprorcad(:,:,:) = 0._wp
101      zprofed (:,:,:) = 0._wp
102      zprofen (:,:,:) = 0._wp
103      zprochln(:,:,:) = 0._wp
104      zprochld(:,:,:) = 0._wp
105      zpronew (:,:,:) = 0._wp
106      zpronewd(:,:,:) = 0._wp
107      zprdia  (:,:,:) = 0._wp
108      zprbio  (:,:,:) = 0._wp
109      zprdch  (:,:,:) = 0._wp
110      zprnch  (:,:,:) = 0._wp
111      zysopt  (:,:,:) = 0._wp
112
113      ! Computation of the optimal production
114      prmax(:,:,:) = 0.6_wp * r1_rday * tgfunc(:,:,:) 
115      IF( lk_degrad )  prmax(:,:,:) = prmax(:,:,:) * facvol(:,:,:) 
116
117      ! compute the day length depending on latitude and the day
118      zrum = REAL( nday_year - 80, wp ) / REAL( nyear_len(1), wp )
119      zcodel = ASIN(  SIN( zrum * rpi * 2._wp ) * SIN( rad * 23.5_wp )  )
120
121      ! day length in hours
122      zstrn(:,:) = 0.
123      DO jj = 1, jpj
124         DO ji = 1, jpi
125            zargu = TAN( zcodel ) * TAN( gphit(ji,jj) * rad )
126            zargu = MAX( -1., MIN(  1., zargu ) )
127            zstrn(ji,jj) = MAX( 0.0, 24. - 2. * ACOS( zargu ) / rad / 15. )
128         END DO
129      END DO
130
131      ! Impact of the day duration on phytoplankton growth
132      DO jk = 1, jpkm1
133         DO jj = 1 ,jpj
134            DO ji = 1, jpi
135               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
136                  zval = MAX( 1., zstrn(ji,jj) )
137                  zval = 1.5 * zval / ( 12. + zval )
138                  zprbio(ji,jj,jk) = prmax(ji,jj,jk) * zval
139                  zprdia(ji,jj,jk) = zprbio(ji,jj,jk)
140               ENDIF
141            END DO
142         END DO
143      END DO
144
145      ! Maximum light intensity
146      WHERE( zstrn(:,:) < 1.e0 ) zstrn(:,:) = 24.
147      zstrn(:,:) = 24. / zstrn(:,:)
148
149      IF( ln_newprod ) THEN
150!CDIR NOVERRCHK
151         DO jk = 1, jpkm1
152!CDIR NOVERRCHK
153            DO jj = 1, jpj
154!CDIR NOVERRCHK
155               DO ji = 1, jpi
156                  ! Computation of the P-I slope for nanos and diatoms
157                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
158                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
159                      zadap       = xadap * ztn / ( 2.+ ztn )
160                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
161                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
162                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
163                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
164                      !
165                      zpislopead (ji,jj,jk) = pislope * ( 1.+ zadap  * EXP( -znanotot ) )  &
166                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
167                      !
168                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp) / ( trb(ji,jj,jk,jpdia) + rtrn )   &
169                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
170
171                      ! Computation of production function for Carbon
172                      !  ---------------------------------------------
173                      zpislopen  = zpislopead (ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
174                      zpislope2n = zpislopead2(ji,jj,jk) / ( ( r1_rday + bresp * r1_rday ) * rday + rtrn)
175                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot )  )
176                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot )  )
177
178                      !  Computation of production function for Chlorophyll
179                      !--------------------------------------------------
180                      zmaxday  = 1._wp / ( prmax(ji,jj,jk) * rday + rtrn )
181                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead (ji,jj,jk) * zmaxday * znanotot ) )
182                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopead2(ji,jj,jk) * zmaxday * zdiattot ) )
183                  ENDIF
184               END DO
185            END DO
186         END DO
187      ELSE
188!CDIR NOVERRCHK
189         DO jk = 1, jpkm1
190!CDIR NOVERRCHK
191            DO jj = 1, jpj
192!CDIR NOVERRCHK
193               DO ji = 1, jpi
194
195                  ! Computation of the P-I slope for nanos and diatoms
196                  IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
197                      ztn         = MAX( 0., tsn(ji,jj,jk,jp_tem) - 15. )
198                      zadap       = ztn / ( 2.+ ztn )
199                      zconctemp   = MAX( 0.e0 , trb(ji,jj,jk,jpdia) - xsizedia )
200                      zconctemp2  = trb(ji,jj,jk,jpdia) - zconctemp
201                      znanotot    = enano(ji,jj,jk) * zstrn(ji,jj)
202                      zdiattot    = ediat(ji,jj,jk) * zstrn(ji,jj)
203                      !
204                      zpislopead (ji,jj,jk) = pislope  * ( 1.+ zadap  * EXP( -znanotot ) )           &
205                         &                   * trb(ji,jj,jk,jpnch) /( trb(ji,jj,jk,jpphy) * 12. + rtrn)
206                      zpislopead2(ji,jj,jk) = (pislope * zconctemp2 + pislope2 * zconctemp)  / ( trb(ji,jj,jk,jpdia) + rtrn )   &
207                         &                   * trb(ji,jj,jk,jpdch) /( trb(ji,jj,jk,jpdia) * 12. + rtrn)
208
209                      ! Computation of production function for Carbon
210                      !  ---------------------------------------------
211                      zpislopen  =  zpislopead(ji,jj,jk)  / ( prmax(ji,jj,jk) * rday * xlimphy(ji,jj,jk) + rtrn )
212                      zpislope2n =  zpislopead2(ji,jj,jk) / ( prmax(ji,jj,jk) * rday * xlimdia(ji,jj,jk) + rtrn )
213                      zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
214                      zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
215
216                      !  Computation of production function for Chlorophyll
217                      !--------------------------------------------------
218                      zprnch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislopen  * znanotot ) )
219                      zprdch(ji,jj,jk) = prmax(ji,jj,jk) * ( 1.- EXP( -zpislope2n * zdiattot ) )
220                  ENDIF
221               END DO
222            END DO
223         END DO
224      ENDIF
225     
226      !  Computation of a proxy of the N/C ratio
227      !  ---------------------------------------
228!CDIR NOVERRCHK
229      DO jk = 1, jpkm1
230!CDIR NOVERRCHK
231         DO jj = 1, jpj
232!CDIR NOVERRCHK
233            DO ji = 1, jpi
234                zval = MIN( xnanopo4(ji,jj,jk), ( xnanonh4(ji,jj,jk) + xnanono3(ji,jj,jk) ) )   &
235                &      * prmax(ji,jj,jk) / ( zprbio(ji,jj,jk) + rtrn )
236                quotan(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
237                zval = MIN( xdiatpo4(ji,jj,jk), ( xdiatnh4(ji,jj,jk) + xdiatno3(ji,jj,jk) ) )   &
238                &      * prmax(ji,jj,jk) / ( zprdia(ji,jj,jk) + rtrn )
239                quotad(ji,jj,jk) = MIN( 1., 0.2 + 0.8 * zval )
240            END DO
241         END DO
242      END DO
243
244
245      DO jk = 1, jpkm1
246         DO jj = 1, jpj
247            DO ji = 1, jpi
248
249                IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
250                   !    Si/C of diatoms
251                   !    ------------------------
252                   !    Si/C increases with iron stress and silicate availability
253                   !    Si/C is arbitrariliy increased for very high Si concentrations
254                   !    to mimic the very high ratios observed in the Southern Ocean (silpot2)
255                  zlim  = trb(ji,jj,jk,jpsil) / ( trb(ji,jj,jk,jpsil) + xksi1 )
256                  zsilim = MIN( zprdia(ji,jj,jk) / ( prmax(ji,jj,jk) + rtrn ), xlimsi(ji,jj,jk) )
257                  zsilfac = 4.4 * EXP( -4.23 * zsilim ) * MAX( 0.e0, MIN( 1., 2.2 * ( zlim - 0.5 ) )  ) + 1.e0
258                  zsiborn = trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil) * trb(ji,jj,jk,jpsil)
259                  IF (gphit(ji,jj) < -30 ) THEN
260                    zsilfac2 = 1. + 2. * zsiborn / ( zsiborn + xksi2**3 )
261                  ELSE
262                    zsilfac2 = 1. +      zsiborn / ( zsiborn + xksi2**3 )
263                  ENDIF
264                  zysopt(ji,jj,jk) = grosip * zlim * zsilfac * zsilfac2
265              ENDIF
266            END DO
267         END DO
268      END DO
269
270      !  Computation of the limitation term due to a mixed layer deeper than the euphotic depth
271      DO jj = 1, jpj
272         DO ji = 1, jpi
273            zmxltst = MAX( 0.e0, hmld(ji,jj) - heup(ji,jj) )
274            zmxlday = zmxltst * zmxltst * r1_rday
275            zmixnano(ji,jj) = 1. - zmxlday / ( 1. + zmxlday )
276            zmixdiat(ji,jj) = 1. - zmxlday / ( 2. + zmxlday )
277         END DO
278      END DO
279 
280      !  Mixed-layer effect on production
281      !  Sea-ice effect on production
282
283      DO jk = 1, jpkm1
284         DO jj = 1, jpj
285            DO ji = 1, jpi
286               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
287                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * zmixnano(ji,jj)
288                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * zmixdiat(ji,jj)
289               ENDIF
290                  zprbio(ji,jj,jk) = zprbio(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
291                  zprdia(ji,jj,jk) = zprdia(ji,jj,jk) * ( 1. - fr_i(ji,jj) )
292            END DO
293         END DO
294      END DO
295
296      ! Computation of the various production terms
297!CDIR NOVERRCHK
298      DO jk = 1, jpkm1
299!CDIR NOVERRCHK
300         DO jj = 1, jpj
301!CDIR NOVERRCHK
302            DO ji = 1, jpi
303               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
304                  !  production terms for nanophyto.
305                  zprorca(ji,jj,jk) = zprbio(ji,jj,jk)  * xlimphy(ji,jj,jk) * trb(ji,jj,jk,jpphy) * rfact2
306                  zpronew(ji,jj,jk) = zprorca(ji,jj,jk) * xnanono3(ji,jj,jk) / ( xnanono3(ji,jj,jk) + xnanonh4(ji,jj,jk) + rtrn )
307                  !
308                  zratio = trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn )
309                  zratio = zratio / fecnm 
310                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
311                  zprofen(ji,jj,jk) = fecnm * prmax(ji,jj,jk)  &
312                  &             * ( 4. - 4.5 * xlimnfe(ji,jj,jk) / ( xlimnfe(ji,jj,jk) + 0.5 ) )    &
313                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concnfe(ji,jj,jk) )  &
314                  &             * zmax * trb(ji,jj,jk,jpphy) * rfact2
315                  !  production terms for diatomees
316                  zprorcad(ji,jj,jk) = zprdia(ji,jj,jk) * xlimdia(ji,jj,jk) * trb(ji,jj,jk,jpdia) * rfact2
317                  zpronewd(ji,jj,jk) = zprorcad(ji,jj,jk) * xdiatno3(ji,jj,jk) / ( xdiatno3(ji,jj,jk) + xdiatnh4(ji,jj,jk) + rtrn )
318                  !
319                  zratio = trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn )
320                  zratio = zratio / fecdm 
321                  zmax   = MAX( 0., ( 1. - zratio ) / ABS( 1.05 - zratio ) ) 
322                  zprofed(ji,jj,jk) = fecdm * prmax(ji,jj,jk)  &
323                  &             * ( 4. - 4.5 * xlimdfe(ji,jj,jk) / ( xlimdfe(ji,jj,jk) + 0.5 ) )    &
324                  &             * biron(ji,jj,jk) / ( biron(ji,jj,jk) + concdfe(ji,jj,jk) )  &
325                  &             * zmax * trb(ji,jj,jk,jpdia) * rfact2
326               ENDIF
327            END DO
328         END DO
329      END DO
330
331!CDIR NOVERRCHK
332      DO jk = 1, jpkm1
333!CDIR NOVERRCHK
334         DO jj = 1, jpj
335!CDIR NOVERRCHK
336            DO ji = 1, jpi
337               IF( fsdepw(ji,jj,jk+1) <= hmld(ji,jj) ) THEN
338                  zprnch(ji,jj,jk) = zprnch(ji,jj,jk) * zmixnano(ji,jj)
339                  zprdch(ji,jj,jk) = zprdch(ji,jj,jk) * zmixdiat(ji,jj)
340               ENDIF
341               IF( etot_ndcy(ji,jj,jk) > 1.E-3 ) THEN
342                  !  production terms for nanophyto. ( chlorophyll )
343                  znanotot = enano(ji,jj,jk) * zstrn(ji,jj)
344                  zprod    = rday * zprorca(ji,jj,jk) * zprnch(ji,jj,jk) * xlimphy(ji,jj,jk)
345                  zprochln(ji,jj,jk) = chlcmin * 12. * zprorca (ji,jj,jk)
346                  zprochln(ji,jj,jk) = zprochln(ji,jj,jk) + (chlcnm-chlcmin) * 12. * zprod / &
347                                     & (  zpislopead(ji,jj,jk) * znanotot +rtrn)
348                  !  production terms for diatomees ( chlorophyll )
349                  zdiattot = ediat(ji,jj,jk) * zstrn(ji,jj)
350                  zprod = rday * zprorcad(ji,jj,jk) * zprdch(ji,jj,jk) * xlimdia(ji,jj,jk)
351                  zprochld(ji,jj,jk) = chlcmin * 12. * zprorcad(ji,jj,jk)
352                  zprochld(ji,jj,jk) = zprochld(ji,jj,jk) + (chlcdm-chlcmin) * 12. * zprod / &
353                                     & ( zpislopead2(ji,jj,jk) * zdiattot +rtrn )
354               ENDIF
355            END DO
356         END DO
357      END DO
358
359      !   Update the arrays TRA which contain the biological sources and sinks
360      DO jk = 1, jpkm1
361         DO jj = 1, jpj
362           DO ji =1 ,jpi
363              zproreg  = zprorca(ji,jj,jk) - zpronew(ji,jj,jk)
364              zproreg2 = zprorcad(ji,jj,jk) - zpronewd(ji,jj,jk)
365              tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
366              tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) - zpronew(ji,jj,jk) - zpronewd(ji,jj,jk)
367              tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) - zproreg - zproreg2
368              tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) + zprorca(ji,jj,jk) * texcret
369              tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) + zprochln(ji,jj,jk) * texcret
370              tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) + zprofen(ji,jj,jk) * texcret
371              tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) + zprorcad(ji,jj,jk) * texcret2
372              tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) + zprochld(ji,jj,jk) * texcret2
373              tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) + zprofed(ji,jj,jk) * texcret2
374              tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) + zprorcad(ji,jj,jk) * zysopt(ji,jj,jk) * texcret2
375              tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + excret2 * zprorcad(ji,jj,jk) + excret * zprorca(ji,jj,jk)
376              tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) + o2ut * ( zproreg + zproreg2) &
377                 &                + ( o2ut + o2nit ) * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) )
378              tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) - texcret * zprofen(ji,jj,jk) - texcret2 * zprofed(ji,jj,jk)
379              tra(ji,jj,jk,jpsil) = tra(ji,jj,jk,jpsil) - texcret2 * zprorcad(ji,jj,jk) * zysopt(ji,jj,jk)
380              tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) - zprorca(ji,jj,jk) - zprorcad(ji,jj,jk)
381              tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * ( zpronew(ji,jj,jk) + zpronewd(ji,jj,jk) ) &
382                 &                                      - rno3 * ( zproreg + zproreg2 )
383          END DO
384        END DO
385     END DO
386
387
388    ! Total primary production per year
389    IF( iom_use( "tintpp" ) .OR. ( ln_check_mass .AND. kt == nitend .AND. knt == nrdttrc )  )  &
390         & tpp = glob_sum( ( zprorca(:,:,:) + zprorcad(:,:,:) ) * cvol(:,:,:) )
391
392    IF( lk_iomput ) THEN
393       IF( knt == nrdttrc ) THEN
394          CALL wrk_alloc( jpi, jpj,      zw2d )
395          CALL wrk_alloc( jpi, jpj, jpk, zw3d )
396          zfact = 1.e+3 * rfact2r  !  conversion from mol/l/kt to  mol/m3/s
397          !
398          IF( iom_use( "PPPHY" ) .OR. iom_use( "PPPHY2" ) )  THEN
399              zw3d(:,:,:) = zprorca (:,:,:) * zfact * tmask(:,:,:)  ! primary production by nanophyto
400              CALL iom_put( "PPPHY"  , zw3d )
401              !
402              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:)  ! primary production by diatomes
403              CALL iom_put( "PPPHY2"  , zw3d )
404          ENDIF
405          IF( iom_use( "PPNEWN" ) .OR. iom_use( "PPNEWD" ) )  THEN
406              zw3d(:,:,:) = zpronew (:,:,:) * zfact * tmask(:,:,:)  ! new primary production by nanophyto
407              CALL iom_put( "PPNEWN"  , zw3d )
408              !
409              zw3d(:,:,:) = zpronewd(:,:,:) * zfact * tmask(:,:,:)  ! new primary production by diatomes
410              CALL iom_put( "PPNEWD"  , zw3d )
411          ENDIF
412          IF( iom_use( "PBSi" ) )  THEN
413              zw3d(:,:,:) = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:) ! biogenic silica production
414              CALL iom_put( "PBSi"  , zw3d )
415          ENDIF
416          IF( iom_use( "PFeN" ) .OR. iom_use( "PFeD" ) )  THEN
417              zw3d(:,:,:) = zprofen(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by nanophyto
418              CALL iom_put( "PFeN"  , zw3d )
419              !
420              zw3d(:,:,:) = zprofed(:,:,:) * zfact * tmask(:,:,:)  ! biogenic iron production by  diatomes
421              CALL iom_put( "PFeD"  , zw3d )
422          ENDIF
423          IF( iom_use( "Mumax" ) )  THEN
424              zw3d(:,:,:) = prmax(:,:,:) * tmask(:,:,:)   ! Maximum growth rate
425              CALL iom_put( "Mumax"  , zw3d )
426          ENDIF
427          IF( iom_use( "MuN" ) .OR. iom_use( "MuD" ) )  THEN
428              zw3d(:,:,:) = zprbio(:,:,:) * xlimphy(:,:,:) * tmask(:,:,:)  ! Realized growth rate for nanophyto
429              CALL iom_put( "MuN"  , zw3d )
430              !
431              zw3d(:,:,:) =  zprdia(:,:,:) * xlimdia(:,:,:) * tmask(:,:,:)  ! Realized growth rate for diatoms
432              CALL iom_put( "MuD"  , zw3d )
433          ENDIF
434          IF( iom_use( "LNlight" ) .OR. iom_use( "LDlight" ) )  THEN
435              zw3d(:,:,:) = zprbio (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:) ! light limitation term
436              CALL iom_put( "LNlight"  , zw3d )
437              !
438              zw3d(:,:,:) =  zprdia (:,:,:) / (prmax(:,:,:) + rtrn) * tmask(:,:,:)  ! light limitation term
439              CALL iom_put( "LDlight"  , zw3d )
440          ENDIF
441          IF( iom_use( "TPP" ) )  THEN
442              zw3d(:,:,:) = ( zprorca(:,:,:) + zprorcad(:,:,:) ) * zfact * tmask(:,:,:)  ! total primary production
443              CALL iom_put( "TPP"  , zw3d )
444          ENDIF
445          IF( iom_use( "TPNEW" ) )  THEN
446              zw3d(:,:,:) = ( zpronew(:,:,:) + zpronewd(:,:,:) ) * zfact * tmask(:,:,:)  ! total new production
447              CALL iom_put( "TPNEW"  , zw3d )
448          ENDIF
449          IF( iom_use( "TPBFE" ) )  THEN
450              zw3d(:,:,:) = ( zprofen(:,:,:) + zprofed(:,:,:) ) * zfact * tmask(:,:,:)  ! total biogenic iron production
451              CALL iom_put( "TPBFE"  , zw3d )
452          ENDIF
453          IF( iom_use( "INTPPPHY" ) .OR. iom_use( "INTPPPHY2" ) ) THEN 
454             zw2d(:,:) = 0.
455             DO jk = 1, jpkm1
456               zw2d(:,:) = zw2d(:,:) + zprorca (:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated  primary produc. by nano
457             ENDDO
458             CALL iom_put( "INTPPPHY" , zw2d )
459             !
460             zw2d(:,:) = 0.
461             DO jk = 1, jpkm1
462                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated  primary produc. by diatom
463             ENDDO
464             CALL iom_put( "INTPPPHY2" , zw2d )
465          ENDIF
466          IF( iom_use( "INTPP" ) ) THEN   
467             zw2d(:,:) = 0.
468             DO jk = 1, jpkm1
469                zw2d(:,:) = zw2d(:,:) + ( zprorca(:,:,jk) + zprorcad(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert. integrated pp
470             ENDDO
471             CALL iom_put( "INTPP" , zw2d )
472          ENDIF
473          IF( iom_use( "INTPNEW" ) ) THEN   
474             zw2d(:,:) = 0.
475             DO jk = 1, jpkm1
476                zw2d(:,:) = zw2d(:,:) + ( zpronew(:,:,jk) + zpronewd(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert. integrated new prod
477             ENDDO
478             CALL iom_put( "INTPNEW" , zw2d )
479          ENDIF
480          IF( iom_use( "INTPBFE" ) ) THEN           !   total biogenic iron production  ( vertically integrated )
481             zw2d(:,:) = 0.
482             DO jk = 1, jpkm1
483                zw2d(:,:) = zw2d(:,:) + ( zprofen(:,:,jk) + zprofed(:,:,jk) ) * fse3t(:,:,jk) * zfact * tmask(:,:,jk) ! vert integr. bfe prod
484             ENDDO
485            CALL iom_put( "INTPBFE" , zw2d )
486          ENDIF
487          IF( iom_use( "INTPBSI" ) ) THEN           !   total biogenic silica production  ( vertically integrated )
488             zw2d(:,:) = 0.
489             DO jk = 1, jpkm1
490                zw2d(:,:) = zw2d(:,:) + zprorcad(:,:,jk) * zysopt(:,:,jk) * fse3t(:,:,jk) * zfact * tmask(:,:,jk)  ! vert integr. bsi prod
491             ENDDO
492             CALL iom_put( "INTPBSI" , zw2d )
493          ENDIF
494          IF( iom_use( "tintpp" ) )  CALL iom_put( "tintpp" , tpp * zfact )  !  global total integrated primary production molC/s
495          !
496          CALL wrk_dealloc( jpi, jpj,      zw2d )
497          CALL wrk_dealloc( jpi, jpj, jpk, zw3d )
498       ENDIF
499     ELSE
500        IF( ln_diatrc ) THEN
501           zfact = 1.e+3 * rfact2r
502           trc3d(:,:,:,jp_pcs0_3d + 4)  = zprorca (:,:,:) * zfact * tmask(:,:,:)
503           trc3d(:,:,:,jp_pcs0_3d + 5)  = zprorcad(:,:,:) * zfact * tmask(:,:,:)
504           trc3d(:,:,:,jp_pcs0_3d + 6)  = zpronew (:,:,:) * zfact * tmask(:,:,:)
505           trc3d(:,:,:,jp_pcs0_3d + 7)  = zpronewd(:,:,:) * zfact * tmask(:,:,:)
506           trc3d(:,:,:,jp_pcs0_3d + 8)  = zprorcad(:,:,:) * zfact * tmask(:,:,:) * zysopt(:,:,:)
507           trc3d(:,:,:,jp_pcs0_3d + 9)  = zprofed (:,:,:) * zfact * tmask(:,:,:)
508#  if ! defined key_kriest
509           trc3d(:,:,:,jp_pcs0_3d + 10) = zprofen (:,:,:) * zfact * tmask(:,:,:)
510#  endif
511        ENDIF
512     ENDIF
513
514     IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
515         WRITE(charout, FMT="('prod')")
516         CALL prt_ctl_trc_info(charout)
517         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
518     ENDIF
519     !
520     CALL wrk_dealloc( jpi, jpj,      zmixnano, zmixdiat, zstrn                                                  )
521     CALL wrk_dealloc( jpi, jpj, jpk, zpislopead, zpislopead2, zprdia, zprbio, zprdch, zprnch, zysopt            ) 
522     CALL wrk_dealloc( jpi, jpj, jpk, zprorca, zprorcad, zprofed, zprofen, zprochln, zprochld, zpronew, zpronewd )
523     !
524     IF( nn_timing == 1 )  CALL timing_stop('p4z_prod')
525     !
526   END SUBROUTINE p4z_prod
527
528
529   SUBROUTINE p4z_prod_init
530      !!----------------------------------------------------------------------
531      !!                  ***  ROUTINE p4z_prod_init  ***
532      !!
533      !! ** Purpose :   Initialization of phytoplankton production parameters
534      !!
535      !! ** Method  :   Read the nampisprod namelist and check the parameters
536      !!      called at the first timestep (nittrc000)
537      !!
538      !! ** input   :   Namelist nampisprod
539      !!----------------------------------------------------------------------
540      !
541      NAMELIST/nampisprod/ pislope, pislope2, xadap, ln_newprod, bresp, excret, excret2,  &
542         &                 chlcnm, chlcdm, chlcmin, fecnm, fecdm, grosip
543      INTEGER :: ios                 ! Local integer output status for namelist read
544      !!----------------------------------------------------------------------
545
546      REWIND( numnatp_ref )              ! Namelist nampisprod in reference namelist : Pisces phytoplankton production
547      READ  ( numnatp_ref, nampisprod, IOSTAT = ios, ERR = 901)
548901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in reference namelist', lwp )
549
550      REWIND( numnatp_cfg )              ! Namelist nampisprod in configuration namelist : Pisces phytoplankton production
551      READ  ( numnatp_cfg, nampisprod, IOSTAT = ios, ERR = 902 )
552902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampisprod in configuration namelist', lwp )
553      IF(lwm) WRITE ( numonp, nampisprod )
554
555      IF(lwp) THEN                         ! control print
556         WRITE(numout,*) ' '
557         WRITE(numout,*) ' Namelist parameters for phytoplankton growth, nampisprod'
558         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
559         WRITE(numout,*) '    Enable new parame. of production (T/F)   ln_newprod   =', ln_newprod
560         WRITE(numout,*) '    mean Si/C ratio                           grosip       =', grosip
561         WRITE(numout,*) '    P-I slope                                 pislope      =', pislope
562         WRITE(numout,*) '    Acclimation factor to low light           xadap       =', xadap
563         WRITE(numout,*) '    excretion ratio of nanophytoplankton      excret       =', excret
564         WRITE(numout,*) '    excretion ratio of diatoms                excret2      =', excret2
565         IF( ln_newprod )  THEN
566            WRITE(numout,*) '    basal respiration in phytoplankton        bresp        =', bresp
567            WRITE(numout,*) '    Maximum Chl/C in phytoplankton            chlcmin      =', chlcmin
568         ENDIF
569         WRITE(numout,*) '    P-I slope  for diatoms                    pislope2     =', pislope2
570         WRITE(numout,*) '    Minimum Chl/C in nanophytoplankton        chlcnm       =', chlcnm
571         WRITE(numout,*) '    Minimum Chl/C in diatoms                  chlcdm       =', chlcdm
572         WRITE(numout,*) '    Maximum Fe/C in nanophytoplankton         fecnm        =', fecnm
573         WRITE(numout,*) '    Minimum Fe/C in diatoms                   fecdm        =', fecdm
574      ENDIF
575      !
576      r1_rday   = 1._wp / rday 
577      texcret   = 1._wp - excret
578      texcret2  = 1._wp - excret2
579      tpp       = 0._wp
580      !
581   END SUBROUTINE p4z_prod_init
582
583
584   INTEGER FUNCTION p4z_prod_alloc()
585      !!----------------------------------------------------------------------
586      !!                     ***  ROUTINE p4z_prod_alloc  ***
587      !!----------------------------------------------------------------------
588      ALLOCATE( prmax(jpi,jpj,jpk), quotan(jpi,jpj,jpk), quotad(jpi,jpj,jpk), STAT = p4z_prod_alloc )
589      !
590      IF( p4z_prod_alloc /= 0 ) CALL ctl_warn('p4z_prod_alloc : failed to allocate arrays.')
591      !
592   END FUNCTION p4z_prod_alloc
593
594#else
595   !!======================================================================
596   !!  Dummy module :                                   No PISCES bio-model
597   !!======================================================================
598CONTAINS
599   SUBROUTINE p4z_prod                    ! Empty routine
600   END SUBROUTINE p4z_prod
601#endif 
602
603   !!======================================================================
604END MODULE p4zprod
Note: See TracBrowser for help on using the repository browser.