source: branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/OFF_SRC/nemogcm.F90 @ 5445

Last change on this file since 5445 was 5445, checked in by davestorkey, 5 years ago

Clear SVN keywords from 2015/dev_r5021_UKMO1_CICE_coupling branch.

File size: 30.0 KB
Line 
1MODULE nemogcm
2   !!======================================================================
3   !!                       ***  MODULE nemogcm   ***
4   !! Off-line Ocean   : passive tracer evolution, dynamics read in files
5   !!======================================================================
6   !! History :  3.3  ! 2010-05  (C. Ethe)  Full reorganization of the off-line: phasing with the on-line
7   !!            4.0  ! 2011-01  (C. Ethe, A. R. Porter, STFC Daresbury) dynamical allocation
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   nemo_gcm        : off-line: solve ocean tracer only
12   !!   nemo_init       : initialization of the nemo model
13   !!   nemo_ctl        : initialisation of algorithm flag
14   !!   nemo_closefile  : close remaining files
15   !!----------------------------------------------------------------------
16   USE dom_oce         ! ocean space domain variables
17   USE oce             ! dynamics and tracers variables
18   USE c1d             ! 1D configuration
19   USE domcfg          ! domain configuration               (dom_cfg routine)
20   USE domain          ! domain initialization             (dom_init routine)
21   USE istate          ! initial state setting          (istate_init routine)
22   USE eosbn2          ! equation of state            (eos bn2 routine)
23   !              ! ocean physics
24   USE ldftra          ! lateral diffusivity setting    (ldf_tra_init routine)
25   USE ldfslp          ! slopes of neutral surfaces     (ldf_slp_init routine)
26   USE traqsr          ! solar radiation penetration    (tra_qsr_init routine)
27   USE trabbl          ! bottom boundary layer          (tra_bbl_init routine)
28   USE zdfini          ! vertical physics: initialization
29   USE sbcmod          ! surface boundary condition       (sbc_init     routine)
30   USE phycst          ! physical constant                  (par_cst routine)
31   USE dtadyn          ! Lecture and Interpolation of the dynamical fields
32   USE trcini          ! Initilization of the passive tracers
33   USE daymod          ! calendar                         (day     routine)
34   USE trcstp          ! passive tracer time-stepping      (trc_stp routine)
35   USE dtadyn          ! Lecture and interpolation of the dynamical fields
36   USE stpctl          ! time stepping control            (stp_ctl routine)
37   !              ! I/O & MPP
38   USE iom             ! I/O library
39   USE in_out_manager  ! I/O manager
40   USE mppini          ! shared/distributed memory setting (mpp_init routine)
41   USE lib_mpp         ! distributed memory computing
42#if defined key_iomput
43   USE xios
44#endif
45   USE prtctl          ! Print control                    (prt_ctl_init routine)
46   USE timing          ! Timing
47   USE lib_fortran     ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
48   USE lbcnfd, ONLY: isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
49
50   USE trc
51   USE trcnam
52   USE trcrst
53   USE diaptr         ! Need to initialise this as some variables are used in if statements later
54
55   IMPLICIT NONE
56   PRIVATE
57   
58   PUBLIC   nemo_gcm   ! called by nemo.F90
59
60   CHARACTER (len=64) ::   cform_aaa="( /, 'AAAAAAAA', / ) "   ! flag for output listing
61
62   !!----------------------------------------------------------------------
63   !! NEMO/OFF 3.3 , NEMO Consortium (2010)
64   !! $Id$
65   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE nemo_gcm
70      !!----------------------------------------------------------------------
71      !!                     ***  ROUTINE nemo_gcm  ***
72      !!
73      !! ** Purpose :   nemo solves the primitive equations on an orthogonal
74      !!      curvilinear mesh on the sphere.
75      !!
76      !! ** Method  : - model general initialization
77      !!              - launch the time-stepping (dta_dyn and trc_stp)
78      !!              - finalize the run by closing files and communications
79      !!
80      !! References : Madec, Delecluse,Imbard, and Levy, 1997:  internal report, IPSL.
81      !!              Madec, 2008, internal report, IPSL.
82      !!----------------------------------------------------------------------
83      INTEGER :: istp, indic       ! time step index
84      !!----------------------------------------------------------------------
85
86      CALL nemo_init  ! Initializations
87
88      ! check that all process are still there... If some process have an error,
89      ! they will never enter in step and other processes will wait until the end of the cpu time!
90      IF( lk_mpp )   CALL mpp_max( nstop )
91
92      !                            !-----------------------!
93      !                            !==   time stepping   ==!
94      !                            !-----------------------!
95      istp = nit000
96      !
97      CALL iom_init( "nemo" )            ! iom_put initialization (must be done after nemo_init for AGRIF+XIOS+OASIS)
98      !
99      DO WHILE ( istp <= nitend .AND. nstop == 0 )    ! time stepping
100         !
101         IF( istp /= nit000 )   CALL day      ( istp )         ! Calendar (day was already called at nit000 in day_init)
102                                CALL iom_setkt( istp - nit000 + 1, "nemo" )   ! say to iom that we are at time step kstp
103                                CALL dta_dyn  ( istp )         ! Interpolation of the dynamical fields
104                                CALL trc_stp  ( istp )         ! time-stepping
105                                CALL stp_ctl  ( istp, indic )  ! Time loop: control and print
106         istp = istp + 1
107         IF( lk_mpp )   CALL mpp_max( nstop )
108      END DO
109#if defined key_iomput
110      CALL iom_context_finalize( "nemo" ) ! needed for XIOS+AGRIF
111#endif
112
113      !                            !------------------------!
114      !                            !==  finalize the run  ==!
115      !                            !------------------------!
116      IF(lwp) WRITE(numout,cform_aaa)                 ! Flag AAAAAAA
117
118      IF( nstop /= 0 .AND. lwp ) THEN                 ! error print
119         WRITE(numout,cform_err)
120         WRITE(numout,*) nstop, ' error have been found'
121      ENDIF
122      !
123      IF( nn_timing == 1 )   CALL timing_finalize
124      !
125      CALL nemo_closefile
126      !
127# if defined key_iomput
128      CALL xios_finalize             ! end mpp communications
129# else
130      IF( lk_mpp )   CALL mppstop       ! end mpp communications
131# endif
132      !
133   END SUBROUTINE nemo_gcm
134
135
136   SUBROUTINE nemo_init
137      !!----------------------------------------------------------------------
138      !!                     ***  ROUTINE nemo_init ***
139      !!
140      !! ** Purpose :   initialization of the nemo model in off-line mode
141      !!----------------------------------------------------------------------
142      INTEGER ::   ji            ! dummy loop indices
143      INTEGER ::   ilocal_comm   ! local integer
144      INTEGER ::   ios
145      CHARACTER(len=80), DIMENSION(16) ::   cltxt
146      !!
147      NAMELIST/namctl/ ln_ctl  , nn_print, nn_ictls, nn_ictle,   &
148         &             nn_isplt, nn_jsplt, nn_jctls, nn_jctle,   &
149         &             nn_bench, nn_timing
150      NAMELIST/namcfg/ cp_cfg, cp_cfz, jp_cfg, jpidta, jpjdta, jpkdta, jpiglo, jpjglo, &
151         &             jpizoom, jpjzoom, jperio, ln_use_jattr
152      !!----------------------------------------------------------------------
153      cltxt = ''
154      cxios_context = 'nemo'
155      !
156      !                             ! Open reference namelist and configuration namelist files
157      CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
158      CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
159      !
160      REWIND( numnam_ref )              ! Namelist namctl in reference namelist : Control prints & Benchmark
161      READ  ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
162901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
163
164      REWIND( numnam_cfg )              ! Namelist namctl in confguration namelist : Control prints & Benchmark
165      READ  ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
166902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
167
168      !
169      REWIND( numnam_ref )              ! Namelist namcfg in reference namelist : Control prints & Benchmark
170      READ  ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
171903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
172
173      REWIND( numnam_cfg )              ! Namelist namcfg in confguration namelist : Control prints & Benchmark
174      READ  ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
175904   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )   
176
177      !
178      !                             !--------------------------------------------!
179      !                             !  set communicator & select the local node  !
180      !                             !  NB: mynode also opens output.namelist.dyn !
181      !                             !      on unit number numond on first proc   !
182      !                             !--------------------------------------------!
183#if defined key_iomput
184      CALL  xios_initialize( "nemo",return_comm=ilocal_comm )
185      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )   ! Nodes selection
186#else
187      ilocal_comm = 0
188      narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )                ! Nodes selection (control print return in cltxt)
189#endif
190
191      narea = narea + 1                       ! mynode return the rank of proc (0 --> jpnij -1 )
192
193      lwm = (narea == 1)                      ! control of output namelists
194      lwp = (narea == 1) .OR. ln_ctl          ! control of all listing output print
195
196      IF(lwm) THEN
197         ! write merged namelists from earlier to output namelist now that the
198         ! file has been opened in call to mynode. nammpp has already been
199         ! written in mynode (if lk_mpp_mpi)
200         WRITE( numond, namctl )
201         WRITE( numond, namcfg )
202      ENDIF
203
204      ! If dimensions of processor grid weren't specified in the namelist file
205      ! then we calculate them here now that we have our communicator size
206      IF( (jpni < 1) .OR. (jpnj < 1) )THEN
207#if   defined key_mpp_mpi
208         CALL nemo_partition(mppsize)
209#else
210         jpni = 1
211         jpnj = 1
212         jpnij = jpni*jpnj
213#endif
214      END IF
215
216      ! Calculate domain dimensions given calculated jpni and jpnj
217      ! This used to be done in par_oce.F90 when they were parameters rather
218      ! than variables
219      jpi = ( jpiglo-2*jpreci + (jpni-1) ) / jpni + 2*jpreci   ! first  dim.
220      jpj = ( jpjglo-2*jprecj + (jpnj-1) ) / jpnj + 2*jprecj   ! second dim.
221      jpk = jpkdta                                             ! third dim
222      jpim1 = jpi-1                                            ! inner domain indices
223      jpjm1 = jpj-1                                            !   "           "
224      jpkm1 = jpk-1                                            !   "           "
225      jpij  = jpi*jpj                                          !  jpi x j
226
227
228      IF(lwp) THEN                            ! open listing units
229         !
230         CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
231         !
232         WRITE(numout,*)
233         WRITE(numout,*) '   CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
234         WRITE(numout,*) '                       NEMO team'
235         WRITE(numout,*) '            Ocean General Circulation Model'
236         WRITE(numout,*) '                  version 3.6  (2015) '
237         WRITE(numout,*)
238         WRITE(numout,*)
239         DO ji = 1, SIZE(cltxt) 
240            IF( TRIM(cltxt(ji)) /= '' )   WRITE(numout,*) cltxt(ji)      ! control print of mynode
241         END DO
242         WRITE(numout,cform_aaa)                                         ! Flag AAAAAAA
243         !
244      ENDIF
245
246      ! Now we know the dimensions of the grid and numout has been set we can
247      ! allocate arrays
248      CALL nemo_alloc()
249
250      !                             !--------------------------------!
251      !                             !  Model general initialization  !
252      !                             !--------------------------------!
253
254      CALL nemo_ctl                           ! Control prints & Benchmark
255
256      !                                      ! Domain decomposition
257      IF( jpni*jpnj == jpnij ) THEN   ;   CALL mpp_init      ! standard cutting out
258      ELSE                            ;   CALL mpp_init2     ! eliminate land processors
259      ENDIF
260      !
261      IF( nn_timing == 1 )  CALL timing_init
262      !
263
264      !                                      ! General initialization
265      IF( nn_timing == 1 )  CALL timing_start( 'nemo_init')
266      !
267                            CALL     phy_cst    ! Physical constants
268                            CALL     eos_init   ! Equation of state
269      IF( lk_c1d        )   CALL     c1d_init   ! 1D column configuration
270                            CALL     dom_cfg    ! Domain configuration
271                            CALL     dom_init   ! Domain
272                            CALL  istate_init   ! ocean initial state (Dynamics and tracers)
273
274      IF( ln_nnogather )    CALL nemo_northcomms   ! Initialise the northfold neighbour lists (must be done after the masks are defined)
275
276      IF( ln_ctl        )   CALL prt_ctl_init   ! Print control
277
278      !                                     ! Ocean physics
279                            CALL     sbc_init   ! Forcings : surface module
280#if ! defined key_degrad
281                            CALL ldf_tra_init   ! Lateral ocean tracer physics
282#endif
283      IF( lk_ldfslp )       CALL ldf_slp_init   ! slope of lateral mixing
284
285      !                                     ! Active tracers
286                            CALL tra_qsr_init   ! penetrative solar radiation qsr
287      IF( lk_trabbl     )   CALL tra_bbl_init   ! advective (and/or diffusive) bottom boundary layer scheme
288
289                            CALL trc_nam_run  ! Needed to get restart parameters for passive tracers
290      IF( ln_rsttr ) THEN
291        neuler = 1   ! Set time-step indicator at nit000 (leap-frog)
292        CALL trc_rst_cal( nit000, 'READ' )   ! calendar
293      ELSE
294        neuler = 0                  ! Set time-step indicator at nit000 (euler)
295        CALL day_init               ! set calendar
296      ENDIF
297      !                                     ! Dynamics
298                            CALL dta_dyn_init   ! Initialization for the dynamics
299
300      !                                     ! Passive tracers
301                            CALL     trc_init   ! Passive tracers initialization
302      !
303      ! Initialise diaptr as some variables are used in if statements later (in
304      ! various advection and diffusion routines.
305                            CALL dia_ptr_init
306      !
307      IF(lwp) WRITE(numout,cform_aaa)       ! Flag AAAAAAA
308      !
309      IF( nn_timing == 1 )  CALL timing_stop( 'nemo_init')
310      !
311   END SUBROUTINE nemo_init
312
313
314   SUBROUTINE nemo_ctl
315      !!----------------------------------------------------------------------
316      !!                     ***  ROUTINE nemo_ctl  ***
317      !!
318      !! ** Purpose :   control print setting
319      !!
320      !! ** Method  : - print namctl information and check some consistencies
321      !!----------------------------------------------------------------------
322      !
323      IF(lwp) THEN                  ! Parameter print
324         WRITE(numout,*)
325         WRITE(numout,*) 'nemo_flg: Control prints & Benchmark'
326         WRITE(numout,*) '~~~~~~~ '
327         WRITE(numout,*) '   Namelist namctl'
328         WRITE(numout,*) '      run control (for debugging)     ln_ctl     = ', ln_ctl
329         WRITE(numout,*) '      level of print                  nn_print   = ', nn_print
330         WRITE(numout,*) '      Start i indice for SUM control  nn_ictls   = ', nn_ictls
331         WRITE(numout,*) '      End i indice for SUM control    nn_ictle   = ', nn_ictle
332         WRITE(numout,*) '      Start j indice for SUM control  nn_jctls   = ', nn_jctls
333         WRITE(numout,*) '      End j indice for SUM control    nn_jctle   = ', nn_jctle
334         WRITE(numout,*) '      number of proc. following i     nn_isplt   = ', nn_isplt
335         WRITE(numout,*) '      number of proc. following j     nn_jsplt   = ', nn_jsplt
336         WRITE(numout,*) '      benchmark parameter (0/1)       nn_bench   = ', nn_bench
337      ENDIF
338      !
339      nprint    = nn_print          ! convert DOCTOR namelist names into OLD names
340      nictls    = nn_ictls
341      nictle    = nn_ictle
342      njctls    = nn_jctls
343      njctle    = nn_jctle
344      isplt     = nn_isplt
345      jsplt     = nn_jsplt
346      nbench    = nn_bench
347     IF(lwp) THEN                  ! control print
348         WRITE(numout,*)
349         WRITE(numout,*) 'namcfg  : configuration initialization through namelist read'
350         WRITE(numout,*) '~~~~~~~ '
351         WRITE(numout,*) '   Namelist namcfg'
352         WRITE(numout,*) '      configuration name              cp_cfg      = ', TRIM(cp_cfg)
353         WRITE(numout,*) '      configuration resolution        jp_cfg      = ', jp_cfg
354         WRITE(numout,*) '      1st lateral dimension ( >= jpi ) jpidta     = ', jpidta
355         WRITE(numout,*) '      2nd    "         "    ( >= jpj ) jpjdta     = ', jpjdta
356         WRITE(numout,*) '      3nd    "         "               jpkdta     = ', jpkdta
357         WRITE(numout,*) '      1st dimension of global domain in i jpiglo  = ', jpiglo
358         WRITE(numout,*) '      2nd    -                  -    in j jpjglo  = ', jpjglo
359         WRITE(numout,*) '      left bottom i index of the zoom (in data domain) jpizoom = ', jpizoom
360         WRITE(numout,*) '      left bottom j index of the zoom (in data domain) jpizoom = ', jpjzoom
361         WRITE(numout,*) '      lateral cond. type (between 0 and 6) jperio = ', jperio   
362         WRITE(numout,*) '      use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
363      ENDIF
364      !                             ! Parameter control
365      !
366      IF( ln_ctl ) THEN                 ! sub-domain area indices for the control prints
367         IF( lk_mpp ) THEN
368            isplt = jpni   ;   jsplt = jpnj   ;   ijsplt = jpni*jpnj   ! the domain is forced to the real splitted domain
369         ELSE
370            IF( isplt == 1 .AND. jsplt == 1  ) THEN
371               CALL ctl_warn( ' - isplt & jsplt are equal to 1',   &
372                  &           ' - the print control will be done over the whole domain' )
373            ENDIF
374            ijsplt = isplt * jsplt            ! total number of processors ijsplt
375         ENDIF
376         IF(lwp) WRITE(numout,*)'          - The total number of processors over which the'
377         IF(lwp) WRITE(numout,*)'            print control will be done is ijsplt : ', ijsplt
378         !
379         !                              ! indices used for the SUM control
380         IF( nictls+nictle+njctls+njctle == 0 )   THEN    ! print control done over the default area
381            lsp_area = .FALSE.
382         ELSE                                             ! print control done over a specific  area
383            lsp_area = .TRUE.
384            IF( nictls < 1 .OR. nictls > jpiglo )   THEN
385               CALL ctl_warn( '          - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
386               nictls = 1
387            ENDIF
388            IF( nictle < 1 .OR. nictle > jpiglo )   THEN
389               CALL ctl_warn( '          - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
390               nictle = jpiglo
391            ENDIF
392            IF( njctls < 1 .OR. njctls > jpjglo )   THEN
393               CALL ctl_warn( '          - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
394               njctls = 1
395            ENDIF
396            IF( njctle < 1 .OR. njctle > jpjglo )   THEN
397               CALL ctl_warn( '          - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
398               njctle = jpjglo
399            ENDIF
400         ENDIF
401      ENDIF
402      !
403      IF( nbench == 1 )   THEN            ! Benchmark
404         SELECT CASE ( cp_cfg )
405         CASE ( 'gyre' )   ;   CALL ctl_warn( ' The Benchmark is activated ' )
406         CASE DEFAULT      ;   CALL ctl_stop( ' The Benchmark is based on the GYRE configuration:',   &
407            &                                 ' cp_cfg="gyre" in namelsit &namcfg or set nbench = 0' )
408         END SELECT
409      ENDIF
410      !
411      IF( lk_c1d .AND. .NOT.lk_iomput )   CALL ctl_stop( 'nemo_ctl: The 1D configuration must be used ',   &
412         &                                               'with the IOM Input/Output manager. '        ,   &
413         &                                               'Compile with key_iomput enabled' )
414      !
415      IF( 1_wp /= SIGN(1._wp,-0._wp)  )   CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows ',  &
416         &                                               'f2003 standard. '                              ,  &
417         &                                               'Compile with key_nosignedzero enabled' )
418      !
419   END SUBROUTINE nemo_ctl
420
421
422   SUBROUTINE nemo_closefile
423      !!----------------------------------------------------------------------
424      !!                     ***  ROUTINE nemo_closefile  ***
425      !!
426      !! ** Purpose :   Close the files
427      !!----------------------------------------------------------------------
428      !
429      IF ( lk_mpp ) CALL mppsync
430      !
431      CALL iom_close                                 ! close all input/output files managed by iom_*
432      !
433      IF( numstp     /= -1 )   CLOSE( numstp     )   ! time-step file
434      IF( numnam_ref /= -1 )   CLOSE( numnam_ref )   ! oce reference namelist
435      IF( numnam_cfg /= -1 )   CLOSE( numnam_cfg )   ! oce configuration namelist
436      IF( numout     /=  6 )   CLOSE( numout     )   ! standard model output file
437      numout = 6                                     ! redefine numout in case it is used after this point...
438      !
439   END SUBROUTINE nemo_closefile
440
441
442   SUBROUTINE nemo_alloc
443      !!----------------------------------------------------------------------
444      !!                     ***  ROUTINE nemo_alloc  ***
445      !!
446      !! ** Purpose :   Allocate all the dynamic arrays of the OPA modules
447      !!
448      !! ** Method  :
449      !!----------------------------------------------------------------------
450      USE diawri,       ONLY: dia_wri_alloc
451      USE dom_oce,      ONLY: dom_oce_alloc
452      USE zdf_oce,      ONLY: zdf_oce_alloc
453      USE ldftra_oce,   ONLY: ldftra_oce_alloc
454      USE trc_oce,      ONLY: trc_oce_alloc
455      !
456      INTEGER :: ierr
457      !!----------------------------------------------------------------------
458      !
459      ierr =        oce_alloc       ()          ! ocean
460      ierr = ierr + dia_wri_alloc   ()
461      ierr = ierr + dom_oce_alloc   ()          ! ocean domain
462      ierr = ierr + ldftra_oce_alloc()          ! ocean lateral  physics : tracers
463      ierr = ierr + zdf_oce_alloc   ()          ! ocean vertical physics
464      !
465      ierr = ierr + trc_oce_alloc   ()          ! shared TRC / TRA arrays
466      !
467      IF( lk_mpp    )   CALL mpp_sum( ierr )
468      IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
469      !
470   END SUBROUTINE nemo_alloc
471
472
473   SUBROUTINE nemo_partition( num_pes )
474      !!----------------------------------------------------------------------
475      !!                 ***  ROUTINE nemo_partition  ***
476      !!
477      !! ** Purpose :   
478      !!
479      !! ** Method  :
480      !!----------------------------------------------------------------------
481      INTEGER, INTENT(in) :: num_pes ! The number of MPI processes we have
482      !
483      INTEGER, PARAMETER :: nfactmax = 20
484      INTEGER :: nfact ! The no. of factors returned
485      INTEGER :: ierr  ! Error flag
486      INTEGER :: ji
487      INTEGER :: idiff, mindiff, imin ! For choosing pair of factors that are closest in value
488      INTEGER, DIMENSION(nfactmax) :: ifact ! Array of factors
489      !!----------------------------------------------------------------------
490
491      ierr = 0
492
493      CALL factorise( ifact, nfactmax, nfact, num_pes, ierr )
494
495      IF( nfact <= 1 ) THEN
496         WRITE (numout, *) 'WARNING: factorisation of number of PEs failed'
497         WRITE (numout, *) '       : using grid of ',num_pes,' x 1'
498         jpnj = 1
499         jpni = num_pes
500      ELSE
501         ! Search through factors for the pair that are closest in value
502         mindiff = 1000000
503         imin    = 1
504         DO ji = 1, nfact-1, 2
505            idiff = ABS( ifact(ji) - ifact(ji+1) )
506            IF( idiff < mindiff ) THEN
507               mindiff = idiff
508               imin = ji
509            ENDIF
510         END DO
511         jpnj = ifact(imin)
512         jpni = ifact(imin + 1)
513      ENDIF
514      !
515      jpnij = jpni*jpnj
516      !
517   END SUBROUTINE nemo_partition
518
519
520   SUBROUTINE factorise( kfax, kmaxfax, knfax, kn, kerr )
521      !!----------------------------------------------------------------------
522      !!                     ***  ROUTINE factorise  ***
523      !!
524      !! ** Purpose :   return the prime factors of n.
525      !!                knfax factors are returned in array kfax which is of
526      !!                maximum dimension kmaxfax.
527      !! ** Method  :
528      !!----------------------------------------------------------------------
529      INTEGER                    , INTENT(in   ) ::   kn, kmaxfax
530      INTEGER                    , INTENT(  out) ::   kerr, knfax
531      INTEGER, DIMENSION(kmaxfax), INTENT(  out) ::   kfax
532      !
533      INTEGER :: ifac, jl, inu
534      INTEGER, PARAMETER :: ntest = 14
535      INTEGER :: ilfax(ntest)
536      !
537      ! lfax contains the set of allowed factors.
538      data (ilfax(jl),jl=1,ntest) / 16384, 8192, 4096, 2048, 1024, 512, 256,  &
539         &                            128,   64,   32,   16,    8,   4,   2  /
540      !!----------------------------------------------------------------------
541
542      ! Clear the error flag and initialise output vars
543      kerr = 0
544      kfax = 1
545      knfax = 0
546
547      ! Find the factors of n.
548      IF( kn == 1 )   GOTO 20
549
550      ! nu holds the unfactorised part of the number.
551      ! knfax holds the number of factors found.
552      ! l points to the allowed factor list.
553      ! ifac holds the current factor.
554
555      inu   = kn
556      knfax = 0
557
558      DO jl = ntest, 1, -1
559         !
560         ifac = ilfax(jl)
561         IF( ifac > inu )   CYCLE
562
563         ! Test whether the factor will divide.
564
565         IF( MOD(inu,ifac) == 0 ) THEN
566            !
567            knfax = knfax + 1            ! Add the factor to the list
568            IF( knfax > kmaxfax ) THEN
569               kerr = 6
570               write (*,*) 'FACTOR: insufficient space in factor array ', knfax
571               return
572            ENDIF
573            kfax(knfax) = ifac
574            ! Store the other factor that goes with this one
575            knfax = knfax + 1
576            kfax(knfax) = inu / ifac
577            !WRITE (*,*) 'ARPDBG, factors ',knfax-1,' & ',knfax,' are ', kfax(knfax-1),' and ',kfax(knfax)
578         ENDIF
579         !
580      END DO
581
582   20 CONTINUE      ! Label 20 is the exit point from the factor search loop.
583      !
584   END SUBROUTINE factorise
585
586#if defined key_mpp_mpi
587   SUBROUTINE nemo_northcomms
588      !!======================================================================
589      !!                     ***  ROUTINE  nemo_northcomms  ***
590      !! nemo_northcomms    :  Setup for north fold exchanges with explicit
591      !!                       point-to-point messaging
592      !!=====================================================================
593      !!----------------------------------------------------------------------
594      !!
595      !! ** Purpose :   Initialization of the northern neighbours lists.
596      !!----------------------------------------------------------------------
597      !!    1.0  ! 2011-10  (A. C. Coward, NOCS & J. Donners, PRACE)
598      !!    2.0  ! 2013-06 Setup avoiding MPI communication (I. Epicoco, S.
599      !Mocavero, CMCC)
600      !!----------------------------------------------------------------------
601
602      INTEGER  ::   sxM, dxM, sxT, dxT, jn
603      INTEGER  ::   njmppmax
604
605      njmppmax = MAXVAL( njmppt )
606
607      !initializes the north-fold communication variables
608      isendto(:) = 0
609      nsndto = 0
610
611      !if I am a process in the north
612      IF ( njmpp == njmppmax ) THEN
613          !sxM is the first point (in the global domain) needed to compute the
614          !north-fold for the current process
615          sxM = jpiglo - nimppt(narea) - nlcit(narea) + 1
616          !dxM is the last point (in the global domain) needed to compute the
617          !north-fold for the current process
618          dxM = jpiglo - nimppt(narea) + 2
619
620          !loop over the other north-fold processes to find the processes
621          !managing the points belonging to the sxT-dxT range
622
623          DO jn = 1, jpni
624                !sxT is the first point (in the global domain) of the jn
625                !process
626                sxT = nfiimpp(jn, jpnj)
627                !dxT is the last point (in the global domain) of the jn
628                !process
629                dxT = nfiimpp(jn, jpnj) + nfilcit(jn, jpnj) - 1
630                IF ((sxM .gt. sxT) .AND. (sxM .lt. dxT)) THEN
631                   nsndto = nsndto + 1
632                     isendto(nsndto) = jn
633                ELSEIF ((sxM .le. sxT) .AND. (dxM .ge. dxT)) THEN
634                   nsndto = nsndto + 1
635                     isendto(nsndto) = jn
636                ELSEIF ((dxM .lt. dxT) .AND. (sxT .lt. dxM)) THEN
637                   nsndto = nsndto + 1
638                     isendto(nsndto) = jn
639                END IF
640          END DO
641          nfsloop = 1
642          nfeloop = nlci
643          DO jn = 2,jpni-1
644           IF(nfipproc(jn,jpnj) .eq. (narea - 1)) THEN
645              IF (nfipproc(jn - 1 ,jpnj) .eq. -1) THEN
646                 nfsloop = nldi
647              ENDIF
648              IF (nfipproc(jn + 1,jpnj) .eq. -1) THEN
649                 nfeloop = nlei
650              ENDIF
651           ENDIF
652        END DO
653
654      ENDIF
655      l_north_nogather = .TRUE.
656   END SUBROUTINE nemo_northcomms
657#else
658   SUBROUTINE nemo_northcomms      ! Dummy routine
659      WRITE(*,*) 'nemo_northcomms: You should not have seen this print! error?'
660   END SUBROUTINE nemo_northcomms
661#endif
662   !!======================================================================
663END MODULE nemogcm
Note: See TracBrowser for help on using the repository browser.