New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limitd_th.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limitd_th.F90 @ 5064

Last change on this file since 5064 was 5064, checked in by clem, 9 years ago

LIM3 now includes specific physics to run with only 1 sea ice category (i.e. LIM2 type)
  • Property svn:keywords set to Id
File size: 40.8 KB
Line 
1MODULE limitd_th
2   !!======================================================================
3   !!                       ***  MODULE limitd_th ***
4   !!   LIM3 ice model : ice thickness distribution: Thermodynamics
5   !!======================================================================
6   !! History :   -   !          (W. H. Lipscomb and E.C. Hunke) CICE (c) original code
7   !!            3.0  ! 2005-12  (M. Vancoppenolle) adaptation to LIM-3
8   !!             -   ! 2006-06  (M. Vancoppenolle) adaptation to include salt, age
9   !!             -   ! 2007-04  (M. Vancoppenolle) Mass conservation checked
10   !!----------------------------------------------------------------------
11#if defined key_lim3
12   !!----------------------------------------------------------------------
13   !!   'key_lim3' :                                   LIM3 sea-ice model
14   !!----------------------------------------------------------------------
15   !!   lim_itd_th_rem   :
16   !!   lim_itd_th_reb   :
17   !!   lim_itd_fitline  :
18   !!   lim_itd_shiftice :
19   !!----------------------------------------------------------------------
20   USE dom_ice          ! LIM-3 domain
21   USE par_oce          ! ocean parameters
22   USE dom_oce          ! ocean domain
23   USE phycst           ! physical constants (ocean directory)
24   USE thd_ice          ! LIM-3 thermodynamic variables
25   USE ice              ! LIM-3 variables
26   USE limvar           ! LIM-3 variables
27   USE limcons          ! LIM-3 conservation
28   USE prtctl           ! Print control
29   USE in_out_manager   ! I/O manager
30   USE lib_mpp          ! MPP library
31   USE wrk_nemo         ! work arrays
32   USE lib_fortran      ! to use key_nosignedzero
33   USE limcons          ! conservation tests
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   lim_itd_th_rem
39   PUBLIC   lim_itd_th_reb
40   PUBLIC   lim_itd_fitline
41   PUBLIC   lim_itd_shiftice
42
43   !!----------------------------------------------------------------------
44   !! NEMO/LIM3 4.0 , UCL - NEMO Consortium (2010)
45   !! $Id$
46   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE lim_itd_th_rem( klbnd, kubnd, kt )
51      !!------------------------------------------------------------------
52      !!                ***  ROUTINE lim_itd_th_rem ***
53      !!
54      !! ** Purpose :   computes the redistribution of ice thickness
55      !!              after thermodynamic growth of ice thickness
56      !!
57      !! ** Method  : Linear remapping
58      !!
59      !! References : W.H. Lipscomb, JGR 2001
60      !!------------------------------------------------------------------
61      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
62      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
63      INTEGER , INTENT (in) ::   kt      ! Ocean time step
64      !
65      INTEGER  ::   ji, jj, jl     ! dummy loop index
66      INTEGER  ::   ii, ij         ! 2D corresponding indices to ji
67      INTEGER  ::   nd             ! local integer
68      REAL(wp) ::   zx1, zwk1, zdh0, zetamin, zdamax   ! local scalars
69      REAL(wp) ::   zx2, zwk2, zda0, zetamax           !   -      -
70      REAL(wp) ::   zx3       
71      CHARACTER (len = 15) :: fieldid
72
73      INTEGER , POINTER, DIMENSION(:,:,:) ::   zdonor   ! donor category index
74
75      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdhice      ! ice thickness increment
76      REAL(wp), POINTER, DIMENSION(:,:,:) ::   g0          ! coefficients for fitting the line of the ITD
77      REAL(wp), POINTER, DIMENSION(:,:,:) ::   g1          ! coefficients for fitting the line of the ITD
78      REAL(wp), POINTER, DIMENSION(:,:,:) ::   hL          ! left boundary for the ITD for each thickness
79      REAL(wp), POINTER, DIMENSION(:,:,:) ::   hR          ! left boundary for the ITD for each thickness
80      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zht_i_b     ! old ice thickness
81      REAL(wp), POINTER, DIMENSION(:,:,:) ::   dummy_es
82      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdaice, zdvice          ! local increment of ice area and volume
83      REAL(wp), POINTER, DIMENSION(:)     ::   zvetamin, zvetamax      ! maximum values for etas
84      INTEGER , POINTER, DIMENSION(:)     ::   nind_i, nind_j          ! compressed indices for i/j directions
85      INTEGER                             ::   nbrem                   ! number of cells with ice to transfer
86      REAL(wp)                            ::   zslope                  ! used to compute local thermodynamic "speeds"
87      REAL(wp), POINTER, DIMENSION(:,:)   ::   zhb0, zhb1              ! category boundaries for thinnes categories
88      REAL(wp), POINTER, DIMENSION(:,:)   ::   vt_i_init, vt_i_final   !  ice volume summed over categories
89      REAL(wp), POINTER, DIMENSION(:,:)   ::   vt_s_init, vt_s_final   !  snow volume summed over categories
90      REAL(wp), POINTER, DIMENSION(:,:)   ::   et_i_init, et_i_final   !  ice energy summed over categories
91      REAL(wp), POINTER, DIMENSION(:,:)   ::   et_s_init, et_s_final   !  snow energy summed over categories
92      INTEGER , POINTER, DIMENSION(:,:)   ::   zremap_flag      ! compute remapping or not ????
93      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhbnew           ! new boundaries of ice categories
94      !!------------------------------------------------------------------
95
96      CALL wrk_alloc( jpi,jpj, zremap_flag )    ! integer
97      CALL wrk_alloc( jpi,jpj,jpl-1, zdonor )   ! integer
98      CALL wrk_alloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_b, dummy_es )
99      CALL wrk_alloc( jpi,jpj,jpl-1, zdaice, zdvice )   
100      CALL wrk_alloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )   
101      CALL wrk_alloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )   
102      CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
103      CALL wrk_alloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
104
105      !!----------------------------------------------------------------------------------------------
106      !! 0) Conservation checkand changes in each ice category
107      !!----------------------------------------------------------------------------------------------
108      IF( con_i ) THEN
109         CALL lim_column_sum (jpl,   v_i, vt_i_init)
110         CALL lim_column_sum (jpl,   v_s, vt_s_init)
111         CALL lim_column_sum_energy (jpl, nlay_i,   e_i, et_i_init)
112         dummy_es(:,:,:) = e_s(:,:,1,:)
113         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_init)
114      ENDIF
115
116      !!----------------------------------------------------------------------------------------------
117      !! 1) Compute thickness and changes in each ice category
118      !!----------------------------------------------------------------------------------------------
119      IF( kt == nit000 .AND. lwp) THEN
120         WRITE(numout,*)
121         WRITE(numout,*) 'lim_itd_th_rem  : Remapping the ice thickness distribution'
122         WRITE(numout,*) '~~~~~~~~~~~~~~~'
123         WRITE(numout,*) ' klbnd :       ', klbnd
124         WRITE(numout,*) ' kubnd :       ', kubnd
125      ENDIF
126
127      zdhice(:,:,:) = 0._wp
128      DO jl = klbnd, kubnd
129         DO jj = 1, jpj
130            DO ji = 1, jpi
131               rswitch           = 1.0 - MAX( 0.0, SIGN( 1.0, - a_i(ji,jj,jl) + epsi10 ) )     !0 if no ice and 1 if yes
132               ht_i(ji,jj,jl)    = v_i(ji,jj,jl) / MAX( a_i(ji,jj,jl), epsi10 ) * rswitch
133               rswitch           = 1.0 - MAX( 0.0, SIGN( 1.0, - a_i_b(ji,jj,jl) + epsi10) ) !0 if no ice and 1 if yes
134               zht_i_b(ji,jj,jl) = v_i_b(ji,jj,jl) / MAX( a_i_b(ji,jj,jl), epsi10 ) * rswitch
135               IF( a_i(ji,jj,jl) > epsi10 )   zdhice(ji,jj,jl) = ht_i(ji,jj,jl) - zht_i_b(ji,jj,jl) 
136            END DO
137         END DO
138      END DO
139
140      !-----------------------------------------------------------------------------------------------
141      !  2) Compute fractional ice area in each grid cell
142      !-----------------------------------------------------------------------------------------------
143      at_i(:,:) = 0._wp
144      DO jl = klbnd, kubnd
145         at_i(:,:) = at_i(:,:) + a_i(:,:,jl)
146      END DO
147
148      !-----------------------------------------------------------------------------------------------
149      !  3) Identify grid cells with ice
150      !-----------------------------------------------------------------------------------------------
151      nbrem = 0
152      DO jj = 1, jpj
153         DO ji = 1, jpi
154            IF ( at_i(ji,jj) > epsi10 ) THEN
155               nbrem         = nbrem + 1
156               nind_i(nbrem) = ji
157               nind_j(nbrem) = jj
158               zremap_flag(ji,jj) = 1
159            ELSE
160               zremap_flag(ji,jj) = 0
161            ENDIF
162         END DO !ji
163      END DO !jj
164
165      !-----------------------------------------------------------------------------------------------
166      !  4) Compute new category boundaries
167      !-----------------------------------------------------------------------------------------------
168      !- 4.1 Compute category boundaries
169      zhbnew(:,:,:) = 0._wp
170
171      DO jl = klbnd, kubnd - 1
172         DO ji = 1, nbrem
173            ii = nind_i(ji)
174            ij = nind_j(ji)
175            !
176            zhbnew(ii,ij,jl) = hi_max(jl)
177            IF ( a_i_b(ii,ij,jl) > epsi10 .AND. a_i_b(ii,ij,jl+1) > epsi10 ) THEN
178               !interpolate between adjacent category growth rates
179               zslope           = ( zdhice(ii,ij,jl+1) - zdhice(ii,ij,jl) ) / ( zht_i_b(ii,ij,jl+1) - zht_i_b(ii,ij,jl) )
180               zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl) + zslope * ( hi_max(jl) - zht_i_b(ii,ij,jl) )
181            ELSEIF ( a_i_b(ii,ij,jl) > epsi10) THEN
182               zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl)
183            ELSEIF ( a_i_b(ii,ij,jl+1) > epsi10) THEN
184               zhbnew(ii,ij,jl) = hi_max(jl) + zdhice(ii,ij,jl+1)
185            ENDIF
186         END DO
187
188         !- 4.2 Check that each zhbnew lies between adjacent values of ice thickness
189         DO ji = 1, nbrem
190            ii = nind_i(ji)
191            ij = nind_j(ji)
192            IF( a_i(ii,ij,jl) > epsi10 .AND. ht_i(ii,ij,jl) >= zhbnew(ii,ij,jl) ) THEN
193               zremap_flag(ii,ij) = 0
194            ELSEIF( a_i(ii,ij,jl+1) > epsi10 .AND. ht_i(ii,ij,jl+1) <= zhbnew(ii,ij,jl) ) THEN
195               zremap_flag(ii,ij) = 0
196            ENDIF
197
198            !- 4.3 Check that each zhbnew does not exceed maximal values hi_max 
199            IF( zhbnew(ii,ij,jl) > hi_max(jl+1) ) zremap_flag(ii,ij) = 0
200            IF( zhbnew(ii,ij,jl) < hi_max(jl-1) ) zremap_flag(ii,ij) = 0
201         END DO
202
203      END DO !jl
204
205      !-----------------------------------------------------------------------------------------------
206      !  5) Identify cells where ITD is to be remapped
207      !-----------------------------------------------------------------------------------------------
208      nbrem = 0
209      DO jj = 1, jpj
210         DO ji = 1, jpi
211            IF( zremap_flag(ji,jj) == 1 ) THEN
212               nbrem         = nbrem + 1
213               nind_i(nbrem) = ji
214               nind_j(nbrem) = jj
215            ENDIF
216         END DO
217      END DO 
218
219      !-----------------------------------------------------------------------------------------------
220      !  6) Fill arrays with lowermost / uppermost boundaries of 'new' categories
221      !-----------------------------------------------------------------------------------------------
222      DO jj = 1, jpj
223         DO ji = 1, jpi
224            zhb0(ji,jj) = hi_max(0) ! 0eme
225            zhb1(ji,jj) = hi_max(1) ! 1er
226
227            zhbnew(ji,jj,klbnd-1) = 0._wp
228
229            IF( a_i(ji,jj,kubnd) > epsi10 ) THEN
230               zhbnew(ji,jj,kubnd) = 3._wp * ht_i(ji,jj,kubnd) - 2._wp * zhbnew(ji,jj,kubnd-1)
231            ELSE
232               zhbnew(ji,jj,kubnd) = hi_max(kubnd) 
233               !!? clem bug: since hi_max(jpl)=99, this limit is very high
234               !!? but I think it is erased in fitline subroutine
235            ENDIF
236
237            IF( zhbnew(ji,jj,kubnd) < hi_max(kubnd-1) ) zhbnew(ji,jj,kubnd) = hi_max(kubnd-1)
238
239         END DO !jj
240      END DO !jj
241
242      !-----------------------------------------------------------------------------------------------
243      !  7) Compute g(h)
244      !-----------------------------------------------------------------------------------------------
245      !- 7.1 g(h) for category 1 at start of time step
246      CALL lim_itd_fitline( klbnd, zhb0, zhb1, zht_i_b(:,:,klbnd),         &
247         &                  g0(:,:,klbnd), g1(:,:,klbnd), hL(:,:,klbnd),   &
248         &                  hR(:,:,klbnd), zremap_flag )
249
250      !- 7.2 Area lost due to melting of thin ice (first category,  klbnd)
251      DO ji = 1, nbrem
252         ii = nind_i(ji) 
253         ij = nind_j(ji) 
254
255         !ji
256         IF (a_i(ii,ij,klbnd) .gt. epsi10) THEN
257            zdh0 = zdhice(ii,ij,klbnd) !decrease of ice thickness in the lower category
258            ! ji, a_i > epsi10
259            IF (zdh0 .lt. 0.0) THEN !remove area from category 1
260               ! ji, a_i > epsi10; zdh0 < 0
261               zdh0 = MIN(-zdh0,hi_max(klbnd))
262
263               !Integrate g(1) from 0 to dh0 to estimate area melted
264               zetamax = MIN(zdh0,hR(ii,ij,klbnd)) - hL(ii,ij,klbnd)
265               IF (zetamax.gt.0.0) THEN
266                  zx1  = zetamax
267                  zx2  = 0.5 * zetamax*zetamax 
268                  zda0 = g1(ii,ij,klbnd) * zx2 + g0(ii,ij,klbnd) * zx1 !ice area removed
269                  ! Constrain new thickness <= ht_i
270                  zdamax = a_i(ii,ij,klbnd) * & 
271                     (1.0 - ht_i(ii,ij,klbnd)/zht_i_b(ii,ij,klbnd)) ! zdamax > 0
272                  !ice area lost due to melting of thin ice
273                  zda0   = MIN(zda0, zdamax)
274
275                  ! Remove area, conserving volume
276                  ht_i(ii,ij,klbnd) = ht_i(ii,ij,klbnd) & 
277                     * a_i(ii,ij,klbnd) / ( a_i(ii,ij,klbnd) - zda0 )
278                  a_i(ii,ij,klbnd)  = a_i(ii,ij,klbnd) - zda0
279                  v_i(ii,ij,klbnd)  = a_i(ii,ij,klbnd)*ht_i(ii,ij,klbnd) ! clem-useless ?
280               ENDIF     ! zetamax > 0
281               ! ji, a_i > epsi10
282
283            ELSE ! if ice accretion
284               ! ji, a_i > epsi10; zdh0 > 0
285               zhbnew(ii,ij,klbnd-1) = MIN(zdh0,hi_max(klbnd)) 
286               ! zhbnew was 0, and is shifted to the right to account for thin ice
287               ! growth in openwater (F0 = f1)
288            ENDIF ! zdh0
289
290            ! a_i > epsi10
291         ENDIF ! a_i > epsi10
292
293      END DO ! ji
294
295      !- 7.3 g(h) for each thickness category 
296      DO jl = klbnd, kubnd
297         CALL lim_itd_fitline(jl, zhbnew(:,:,jl-1), zhbnew(:,:,jl), ht_i(:,:,jl), &
298            g0(:,:,jl), g1(:,:,jl), hL(:,:,jl), hR(:,:,jl), zremap_flag)
299      END DO
300
301      !-----------------------------------------------------------------------------------------------
302      !  8) Compute area and volume to be shifted across each boundary
303      !-----------------------------------------------------------------------------------------------
304
305      DO jl = klbnd, kubnd - 1
306         DO jj = 1, jpj
307            DO ji = 1, jpi
308               zdonor(ji,jj,jl) = 0
309               zdaice(ji,jj,jl) = 0.0
310               zdvice(ji,jj,jl) = 0.0
311            END DO
312         END DO
313
314         DO ji = 1, nbrem
315            ii = nind_i(ji)
316            ij = nind_j(ji)
317
318            IF (zhbnew(ii,ij,jl) .gt. hi_max(jl)) THEN ! transfer from jl to jl+1
319
320               ! left and right integration limits in eta space
321               zvetamin(ji) = MAX(hi_max(jl), hL(ii,ij,jl)) - hL(ii,ij,jl)
322               zvetamax(ji) = MIN(zhbnew(ii,ij,jl), hR(ii,ij,jl)) - hL(ii,ij,jl)
323               zdonor(ii,ij,jl) = jl
324
325            ELSE  ! zhbnew(jl) <= hi_max(jl) ; transfer from jl+1 to jl
326
327               ! left and right integration limits in eta space
328               zvetamin(ji) = 0.0
329               zvetamax(ji) = MIN(hi_max(jl), hR(ii,ij,jl+1)) - hL(ii,ij,jl+1)
330               zdonor(ii,ij,jl) = jl + 1
331
332            ENDIF  ! zhbnew(jl) > hi_max(jl)
333
334            zetamax = MAX(zvetamax(ji), zvetamin(ji)) ! no transfer if etamax < etamin
335            zetamin = zvetamin(ji)
336
337            zx1  = zetamax - zetamin
338            zwk1 = zetamin*zetamin
339            zwk2 = zetamax*zetamax
340            zx2  = 0.5 * (zwk2 - zwk1)
341            zwk1 = zwk1 * zetamin
342            zwk2 = zwk2 * zetamax
343            zx3  = 1.0/3.0 * (zwk2 - zwk1)
344            nd   = zdonor(ii,ij,jl)
345            zdaice(ii,ij,jl) = g1(ii,ij,nd)*zx2 + g0(ii,ij,nd)*zx1
346            zdvice(ii,ij,jl) = g1(ii,ij,nd)*zx3 + g0(ii,ij,nd)*zx2 + zdaice(ii,ij,jl)*hL(ii,ij,nd)
347
348         END DO ! ji
349      END DO ! jl klbnd -> kubnd - 1
350
351      !!----------------------------------------------------------------------------------------------
352      !! 9) Shift ice between categories
353      !!----------------------------------------------------------------------------------------------
354      CALL lim_itd_shiftice ( klbnd, kubnd, zdonor, zdaice, zdvice )
355
356      !!----------------------------------------------------------------------------------------------
357      !! 10) Make sure ht_i >= minimum ice thickness hi_min
358      !!----------------------------------------------------------------------------------------------
359
360      DO ji = 1, nbrem
361         ii = nind_i(ji)
362         ij = nind_j(ji)
363         IF ( a_i(ii,ij,1) > epsi10 .AND. ht_i(ii,ij,1) < hiclim ) THEN
364            a_i(ii,ij,1)  = a_i(ii,ij,1) * ht_i(ii,ij,1) / hiclim 
365            ht_i(ii,ij,1) = hiclim
366         ENDIF
367      END DO !ji
368
369      !!----------------------------------------------------------------------------------------------
370      !! 11) Conservation check
371      !!----------------------------------------------------------------------------------------------
372      IF ( con_i ) THEN
373         CALL lim_column_sum (jpl,   v_i, vt_i_final)
374         fieldid = ' v_i : limitd_th '
375         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
376
377         CALL lim_column_sum_energy (jpl, nlay_i,  e_i, et_i_final)
378         fieldid = ' e_i : limitd_th '
379         CALL lim_cons_check (et_i_init, et_i_final, 1.0e-3, fieldid) 
380
381         CALL lim_column_sum (jpl,   v_s, vt_s_final)
382         fieldid = ' v_s : limitd_th '
383         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
384
385         dummy_es(:,:,:) = e_s(:,:,1,:)
386         CALL lim_column_sum (jpl, dummy_es(:,:,:) , et_s_final)
387         fieldid = ' e_s : limitd_th '
388         CALL lim_cons_check (et_s_init, et_s_final, 1.0e-3, fieldid) 
389      ENDIF
390
391      CALL wrk_dealloc( jpi,jpj, zremap_flag )    ! integer
392      CALL wrk_dealloc( jpi,jpj,jpl-1, zdonor )   ! integer
393      CALL wrk_dealloc( jpi,jpj,jpl, zdhice, g0, g1, hL, hR, zht_i_b, dummy_es )
394      CALL wrk_dealloc( jpi,jpj,jpl-1, zdaice, zdvice )   
395      CALL wrk_dealloc( jpi,jpj,jpl+1, zhbnew, kkstart = 0 )   
396      CALL wrk_dealloc( (jpi+1)*(jpj+1), zvetamin, zvetamax )   
397      CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
398      CALL wrk_dealloc( jpi,jpj, zhb0,zhb1,vt_i_init,vt_i_final,vt_s_init,vt_s_final,et_i_init,et_i_final,et_s_init,et_s_final )
399
400   END SUBROUTINE lim_itd_th_rem
401
402
403   SUBROUTINE lim_itd_fitline( num_cat, HbL, Hbr, hice,   &
404      &                        g0, g1, hL, hR, zremap_flag )
405      !!------------------------------------------------------------------
406      !!                ***  ROUTINE lim_itd_fitline ***
407      !!
408      !! ** Purpose :   fit g(h) with a line using area, volume constraints
409      !!
410      !! ** Method  :   Fit g(h) with a line, satisfying area and volume constraints.
411      !!              To reduce roundoff errors caused by large values of g0 and g1,
412      !!              we actually compute g(eta), where eta = h - hL, and hL is the
413      !!              left boundary.
414      !!------------------------------------------------------------------
415      INTEGER                     , INTENT(in   ) ::   num_cat      ! category index
416      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   HbL, HbR     ! left and right category boundaries
417      REAL(wp), DIMENSION(jpi,jpj), INTENT(in   ) ::   hice         ! ice thickness
418      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   g0, g1       ! coefficients in linear equation for g(eta)
419      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hL           ! min value of range over which g(h) > 0
420      REAL(wp), DIMENSION(jpi,jpj), INTENT(  out) ::   hR           ! max value of range over which g(h) > 0
421      INTEGER , DIMENSION(jpi,jpj), INTENT(in   ) ::   zremap_flag  !
422      !
423      INTEGER ::   ji,jj           ! horizontal indices
424      REAL(wp) ::   zh13         ! HbL + 1/3 * (HbR - HbL)
425      REAL(wp) ::   zh23         ! HbL + 2/3 * (HbR - HbL)
426      REAL(wp) ::   zdhr         ! 1 / (hR - hL)
427      REAL(wp) ::   zwk1, zwk2   ! temporary variables
428      !!------------------------------------------------------------------
429      !
430      !
431      DO jj = 1, jpj
432         DO ji = 1, jpi
433            !
434            IF( zremap_flag(ji,jj) == 1 .AND. a_i(ji,jj,num_cat) > epsi10   &
435               &                        .AND. hice(ji,jj)        > 0._wp     ) THEN
436
437               ! Initialize hL and hR
438
439               hL(ji,jj) = HbL(ji,jj)
440               hR(ji,jj) = HbR(ji,jj)
441
442               ! Change hL or hR if hice falls outside central third of range
443
444               zh13 = 1.0/3.0 * (2.0*hL(ji,jj) + hR(ji,jj))
445               zh23 = 1.0/3.0 * (hL(ji,jj) + 2.0*hR(ji,jj))
446
447               IF    ( hice(ji,jj) < zh13 ) THEN   ;   hR(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hL(ji,jj)
448               ELSEIF( hice(ji,jj) > zh23 ) THEN   ;   hL(ji,jj) = 3._wp * hice(ji,jj) - 2._wp * hR(ji,jj)
449               ENDIF
450
451               ! Compute coefficients of g(eta) = g0 + g1*eta
452
453               zdhr = 1._wp / (hR(ji,jj) - hL(ji,jj))
454               zwk1 = 6._wp * a_i(ji,jj,num_cat) * zdhr
455               zwk2 = ( hice(ji,jj) - hL(ji,jj) ) * zdhr
456               g0(ji,jj) = zwk1 * ( 2._wp/3._wp - zwk2 )
457               g1(ji,jj) = 2._wp * zdhr * zwk1 * (zwk2 - 0.5)
458               !
459            ELSE                   ! remap_flag = .false. or a_i < epsi10
460               hL(ji,jj) = 0._wp
461               hR(ji,jj) = 0._wp
462               g0(ji,jj) = 0._wp
463               g1(ji,jj) = 0._wp
464            ENDIF                  ! a_i > epsi10
465            !
466         END DO
467      END DO
468      !
469   END SUBROUTINE lim_itd_fitline
470
471
472   SUBROUTINE lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
473      !!------------------------------------------------------------------
474      !!                ***  ROUTINE lim_itd_shiftice ***
475      !!
476      !! ** Purpose :   shift ice across category boundaries, conserving everything
477      !!              ( area, volume, energy, age*vol, and mass of salt )
478      !!
479      !! ** Method  :
480      !!------------------------------------------------------------------
481      INTEGER                           , INTENT(in   ) ::   klbnd    ! Start thickness category index point
482      INTEGER                           , INTENT(in   ) ::   kubnd    ! End point on which the  the computation is applied
483      INTEGER , DIMENSION(jpi,jpj,jpl-1), INTENT(in   ) ::   zdonor   ! donor category index
484      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdaice   ! ice area transferred across boundary
485      REAL(wp), DIMENSION(jpi,jpj,jpl-1), INTENT(inout) ::   zdvice   ! ice volume transferred across boundary
486
487      INTEGER ::   ji, jj, jl, jl2, jl1, jk   ! dummy loop indices
488      INTEGER ::   ii, ij          ! indices when changing from 2D-1D is done
489
490      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zaTsfn
491      REAL(wp), POINTER, DIMENSION(:,:)   ::   zworka            ! temporary array used here
492
493      REAL(wp) ::   zdvsnow, zdesnow   ! snow volume and energy transferred
494      REAL(wp) ::   zdeice             ! ice energy transferred
495      REAL(wp) ::   zdsm_vice          ! ice salinity times volume transferred
496      REAL(wp) ::   zdo_aice           ! ice age times volume transferred
497      REAL(wp) ::   zdaTsf             ! aicen*Tsfcn transferred
498
499      INTEGER, POINTER, DIMENSION(:) ::   nind_i, nind_j   ! compressed indices for i/j directions
500
501      INTEGER ::   nbrem             ! number of cells with ice to transfer
502
503      LOGICAL ::   zdaice_negative         ! true if daice < -puny
504      LOGICAL ::   zdvice_negative         ! true if dvice < -puny
505      LOGICAL ::   zdaice_greater_aicen    ! true if daice > aicen
506      LOGICAL ::   zdvice_greater_vicen    ! true if dvice > vicen
507      !!------------------------------------------------------------------
508
509      CALL wrk_alloc( jpi,jpj,jpl, zaTsfn )
510      CALL wrk_alloc( jpi,jpj, zworka )
511      CALL wrk_alloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
512
513      !----------------------------------------------------------------------------------------------
514      ! 1) Define a variable equal to a_i*T_su
515      !----------------------------------------------------------------------------------------------
516
517      DO jl = klbnd, kubnd
518         zaTsfn(:,:,jl) = a_i(:,:,jl)*t_su(:,:,jl)
519      END DO
520
521      !----------------------------------------------------------------------------------------------
522      ! 2) Check for daice or dvice out of range, allowing for roundoff error
523      !----------------------------------------------------------------------------------------------
524      ! Note: zdaice < 0 or zdvice < 0 usually happens when category jl
525      ! has a small area, with h(n) very close to a boundary.  Then
526      ! the coefficients of g(h) are large, and the computed daice and
527      ! dvice can be in error. If this happens, it is best to transfer
528      ! either the entire category or nothing at all, depending on which
529      ! side of the boundary hice(n) lies.
530      !-----------------------------------------------------------------
531      DO jl = klbnd, kubnd-1
532
533         zdaice_negative = .false.
534         zdvice_negative = .false.
535         zdaice_greater_aicen = .false.
536         zdvice_greater_vicen = .false.
537
538         DO jj = 1, jpj
539            DO ji = 1, jpi
540
541               IF (zdonor(ji,jj,jl) .GT. 0) THEN
542                  jl1 = zdonor(ji,jj,jl)
543
544                  IF (zdaice(ji,jj,jl) .LT. 0.0) THEN
545                     IF (zdaice(ji,jj,jl) .GT. -epsi10) THEN
546                        IF ( ( jl1.EQ.jl   .AND. ht_i(ji,jj,jl1) .GT. hi_max(jl) )           &
547                           .OR.                                      &
548                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) )           & 
549                           ) THEN                                                             
550                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1)  ! shift entire category
551                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1)
552                        ELSE
553                           zdaice(ji,jj,jl) = 0.0 ! shift no ice
554                           zdvice(ji,jj,jl) = 0.0
555                        ENDIF
556                     ELSE
557                        zdaice_negative = .true.
558                     ENDIF
559                  ENDIF
560
561                  IF (zdvice(ji,jj,jl) .LT. 0.0) THEN
562                     IF (zdvice(ji,jj,jl) .GT. -epsi10 ) THEN
563                        IF ( ( jl1.EQ.jl .AND. ht_i(ji,jj,jl1).GT.hi_max(jl) )     &
564                           .OR.                                     &
565                           ( jl1.EQ.jl+1 .AND. ht_i(ji,jj,jl1) .LE. hi_max(jl) ) &
566                           ) THEN
567                           zdaice(ji,jj,jl) = a_i(ji,jj,jl1) ! shift entire category
568                           zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
569                        ELSE
570                           zdaice(ji,jj,jl) = 0.0    ! shift no ice
571                           zdvice(ji,jj,jl) = 0.0
572                        ENDIF
573                     ELSE
574                        zdvice_negative = .true.
575                     ENDIF
576                  ENDIF
577
578                  ! If daice is close to aicen, set daice = aicen.
579                  IF (zdaice(ji,jj,jl) .GT. a_i(ji,jj,jl1) - epsi10 ) THEN
580                     IF (zdaice(ji,jj,jl) .LT. a_i(ji,jj,jl1)+epsi10) THEN
581                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
582                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
583                     ELSE
584                        zdaice_greater_aicen = .true.
585                     ENDIF
586                  ENDIF
587
588                  IF (zdvice(ji,jj,jl) .GT. v_i(ji,jj,jl1)-epsi10) THEN
589                     IF (zdvice(ji,jj,jl) .LT. v_i(ji,jj,jl1)+epsi10) THEN
590                        zdaice(ji,jj,jl) = a_i(ji,jj,jl1)
591                        zdvice(ji,jj,jl) = v_i(ji,jj,jl1) 
592                     ELSE
593                        zdvice_greater_vicen = .true.
594                     ENDIF
595                  ENDIF
596
597               ENDIF               ! donor > 0
598            END DO                   ! i
599         END DO                 ! j
600
601      END DO !jl
602
603      !-------------------------------------------------------------------------------
604      ! 3) Transfer volume and energy between categories
605      !-------------------------------------------------------------------------------
606
607      DO jl = klbnd, kubnd - 1
608         nbrem = 0
609         DO jj = 1, jpj
610            DO ji = 1, jpi
611               IF (zdaice(ji,jj,jl) .GT. 0.0 ) THEN ! daice(n) can be < puny
612                  nbrem = nbrem + 1
613                  nind_i(nbrem) = ji
614                  nind_j(nbrem) = jj
615               ENDIF ! tmask
616            END DO
617         END DO
618
619         DO ji = 1, nbrem 
620            ii = nind_i(ji)
621            ij = nind_j(ji)
622
623            jl1 = zdonor(ii,ij,jl)
624            rswitch             = MAX( 0.0 , SIGN( 1.0 , v_i(ii,ij,jl1) - epsi10 ) )
625            zworka(ii,ij)   = zdvice(ii,ij,jl) / MAX(v_i(ii,ij,jl1),epsi10) * rswitch
626            IF( jl1 == jl) THEN   ;   jl2 = jl1+1
627            ELSE                    ;   jl2 = jl 
628            ENDIF
629
630            !--------------
631            ! Ice areas
632            !--------------
633
634            a_i(ii,ij,jl1) = a_i(ii,ij,jl1) - zdaice(ii,ij,jl)
635            a_i(ii,ij,jl2) = a_i(ii,ij,jl2) + zdaice(ii,ij,jl)
636
637            !--------------
638            ! Ice volumes
639            !--------------
640
641            v_i(ii,ij,jl1) = v_i(ii,ij,jl1) - zdvice(ii,ij,jl) 
642            v_i(ii,ij,jl2) = v_i(ii,ij,jl2) + zdvice(ii,ij,jl)
643
644            !--------------
645            ! Snow volumes
646            !--------------
647
648            zdvsnow        = v_s(ii,ij,jl1) * zworka(ii,ij)
649            v_s(ii,ij,jl1) = v_s(ii,ij,jl1) - zdvsnow
650            v_s(ii,ij,jl2) = v_s(ii,ij,jl2) + zdvsnow 
651
652            !--------------------
653            ! Snow heat content 
654            !--------------------
655
656            zdesnow            = e_s(ii,ij,1,jl1) * zworka(ii,ij)
657            e_s(ii,ij,1,jl1)   = e_s(ii,ij,1,jl1) - zdesnow
658            e_s(ii,ij,1,jl2)   = e_s(ii,ij,1,jl2) + zdesnow
659
660            !--------------
661            ! Ice age
662            !--------------
663
664            zdo_aice           = oa_i(ii,ij,jl1) * zdaice(ii,ij,jl)
665            oa_i(ii,ij,jl1)    = oa_i(ii,ij,jl1) - zdo_aice
666            oa_i(ii,ij,jl2)    = oa_i(ii,ij,jl2) + zdo_aice
667
668            !--------------
669            ! Ice salinity
670            !--------------
671
672            zdsm_vice          = smv_i(ii,ij,jl1) * zworka(ii,ij)
673            smv_i(ii,ij,jl1)   = smv_i(ii,ij,jl1) - zdsm_vice
674            smv_i(ii,ij,jl2)   = smv_i(ii,ij,jl2) + zdsm_vice
675
676            !---------------------
677            ! Surface temperature
678            !---------------------
679
680            zdaTsf             = t_su(ii,ij,jl1) * zdaice(ii,ij,jl)
681            zaTsfn(ii,ij,jl1)  = zaTsfn(ii,ij,jl1) - zdaTsf
682            zaTsfn(ii,ij,jl2)  = zaTsfn(ii,ij,jl2) + zdaTsf 
683
684         END DO                 ! ji
685
686         !------------------
687         ! Ice heat content
688         !------------------
689
690         DO jk = 1, nlay_i
691!CDIR NODEP
692            DO ji = 1, nbrem
693               ii = nind_i(ji)
694               ij = nind_j(ji)
695
696               jl1 = zdonor(ii,ij,jl)
697               IF (jl1 .EQ. jl) THEN
698                  jl2 = jl+1
699               ELSE             ! n1 = n+1
700                  jl2 = jl 
701               ENDIF
702
703               zdeice = e_i(ii,ij,jk,jl1) * zworka(ii,ij)
704               e_i(ii,ij,jk,jl1) =  e_i(ii,ij,jk,jl1) - zdeice
705               e_i(ii,ij,jk,jl2) =  e_i(ii,ij,jk,jl2) + zdeice 
706            END DO              ! ji
707         END DO                 ! jk
708
709      END DO                   ! boundaries, 1 to ncat-1
710
711      !-----------------------------------------------------------------
712      ! Update ice thickness and temperature
713      !-----------------------------------------------------------------
714
715      DO jl = klbnd, kubnd
716         DO jj = 1, jpj
717            DO ji = 1, jpi 
718               IF ( a_i(ji,jj,jl) > epsi10 ) THEN
719                  ht_i(ji,jj,jl)  =  v_i   (ji,jj,jl) / a_i(ji,jj,jl) 
720                  t_su(ji,jj,jl)  =  zaTsfn(ji,jj,jl) / a_i(ji,jj,jl) 
721                  rswitch         =  1.0 - MAX(0.0,SIGN(1.0,-v_s(ji,jj,jl)+epsi10)) !0 if no ice and 1 if yes
722               ELSE
723                  ht_i(ji,jj,jl)  = 0._wp
724                  t_su(ji,jj,jl)  = rtt
725               ENDIF
726            END DO                 ! ji
727         END DO                 ! jj
728      END DO                    ! jl
729      !
730      CALL wrk_dealloc( jpi,jpj,jpl, zaTsfn )
731      CALL wrk_dealloc( jpi,jpj, zworka )
732      CALL wrk_dealloc( (jpi+1)*(jpj+1), nind_i, nind_j )   ! integer
733      !
734   END SUBROUTINE lim_itd_shiftice
735   
736
737   SUBROUTINE lim_itd_th_reb( klbnd, kubnd )
738      !!------------------------------------------------------------------
739      !!                ***  ROUTINE lim_itd_th_reb ***
740      !!
741      !! ** Purpose : rebin - rebins thicknesses into defined categories
742      !!
743      !! ** Method  :
744      !!------------------------------------------------------------------
745      INTEGER , INTENT (in) ::   klbnd   ! Start thickness category index point
746      INTEGER , INTENT (in) ::   kubnd   ! End point on which the  the computation is applied
747      !
748      INTEGER ::   ji,jj, jl   ! dummy loop indices
749      INTEGER ::   zshiftflag          ! = .true. if ice must be shifted
750      CHARACTER (len = 15) :: fieldid
751
752      INTEGER , POINTER, DIMENSION(:,:,:) ::   zdonor           ! donor category index
753      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdaice, zdvice   ! ice area and volume transferred
754
755      REAL(wp), POINTER, DIMENSION(:,:) ::   vt_i_init, vt_i_final   ! ice volume summed over categories
756      REAL(wp), POINTER, DIMENSION(:,:) ::   vt_s_init, vt_s_final   ! snow volume summed over categories
757      !!------------------------------------------------------------------
758      !! clem 2014/04: be carefull, rebining does not conserve salt(maybe?) => the difference is taken into account in limupdate
759     
760      CALL wrk_alloc( jpi,jpj,jpl, zdonor )   ! interger
761      CALL wrk_alloc( jpi,jpj,jpl, zdaice, zdvice )
762      CALL wrk_alloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
763      !     
764      IF( con_i ) THEN                 ! conservation check
765         CALL lim_column_sum (jpl,   v_i, vt_i_init)
766         CALL lim_column_sum (jpl,   v_s, vt_s_init)
767      ENDIF
768
769      !
770      !------------------------------------------------------------------------------
771      ! 1) Compute ice thickness.
772      !------------------------------------------------------------------------------
773      DO jl = klbnd, kubnd
774         DO jj = 1, jpj
775            DO ji = 1, jpi 
776               IF( a_i(ji,jj,jl) > epsi10 ) THEN
777                  ht_i(ji,jj,jl) = v_i(ji,jj,jl) / a_i(ji,jj,jl)
778               ELSE
779                  ht_i(ji,jj,jl) = 0._wp
780               ENDIF
781            END DO
782         END DO
783      END DO
784
785      !------------------------------------------------------------------------------
786      ! 2) Make sure thickness of cat klbnd is at least hi_max(klbnd)
787      !------------------------------------------------------------------------------
788      DO jj = 1, jpj 
789         DO ji = 1, jpi 
790            IF( a_i(ji,jj,klbnd) > epsi10 ) THEN
791               IF( ht_i(ji,jj,klbnd) <= hi_max(0) .AND. hi_max(0) > 0._wp ) THEN
792                  a_i(ji,jj,klbnd)  = v_i(ji,jj,klbnd) / hi_max(0) 
793                  ht_i(ji,jj,klbnd) = hi_max(0)
794               ENDIF
795            ENDIF
796         END DO
797      END DO
798
799      !------------------------------------------------------------------------------
800      ! 3) If a category thickness is not in bounds, shift the
801      ! entire area, volume, and energy to the neighboring category
802      !------------------------------------------------------------------------------
803      !-------------------------
804      ! Initialize shift arrays
805      !-------------------------
806      DO jl = klbnd, kubnd
807         zdonor(:,:,jl) = 0
808         zdaice(:,:,jl) = 0._wp
809         zdvice(:,:,jl) = 0._wp
810      END DO
811
812      !-------------------------
813      ! Move thin categories up
814      !-------------------------
815
816      DO jl = klbnd, kubnd - 1  ! loop over category boundaries
817
818         !---------------------------------------
819         ! identify thicknesses that are too big
820         !---------------------------------------
821         zshiftflag = 0
822
823         DO jj = 1, jpj 
824            DO ji = 1, jpi 
825               IF( a_i(ji,jj,jl) > epsi10 .AND. ht_i(ji,jj,jl) > hi_max(jl) ) THEN
826                  zshiftflag        = 1
827                  zdonor(ji,jj,jl)  = jl 
828                  ! begin TECLIM change
829                  !zdaice(ji,jj,jl)  = a_i(ji,jj,jl)
830                  !zdvice(ji,jj,jl)  = v_i(ji,jj,jl)
831                  !zdaice(ji,jj,jl)  = a_i(ji,jj,jl) * 0.5_wp
832                  !zdvice(ji,jj,jl)  = v_i(ji,jj,jl)-zdaice(ji,jj,jl)*(hi_max(jl)+hi_max(jl-1)) * 0.5_wp
833                  ! end TECLIM change
834                  ! clem: how much of a_i you send in cat sup is somewhat arbitrary
835                  zdaice(ji,jj,jl)  = a_i(ji,jj,jl) * ( ht_i(ji,jj,jl) - hi_max(jl) + epsi10 ) / ht_i(ji,jj,jl) 
836                  zdvice(ji,jj,jl)  = v_i(ji,jj,jl) - ( a_i(ji,jj,jl) - zdaice(ji,jj,jl) ) * ( hi_max(jl) - epsi10 )
837               ENDIF
838            END DO                 ! ji
839         END DO                 ! jj
840         IF(lk_mpp)   CALL mpp_max( zshiftflag )
841
842         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
843            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
844            ! Reset shift parameters
845            zdonor(:,:,jl) = 0
846            zdaice(:,:,jl) = 0._wp
847            zdvice(:,:,jl) = 0._wp
848         ENDIF
849         !
850      END DO                    ! jl
851
852      !----------------------------
853      ! Move thick categories down
854      !----------------------------
855
856      DO jl = kubnd - 1, 1, -1       ! loop over category boundaries
857
858         !-----------------------------------------
859         ! Identify thicknesses that are too small
860         !-----------------------------------------
861         zshiftflag = 0
862
863         DO jj = 1, jpj
864            DO ji = 1, jpi
865               IF( a_i(ji,jj,jl+1) > epsi10 .AND. ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
866                  !
867                  zshiftflag = 1
868                  zdonor(ji,jj,jl) = jl + 1
869                  zdaice(ji,jj,jl) = a_i(ji,jj,jl+1) 
870                  zdvice(ji,jj,jl) = v_i(ji,jj,jl+1)
871               ENDIF
872            END DO                 ! ji
873         END DO                 ! jj
874
875         IF(lk_mpp)   CALL mpp_max( zshiftflag )
876         
877         IF( zshiftflag == 1 ) THEN            ! Shift ice between categories
878            CALL lim_itd_shiftice( klbnd, kubnd, zdonor, zdaice, zdvice )
879            ! Reset shift parameters
880            zdonor(:,:,jl) = 0
881            zdaice(:,:,jl) = 0._wp
882            zdvice(:,:,jl) = 0._wp
883         ENDIF
884
885!         ! clem-change begin: why not doing that?
886!         DO jj = 1, jpj
887!            DO ji = 1, jpi
888!               IF( a_i(ji,jj,jl+1) > epsi10 .AND. ht_i(ji,jj,jl+1) <= hi_max(jl) ) THEN
889!                  ht_i(ji,jj,jl+1) = hi_max(jl) + epsi10
890!                  a_i (ji,jj,jl+1) = v_i(ji,jj,jl+1) / ht_i(ji,jj,jl+1)
891!               ENDIF
892!            END DO                 ! ji
893!         END DO                 ! jj
894         ! clem-change end
895
896      END DO                    ! jl
897
898      !------------------------------------------------------------------------------
899      ! 4) Conservation check
900      !------------------------------------------------------------------------------
901
902      IF( con_i ) THEN
903         CALL lim_column_sum (jpl,   v_i, vt_i_final)
904         fieldid = ' v_i : limitd_reb '
905         CALL lim_cons_check (vt_i_init, vt_i_final, 1.0e-6, fieldid) 
906
907         CALL lim_column_sum (jpl,   v_s, vt_s_final)
908         fieldid = ' v_s : limitd_reb '
909         CALL lim_cons_check (vt_s_init, vt_s_final, 1.0e-6, fieldid) 
910      ENDIF
911      !
912      CALL wrk_dealloc( jpi,jpj,jpl, zdonor )   ! interger
913      CALL wrk_dealloc( jpi,jpj,jpl, zdaice, zdvice )
914      CALL wrk_dealloc( jpi,jpj, vt_i_init, vt_i_final, vt_s_init, vt_s_final )
915
916   END SUBROUTINE lim_itd_th_reb
917
918#else
919   !!----------------------------------------------------------------------
920   !!   Default option            Dummy module         NO LIM sea-ice model
921   !!----------------------------------------------------------------------
922CONTAINS
923   SUBROUTINE lim_itd_th_rem
924   END SUBROUTINE lim_itd_th_rem
925   SUBROUTINE lim_itd_fitline
926   END SUBROUTINE lim_itd_fitline
927   SUBROUTINE lim_itd_shiftice
928   END SUBROUTINE lim_itd_shiftice
929   SUBROUTINE lim_itd_th_reb
930   END SUBROUTINE lim_itd_th_reb
931#endif
932   !!======================================================================
933END MODULE limitd_th
Note: See TracBrowser for help on using the repository browser.