New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 5234

Last change on this file since 5234 was 5234, checked in by davestorkey, 9 years ago

Clear svn keyword information in branch
2015/dev_r5021_UKMO1_CICE_coupling

File size: 12.1 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm         ! routine called by step.F90
28   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
29
30   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
31                                                  ! from restart file
32   
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE sbc_ssm( kt )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
50      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
51      !!      the periode (kt - nn_fsbc) to kt
52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time step
56      !
57      INTEGER  ::   ji, jj               ! loop index
58      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
59      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
60      REAL(wp), DIMENSION(jpi,jpj)      :: zub, zvb,zdep
61      !!---------------------------------------------------------------------
62     
63      !                                        !* first wet T-, U-, V- ocean level (ISF) variables (T, S, depth, velocity)
64      DO jj = 1, jpj
65         DO ji = 1, jpi
66            zub(ji,jj)        = ub (ji,jj,miku(ji,jj))
67            zvb(ji,jj)        = vb (ji,jj,mikv(ji,jj))
68            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
69            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
70         END DO
71      END DO
72      !
73      IF( lk_vvl ) THEN
74         DO jj = 1, jpj
75            DO ji = 1, jpi
76               zdep(ji,jj) = fse3t_n(ji,jj,mikt(ji,jj))
77            END DO
78         END DO
79      ENDIF
80      !                                                   ! ---------------------------------------- !
81      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
82         !                                                ! ---------------------------------------- !
83         ssu_m(:,:) = zub(:,:)
84         ssv_m(:,:) = zvb(:,:)
85         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
86         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
87         ENDIF
88         sss_m(:,:) = zts(:,:,jp_sal)
89         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
90         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
91         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
92         ENDIF
93         !
94         IF( lk_vvl )   fse3t_m(:,:) = zdep(:,:)
95         !
96      ELSE
97         !                                                ! ----------------------------------------------- !
98         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
99            !                                             ! ----------------------------------------------- !
100            IF(lwp) WRITE(numout,*)
101            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
102            zcoef = REAL( nn_fsbc - 1, wp )
103            ssu_m(:,:) = zcoef * zub(:,:)
104            ssv_m(:,:) = zcoef * zvb(:,:)
105            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
106            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
107            ENDIF
108            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
109            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
110            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
111            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
112            ENDIF
113            !
114            IF( lk_vvl )   fse3t_m(:,:) = zcoef * zdep(:,:)
115            !                                             ! ---------------------------------------- !
116         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
117            !                                             ! ---------------------------------------- !
118            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
119            ssv_m(:,:) = 0.e0
120            sst_m(:,:) = 0.e0
121            sss_m(:,:) = 0.e0
122            ssh_m(:,:) = 0.e0
123            IF( lk_vvl )   fse3t_m(:,:) = 0.e0
124         ENDIF
125         !                                                ! ---------------------------------------- !
126         !                                                !        Cumulate at each time step        !
127         !                                                ! ---------------------------------------- !
128         ssu_m(:,:) = ssu_m(:,:) + zub(:,:)
129         ssv_m(:,:) = ssv_m(:,:) + zvb(:,:)
130         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
131         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
132         ENDIF
133         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
134         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
135         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
136         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
137         ENDIF
138         !
139         IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) + zdep(:,:)
140
141         !                                                ! ---------------------------------------- !
142         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
143            !                                             ! ---------------------------------------- !
144            zcoef = 1. / REAL( nn_fsbc, wp )
145            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
146            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
147            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
148            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
149            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
150            IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
151            !
152         ENDIF
153         !                                                ! ---------------------------------------- !
154         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
155            !                                             ! ---------------------------------------- !
156            IF(lwp) WRITE(numout,*)
157            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
158               &                    'at it= ', kt,' date= ', ndastp
159            IF(lwp) WRITE(numout,*) '~~~~~~~'
160            zf_sbc = REAL( nn_fsbc, wp )
161            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
162            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
163            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
164            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
165            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
166            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
167            IF( lk_vvl ) THEN
168               CALL iom_rstput( kt, nitrst, numrow, 'fse3t_m'  , fse3t_m(:,:)  )
169            END IF
170            !
171         ENDIF
172         !
173      ENDIF
174      !
175   END SUBROUTINE sbc_ssm
176
177   SUBROUTINE sbc_ssm_init
178      !!----------------------------------------------------------------------
179      !!                  ***  ROUTINE sbc_ssm_init  ***
180      !!
181      !! ** Purpose :   Initialisation of the sbc data
182      !!
183      !! ** Action  : - read parameters
184      !!----------------------------------------------------------------------
185      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
186      !!----------------------------------------------------------------------
187
188      IF( nn_fsbc == 1 ) THEN
189         !
190         IF(lwp) WRITE(numout,*)
191         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
192         IF(lwp) WRITE(numout,*) '~~~~~~~ '
193         !
194      ELSE
195         !               
196         IF(lwp) WRITE(numout,*)
197         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
198         IF(lwp) WRITE(numout,*) '~~~~~~~ '
199         !
200         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
201            l_ssm_mean = .TRUE.
202            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
203            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
204            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
205            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
206            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
207            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
208            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'fse3t_m', fse3t_m(:,:) )
209            !
210            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
211               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
212                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
213               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
214               ssu_m(:,:) = zcoef * ssu_m(:,:) 
215               ssv_m(:,:) = zcoef * ssv_m(:,:)
216               sst_m(:,:) = zcoef * sst_m(:,:)
217               sss_m(:,:) = zcoef * sss_m(:,:)
218               ssh_m(:,:) = zcoef * ssh_m(:,:)
219               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
220            ELSE
221               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
222            ENDIF
223         ENDIF
224      ENDIF
225      !
226   END SUBROUTINE sbc_ssm_init
227
228   !!======================================================================
229END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.