New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limitd_th.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limitd_th.F90 @ 5048

Last change on this file since 5048 was 5048, checked in by vancop, 9 years ago

new itd boundaries, namelist changes, mono-category and comments
  • Property svn:keywords set to Id
File size: 45.4 KB
Line 
1MODULE limitd_th
2   !!======================================================================
3   !!                       ***  MODULE limitd_th ***
4   !!   LIM3 ice model : ice thickness distribution: Thermodynamics
5   !!======================================================================
6   !! History :   -   !          (W. H. Lipscomb and E.C. Hunke) CICE (c) original code
7   !!            3.0  ! 2005-12  (M. Vancoppenolle) adaptation to LIM-3
8   !!             -   ! 2006-06  (M. Vancoppenolle) adaptation to include salt, age
9   !!             -   ! 2007-04  (M. Vancoppenolle) Mass conservation checked
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3' :                                   LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_itd_th       : thermodynamics of ice thickness distribution
16   !!   lim_itd_th_rem   :
17   !!   lim_itd_th_reb   :
18   !!   lim_itd_fitline  :
19   !!   lim_itd_shiftice :
20   !!----------------------------------------------------------------------
21   USE dom_ice          ! LIM-3 domain
22   USE par_oce          ! ocean parameters
23   USE dom_oce          ! ocean domain
24   USE phycst           ! physical constants (ocean directory)
25   USE thd_ice          ! LIM-3 thermodynamic variables
26   USE ice              ! LIM-3 variables
27   USE par_ice          ! LIM-3 parameters
28   USE limthd_lac       ! LIM-3 lateral accretion
29   USE limvar           ! LIM-3 variables
30   USE limcons          ! LIM-3 conservation
31   USE prtctl           ! Print control
32   USE in_out_manager   ! I/O manager
33   USE lib_mpp          ! MPP library
34   USE wrk_nemo         ! work arrays
35   USE lib_fortran      ! to use key_nosignedzero
36   USE timing          ! Timing
37   USE limcons        ! conservation tests
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   lim_itd_th         ! called by ice_stp
43   PUBLIC   lim_itd_th_rem
44   PUBLIC   lim_itd_th_reb
45   PUBLIC   lim_itd_fitline
46   PUBLIC   lim_itd_shiftice
47
48   !!----------------------------------------------------------------------
49   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE lim_itd_th( kt )
56      !!------------------------------------------------------------------
57      !!                ***  ROUTINE lim_itd_th ***
58      !!
59      !! ** Purpose :   computes the thermodynamics of ice thickness distribution
60      !!
61      !! ** Method  :
62      !!------------------------------------------------------------------
63      INTEGER, INTENT(in) ::   kt   ! time step index
64      !
65      INTEGER ::   ji, jj, jk, jl   ! dummy loop index         
66      !
67      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
68      !!------------------------------------------------------------------
69      IF( nn_timing == 1 )  CALL timing_start('limitd_th')
70
71      ! conservation test
72      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
73
74      IF( kt == nit000 .AND. lwp ) THEN
75         WRITE(numout,*)
76         WRITE(numout,*) 'lim_itd_th  : Thermodynamics of the ice thickness distribution'
77         WRITE(numout,*) '~~~~~~~~~~~'
78      ENDIF
79
80      !------------------------------------------------------------------------------|
81      !  1) Transport of ice between thickness categories.                           |
82      !------------------------------------------------------------------------------|
83      ! Given thermodynamic growth rates, transport ice between
84      ! thickness categories.
85      IF( jpl > 1 )   CALL lim_itd_th_rem( 1, jpl, kt )
86      !
87      CALL lim_var_glo2eqv    ! only for info
88      CALL lim_var_agg(1)
89
90      !------------------------------------------------------------------------------|
91      !  3) Add frazil ice growing in leads.
92      !------------------------------------------------------------------------------|
93      CALL lim_thd_lac
94      CALL lim_var_glo2eqv    ! only for info
95
96      ! MV: Could put lateral melting here, would be better I think ???
97
98     
99      IF(ln_ctl) THEN   ! Control print
100         CALL prt_ctl_info(' ')
101         CALL prt_ctl_info(' - Cell values : ')
102         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
103         CALL prt_ctl(tab2d_1=area , clinfo1=' lim_itd_th  : cell area :')
104         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
105         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
106         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
107         DO jl = 1, jpl
108            CALL prt_ctl_info(' ')
109            CALL prt_ctl_info(' - Category : ', ivar1=jl)
110            CALL prt_ctl_info('   ~~~~~~~~~~')
111            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
112            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
113            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
114            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
115            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
116            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
117            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
118            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
119            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
120            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
121            DO jk = 1, nlay_i
122               CALL prt_ctl_info(' ')
123               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
124               CALL prt_ctl_info('   ~~~~~~~')
125               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
126               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
127            END DO
128         END DO
129      ENDIF
130      !
131      ! conservation test
132      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
133      !
134     IF( nn_timing == 1 )  CALL timing_stop('limitd_th')
135   END SUBROUTINE lim_itd_th
136   !
137
138   SUBROUTINE lim_itd_th_rem( klbnd, kubnd, kt )
139      !!------------------------------------------------------------------
140      !!                ***  ROUTINE lim_itd_th_rem ***
141      !!
142      !! ** Purpose :   computes the redistribution of ice thickness
143      !!              after thermodynamic growth of ice thickness
144      !!
145      !! ** Method  : Linear remapping
146      !!
147      !! References : W.H. Lipscomb, JGR 2001
148      !!------------------------------------------------------------------
149      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
150      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
151      INTEGER , INTENT (in) ::   kt      ! Ocean time step
152      !
153      INTEGER  ::   ji, jj, jl     ! dummy loop index
154      INTEGER  ::   ii, ij         ! 2D corresponding indices to ji
155      INTEGER  ::   nd             ! local integer
156      REAL(wp) ::   zx1, zwk1, zdh0, zetamin, zdamax   ! local scalars
157      REAL(wp) ::   zx2, zwk2, zda0, zetamax           !   -      -
158      REAL(wp) ::   zx3,             zareamin          !   -      -
159      CHARACTER (len = 15) :: fieldid
160
161      INTEGER , POINTER, DIMENSION(:,:,:) ::   zdonor   ! donor category index
162
163      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdhice      ! ice thickness increment
164      REAL(wp), POINTER, DIMENSION(:,:,:) ::   g0          ! coefficients for fitting the line of the ITD
165      REAL(wp), POINTER, DIMENSION(:,:,:) ::   g1          ! coefficients for fitting the line of the ITD
166      REAL(wp), POINTER, DIMENSION(:,:,:) ::   hL          ! left boundary for the ITD for each thickness
167      REAL(wp), POINTER, DIMENSION(:,:,:) ::   hR          ! left boundary for the ITD for each thickness
168      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zht_i_b     ! old ice thickness
169      REAL(wp), POINTER, DIMENSION(:,:,:) ::   dummy_es
170      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdaice, zdvice          ! local increment of ice area and volume
171      REAL(wp), POINTER, DIMENSION(:)     ::   zvetamin, zvetamax      ! maximum values for etas
172      INTEGER , POINTER, DIMENSION(:)     ::   nind_i, nind_j          ! compressed indices for i/j directions
173      INTEGER                             ::   nbrem                   ! number of cells with ice to transfer
174      REAL(wp)                            ::   zslope                  ! used to compute local thermodynamic "speeds"
175      REAL(wp), POINTER, DIMENSION(:,:)   ::   zhb0, zhb1              ! category boundaries for thinnes categories
176      REAL(wp), POINTER, DIMENSION(:,:)   ::   vt_i_init, vt_i_final   !  ice volume summed over categories
177      REAL(wp), POINTER, DIMENSION(:,:)   ::   vt_s_init, vt_s_final   !  snow volume summed over categories
178      REAL(wp), POINTER, DIMENSION(:,:)   ::   et_i_init, et_i_final   !  ice energy summed over categories
179      REAL(wp), POINTER, DIMENSION(:,:)   ::   et_s_init, et_s_final   !  snow energy summed over categories
180      INTEGER , POINTER, DIMENSION(:,:)   ::   zremap_flag      ! compute remapping or not ????
181      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhbnew           ! new boundaries of ice categories
182      !!------------------------------------------------------------------
183
184      CALL wrk_alloc( jpi,jpj, zremap_flag )    ! integer
185      CALL wrk_alloc( jpi,jpj,jpl-1, zdonor )   ! integer
186      CALL wrk_alloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_b, dummy_es )
187      CALL wrk_alloc( jpi,jpj,jpl-1, zdaice, zdvice )   
188      CALL wrk_alloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )   
189      CALL wrk_alloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )   
190      CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
191      CALL wrk_alloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
192
193      zareamin = epsi10   !minimum area in thickness categories tolerated by the conceptors of the model
194
195      !!----------------------------------------------------------------------------------------------
196      !! 0) Conservation checkand changes in each ice category
197      !!----------------------------------------------------------------------------------------------
198      IF( con_i ) THEN
199         CALL lim_column_sum (jpl,   v_i, vt_i_init)
200         CALL lim_column_sum (jpl,   v_s, vt_s_init)
201         CALL lim_column_sum_energy (jpl, nlay_i,   e_i, et_i_init)
202         dummy_es(:,:,:) = e_s(:,:,1,:)
203         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_init)
204      ENDIF
205
206      !!----------------------------------------------------------------------------------------------
207      !! 1) Compute thickness and changes in each ice category
208      !!----------------------------------------------------------------------------------------------
209      IF( kt == nit000 .AND. lwp) THEN
210         WRITE(numout,*)
211         WRITE(numout,*) 'lim_itd_th_rem  : Remapping the ice thickness distribution'
212         WRITE(numout,*) '~~~~~~~~~~~~~~~'
213         WRITE(numout,*) ' klbnd :       ', klbnd
214         WRITE(numout,*) ' kubnd :       ', kubnd
215      ENDIF
216
217      zdhice(:,:,:) = 0._wp
218      DO jl = klbnd, kubnd
219         DO jj = 1, jpj
220            DO ji = 1, jpi
221               rswitch             = 1.0 - MAX( 0.0, SIGN( 1.0, - a_i(ji,jj,jl) + epsi10 ) )     !0 if no ice and 1 if yes
222               ht_i(ji,jj,jl)    = v_i(ji,jj,jl) / MAX( a_i(ji,jj,jl), epsi10 ) * rswitch
223               rswitch             = 1.0 - MAX( 0.0, SIGN( 1.0, - a_i_b(ji,jj,jl) + epsi10) ) !0 if no ice and 1 if yes
224               zht_i_b(ji,jj,jl) = v_i_b(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 ) * rswitch
225               IF( a_i(ji,jj,jl) > epsi10 )   zdhice(ji,jj,jl) = ht_i(ji,jj,jl) - zht_i_b(ji,jj,jl) 
226            END DO
227         END DO
228      END DO
229
230      !-----------------------------------------------------------------------------------------------
231      !  2) Compute fractional ice area in each grid cell
232      !-----------------------------------------------------------------------------------------------
233      at_i(:,:) = 0._wp
234      DO jl = klbnd, kubnd
235         at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
236      END DO
237
238      !-----------------------------------------------------------------------------------------------
239      !  3) Identify grid cells with ice
240      !-----------------------------------------------------------------------------------------------
241      nbrem = 0
242      DO jj = 1, jpj
243         DO ji = 1, jpi
244            IF ( at_i(ji,jj) .gt. zareamin ) THEN
245               nbrem         = nbrem + 1
246               nind_i(nbrem) = ji
247               nind_j(nbrem) = jj
248               zremap_flag(ji,jj) = 1
249            ELSE
250               zremap_flag(ji,jj) = 0
251            ENDIF
252         END DO !ji
253      END DO !jj
254
255      !-----------------------------------------------------------------------------------------------
256      !  4) Compute new category boundaries
257      !-----------------------------------------------------------------------------------------------
258      !- 4.1 Compute category boundaries
259      ! Tricky trick see limitd_me.F90
260      ! will be soon removed, CT
261      ! hi_max(kubnd) = 99.
262      zhbnew(:,:,:) = 0._wp
263
264      DO jl = klbnd, kubnd - 1
265         DO ji = 1, nbrem
266            ii = nind_i(ji)
267            ij = nind_j(ji)
268            !
269            zhbnew(ii,ij,jl) = hi_max(jl)
270            IF ( a_i_b(ii,ij,jl) > epsi10 .AND. a_i_b(ii,ij,jl+1) > epsi10 ) THEN
271               !interpolate between adjacent category growth rates
272               zslope           = ( zdhice(ii,ij,jl+1) - zdhice(ii,ij,jl) ) / ( zht_i_b(ii,ij,jl+1) - zht_i_b(ii,ij,jl) )
273               zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl) + zslope * ( hi_max(jl) - zht_i_b(ii,ij,jl) )
274            ELSEIF ( a_i_b(ii,ij,jl) > epsi10) THEN
275               zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl)
276            ELSEIF ( a_i_b(ii,ij,jl+1) > epsi10) THEN
277               zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl+1)
278            ENDIF
279         END DO
280
281         !- 4.2 Check that each zhbnew lies between adjacent values of ice thickness
282         DO ji = 1, nbrem
283            ii = nind_i(ji)
284            ij = nind_j(ji)
285            IF( a_i(ii,ij,jl) > epsi10 .AND. ht_i(ii,ij,jl) >= zhbnew(ii,ij,jl) ) THEN
286               zremap_flag(ii,ij) = 0
287            ELSEIF( a_i(ii,ij,jl+1) > epsi10 .AND. ht_i(ii,ij,jl+1) <= zhbnew(ii,ij,jl) ) THEN
288               zremap_flag(ii,ij) = 0
289            ENDIF
290
291            !- 4.3 Check that each zhbnew does not exceed maximal values hi_max 
292            IF( zhbnew(ii,ij,jl) > hi_max(jl+1) ) zremap_flag(ii,ij) = 0
293            IF( zhbnew(ii,ij,jl) < hi_max(jl-1) ) zremap_flag(ii,ij) = 0
294         END DO
295
296      END DO !jl
297
298      !-----------------------------------------------------------------------------------------------
299      !  5) Identify cells where ITD is to be remapped
300      !-----------------------------------------------------------------------------------------------
301      nbrem = 0
302      DO jj = 1, jpj
303         DO ji = 1, jpi
304            IF( zremap_flag(ji,jj) == 1 ) THEN
305               nbrem         = nbrem + 1
306               nind_i(nbrem) = ji
307               nind_j(nbrem) = jj
308            ENDIF
309         END DO
310      END DO 
311
312      !-----------------------------------------------------------------------------------------------
313      !  6) Fill arrays with lowermost / uppermost boundaries of 'new' categories
314      !-----------------------------------------------------------------------------------------------
315      DO jj = 1, jpj
316         DO ji = 1, jpi
317            zhb0(ji,jj) = hi_max(0) ! 0eme
318            zhb1(ji,jj) = hi_max(1) ! 1er
319
320            zhbnew(ji,jj,klbnd-1) = 0._wp
321
322            IF( a_i(ji,jj,kubnd) > epsi10 ) THEN
323               zhbnew(ji,jj,kubnd) = 3._wp * ht_i(ji,jj,kubnd) - 2._wp * zhbnew(ji,jj,kubnd-1)
324            ELSE
325               zhbnew(ji,jj,kubnd) = hi_max(kubnd) 
326               !!? clem bug: since hi_max(jpl)=99, this limit is very high
327               !!? but I think it is erased in fitline subroutine
328            ENDIF
329
330            IF( zhbnew(ji,jj,kubnd) < hi_max(kubnd-1) ) zhbnew(ji,jj,kubnd) = hi_max(kubnd-1)
331
332         END DO !jj
333      END DO !jj
334
335      !-----------------------------------------------------------------------------------------------
336      !  7) Compute g(h)
337      !-----------------------------------------------------------------------------------------------
338      !- 7.1 g(h) for category 1 at start of time step
339      CALL lim_itd_fitline( klbnd, zhb0, zhb1, zht_i_b(:,:,klbnd),         &
340         &                  g0(:,:,klbnd), g1(:,:,klbnd), hL(:,:,klbnd),   &
341         &                  hR(:,:,klbnd), zremap_flag )
342
343      !- 7.2 Area lost due to melting of thin ice (first category,  klbnd)
344      DO ji = 1, nbrem
345         ii = nind_i(ji) 
346         ij = nind_j(ji) 
347
348         !ji
349         IF (a_i(ii,ij,klbnd) .gt. epsi10) THEN
350            zdh0 = zdhice(ii,ij,klbnd) !decrease of ice thickness in the lower category
351            ! ji, a_i > epsi10
352            IF (zdh0 .lt. 0.0) THEN !remove area from category 1
353               ! ji, a_i > epsi10; zdh0 < 0
354               zdh0 = MIN(-zdh0,hi_max(klbnd))
355
356               !Integrate g(1) from 0 to dh0 to estimate area melted
357               zetamax = MIN(zdh0,hR(ii,ij,klbnd)) - hL(ii,ij,klbnd)
358               IF (zetamax.gt.0.0) THEN
359                  zx1  = zetamax
360                  zx2  = 0.5 * zetamax*zetamax 
361                  zda0 = g1(ii,ij,klbnd) * zx2 + g0(ii,ij,klbnd) * zx1 !ice area removed
362                  ! Constrain new thickness <= ht_i
363                  zdamax = a_i(ii,ij,klbnd) * & 
364                     (1.0 - ht_i(ii,ij,klbnd)/zht_i_b(ii,ij,klbnd)) ! zdamax > 0
365                  !ice area lost due to melting of thin ice
366                  zda0   = MIN(zda0, zdamax)
367
368                  ! Remove area, conserving volume
369                  ht_i(ii,ij,klbnd) = ht_i(ii,ij,klbnd) & 
370                     * a_i(ii,ij,klbnd) / ( a_i(ii,ij,klbnd) - zda0 )
371                  a_i(ii,ij,klbnd)  = a_i(ii,ij,klbnd) - zda0
372                  v_i(ii,ij,klbnd)  = a_i(ii,ij,klbnd)*ht_i(ii,ij,klbnd) ! clem-useless ?
373               ENDIF     ! zetamax > 0
374               ! ji, a_i > epsi10
375
376            ELSE ! if ice accretion
377               ! ji, a_i > epsi10; zdh0 > 0
378               zhbnew(ii,ij,klbnd-1) = MIN(zdh0,hi_max(klbnd)) 
379               ! zhbnew was 0, and is shifted to the right to account for thin ice
380               ! growth in openwater (F0 = f1)
381            ENDIF ! zdh0
382
383            ! a_i > epsi10
384         ENDIF ! a_i > epsi10
385
386      END DO ! ji
387
388      !- 7.3 g(h) for each thickness category 
389      DO jl = klbnd, kubnd
390         CALL lim_itd_fitline(jl, zhbnew(:,:,jl-1), zhbnew(:,:,jl), ht_i(:,:,jl), &
391            g0(:,:,jl), g1(:,:,jl), hL(:,:,jl), hR(:,:,jl), zremap_flag)
392      END DO
393
394      !-----------------------------------------------------------------------------------------------
395      !  8) Compute area and volume to be shifted across each boundary
396      !-----------------------------------------------------------------------------------------------
397
398      DO jl = klbnd, kubnd - 1
399         DO jj = 1, jpj
400            DO ji = 1, jpi
401               zdonor(ji,jj,jl) = 0
402               zdaice(ji,jj,jl) = 0.0
403               zdvice(ji,jj,jl) = 0.0
404            END DO
405         END DO
406
407         DO ji = 1, nbrem
408            ii = nind_i(ji)
409            ij = nind_j(ji)
410
411            IF (zhbnew(ii,ij,jl) .gt. hi_max(jl)) THEN ! transfer from jl to jl+1
412
413               ! left and right integration limits in eta space
414               zvetamin(ji) = MAX(hi_max(jl), hL(ii,ij,jl)) - hL(ii,ij,jl)
415               zvetamax(ji) = MIN(zhbnew(ii,ij,jl), hR(ii,ij,jl)) - hL(ii,ij,jl)
416               zdonor(ii,ij,jl) = jl
417
418            ELSE  ! zhbnew(jl) <= hi_max(jl) ; transfer from jl+1 to jl
419
420               ! left and right integration limits in eta space
421               zvetamin(ji) = 0.0
422               zvetamax(ji) = MIN(hi_max(jl), hR(ii,ij,jl+1)) - hL(ii,ij,jl+1)
423               zdonor(ii,ij,jl) = jl + 1
424
425            ENDIF  ! zhbnew(jl) > hi_max(jl)
426
427            zetamax = MAX(zvetamax(ji), zvetamin(ji)) ! no transfer if etamax < etamin
428            zetamin = zvetamin(ji)
429
430            zx1  = zetamax - zetamin
431            zwk1 = zetamin*zetamin
432            zwk2 = zetamax*zetamax
433            zx2  = 0.5 * (zwk2 - zwk1)
434            zwk1 = zwk1 * zetamin
435            zwk2 = zwk2 * zetamax
436            zx3  = 1.0/3.0 * (zwk2 - zwk1)
437            nd   = zdonor(ii,ij,jl)
438            zdaice(ii,ij,jl) = g1(ii,ij,nd)*zx2 + g0(ii,ij,nd)*zx1
439            zdvice(ii,ij,jl) = g1(ii,ij,nd)*zx3 + g0(ii,ij,nd)*zx2 + zdaice(ii,ij,jl)*hL(ii,ij,nd)
440
441         END DO ! ji
442      END DO ! jl klbnd -> kubnd - 1
443
444      !!----------------------------------------------------------------------------------------------
445      !! 9) Shift ice between categories
446      !!----------------------------------------------------------------------------------------------
447      CALL lim_itd_shiftice ( klbnd, kubnd, zdonor, zdaice, zdvice )
448
449      !!----------------------------------------------------------------------------------------------
450      !! 10) Make sure ht_i >= minimum ice thickness hi_min
451      !!----------------------------------------------------------------------------------------------
452
453      DO ji = 1, nbrem
454         ii = nind_i(ji)
455         ij = nind_j(ji)
456         IF ( a_i(ii,ij,1) > epsi10 .AND. ht_i(ii,ij,1) < hiclim ) THEN
457            a_i(ii,ij,1)  = a_i(ii,ij,1) * ht_i(ii,ij,1) / hiclim 
458            ht_i(ii,ij,1) = hiclim
459         ENDIF
460      END DO !ji
461
462      !!----------------------------------------------------------------------------------------------
463      !! 11) Conservation check
464      !!----------------------------------------------------------------------------------------------
465      IF ( con_i ) THEN
466         CALL lim_column_sum (jpl,   v_i, vt_i_final)
467         fieldid = ' v_i : limitd_th '
468         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
469
470         CALL lim_column_sum_energy (jpl, nlay_i,  e_i, et_i_final)
471         fieldid = ' e_i : limitd_th '
472         CALL lim_cons_check (et_i_init, et_i_final, 1.0e-3, fieldid) 
473
474         CALL lim_column_sum (jpl,   v_s, vt_s_final)
475         fieldid = ' v_s : limitd_th '
476         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
477
478         dummy_es(:,:,:) = e_s(:,:,1,:)
479         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_final)
480         fieldid = ' e_s : limitd_th '
481         CALL lim_cons_check (et_s_init, et_s_final, 1.0e-3, fieldid) 
482      ENDIF
483
484      CALL wrk_dealloc( jpi,jpj, zremap_flag )    ! integer
485      CALL wrk_dealloc( jpi,jpj,jpl-1, zdonor )   ! integer
486      CALL wrk_dealloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_b, dummy_es )
487      CALL wrk_dealloc( jpi,jpj,jpl-1, zdaice, zdvice )   
488      CALL wrk_dealloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )   
489      CALL wrk_dealloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )   
490      CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
491      CALL wrk_dealloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
492
493   END SUBROUTINE lim_itd_th_rem
494
495
496   SUBROUTINE lim_itd_fitline( num_cat, HbL, Hbr, hice,   &
497      &                        g0, g1, hL, hR, zremap_flag )
498      !!------------------------------------------------------------------
499      !!                ***  ROUTINE lim_itd_fitline ***
500      !!
501      !! ** Purpose :   fit g(h) with a line using area, volume constraints
502      !!
503      !! ** Method  :   Fit g(h) with a line, satisfying area and volume constraints.
504      !!              To reduce roundoff errors caused by large values of g0 and g1,
505      !!              we actually compute g(eta), where eta = h - hL, and hL is the
506      !!              left boundary.
507      !!------------------------------------------------------------------
508      INTEGER                     , INTENT(in   ) ::   num_cat      ! category index
509      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   HbL, HbR     ! left and right category boundaries
510      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   hice         ! ice thickness
511      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   g0, g1       ! coefficients in linear equation for g(eta)
512      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hL           ! min value of range over which g(h) > 0
513      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hR           ! max value of range over which g(h) > 0
514      INTEGER , DIMENSION(jpi,jpj), INTENT(in   ) ::   zremap_flag  !
515      !
516      INTEGER ::   ji,jj           ! horizontal indices
517      REAL(wp) ::   zh13         ! HbL + 1/3 * (HbR - HbL)
518      REAL(wp) ::   zh23         ! HbL + 2/3 * (HbR - HbL)
519      REAL(wp) ::   zdhr         ! 1 / (hR - hL)
520      REAL(wp) ::   zwk1, zwk2   ! temporary variables
521      !!------------------------------------------------------------------
522      !
523      !
524      DO jj = 1, jpj
525         DO ji = 1, jpi
526            !
527            IF( zremap_flag(ji,jj) == 1 .AND. a_i(ji,jj,num_cat) > epsi10   &
528               &                        .AND. hice(ji,jj)        > 0._wp     ) THEN
529
530               ! Initialize hL and hR
531
532               hL(ji,jj) = HbL(ji,jj)
533               hR(ji,jj) = HbR(ji,jj)
534
535               ! Change hL or hR if hice falls outside central third of range
536
537               zh13 = 1.0/3.0 * (2.0*hL(ji,jj) + hR(ji,jj))
538               zh23 = 1.0/3.0 * (hL(ji,jj) + 2.0*hR(ji,jj))
539
540               IF    ( hice(ji,jj) < zh13 ) THEN   ;   hR(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hL(ji,jj)
541               ELSEIF( hice(ji,jj) > zh23 ) THEN   ;   hL(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hR(ji,jj)
542               ENDIF
543
544               ! Compute coefficients of g(eta) = g0 + g1*eta
545
546               zdhr = 1._wp / (hR(ji,jj) - hL(ji,jj))
547               zwk1 = 6._wp * a_i(ji,jj,num_cat) * zdhr
548               zwk2 = ( hice(ji,jj) - hL(ji,jj) ) * zdhr
549               g0(ji,jj) = zwk1 * ( 2._wp/3._wp - zwk2 )
550               g1(ji,jj) = 2._wp * zdhr * zwk1 * (zwk2 - 0.5)
551               !
552            ELSE                   ! remap_flag = .false. or a_i < epsi10
553               hL(ji,jj) = 0._wp
554               hR(ji,jj) = 0._wp
555               g0(ji,jj) = 0._wp
556               g1(ji,jj) = 0._wp
557            ENDIF                  ! a_i > epsi10
558            !
559         END DO
560      END DO
561      !
562   END SUBROUTINE lim_itd_fitline
563
564
565   SUBROUTINE lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
566      !!------------------------------------------------------------------
567      !!                ***  ROUTINE lim_itd_shiftice ***
568      !!
569      !! ** Purpose :   shift ice across category boundaries, conserving everything
570      !!              ( area, volume, energy, age*vol, and mass of salt )
571      !!
572      !! ** Method  :
573      !!------------------------------------------------------------------
574      INTEGER                           , INTENT(in   ) ::   klbnd    ! Start thickness category index point
575      INTEGER                           , INTENT(in   ) ::   kubnd    ! End point on which the  the computation is applied
576      INTEGER , DIMENSION(jpi,jpj,jpl-1), INTENT(in   ) ::   zdonor   ! donor category index
577      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdaice   ! ice area transferred across boundary
578      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdvice   ! ice volume transferred across boundary
579
580      INTEGER ::   ji, jj, jl, jl2, jl1, jk   ! dummy loop indices
581      INTEGER ::   ii, ij          ! indices when changing from 2D-1D is done
582
583      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zaTsfn
584      REAL(wp), POINTER, DIMENSION(:,:)   ::   zworka            ! temporary array used here
585
586      REAL(wp) ::   zdvsnow, zdesnow   ! snow volume and energy transferred
587      REAL(wp) ::   zdeice             ! ice energy transferred
588      REAL(wp) ::   zdsm_vice          ! ice salinity times volume transferred
589      REAL(wp) ::   zdo_aice           ! ice age times volume transferred
590      REAL(wp) ::   zdaTsf             ! aicen*Tsfcn transferred
591
592      INTEGER, POINTER, DIMENSION(:) ::   nind_i, nind_j   ! compressed indices for i/j directions
593
594      INTEGER ::   nbrem             ! number of cells with ice to transfer
595
596      LOGICAL ::   zdaice_negative         ! true if daice < -puny
597      LOGICAL ::   zdvice_negative         ! true if dvice < -puny
598      LOGICAL ::   zdaice_greater_aicen    ! true if daice > aicen
599      LOGICAL ::   zdvice_greater_vicen    ! true if dvice > vicen
600      !!------------------------------------------------------------------
601
602      CALL wrk_alloc( jpi,jpj,jpl, zaTsfn )
603      CALL wrk_alloc( jpi,jpj, zworka )
604      CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
605
606      !----------------------------------------------------------------------------------------------
607      ! 1) Define a variable equal to a_i*T_su
608      !----------------------------------------------------------------------------------------------
609
610      DO jl = klbnd, kubnd
611         zaTsfn(:,:,jl) = a_i(:,:,jl)*t_su(:,:,jl)
612      END DO
613
614      !----------------------------------------------------------------------------------------------
615      ! 2) Check for daice or dvice out of range, allowing for roundoff error
616      !----------------------------------------------------------------------------------------------
617      ! Note: zdaice < 0 or zdvice < 0 usually happens when category jl
618      ! has a small area, with h(n) very close to a boundary.  Then
619      ! the coefficients of g(h) are large, and the computed daice and
620      ! dvice can be in error. If this happens, it is best to transfer
621      ! either the entire category or nothing at all, depending on which
622      ! side of the boundary hice(n) lies.
623      !-----------------------------------------------------------------
624      DO jl = klbnd, kubnd-1
625
626         zdaice_negative = .false.
627         zdvice_negative = .false.
628         zdaice_greater_aicen = .false.
629         zdvice_greater_vicen = .false.
630
631         DO jj = 1, jpj
632            DO ji = 1, jpi
633
634               IF (zdonor(ji,jj,jl) .GT. 0) THEN
635                  jl1 = zdonor(ji,jj,jl)
636
637                  IF (zdaice(ji,jj,jl) .LT. 0.0) THEN
638                     IF (zdaice(ji,jj,jl) .GT. -epsi10) THEN
639                        IF ( ( jl1.EQ.jl   .AND. ht_i(ji,jj,jl1) .GT. hi_max(jl) )           &
640                           .OR.                                      &
641                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) )           & 
642                           ) THEN                                                             
643                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1)  ! shift entire category
644                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
645                        ELSE
646                           zdaice(ji,jj,jl) = 0.0 ! shift no ice
647                           zdvice(ji,jj,jl) = 0.0
648                        ENDIF
649                     ELSE
650                        zdaice_negative = .true.
651                     ENDIF
652                  ENDIF
653
654                  IF (zdvice(ji,jj,jl) .LT. 0.0) THEN
655                     IF (zdvice(ji,jj,jl) .GT. -epsi10 ) THEN
656                        IF ( ( jl1.EQ.jl .AND. ht_i(ji,jj,jl1).GT.hi_max(jl) )     &
657                           .OR.                                     &
658                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) ) &
659                           ) THEN
660                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1) ! shift entire category
661                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
662                        ELSE
663                           zdaice(ji,jj,jl) = 0.0    ! shift no ice
664                           zdvice(ji,jj,jl) = 0.0
665                        ENDIF
666                     ELSE
667                        zdvice_negative = .true.
668                     ENDIF
669                  ENDIF
670
671                  ! If daice is close to aicen, set daice = aicen.
672                  IF (zdaice(ji,jj,jl) .GT. a_i(ji,jj,jl1) - epsi10 ) THEN
673                     IF (zdaice(ji,jj,jl) .LT. a_i(ji,jj,jl1)+epsi10) THEN
674                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
675                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
676                     ELSE
677                        zdaice_greater_aicen = .true.
678                     ENDIF
679                  ENDIF
680
681                  IF (zdvice(ji,jj,jl) .GT. v_i(ji,jj,jl1)-epsi10) THEN
682                     IF (zdvice(ji,jj,jl) .LT. v_i(ji,jj,jl1)+epsi10) THEN
683                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
684                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
685                     ELSE
686                        zdvice_greater_vicen = .true.
687                     ENDIF
688                  ENDIF
689
690               ENDIF               ! donor > 0
691            END DO                   ! i
692         END DO                 ! j
693
694      END DO !jl
695
696      !-------------------------------------------------------------------------------
697      ! 3) Transfer volume and energy between categories
698      !-------------------------------------------------------------------------------
699
700      DO jl = klbnd, kubnd - 1
701         nbrem = 0
702         DO jj = 1, jpj
703            DO ji = 1, jpi
704               IF (zdaice(ji,jj,jl) .GT. 0.0 ) THEN ! daice(n) can be < puny
705                  nbrem = nbrem + 1
706                  nind_i(nbrem) = ji
707                  nind_j(nbrem) = jj
708               ENDIF ! tmask
709            END DO
710         END DO
711
712         DO ji = 1, nbrem 
713            ii = nind_i(ji)
714            ij = nind_j(ji)
715
716            jl1 = zdonor(ii,ij,jl)
717            rswitch             = MAX( 0.0 , SIGN( 1.0 , v_i(ii,ij,jl1) - epsi10 ) )
718            zworka(ii,ij)   = zdvice(ii,ij,jl) / MAX(v_i(ii,ij,jl1),epsi10) * rswitch
719            IF( jl1 == jl) THEN   ;   jl2 = jl1+1
720            ELSE                    ;   jl2 = jl 
721            ENDIF
722
723            !--------------
724            ! Ice areas
725            !--------------
726
727            a_i(ii,ij,jl1) = a_i(ii,ij,jl1) - zdaice(ii,ij,jl)
728            a_i(ii,ij,jl2) = a_i(ii,ij,jl2) + zdaice(ii,ij,jl)
729
730            !--------------
731            ! Ice volumes
732            !--------------
733
734            v_i(ii,ij,jl1) = v_i(ii,ij,jl1) - zdvice(ii,ij,jl) 
735            v_i(ii,ij,jl2) = v_i(ii,ij,jl2) + zdvice(ii,ij,jl)
736
737            !--------------
738            ! Snow volumes
739            !--------------
740
741            zdvsnow        = v_s(ii,ij,jl1) * zworka(ii,ij)
742            v_s(ii,ij,jl1) = v_s(ii,ij,jl1) - zdvsnow
743            v_s(ii,ij,jl2) = v_s(ii,ij,jl2) + zdvsnow 
744
745            !--------------------
746            ! Snow heat content 
747            !--------------------
748
749            zdesnow            = e_s(ii,ij,1,jl1) * zworka(ii,ij)
750            e_s(ii,ij,1,jl1)   = e_s(ii,ij,1,jl1) - zdesnow
751            e_s(ii,ij,1,jl2)   = e_s(ii,ij,1,jl2) + zdesnow
752
753            !--------------
754            ! Ice age
755            !--------------
756
757            zdo_aice           = oa_i(ii,ij,jl1) * zdaice(ii,ij,jl)
758            oa_i(ii,ij,jl1)    = oa_i(ii,ij,jl1) - zdo_aice
759            oa_i(ii,ij,jl2)    = oa_i(ii,ij,jl2) + zdo_aice
760
761            !--------------
762            ! Ice salinity
763            !--------------
764
765            zdsm_vice          = smv_i(ii,ij,jl1) * zworka(ii,ij)
766            smv_i(ii,ij,jl1)   = smv_i(ii,ij,jl1) - zdsm_vice
767            smv_i(ii,ij,jl2)   = smv_i(ii,ij,jl2) + zdsm_vice
768
769            !---------------------
770            ! Surface temperature
771            !---------------------
772
773            zdaTsf             = t_su(ii,ij,jl1) * zdaice(ii,ij,jl)
774            zaTsfn(ii,ij,jl1)  = zaTsfn(ii,ij,jl1) - zdaTsf
775            zaTsfn(ii,ij,jl2)  = zaTsfn(ii,ij,jl2) + zdaTsf 
776
777         END DO                 ! ji
778
779         !------------------
780         ! Ice heat content
781         !------------------
782
783         DO jk = 1, nlay_i
784!CDIR NODEP
785            DO ji = 1, nbrem
786               ii = nind_i(ji)
787               ij = nind_j(ji)
788
789               jl1 = zdonor(ii,ij,jl)
790               IF (jl1 .EQ. jl) THEN
791                  jl2 = jl+1
792               ELSE             ! n1 = n+1
793                  jl2 = jl 
794               ENDIF
795
796               zdeice = e_i(ii,ij,jk,jl1) * zworka(ii,ij)
797               e_i(ii,ij,jk,jl1) =  e_i(ii,ij,jk,jl1) - zdeice
798               e_i(ii,ij,jk,jl2) =  e_i(ii,ij,jk,jl2) + zdeice 
799            END DO              ! ji
800         END DO                 ! jk
801
802      END DO                   ! boundaries, 1 to ncat-1
803
804      !-----------------------------------------------------------------
805      ! Update ice thickness and temperature
806      !-----------------------------------------------------------------
807
808      DO jl = klbnd, kubnd
809         DO jj = 1, jpj
810            DO ji = 1, jpi 
811               IF ( a_i(ji,jj,jl) > epsi10 ) THEN
812                  ht_i(ji,jj,jl)  =  v_i   (ji,jj,jl) / a_i(ji,jj,jl) 
813                  t_su(ji,jj,jl)  =  zaTsfn(ji,jj,jl) / a_i(ji,jj,jl) 
814                  rswitch         =  1.0 - MAX(0.0,SIGN(1.0,-v_s(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
815               ELSE
816                  ht_i(ji,jj,jl)  = 0._wp
817                  t_su(ji,jj,jl)  = rtt
818               ENDIF
819            END DO                 ! ji
820         END DO                 ! jj
821      END DO                    ! jl
822      !
823      CALL wrk_dealloc( jpi,jpj,jpl, zaTsfn )
824      CALL wrk_dealloc( jpi,jpj, zworka )
825      CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
826      !
827   END SUBROUTINE lim_itd_shiftice
828   
829
830   SUBROUTINE lim_itd_th_reb( klbnd, kubnd )
831      !!------------------------------------------------------------------
832      !!                ***  ROUTINE lim_itd_th_reb ***
833      !!
834      !! ** Purpose : rebin - rebins thicknesses into defined categories
835      !!
836      !! ** Method  :
837      !!------------------------------------------------------------------
838      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
839      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
840      !
841      INTEGER ::   ji,jj, jl   ! dummy loop indices
842      INTEGER ::   zshiftflag          ! = .true. if ice must be shifted
843      CHARACTER (len = 15) :: fieldid
844
845      INTEGER , POINTER, DIMENSION(:,:,:) ::   zdonor           ! donor category index
846      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdaice, zdvice   ! ice area and volume transferred
847
848      REAL(wp), POINTER, DIMENSION(:,:) ::   vt_i_init, vt_i_final   ! ice volume summed over categories
849      REAL(wp), POINTER, DIMENSION(:,:) ::   vt_s_init, vt_s_final   ! snow volume summed over categories
850      !!------------------------------------------------------------------
851      !! clem 2014/04: be carefull, rebining does not conserve salt(maybe?) => the difference is taken into account in limupdate
852     
853      CALL wrk_alloc( jpi,jpj,jpl, zdonor )   ! interger
854      CALL wrk_alloc( jpi,jpj,jpl, zdaice, zdvice )
855      CALL wrk_alloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
856      !     
857      IF( con_i ) THEN                 ! conservation check
858         CALL lim_column_sum (jpl,   v_i, vt_i_init)
859         CALL lim_column_sum (jpl,   v_s, vt_s_init)
860      ENDIF
861
862      !
863      !------------------------------------------------------------------------------
864      ! 1) Compute ice thickness.
865      !------------------------------------------------------------------------------
866      DO jl = klbnd, kubnd
867         DO jj = 1, jpj
868            DO ji = 1, jpi 
869               IF( a_i(ji,jj,jl) > epsi10 ) THEN
870                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
871               ELSE
872                  ht_i(ji,jj,jl) = 0._wp
873               ENDIF
874            END DO
875         END DO
876      END DO
877
878      !------------------------------------------------------------------------------
879      ! 2) Make sure thickness of cat klbnd is at least hi_max(klbnd)
880      !------------------------------------------------------------------------------
881      DO jj = 1, jpj 
882         DO ji = 1, jpi 
883            IF( a_i(ji,jj,klbnd) > epsi10 ) THEN
884               IF( ht_i(ji,jj,klbnd) <= hi_max(0) .AND. hi_max(0) > 0._wp ) THEN
885                  a_i(ji,jj,klbnd)  = v_i(ji,jj,klbnd) / hi_max(0) 
886                  ht_i(ji,jj,klbnd) = hi_max(0)
887               ENDIF
888            ENDIF
889         END DO
890      END DO
891
892      !------------------------------------------------------------------------------
893      ! 3) If a category thickness is not in bounds, shift the
894      ! entire area, volume, and energy to the neighboring category
895      !------------------------------------------------------------------------------
896      !-------------------------
897      ! Initialize shift arrays
898      !-------------------------
899      DO jl = klbnd, kubnd
900         zdonor(:,:,jl) = 0
901         zdaice(:,:,jl) = 0._wp
902         zdvice(:,:,jl) = 0._wp
903      END DO
904
905      !-------------------------
906      ! Move thin categories up
907      !-------------------------
908
909      DO jl = klbnd, kubnd - 1  ! loop over category boundaries
910
911         !---------------------------------------
912         ! identify thicknesses that are too big
913         !---------------------------------------
914         zshiftflag = 0
915
916         DO jj = 1, jpj 
917            DO ji = 1, jpi 
918               IF( a_i(ji,jj,jl) > epsi10 .AND. ht_i(ji,jj,jl) > hi_max(jl) ) THEN
919                  zshiftflag        = 1
920                  zdonor(ji,jj,jl)  = jl 
921                  ! begin TECLIM change
922                  !zdaice(ji,jj,jl)  = a_i(ji,jj,jl)
923                  !zdvice(ji,jj,jl)  = v_i(ji,jj,jl)
924                  !zdaice(ji,jj,jl)  = a_i(ji,jj,jl) * 0.5_wp
925                  !zdvice(ji,jj,jl)  = v_i(ji,jj,jl)-zdaice(ji,jj,jl)*(hi_max(jl)+hi_max(jl-1)) * 0.5_wp
926                  ! end TECLIM change
927                  ! clem: how much of a_i you send in cat sup is somewhat arbitrary
928                  zdaice(ji,jj,jl)  = a_i(ji,jj,jl) * ( ht_i(ji,jj,jl) - hi_max(jl) + epsi10 ) / ht_i(ji,jj,jl) 
929                  zdvice(ji,jj,jl)  = v_i(ji,jj,jl) - ( a_i(ji,jj,jl) - zdaice(ji,jj,jl) ) * ( hi_max(jl) - epsi10 )
930               ENDIF
931            END DO                 ! ji
932         END DO                 ! jj
933         IF(lk_mpp)   CALL mpp_max( zshiftflag )
934
935         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
936            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
937            ! Reset shift parameters
938            zdonor(:,:,jl) = 0
939            zdaice(:,:,jl) = 0._wp
940            zdvice(:,:,jl) = 0._wp
941         ENDIF
942         !
943      END DO                    ! jl
944
945      !----------------------------
946      ! Move thick categories down
947      !----------------------------
948
949      DO jl = kubnd - 1, 1, -1       ! loop over category boundaries
950
951         !-----------------------------------------
952         ! Identify thicknesses that are too small
953         !-----------------------------------------
954         zshiftflag = 0
955
956!clem-change
957         DO jj = 1, jpj
958            DO ji = 1, jpi
959               IF( a_i(ji,jj,jl+1) > epsi10 .AND. ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
960                  !
961                  zshiftflag = 1
962                  zdonor(ji,jj,jl) = jl + 1
963                  zdaice(ji,jj,jl) = a_i(ji,jj,jl+1) 
964                  zdvice(ji,jj,jl) = v_i(ji,jj,jl+1)
965               ENDIF
966            END DO                 ! ji
967         END DO                 ! jj
968
969         IF(lk_mpp)   CALL mpp_max( zshiftflag )
970         
971         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
972            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
973            ! Reset shift parameters
974            zdonor(:,:,jl) = 0
975            zdaice(:,:,jl) = 0._wp
976            zdvice(:,:,jl) = 0._wp
977         ENDIF
978!clem-change
979
980!         ! clem-change begin: why not doing that?
981!         DO jj = 1, jpj
982!            DO ji = 1, jpi
983!               IF( a_i(ji,jj,jl+1) > epsi10 .AND. ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
984!                  ht_i(ji,jj,jl+1) = hi_max(jl) + epsi10
985!                  a_i (ji,jj,jl+1) = v_i(ji,jj,jl+1) / ht_i(ji,jj,jl+1)
986!               ENDIF
987!            END DO                 ! ji
988!         END DO                 ! jj
989         ! clem-change end
990
991      END DO                    ! jl
992
993      !------------------------------------------------------------------------------
994      ! 4) Conservation check
995      !------------------------------------------------------------------------------
996
997      IF( con_i ) THEN
998         CALL lim_column_sum (jpl,   v_i, vt_i_final)
999         fieldid = ' v_i : limitd_reb '
1000         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
1001
1002         CALL lim_column_sum (jpl,   v_s, vt_s_final)
1003         fieldid = ' v_s : limitd_reb '
1004         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
1005      ENDIF
1006      !
1007      CALL wrk_dealloc( jpi,jpj,jpl, zdonor )   ! interger
1008      CALL wrk_dealloc( jpi,jpj,jpl, zdaice, zdvice )
1009      CALL wrk_dealloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
1010
1011   END SUBROUTINE lim_itd_th_reb
1012
1013#else
1014   !!----------------------------------------------------------------------
1015   !!   Default option            Dummy module         NO LIM sea-ice model
1016   !!----------------------------------------------------------------------
1017CONTAINS
1018   SUBROUTINE lim_itd_th           ! Empty routines
1019   END SUBROUTINE lim_itd_th
1020   SUBROUTINE lim_itd_th_ini
1021   END SUBROUTINE lim_itd_th_ini
1022   SUBROUTINE lim_itd_th_rem
1023   END SUBROUTINE lim_itd_th_rem
1024   SUBROUTINE lim_itd_fitline
1025   END SUBROUTINE lim_itd_fitline
1026   SUBROUTINE lim_itd_shiftice
1027   END SUBROUTINE lim_itd_shiftice
1028   SUBROUTINE lim_itd_th_reb
1029   END SUBROUTINE lim_itd_th_reb
1030#endif
1031   !!======================================================================
1032END MODULE limitd_th
Note: See TracBrowser for help on using the repository browser.