New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcnxt.F90 in branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_r5021_UKMO1_CICE_coupling/NEMOGCM/NEMO/TOP_SRC/TRP/trcnxt.F90 @ 5443

Last change on this file since 5443 was 5443, checked in by davestorkey, 9 years ago

Update 2015/dev_r5021_UKMO1_CICE_coupling branch to revision 5442 of the trunk.

File size: 7.6 KB
Line 
1MODULE trcnxt
2   !!======================================================================
3   !!                       ***  MODULE  trcnxt  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_nxt     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE trc             ! ocean passive tracers variables
30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE prtctl_trc      ! Print control for debbuging
32   USE trd_oce
33   USE trdtra
34   USE tranxt
35# if defined key_agrif
36   USE agrif_top_interp
37# endif
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   trc_nxt          ! routine called by step.F90
43   PUBLIC   trc_nxt_alloc    ! routine called by nemogcm.F90
44
45   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt
46
47   !!----------------------------------------------------------------------
48   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
49   !! $Id$
50   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
51   !!----------------------------------------------------------------------
52CONTAINS
53
54   INTEGER FUNCTION trc_nxt_alloc()
55      !!----------------------------------------------------------------------
56      !!                   ***  ROUTINE trc_nxt_alloc  ***
57      !!----------------------------------------------------------------------
58      ALLOCATE( r2dt(jpk), STAT=trc_nxt_alloc )
59      !
60      IF( trc_nxt_alloc /= 0 )   CALL ctl_warn('trc_nxt_alloc : failed to allocate array')
61      !
62   END FUNCTION trc_nxt_alloc
63
64
65   SUBROUTINE trc_nxt( kt )
66      !!----------------------------------------------------------------------
67      !!                   ***  ROUTINE trcnxt  ***
68      !!
69      !! ** Purpose :   Compute the passive tracers fields at the
70      !!      next time-step from their temporal trends and swap the fields.
71      !!
72      !! ** Method  :   Apply lateral boundary conditions on (ua,va) through
73      !!      call to lbc_lnk routine
74      !!   default:
75      !!      arrays swap
76      !!         (trn) = (tra) ; (tra) = (0,0)
77      !!         (trb) = (trn)
78      !!
79      !!   For Arakawa or TVD Scheme :
80      !!      A Asselin time filter applied on now tracers (trn) to avoid
81      !!      the divergence of two consecutive time-steps and tr arrays
82      !!      to prepare the next time_step:
83      !!         (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ]
84      !!         (trn) = (tra) ; (tra) = (0,0)
85      !!
86      !!
87      !! ** Action  : - update trb, trn
88      !!----------------------------------------------------------------------
89      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
90      !
91      INTEGER  ::   jk, jn   ! dummy loop indices
92      REAL(wp) ::   zfact            ! temporary scalar
93      CHARACTER (len=22) :: charout
94      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  ztrdt 
95      !!----------------------------------------------------------------------
96      !
97      IF( nn_timing == 1 )  CALL timing_start('trc_nxt')
98      !
99      IF( kt == nittrc000 .AND. lwp ) THEN
100         WRITE(numout,*)
101         WRITE(numout,*) 'trc_nxt : time stepping on passive tracers'
102      ENDIF
103
104      ! Update after tracer on domain lateral boundaries
105      DO jn = 1, jptra
106         CALL lbc_lnk( tra(:,:,:,jn), 'T', 1. )   
107      END DO
108
109
110#if defined key_bdy
111!!      CALL bdy_trc( kt )               ! BDY open boundaries
112#endif
113#if defined key_agrif
114      CALL Agrif_trc                   ! AGRIF zoom boundaries
115#endif
116
117
118      ! set time step size (Euler/Leapfrog)
119      IF( neuler == 0 .AND. kt ==  nittrc000 ) THEN  ;  r2dt(:) =     rdttrc(:)   ! at nittrc000             (Euler)
120      ELSEIF( kt <= nittrc000 + nn_dttrc )     THEN  ;  r2dt(:) = 2.* rdttrc(:)   ! at nit000 or nit000+1 (Leapfrog)
121      ENDIF
122
123      ! trends computation initialisation
124      IF( l_trdtrc )  THEN
125         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrdt )  !* store now fields before applying the Asselin filter
126         ztrdt(:,:,:,:)  = trn(:,:,:,:)
127      ENDIF
128      ! Leap-Frog + Asselin filter time stepping
129      IF( neuler == 0 .AND. kt == nittrc000 ) THEN        ! Euler time-stepping at first time-step
130         !                                                ! (only swap)
131         DO jn = 1, jptra
132            DO jk = 1, jpkm1
133               trn(:,:,jk,jn) = tra(:,:,jk,jn)
134            END DO
135         END DO
136         !                                             
137      ELSE
138         ! Leap-Frog + Asselin filter time stepping
139         IF( lk_vvl ) THEN   ;   CALL tra_nxt_vvl( kt, nittrc000, rdttrc, 'TRC', trb, trn, tra,      &
140           &                                                                sbc_trc, sbc_trc_b, jptra )      ! variable volume level (vvl)
141         ELSE                ;   CALL tra_nxt_fix( kt, nittrc000,         'TRC', trb, trn, tra, jptra )      ! fixed    volume level
142         ENDIF
143      ENDIF
144
145      ! trends computation
146      IF( l_trdtrc ) THEN                                      ! trends
147         DO jn = 1, jptra
148            DO jk = 1, jpkm1
149               zfact = 1.e0 / r2dt(jk) 
150               ztrdt(:,:,jk,jn) = ( trb(:,:,jk,jn) - ztrdt(:,:,jk,jn) ) * zfact 
151               CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt )
152            END DO
153         END DO
154         CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrdt ) 
155      END IF
156      !
157      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
158         WRITE(charout, FMT="('nxt')")
159         CALL prt_ctl_trc_info(charout)
160         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
161      ENDIF
162      !
163      IF( nn_timing == 1 )  CALL timing_stop('trc_nxt')
164      !
165   END SUBROUTINE trc_nxt
166
167#else
168   !!----------------------------------------------------------------------
169   !!   Default option                                         Empty module
170   !!----------------------------------------------------------------------
171CONTAINS
172   SUBROUTINE trc_nxt( kt ) 
173      INTEGER, INTENT(in) :: kt
174      WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt
175   END SUBROUTINE trc_nxt
176#endif
177   !!======================================================================
178END MODULE trcnxt
Note: See TracBrowser for help on using the repository browser.