New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcstp.F90 in branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/TOP_SRC – NEMO

source: branches/2015/dev_r5003_MERCATOR6_CRS/NEMOGCM/NEMO/TOP_SRC/trcstp.F90 @ 7795

Last change on this file since 7795 was 7398, checked in by cbricaud, 7 years ago

coarsening branch: first implementation of coarsening in PISCES

  • Property svn:keywords set to Id
File size: 9.9 KB
Line 
1MODULE trcstp
2   !!======================================================================
3   !!                       ***  MODULE trcstp  ***
4   !! Time-stepping    : time loop of opa for passive tracer
5   !!======================================================================
6   !! History :  1.0  !  2004-03  (C. Ethe)  Original
7   !!----------------------------------------------------------------------
8#if defined key_top
9   !!----------------------------------------------------------------------
10   !!   trc_stp      : passive tracer system time-stepping
11   !!----------------------------------------------------------------------
12   USE oce_trc          ! ocean dynamics and active tracers variables
13   USE trc, ONLY: cvol,numont,numstr
14   USE trctrp           ! passive tracers transport
15   USE trcsms           ! passive tracers sources and sinks
16   USE prtctl_trc       ! Print control for debbuging
17   USE trcdia
18   USE trcwri , ONLY : trc_wri
19   USE trcrst
20   USE trdtrc_oce
21   USE trdmxl_trc
22   USE iom, ONLY : lk_iomput , iom_close, iom_varid, jpdom_autoglo, iom_get, iom_rstput
23   USE in_out_manager
24   USE trcsub, ONLY: trc_sub_stp,trc_sub_reset
25   USE dom_oce, ONLY : nday, nmonth, nyear, nsec1jan000, nsec_year
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   trc_stp    ! called by step
31
32   REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   qsr_arr ! save qsr during TOP time-step
33   REAL(wp) :: rdt_sampl
34   INTEGER  :: nb_rec_per_day
35   REAL(wp) :: rsecfst, rseclast
36   LOGICAL  :: llnew
37
38   !! * Substitutions
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE trc_stp( kt )
48      !!-------------------------------------------------------------------
49      !!                     ***  ROUTINE trc_stp  ***
50      !!                     
51      !! ** Purpose : Time loop of opa for passive tracer
52      !!
53      !! ** Method  :
54      !!              Compute the passive tracers trends
55      !!              Update the passive tracers
56      !!-------------------------------------------------------------------
57      INTEGER, INTENT( in ) ::  kt      ! ocean time-step index
58      INTEGER               ::  jk, jn  ! dummy loop indices
59      REAL(wp)              ::  ztrai
60      CHARACTER (len=25)    ::  charout 
61      !!-------------------------------------------------------------------
62      !
63      IF( nn_timing == 1 )   CALL timing_start('trc_stp')
64      !
65      IF( kt == nittrc000 .AND. lk_trdmxl_trc )  CALL trd_mxl_trc_init    ! trends: Mixed-layer
66      !
67      IF( lk_vvl ) THEN                                                   ! update ocean volume due to ssh temporal evolution
68         DO jk = 1, jpk
69            cvol(:,:,jk) = e1e2t(:,:) * fse3t(:,:,jk) * tmask(:,:,jk)
70         END DO
71         !cbr IF( lk_degrad )  cvol(:,:,:) = cvol(:,:,:) * facvol(:,:,:)       ! degrad option: reduction by facvol
72         areatot         = glob_sum( cvol(:,:,:) )
73      ENDIF
74      !
75      IF( l_trcdm2dc )   CALL trc_mean_qsr( kt )
76      !   
77      IF( nn_dttrc /= 1 )   CALL trc_sub_stp( kt )  ! averaging physical variables for sub-stepping
78      !   
79      IF( MOD( kt , nn_dttrc ) == 0 ) THEN      ! only every nn_dttrc time step
80         !
81         IF(ln_ctl) THEN
82            WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
83            CALL prt_ctl_trc_info(charout)
84         ENDIF
85         !
86         tra(:,:,:,:) = 0.e0
87         !
88                                   CALL trc_rst_opn  ( kt )       ! Open tracer restart file
89         IF( lrst_trc )            CALL trc_rst_cal  ( kt, 'WRITE' )   ! calendar
90         IF( lk_iomput ) THEN  ;   CALL trc_wri      ( kt )       ! output of passive tracers with iom I/O manager
91         ELSE                  ;   CALL trc_dia      ( kt )       ! output of passive tracers with old I/O manager
92         ENDIF
93                                   CALL trc_sms      ( kt )       ! tracers: sinks and sources
94                                   CALL trc_trp      ( kt )       ! transport of passive tracers
95
96         IF( kt == nittrc000 ) THEN
97            CALL iom_close( numrtr )       ! close input tracer restart file
98            IF(lwm) CALL FLUSH( numont )   ! flush namelist output
99         ENDIF
100         IF( lrst_trc )            CALL trc_rst_wri  ( kt )       ! write tracer restart file
101         IF( lk_trdmxl_trc  )      CALL trd_mxl_trc  ( kt )       ! trends: Mixed-layer
102         !
103         IF( nn_dttrc /= 1   )     CALL trc_sub_reset( kt )       ! resetting physical variables when sub-stepping
104         !
105      ENDIF
106      !
107
108      ztrai = 0._wp                                                   !  content of all tracers
109      DO jn = 1, jptra
110         ztrai = ztrai + glob_sum( trn(:,:,:,jn) * cvol(:,:,:)   )
111      END DO
112      IF( lwp ) WRITE(numstr,9300) kt,  ztrai / areatot
1139300  FORMAT(i10,D23.16)
114      !
115      IF( nn_timing == 1 )   CALL timing_stop('trc_stp')
116      !
117   END SUBROUTINE trc_stp
118
119   SUBROUTINE trc_mean_qsr( kt )
120      !!----------------------------------------------------------------------
121      !!             ***  ROUTINE trc_mean_qsr  ***
122      !!
123      !! ** Purpose :  Compute daily mean qsr for biogeochemical model in case
124      !!               of diurnal cycle
125      !!
126      !! ** Method  : store in TOP the qsr every hour ( or every time-step if the latter
127      !!              is greater than 1 hour ) and then, compute the  mean with
128      !!              a moving average over 24 hours.
129      !!              In coupled mode, the sampling is done at every coupling frequency
130      !!----------------------------------------------------------------------
131      INTEGER, INTENT(in) ::   kt
132      INTEGER  :: jn
133      REAL(wp) :: zkt
134      CHARACTER(len=1)               ::   cl1                      ! 1 character
135      CHARACTER(len=2)               ::   cl2                      ! 2 characters
136
137      IF( kt == nit000 ) THEN
138         IF( ln_cpl )  THEN 
139            rdt_sampl = rday / ncpl_qsr_freq
140            nb_rec_per_day = ncpl_qsr_freq
141         ELSE 
142            rdt_sampl = MAX( 3600., rdttrc(1) )
143            nb_rec_per_day = INT( rday / rdt_sampl )
144         ENDIF
145         !
146         IF( lwp ) THEN
147            WRITE(numout,*) 
148            WRITE(numout,*) ' Sampling frequency dt = ', rdt_sampl, 's','   Number of sampling per day  nrec = ', nb_rec_per_day
149            WRITE(numout,*) 
150         ENDIF
151         !
152         ALLOCATE( qsr_arr(jpi,jpj,nb_rec_per_day ) )
153         !
154         !                                            !* Restart: read in restart file
155         IF( ln_rsttr .AND. iom_varid( numrtr, 'qsr_mean' , ldstop = .FALSE. ) > 0 .AND. &
156                            iom_varid( numrtr, 'qsr_arr_1', ldstop = .FALSE. ) > 0 .AND. &
157                            iom_varid( numrtr, 'ktdcy'    , ldstop = .FALSE. ) > 0 ) THEN
158            CALL iom_get( numrtr, 'ktdcy', zkt )   !  A mean of qsr
159            rsecfst = INT( zkt ) * rdttrc(1)
160            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean read in the restart file at time-step rsecfst =', rsecfst, ' s '
161            CALL iom_get( numrtr, jpdom_autoglo, 'qsr_mean', qsr_mean )   !  A mean of qsr
162            DO jn = 1, nb_rec_per_day 
163             IF( jn <= 9 )  THEN
164               WRITE(cl1,'(i1)') jn
165               CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )   !  A mean of qsr
166             ELSE
167               WRITE(cl2,'(i2.2)') jn
168               CALL iom_get( numrtr, jpdom_autoglo, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )   !  A mean of qsr
169             ENDIF
170           ENDDO
171         ELSE                                         !* no restart: set from nit000 values
172            IF(lwp) WRITE(numout,*) 'trc_qsr_mean:   qsr_mean set to nit000 values'
173            rsecfst  = kt * rdttrc(1)
174            !
175            qsr_mean(:,:) = qsr(:,:)
176            DO jn = 1, nb_rec_per_day
177               qsr_arr(:,:,jn) = qsr_mean(:,:)
178            ENDDO
179         ENDIF
180         !
181      ENDIF
182      !
183      rseclast = kt * rdttrc(1)
184      !
185      llnew   = ( rseclast - rsecfst ) .ge.  rdt_sampl    !   new shortwave to store
186      IF( llnew ) THEN
187          IF( lwp ) WRITE(numout,*) ' New shortwave to sample for TOP at time kt = ', kt, &
188             &                      ' time = ', rseclast/3600.,'hours '
189          rsecfst = rseclast
190          DO jn = 1, nb_rec_per_day - 1
191             qsr_arr(:,:,jn) = qsr_arr(:,:,jn+1)
192          ENDDO
193          qsr_arr (:,:,nb_rec_per_day) = qsr(:,:)
194          qsr_mean(:,:                ) = SUM( qsr_arr(:,:,:), 3 ) / nb_rec_per_day
195      ENDIF
196      !
197      IF( lrst_trc ) THEN    !* Write the mean of qsr in restart file
198         IF(lwp) WRITE(numout,*)
199         IF(lwp) WRITE(numout,*) 'trc_mean_qsr : write qsr_mean in restart file  kt =', kt
200         IF(lwp) WRITE(numout,*) '~~~~~~~'
201         zkt = REAL( kt, wp )
202         CALL iom_rstput( kt, nitrst, numrtw, 'ktdcy', zkt )
203          DO jn = 1, nb_rec_per_day 
204             IF( jn <= 9 )  THEN
205               WRITE(cl1,'(i1)') jn
206               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl1, qsr_arr(:,:,jn) )
207             ELSE
208               WRITE(cl2,'(i2.2)') jn
209               CALL iom_rstput( kt, nitrst, numrtw, 'qsr_arr_'//cl2, qsr_arr(:,:,jn) )
210             ENDIF
211         ENDDO
212         CALL iom_rstput( kt, nitrst, numrtw, 'qsr_mean', qsr_mean(:,:) )
213      ENDIF
214      !
215   END SUBROUTINE trc_mean_qsr
216
217#else
218   !!----------------------------------------------------------------------
219   !!   Default key                                     NO passive tracers
220   !!----------------------------------------------------------------------
221CONTAINS
222   SUBROUTINE trc_stp( kt )        ! Empty routine
223      WRITE(*,*) 'trc_stp: You should not have seen this print! error?', kt
224   END SUBROUTINE trc_stp
225#endif
226
227   !!======================================================================
228END MODULE trcstp
Note: See TracBrowser for help on using the repository browser.