New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limdyn.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limdyn.F90 @ 5053

Last change on this file since 5053 was 5053, checked in by clem, 9 years ago

LIM3 cleaning continues. No change in the physics besides the introduction of the monocategory sea ice
  • Property svn:keywords set to Id
File size: 13.8 KB
Line 
1MODULE limdyn
2   !!======================================================================
3   !!                     ***  MODULE  limdyn  ***
4   !!   Sea-Ice dynamics : 
5   !!======================================================================
6   !! history :  1.0  ! 2002-08  (C. Ethe, G. Madec)  original VP code
7   !!            3.0  ! 2007-03  (MA Morales Maqueda, S. Bouillon, M. Vancoppenolle)  LIM3: EVP-Cgrid
8   !!            4.0  ! 2011-02  (G. Madec) dynamical allocation
9   !!----------------------------------------------------------------------
10#if defined key_lim3
11   !!----------------------------------------------------------------------
12   !!   'key_lim3' :                                 LIM3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!    lim_dyn      : computes ice velocities
15   !!    lim_dyn_init : initialization and namelist read
16   !!----------------------------------------------------------------------
17   USE phycst           ! physical constants
18   USE dom_oce          ! ocean space and time domain
19   USE sbc_oce          ! Surface boundary condition: ocean fields
20   USE sbc_ice          ! Surface boundary condition: ice   fields
21   USE ice              ! LIM-3 variables
22   USE par_ice          ! LIM-3 parameters
23   USE dom_ice          ! LIM-3 domain
24   USE limrhg           ! LIM-3 rheology
25   USE lbclnk           ! lateral boundary conditions - MPP exchanges
26   USE lib_mpp          ! MPP library
27   USE wrk_nemo         ! work arrays
28   USE in_out_manager   ! I/O manager
29   USE prtctl           ! Print control
30   USE lib_fortran      ! glob_sum
31   USE timing          ! Timing
32   USE limcons        ! conservation tests
33   USE limvar
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   lim_dyn   ! routine called by ice_step
39
40   !! * Substitutions
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2011)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE lim_dyn( kt )
50      !!-------------------------------------------------------------------
51      !!               ***  ROUTINE lim_dyn  ***
52      !!               
53      !! ** Purpose :   compute ice velocity and ocean-ice stress
54      !!               
55      !! ** Method  :
56      !!
57      !! ** Action  : - Initialisation
58      !!              - Call of the dynamic routine for each hemisphere
59      !!              - computation of the stress at the ocean surface         
60      !!              - treatment of the case if no ice dynamic
61      !!------------------------------------------------------------------------------------
62      INTEGER, INTENT(in) ::   kt     ! number of iteration
63      !!
64      INTEGER  ::   ji, jj, jl, ja    ! dummy loop indices
65      INTEGER  ::   i_j1, i_jpj       ! Starting/ending j-indices for rheology
66      REAL(wp) ::   zcoef             ! local scalar
67      REAL(wp), POINTER, DIMENSION(:)   ::   zswitch        ! i-averaged indicator of sea-ice
68      REAL(wp), POINTER, DIMENSION(:)   ::   zmsk           ! i-averaged of tmask
69      REAL(wp), POINTER, DIMENSION(:,:) ::   zu_io, zv_io   ! ice-ocean velocity
70      !
71      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
72     !!---------------------------------------------------------------------
73
74      IF( nn_timing == 1 )  CALL timing_start('limdyn')
75
76      CALL wrk_alloc( jpi, jpj, zu_io, zv_io )
77      CALL wrk_alloc( jpj, zswitch, zmsk )
78
79      CALL lim_var_agg(1)             ! aggregate ice categories
80
81      IF( kt == nit000 )   CALL lim_dyn_init   ! Initialization (first time-step only)
82
83      IF( ln_limdyn ) THEN
84         !
85         ! conservation test
86         IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limdyn', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
87
88         u_ice_b(:,:) = u_ice(:,:) * tmu(:,:)
89         v_ice_b(:,:) = v_ice(:,:) * tmv(:,:)
90
91         ! Rheology (ice dynamics)
92         ! ========
93
94         !  Define the j-limits where ice rheology is computed
95         ! ---------------------------------------------------
96
97         IF( lk_mpp .OR. lk_mpp_rep ) THEN                    ! mpp: compute over the whole domain
98            i_j1 = 1
99            i_jpj = jpj
100            IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn  :    i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj )
101            CALL lim_rhg( i_j1, i_jpj )
102         ELSE                                 ! optimization of the computational area
103            !
104            DO jj = 1, jpj
105               zswitch(jj) = SUM( 1.0 - at_i(:,jj) )   ! = REAL(jpj) if ocean everywhere on a j-line
106               zmsk(jj) = SUM( tmask(:,jj,1)    )   ! = 0         if land  everywhere on a j-line
107            END DO
108
109            IF( l_jeq ) THEN                     ! local domain include both hemisphere
110               !                                 ! Rheology is computed in each hemisphere
111               !                                 ! only over the ice cover latitude strip
112               ! Northern hemisphere
113               i_j1  = njeq
114               i_jpj = jpj
115               DO WHILE ( i_j1 <= jpj .AND. zswitch(i_j1) == FLOAT(jpi) .AND. zmsk(i_j1) /=0 )
116                  i_j1 = i_j1 + 1
117               END DO
118               i_j1 = MAX( 1, i_j1-2 )
119               IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn  : NH  i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj )
120               CALL lim_rhg( i_j1, i_jpj )
121               !
122               ! Southern hemisphere
123               i_j1  =  1
124               i_jpj = njeq
125               DO WHILE ( i_jpj >= 1 .AND. zswitch(i_jpj) == FLOAT(jpi) .AND. zmsk(i_jpj) /=0 )
126                  i_jpj = i_jpj - 1
127               END DO
128               i_jpj = MIN( jpj, i_jpj+1 )
129               IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn  : SH  i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj )
130               !
131               CALL lim_rhg( i_j1, i_jpj )
132               !
133            ELSE                                 ! local domain extends over one hemisphere only
134               !                                 ! Rheology is computed only over the ice cover
135               !                                 ! latitude strip
136               i_j1  = 1
137               DO WHILE ( i_j1 <= jpj .AND. zswitch(i_j1) == FLOAT(jpi) .AND. zmsk(i_j1) /=0 )
138                  i_j1 = i_j1 + 1
139               END DO
140               i_j1 = MAX( 1, i_j1-2 )
141
142               i_jpj  = jpj
143               DO WHILE ( i_jpj >= 1  .AND. zswitch(i_jpj) == FLOAT(jpi) .AND. zmsk(i_jpj) /=0 )
144                  i_jpj = i_jpj - 1
145               END DO
146               i_jpj = MIN( jpj, i_jpj+1)
147               !
148               IF(ln_ctl) CALL prt_ctl_info( 'lim_dyn  : one hemisphere:  i_j1 = ', ivar1=i_j1, clinfo2=' ij_jpj = ', ivar2=i_jpj )
149               !
150               CALL lim_rhg( i_j1, i_jpj )
151               !
152            ENDIF
153            !
154         ENDIF
155
156         ! computation of friction velocity
157         ! --------------------------------
158         ! ice-ocean velocity at U & V-points (u_ice v_ice at U- & V-points ; ssu_m, ssv_m at U- & V-points)
159         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
160         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
161         ! frictional velocity at T-point
162         zcoef = 0.5_wp * cw
163         DO jj = 2, jpjm1 
164            DO ji = fs_2, fs_jpim1   ! vector opt.
165               ust2s(ji,jj) = zcoef * (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
166                  &                    + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1)   ) * tms(ji,jj)
167            END DO
168         END DO
169         !
170         ! conservation test
171         IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limdyn', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
172         !
173      ELSE      ! no ice dynamics : transmit directly the atmospheric stress to the ocean
174         !
175         zcoef = SQRT( 0.5_wp ) / rau0
176         DO jj = 2, jpjm1
177            DO ji = fs_2, fs_jpim1   ! vector opt.
178               ust2s(ji,jj) = zcoef * SQRT(  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
179                  &                        + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1)   ) * tms(ji,jj)
180            END DO
181         END DO
182         !
183      ENDIF
184      CALL lbc_lnk( ust2s, 'T',  1. )   ! T-point
185
186      IF(ln_ctl) THEN   ! Control print
187         CALL prt_ctl_info(' ')
188         CALL prt_ctl_info(' - Cell values : ')
189         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
190         CALL prt_ctl(tab2d_1=ust2s     , clinfo1=' lim_dyn  : ust2s     :')
191         CALL prt_ctl(tab2d_1=divu_i    , clinfo1=' lim_dyn  : divu_i    :')
192         CALL prt_ctl(tab2d_1=delta_i   , clinfo1=' lim_dyn  : delta_i   :')
193         CALL prt_ctl(tab2d_1=strength  , clinfo1=' lim_dyn  : strength  :')
194         CALL prt_ctl(tab2d_1=area      , clinfo1=' lim_dyn  : cell area :')
195         CALL prt_ctl(tab2d_1=at_i      , clinfo1=' lim_dyn  : at_i      :')
196         CALL prt_ctl(tab2d_1=vt_i      , clinfo1=' lim_dyn  : vt_i      :')
197         CALL prt_ctl(tab2d_1=vt_s      , clinfo1=' lim_dyn  : vt_s      :')
198         CALL prt_ctl(tab2d_1=stress1_i , clinfo1=' lim_dyn  : stress1_i :')
199         CALL prt_ctl(tab2d_1=stress2_i , clinfo1=' lim_dyn  : stress2_i :')
200         CALL prt_ctl(tab2d_1=stress12_i, clinfo1=' lim_dyn  : stress12_i:')
201         DO jl = 1, jpl
202            CALL prt_ctl_info(' ')
203            CALL prt_ctl_info(' - Category : ', ivar1=jl)
204            CALL prt_ctl_info('   ~~~~~~~~~~')
205            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_dyn  : a_i      : ')
206            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_dyn  : ht_i     : ')
207            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_dyn  : ht_s     : ')
208            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_dyn  : v_i      : ')
209            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_dyn  : v_s      : ')
210            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_dyn  : e_s      : ')
211            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_dyn  : t_su     : ')
212            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_dyn  : t_snow   : ')
213            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_dyn  : sm_i     : ')
214            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_dyn  : smv_i    : ')
215            DO ja = 1, nlay_i
216               CALL prt_ctl_info(' ')
217               CALL prt_ctl_info(' - Layer : ', ivar1=ja)
218               CALL prt_ctl_info('   ~~~~~~~')
219               CALL prt_ctl(tab2d_1=t_i(:,:,ja,jl) , clinfo1= ' lim_dyn  : t_i      : ')
220               CALL prt_ctl(tab2d_1=e_i(:,:,ja,jl) , clinfo1= ' lim_dyn  : e_i      : ')
221            END DO
222         END DO
223      ENDIF
224      !
225      CALL wrk_dealloc( jpi, jpj, zu_io, zv_io )
226      CALL wrk_dealloc( jpj, zswitch, zmsk )
227      !
228      IF( nn_timing == 1 )  CALL timing_stop('limdyn')
229
230   END SUBROUTINE lim_dyn
231
232
233   SUBROUTINE lim_dyn_init
234      !!-------------------------------------------------------------------
235      !!                  ***  ROUTINE lim_dyn_init  ***
236      !!
237      !! ** Purpose : Physical constants and parameters linked to the ice
238      !!      dynamics
239      !!
240      !! ** Method  :  Read the namicedyn namelist and check the ice-dynamic
241      !!       parameter values called at the first timestep (nit000)
242      !!
243      !! ** input   :   Namelist namicedyn
244      !!-------------------------------------------------------------------
245      INTEGER  ::   ios                 ! Local integer output status for namelist read
246      NAMELIST/namicedyn/ cw, pstar, c_rhg, creepl, ecc, ahi0, nevp, relast
247      !!-------------------------------------------------------------------
248
249      REWIND( numnam_ice_ref )              ! Namelist namicedyn in reference namelist : Ice dynamics
250      READ  ( numnam_ice_ref, namicedyn, IOSTAT = ios, ERR = 901)
251901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicedyn in reference namelist', lwp )
252
253      REWIND( numnam_ice_cfg )              ! Namelist namicedyn in configuration namelist : Ice dynamics
254      READ  ( numnam_ice_cfg, namicedyn, IOSTAT = ios, ERR = 902 )
255902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicedyn in configuration namelist', lwp )
256      IF(lwm) WRITE ( numoni, namicedyn )
257     
258      IF(lwp) THEN                        ! control print
259         WRITE(numout,*)
260         WRITE(numout,*) 'lim_dyn_init : ice parameters for ice dynamics '
261         WRITE(numout,*) '~~~~~~~~~~~~'
262         WRITE(numout,*) '   drag coefficient for oceanic stress              cw     = ', cw
263         WRITE(numout,*) '   first bulk-rheology parameter                    pstar  = ', pstar
264         WRITE(numout,*) '   second bulk-rhelogy parameter                    c_rhg  = ', c_rhg
265         WRITE(numout,*) '   creep limit                                      creepl = ', creepl
266         WRITE(numout,*) '   eccentricity of the elliptical yield curve       ecc    = ', ecc
267         WRITE(numout,*) '   horizontal diffusivity coeff. for sea-ice        ahi0   = ', ahi0
268         WRITE(numout,*) '   number of iterations for subcycling              nevp   = ', nevp
269         WRITE(numout,*) '   ratio of elastic timescale over ice time step    relast = ', relast
270      ENDIF
271      !
272      usecc2 = 1._wp / ( ecc * ecc )
273      rhoco  = rau0  * cw
274
275      !  Diffusion coefficients.
276      ahiu(:,:) = ahi0 * umask(:,:,1)
277      ahiv(:,:) = ahi0 * vmask(:,:,1)
278      !
279   END SUBROUTINE lim_dyn_init
280
281#else
282   !!----------------------------------------------------------------------
283   !!   Default option          Empty module           NO LIM sea-ice model
284   !!----------------------------------------------------------------------
285CONTAINS
286   SUBROUTINE lim_dyn         ! Empty routine
287   END SUBROUTINE lim_dyn
288#endif 
289
290   !!======================================================================
291END MODULE limdyn
Note: See TracBrowser for help on using the repository browser.