New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcadv.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/TOP_SRC/TRP/trcadv.F90 @ 7806

Last change on this file since 7806 was 7806, checked in by cbricaud, 7 years ago

phaze dev_r5003_MERCATOR6_CRS branch with rev7805 of 3.6_stable branch
  • Property svn:keywords set to Id
File size: 11.5 KB
Line 
1MODULE trcadv
2   !!==============================================================================
3   !!                       ***  MODULE  trcadv  ***
4   !! Ocean passive tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  05-11  (G. Madec)  Original code
7   !!            3.0  !  10-06  (C. Ethe)   Adapted to passive tracers
8   !!----------------------------------------------------------------------
9#if defined key_top
10   !!----------------------------------------------------------------------
11   !!   'key_top'                                                TOP models
12   !!----------------------------------------------------------------------
13   !!   trc_adv      : compute ocean tracer advection trend
14   !!   trc_adv_ctl  : control the different options of advection scheme
15   !!----------------------------------------------------------------------
16   USE oce_trc         ! ocean dynamics and active tracers
17   USE trc             ! ocean passive tracers variables
18   USe domvvl
19   USE trcnam_trp      ! passive tracers transport namelist variables
20   USE traadv_cen2     ! 2nd order centered scheme (tra_adv_cen2   routine)
21   USE traadv_tvd      ! TVD      scheme           (tra_adv_tvd    routine)
22   USE traadv_muscl    ! MUSCL    scheme           (tra_adv_muscl  routine)
23   USE traadv_muscl2   ! MUSCL2   scheme           (tra_adv_muscl2 routine)
24   USE traadv_ubs      ! UBS      scheme           (tra_adv_ubs    routine)
25   USE traadv_qck      ! QUICKEST scheme           (tra_adv_qck    routine)
26   USE traadv_eiv      ! eddy induced velocity     (tra_adv_eiv    routine)
27   USE traadv_mle      ! ML eddy induced velocity  (tra_adv_mle    routine)
28   USE ldftra_oce      ! lateral diffusion coefficient on tracers
29   USE prtctl_trc      ! Print control
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   trc_adv          ! routine called by step module
35   PUBLIC   trc_adv_alloc    ! routine called by nemogcm module
36
37   INTEGER ::   nadv   ! choice of the type of advection scheme
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt  ! vertical profile time-step, = 2 rdttra
39   !                                                    ! except at nitrrc000 (=rdttra) if neuler=0
40
41   !! * Substitutions
42#  include "domzgr_substitute.h90"
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   INTEGER FUNCTION trc_adv_alloc()
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE trc_adv_alloc  ***
54      !!----------------------------------------------------------------------
55
56      ALLOCATE( r2dt(jpk), STAT=trc_adv_alloc )
57
58      IF( trc_adv_alloc /= 0 ) CALL ctl_warn('trc_adv_alloc : failed to allocate array.')
59
60   END FUNCTION trc_adv_alloc
61
62
63   SUBROUTINE trc_adv( kt )
64      !!----------------------------------------------------------------------
65      !!                  ***  ROUTINE trc_adv  ***
66      !!
67      !! ** Purpose :   compute the ocean tracer advection trend.
68      !!
69      !! ** Method  : - Update the tracer with the advection term following nadv
70      !!----------------------------------------------------------------------
71      !!
72      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
73      !
74      INTEGER ::   jk 
75      CHARACTER (len=22) ::   charout
76      REAL(wp), POINTER, DIMENSION(:,:,:) :: zun, zvn, zwn  ! effective velocity
77      !!----------------------------------------------------------------------
78      !
79      IF( nn_timing == 1 )  CALL timing_start('trc_adv')
80      !
81      CALL wrk_alloc( jpi, jpj, jpk, zun, zvn, zwn )
82      !
83
84      IF( kt == nittrc000 )   CALL trc_adv_ctl          ! initialisation & control of options
85
86      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN     ! at nittrc000
87         r2dt(:) =  rdttrc(:)           ! = rdttrc (use or restarting with Euler time stepping)
88      ELSEIF( kt <= nittrc000 + nn_dttrc ) THEN          ! at nittrc000 or nittrc000+1
89         r2dt(:) = 2. * rdttrc(:)       ! = 2 rdttrc (leapfrog)
90      ENDIF
91      ! 
92      IF( lk_offline ) THEN
93         zun(:,:,:) = un(:,:,:)     ! effective transport already in un/vn/wn
94         zvn(:,:,:) = vn(:,:,:)
95         zwn(:,:,:) = wn(:,:,:)
96      ELSE
97         !                                                         ! effective transport
98         DO jk = 1, jpkm1
99            !                                                ! eulerian transport only
100            zun(:,:,jk) = e2u  (:,:) * fse3u(:,:,jk) * un(:,:,jk)
101            zvn(:,:,jk) = e1v  (:,:) * fse3v(:,:,jk) * vn(:,:,jk)
102            zwn(:,:,jk) = e1e2t(:,:)                 * wn(:,:,jk)
103            !
104         END DO
105         !
106         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN
107            zun(:,:,:) = zun(:,:,:) + un_td(:,:,:)
108            zvn(:,:,:) = zvn(:,:,:) + vn_td(:,:,:)
109         ENDIF
110         !
111         zun(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
112         zvn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
113         zwn(:,:,jpk) = 0._wp                                                     ! no transport trough the bottom
114         !
115
116         IF( lk_traldf_eiv .AND. .NOT. ln_traldf_grif )   &  ! add the eiv transport (if necessary)
117            &              CALL tra_adv_eiv( kt, nittrc000, zun, zvn, zwn, 'TRC' )
118         !
119         IF( ln_mle    )   CALL tra_adv_mle( kt, nittrc000, zun, zvn, zwn, 'TRC' )    ! add the mle transport (if necessary)
120         !
121      ENDIF
122      !
123      SELECT CASE ( nadv )                            !==  compute advection trend and add it to general trend  ==!
124      CASE ( 1 )   ;    CALL tra_adv_cen2  ( kt, nittrc000, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )   !  2nd order centered
125      CASE ( 2 )   ;    CALL tra_adv_tvd   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  TVD
126      CASE ( 3 )   ;    CALL tra_adv_muscl ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra, ln_trcadv_msc_ups )   !  MUSCL
127      CASE ( 4 )   ;    CALL tra_adv_muscl2( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  MUSCL2
128      CASE ( 5 )   ;    CALL tra_adv_ubs   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  UBS
129      CASE ( 6 )   ;    CALL tra_adv_qck   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )   !  QUICKEST
130      !
131      CASE (-1 )                                      !==  esopa: test all possibility with control print  ==!
132         CALL tra_adv_cen2  ( kt, nittrc000, 'TRC',       zun, zvn, zwn, trb, trn, tra, jptra )         
133         WRITE(charout, FMT="('adv1')")  ; CALL prt_ctl_trc_info(charout)
134                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
135         CALL tra_adv_tvd   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
136         WRITE(charout, FMT="('adv2')")  ; CALL prt_ctl_trc_info(charout)
137                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
138         CALL tra_adv_muscl ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb,      tra, jptra, ln_trcadv_msc_ups  )         
139         WRITE(charout, FMT="('adv3')")  ; CALL prt_ctl_trc_info(charout)
140                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
141         CALL tra_adv_muscl2( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
142         WRITE(charout, FMT="('adv4')")  ; CALL prt_ctl_trc_info(charout)
143                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
144         CALL tra_adv_ubs   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
145         WRITE(charout, FMT="('adv5')")  ; CALL prt_ctl_trc_info(charout)
146                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
147         CALL tra_adv_qck   ( kt, nittrc000, 'TRC', r2dt, zun, zvn, zwn, trb, trn, tra, jptra )         
148         WRITE(charout, FMT="('adv6')")  ; CALL prt_ctl_trc_info(charout)
149                                           CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm,clinfo2='trd')
150         !
151      END SELECT
152
153      !                                              ! print mean trends (used for debugging)
154      IF( ln_ctl )   THEN
155         WRITE(charout, FMT="('adv ')")  ;  CALL prt_ctl_trc_info(charout)
156                                            CALL prt_ctl_trc( tab4d=tra, mask=tmask, clinfo=ctrcnm, clinfo2='trd' )
157      END IF
158      !
159      CALL wrk_dealloc( jpi, jpj, jpk, zun, zvn, zwn )
160      !
161      IF( nn_timing == 1 )  CALL timing_stop('trc_adv')
162      !
163   END SUBROUTINE trc_adv
164
165
166   SUBROUTINE trc_adv_ctl
167      !!---------------------------------------------------------------------
168      !!                  ***  ROUTINE trc_adv_ctl  ***
169      !!               
170      !! ** Purpose : Control the consistency between namelist options for
171      !!              passive tracer advection schemes and set nadv
172      !!----------------------------------------------------------------------
173      INTEGER ::   ioptio
174      !!----------------------------------------------------------------------
175
176      ioptio = 0                      ! Parameter control
177      IF( ln_trcadv_cen2   )   ioptio = ioptio + 1
178      IF( ln_trcadv_tvd    )   ioptio = ioptio + 1
179      IF( ln_trcadv_muscl  )   ioptio = ioptio + 1
180      IF( ln_trcadv_muscl2 )   ioptio = ioptio + 1
181      IF( ln_trcadv_ubs    )   ioptio = ioptio + 1
182      IF( ln_trcadv_qck    )   ioptio = ioptio + 1
183      IF( lk_esopa         )   ioptio =          1
184
185      IF( ioptio /= 1 )   CALL ctl_stop( 'Choose ONE advection scheme in namelist namtrc_adv' )
186
187      !                              ! Set nadv
188      IF( ln_trcadv_cen2   )   nadv =  1
189      IF( ln_trcadv_tvd    )   nadv =  2
190      IF( ln_trcadv_muscl  )   nadv =  3
191      IF( ln_trcadv_muscl2 )   nadv =  4
192      IF( ln_trcadv_ubs    )   nadv =  5
193      IF( ln_trcadv_qck    )   nadv =  6
194      IF( lk_esopa         )   nadv = -1
195
196      IF(lwp) THEN                   ! Print the choice
197         WRITE(numout,*)
198         IF( nadv ==  1 )   WRITE(numout,*) '         2nd order scheme is used'
199         IF( nadv ==  2 )   WRITE(numout,*) '         TVD       scheme is used'
200         IF( nadv ==  3 )   WRITE(numout,*) '         MUSCL     scheme is used'
201         IF( nadv ==  4 )   WRITE(numout,*) '         MUSCL2    scheme is used'
202         IF( nadv ==  5 )   WRITE(numout,*) '         UBS       scheme is used'
203         IF( nadv ==  6 )   WRITE(numout,*) '         QUICKEST  scheme is used'
204         IF( nadv == -1 )   WRITE(numout,*) '         esopa test: use all advection scheme'
205      ENDIF
206      !
207   END SUBROUTINE trc_adv_ctl
208   
209#else
210   !!----------------------------------------------------------------------
211   !!   Default option                                         Empty module
212   !!----------------------------------------------------------------------
213CONTAINS
214   SUBROUTINE trc_adv( kt )
215      INTEGER, INTENT(in) :: kt
216      WRITE(*,*) 'trc_adv: You should not have seen this print! error?', kt
217   END SUBROUTINE trc_adv
218#endif
219
220  !!======================================================================
221END MODULE trcadv
Note: See TracBrowser for help on using the repository browser.