New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
limthd.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3 – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/LIM_SRC_3/limthd.F90 @ 5070

Last change on this file since 5070 was 5070, checked in by clem, 9 years ago

LIM3 cosmetic changes
  • Property svn:keywords set to Id
File size: 39.3 KB
Line 
1MODULE limthd
2   !!======================================================================
3   !!                  ***  MODULE limthd   ***
4   !!  LIM-3 :   ice thermodynamic
5   !!======================================================================
6   !! History :  LIM  ! 2000-01 (M.A. Morales Maqueda, H. Goosse, T. Fichefet) LIM-1
7   !!            2.0  ! 2002-07 (C. Ethe, G. Madec)  LIM-2 (F90 rewriting)
8   !!            3.0  ! 2005-11 (M. Vancoppenolle)  LIM-3 : Multi-layer thermodynamics + salinity variations
9   !!             -   ! 2007-04 (M. Vancoppenolle) add lim_thd_glohec, lim_thd_con_dh and lim_thd_con_dif
10   !!            3.2  ! 2009-07 (M. Vancoppenolle, Y. Aksenov, G. Madec) bug correction in wfx_snw
11   !!            3.3  ! 2010-11 (G. Madec) corrected snow melting heat (due to factor betas)
12   !!            4.0  ! 2011-02 (G. Madec) dynamical allocation
13   !!             -   ! 2012-05 (C. Rousset) add penetration solar flux
14   !!----------------------------------------------------------------------
15#if defined key_lim3
16   !!----------------------------------------------------------------------
17   !!   'key_lim3'                                      LIM3 sea-ice model
18   !!----------------------------------------------------------------------
19   !!   lim_thd       : thermodynamic of sea ice
20   !!   lim_thd_init  : initialisation of sea-ice thermodynamic
21   !!----------------------------------------------------------------------
22   USE phycst         ! physical constants
23   USE dom_oce        ! ocean space and time domain variables
24   USE oce     , ONLY : fraqsr_1lev 
25   USE ice            ! LIM: sea-ice variables
26   USE sbc_oce        ! Surface boundary condition: ocean fields
27   USE sbc_ice        ! Surface boundary condition: ice fields
28   USE thd_ice        ! LIM thermodynamic sea-ice variables
29   USE dom_ice        ! LIM sea-ice domain
30   USE domvvl         ! domain: variable volume level
31   USE limthd_dif     ! LIM: thermodynamics, vertical diffusion
32   USE limthd_dh      ! LIM: thermodynamics, ice and snow thickness variation
33   USE limthd_sal     ! LIM: thermodynamics, ice salinity
34   USE limthd_ent     ! LIM: thermodynamics, ice enthalpy redistribution
35   USE limthd_lac     ! LIM-3 lateral accretion
36   USE limitd_th      ! remapping thickness distribution
37   USE limtab         ! LIM: 1D <==> 2D transformation
38   USE limvar         ! LIM: sea-ice variables
39   USE lbclnk         ! lateral boundary condition - MPP links
40   USE lib_mpp        ! MPP library
41   USE wrk_nemo       ! work arrays
42   USE in_out_manager ! I/O manager
43   USE prtctl         ! Print control
44   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
45   USE timing         ! Timing
46   USE limcons        ! conservation tests
47   USE limctl
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   lim_thd        ! called by limstp module
53   PUBLIC   lim_thd_init   ! called by sbc_lim_init
54
55   !! * Substitutions
56#  include "domzgr_substitute.h90"
57#  include "vectopt_loop_substitute.h90"
58   !!----------------------------------------------------------------------
59   !! NEMO/LIM3 3.3 , UCL - NEMO Consortium (2010)
60   !! $Id$
61   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
62   !!----------------------------------------------------------------------
63CONTAINS
64
65   SUBROUTINE lim_thd( kt )
66      !!-------------------------------------------------------------------
67      !!                ***  ROUTINE lim_thd  ***       
68      !! 
69      !! ** Purpose : This routine manages ice thermodynamics
70      !!         
71      !! ** Action : - Initialisation of some variables
72      !!             - Some preliminary computation (oceanic heat flux
73      !!               at the ice base, snow acc.,heat budget of the leads)
74      !!             - selection of the icy points and put them in an array
75      !!             - call lim_thd_dif  for vertical heat diffusion
76      !!             - call lim_thd_dh   for vertical ice growth and melt
77      !!             - call lim_thd_ent  for enthalpy remapping
78      !!             - call lim_thd_sal  for ice desalination
79      !!             - call lim_thd_temp to  retrieve temperature from ice enthalpy
80      !!             - back to the geographic grid
81      !!     
82      !! ** References :
83      !!---------------------------------------------------------------------
84      INTEGER, INTENT(in) :: kt    ! number of iteration
85      !!
86      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
87      INTEGER  :: nbpb             ! nb of icy pts for vertical thermo calculations
88      INTEGER  :: ii, ij           ! temporary dummy loop index
89      REAL(wp) :: zfric_u, zqld, zqfr
90      REAL(wp) :: zvi_b, zsmv_b, zei_b, zfs_b, zfw_b, zft_b 
91      REAL(wp), PARAMETER :: zfric_umin = 0._wp        ! lower bound for the friction velocity (cice value=5.e-04)
92      REAL(wp), PARAMETER :: zch        = 0.0057_wp    ! heat transfer coefficient
93      !
94      REAL(wp), POINTER, DIMENSION(:,:) ::  zqsr, zqns
95      !!-------------------------------------------------------------------
96      CALL wrk_alloc( jpi, jpj, zqsr, zqns )
97
98      IF( nn_timing == 1 )  CALL timing_start('limthd')
99
100      ! conservation test
101      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
102
103      !------------------------------------------------------------------------!
104      ! 1) Initialization of some variables                                    !
105      !------------------------------------------------------------------------!
106      ftr_ice(:,:,:) = 0._wp  ! part of solar radiation transmitted through the ice
107
108      !--------------------
109      ! 1.2) Heat content   
110      !--------------------
111      ! Change the units of heat content; from J/m2 to J/m3
112      DO jl = 1, jpl
113         DO jk = 1, nlay_i
114            DO jj = 1, jpj
115               DO ji = 1, jpi
116                  !0 if no ice and 1 if yes
117                  rswitch = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_i(ji,jj,jl) + epsi20 )  )
118                  !Energy of melting q(S,T) [J.m-3]
119                  e_i(ji,jj,jk,jl) = rswitch * e_i(ji,jj,jk,jl) / MAX( v_i(ji,jj,jl) , epsi20 ) * REAL( nlay_i )
120               END DO
121            END DO
122         END DO
123         DO jk = 1, nlay_s
124            DO jj = 1, jpj
125               DO ji = 1, jpi
126                  !0 if no ice and 1 if yes
127                  rswitch = 1.0 - MAX(  0.0 , SIGN( 1.0 , - v_s(ji,jj,jl) + epsi20 )  )
128                  !Energy of melting q(S,T) [J.m-3]
129                  e_s(ji,jj,jk,jl) = rswitch * e_s(ji,jj,jk,jl) / MAX( v_s(ji,jj,jl) , epsi20 ) * REAL( nlay_s )
130               END DO
131            END DO
132         END DO
133      END DO
134
135      ! 2) Partial computation of forcing for the thermodynamic sea ice model.      !
136      !-----------------------------------------------------------------------------!
137
138      !--- Ocean solar and non solar fluxes to be used in zqld
139      IF ( .NOT. lk_cpl ) THEN   ! --- forced case, fluxes to the lead are the same as over the ocean
140         !
141         zqsr(:,:) = qsr(:,:)      ; zqns(:,:) = qns(:,:)
142         !
143      ELSE                       ! --- coupled case, fluxes to the lead are total - intercepted
144         !
145         zqsr(:,:) = qsr_tot(:,:)  ; zqns(:,:) = qns_tot(:,:)
146         !
147         DO jl = 1, jpl
148            DO jj = 1, jpj
149               DO ji = 1, jpi
150                  zqsr(ji,jj) = zqsr(ji,jj) - qsr_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
151                  zqns(ji,jj) = zqns(ji,jj) - qns_ice(ji,jj,jl) * a_i_b(ji,jj,jl)
152               END DO
153            END DO
154         END DO
155         !
156      ENDIF
157
158      DO jj = 1, jpj
159         DO ji = 1, jpi
160            rswitch  = tmask(ji,jj,1) * ( 1._wp - MAX( 0._wp , SIGN( 1._wp , - at_i(ji,jj) + epsi10 ) ) ) ! 0 if no ice
161            !
162            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
163            !           !  practically no "direct lateral ablation"
164            !           
165            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
166            !           !  temperature and turbulent mixing (McPhee, 1992)
167            !
168
169            ! --- Energy received in the lead, zqld is defined everywhere (J.m-2) --- !
170            ! REMARK valid at least in forced mode from clem
171            ! precip is included in qns but not in qns_ice
172            IF ( lk_cpl ) THEN
173               zqld =  tmask(ji,jj,1) * rdt_ice *  &
174                  &    (   zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj)               &   ! pfrld already included in coupled mode
175                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *     &   ! heat content of precip
176                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )   &
177                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
178            ELSE
179               zqld =  tmask(ji,jj,1) * rdt_ice *  &
180                  &      ( pfrld(ji,jj) * ( zqsr(ji,jj) * fraqsr_1lev(ji,jj) + zqns(ji,jj) )    &
181                  &    + ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)  *             &  ! heat content of precip
182                  &      ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )           &
183                  &    + ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt ) )
184            ENDIF
185
186            !-- Energy needed to bring ocean surface layer until its freezing (<0, J.m-2) --- !
187            zqfr = tmask(ji,jj,1) * rau0 * rcp * fse3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) )
188
189            !-- Energy Budget of the leads (J.m-2). Must be < 0 to form ice
190            qlead(ji,jj) = MIN( 0._wp , zqld - zqfr ) 
191
192            ! If there is ice and leads are warming, then transfer energy from the lead budget and use it for bottom melting
193            IF( at_i(ji,jj) > epsi10 .AND. zqld > 0._wp ) THEN
194               fhld (ji,jj) = zqld * r1_rdtice / at_i(ji,jj) ! divided by at_i since this is (re)multiplied by a_i in limthd_dh.F90
195               qlead(ji,jj) = 0._wp
196            ELSE
197               fhld (ji,jj) = 0._wp
198            ENDIF
199            !
200            !-- Energy from the turbulent oceanic heat flux --- !
201            !clem zfric_u        = MAX ( MIN( SQRT( ust2s(ji,jj) ) , zfric_umax ) , zfric_umin )
202            zfric_u      = MAX( SQRT( ust2s(ji,jj) ), zfric_umin ) 
203            fhtur(ji,jj) = MAX( 0._wp, rswitch * rau0 * rcp * zch  * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ) ! W.m-2
204            ! upper bound for fhtur: we do not want SST to drop below Tfreeze.
205            ! So we say that the heat retrieved from the ocean (fhtur+fhld) must be < to the heat necessary to reach Tfreeze (zqfr)   
206            ! This is not a clean budget, so that should be corrected at some point
207            fhtur(ji,jj) = rswitch * MIN( fhtur(ji,jj), - fhld(ji,jj) - zqfr * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
208
209            ! -----------------------------------------
210            ! Net heat flux on top of ice-ocean [W.m-2]
211            ! -----------------------------------------
212            !     First  step here      : heat flux at the ocean surface + precip
213            !     Second step below     : heat flux at the ice   surface (after limthd_dif)
214            hfx_in(ji,jj) = hfx_in(ji,jj)                                                                                         & 
215               ! heat flux above the ocean
216               &    +             pfrld(ji,jj)   * ( zqns(ji,jj) + zqsr(ji,jj) )                                                  &
217               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
218               &    +   ( 1._wp - pfrld(ji,jj) ) * sprecip(ji,jj) * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
219               &    +   ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )
220
221            ! -----------------------------------------------------------------------------
222            ! Net heat flux that is retroceded to the ocean or taken from the ocean [W.m-2]
223            ! -----------------------------------------------------------------------------
224            !     First  step here              :  non solar + precip - qlead - qturb
225            !     Second step in limthd_dh      :  heat remaining if total melt (zq_rema)
226            !     Third  step in limsbc         :  heat from ice-ocean mass exchange (zf_mass) + solar
227            hfx_out(ji,jj) = hfx_out(ji,jj)                                                                                       & 
228               ! Non solar heat flux received by the ocean
229               &    +        pfrld(ji,jj) * qns(ji,jj)                                                                            &
230               ! latent heat of precip (note that precip is included in qns but not in qns_ice)
231               &    +      ( pfrld(ji,jj)**rn_betas - pfrld(ji,jj) ) * sprecip(ji,jj)       &
232               &         * ( cpic * ( MIN( tatm_ice(ji,jj), rt0_snow ) - rtt ) - lfus )  &
233               &    +      ( 1._wp - pfrld(ji,jj) ) * ( tprecip(ji,jj) - sprecip(ji,jj) ) * rcp * ( tatm_ice(ji,jj) - rtt )       &
234               ! heat flux taken from the ocean where there is open water ice formation
235               &    -      qlead(ji,jj) * r1_rdtice                                                                               &
236               ! heat flux taken from the ocean during bottom growth/melt (fhld should be 0 while bott growth)
237               &    -      at_i(ji,jj) * fhtur(ji,jj)                                                                             &
238               &    -      at_i(ji,jj) *  fhld(ji,jj)
239
240         END DO
241      END DO
242
243      !------------------------------------------------------------------------------!
244      ! 3) Select icy points and fulfill arrays for the vectorial grid.           
245      !------------------------------------------------------------------------------!
246
247      DO jl = 1, jpl      !loop over ice categories
248
249         IF( kt == nit000 .AND. lwp ) THEN
250            WRITE(numout,*) ' lim_thd : transfer to 1D vectors. Category no : ', jl 
251            WRITE(numout,*) ' ~~~~~~~~'
252         ENDIF
253
254         nbpb = 0
255         DO jj = 1, jpj
256            DO ji = 1, jpi
257               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
258                  nbpb      = nbpb  + 1
259                  npb(nbpb) = (jj - 1) * jpi + ji
260               ENDIF
261            END DO
262         END DO
263
264         ! debug point to follow
265         jiindex_1d = 0
266         IF( ln_nicep ) THEN
267            DO ji = mi0(jiindx), mi1(jiindx)
268               DO jj = mj0(jjindx), mj1(jjindx)
269                  jiindex_1d = (jj - 1) * jpi + ji
270                  WRITE(numout,*) ' lim_thd : Category no : ', jl 
271               END DO
272            END DO
273         ENDIF
274
275         !------------------------------------------------------------------------------!
276         ! 4) Thermodynamic computation
277         !------------------------------------------------------------------------------!
278
279         IF( lk_mpp )   CALL mpp_ini_ice( nbpb , numout )
280
281         IF( nbpb > 0 ) THEN  ! If there is no ice, do nothing.
282
283            !-------------------------
284            ! 4.1 Move to 1D arrays
285            !-------------------------
286
287            CALL tab_2d_1d( nbpb, at_i_1d     (1:nbpb), at_i            , jpi, jpj, npb(1:nbpb) )
288            CALL tab_2d_1d( nbpb, a_i_1d      (1:nbpb), a_i(:,:,jl)     , jpi, jpj, npb(1:nbpb) )
289            CALL tab_2d_1d( nbpb, ht_i_1d     (1:nbpb), ht_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
290            CALL tab_2d_1d( nbpb, ht_s_1d     (1:nbpb), ht_s(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
291
292            CALL tab_2d_1d( nbpb, t_su_1d     (1:nbpb), t_su(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
293            CALL tab_2d_1d( nbpb, sm_i_1d     (1:nbpb), sm_i(:,:,jl)    , jpi, jpj, npb(1:nbpb) )
294            DO jk = 1, nlay_s
295               CALL tab_2d_1d( nbpb, t_s_1d(1:nbpb,jk), t_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
296               CALL tab_2d_1d( nbpb, q_s_1d(1:nbpb,jk), e_s(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
297            END DO
298            DO jk = 1, nlay_i
299               CALL tab_2d_1d( nbpb, t_i_1d(1:nbpb,jk), t_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
300               CALL tab_2d_1d( nbpb, q_i_1d(1:nbpb,jk), e_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
301               CALL tab_2d_1d( nbpb, s_i_1d(1:nbpb,jk), s_i(:,:,jk,jl)  , jpi, jpj, npb(1:nbpb) )
302            END DO
303
304            CALL tab_2d_1d( nbpb, tatm_ice_1d(1:nbpb), tatm_ice(:,:)   , jpi, jpj, npb(1:nbpb) )
305            CALL tab_2d_1d( nbpb, qsr_ice_1d (1:nbpb), qsr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
306            CALL tab_2d_1d( nbpb, fr1_i0_1d  (1:nbpb), fr1_i0          , jpi, jpj, npb(1:nbpb) )
307            CALL tab_2d_1d( nbpb, fr2_i0_1d  (1:nbpb), fr2_i0          , jpi, jpj, npb(1:nbpb) )
308            CALL tab_2d_1d( nbpb, qns_ice_1d (1:nbpb), qns_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
309            CALL tab_2d_1d( nbpb, ftr_ice_1d (1:nbpb), ftr_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
310            IF( .NOT. lk_cpl ) THEN
311               CALL tab_2d_1d( nbpb, qla_ice_1d (1:nbpb), qla_ice(:,:,jl) , jpi, jpj, npb(1:nbpb) )
312               CALL tab_2d_1d( nbpb, dqla_ice_1d(1:nbpb), dqla_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
313            ENDIF
314            CALL tab_2d_1d( nbpb, dqns_ice_1d(1:nbpb), dqns_ice(:,:,jl), jpi, jpj, npb(1:nbpb) )
315            CALL tab_2d_1d( nbpb, t_bo_1d     (1:nbpb), t_bo            , jpi, jpj, npb(1:nbpb) )
316            CALL tab_2d_1d( nbpb, sprecip_1d (1:nbpb), sprecip         , jpi, jpj, npb(1:nbpb) ) 
317            CALL tab_2d_1d( nbpb, fhtur_1d   (1:nbpb), fhtur           , jpi, jpj, npb(1:nbpb) )
318            CALL tab_2d_1d( nbpb, qlead_1d   (1:nbpb), qlead           , jpi, jpj, npb(1:nbpb) )
319            CALL tab_2d_1d( nbpb, fhld_1d    (1:nbpb), fhld            , jpi, jpj, npb(1:nbpb) )
320
321            CALL tab_2d_1d( nbpb, wfx_snw_1d (1:nbpb), wfx_snw         , jpi, jpj, npb(1:nbpb) )
322            CALL tab_2d_1d( nbpb, wfx_sub_1d (1:nbpb), wfx_sub         , jpi, jpj, npb(1:nbpb) )
323
324            CALL tab_2d_1d( nbpb, wfx_bog_1d (1:nbpb), wfx_bog         , jpi, jpj, npb(1:nbpb) )
325            CALL tab_2d_1d( nbpb, wfx_bom_1d (1:nbpb), wfx_bom         , jpi, jpj, npb(1:nbpb) )
326            CALL tab_2d_1d( nbpb, wfx_sum_1d (1:nbpb), wfx_sum         , jpi, jpj, npb(1:nbpb) )
327            CALL tab_2d_1d( nbpb, wfx_sni_1d (1:nbpb), wfx_sni         , jpi, jpj, npb(1:nbpb) )
328            CALL tab_2d_1d( nbpb, wfx_res_1d (1:nbpb), wfx_res         , jpi, jpj, npb(1:nbpb) )
329            CALL tab_2d_1d( nbpb, wfx_spr_1d (1:nbpb), wfx_spr         , jpi, jpj, npb(1:nbpb) )
330
331            CALL tab_2d_1d( nbpb, sfx_bog_1d (1:nbpb), sfx_bog         , jpi, jpj, npb(1:nbpb) )
332            CALL tab_2d_1d( nbpb, sfx_bom_1d (1:nbpb), sfx_bom         , jpi, jpj, npb(1:nbpb) )
333            CALL tab_2d_1d( nbpb, sfx_sum_1d (1:nbpb), sfx_sum         , jpi, jpj, npb(1:nbpb) )
334            CALL tab_2d_1d( nbpb, sfx_sni_1d (1:nbpb), sfx_sni         , jpi, jpj, npb(1:nbpb) )
335            CALL tab_2d_1d( nbpb, sfx_bri_1d (1:nbpb), sfx_bri         , jpi, jpj, npb(1:nbpb) )
336            CALL tab_2d_1d( nbpb, sfx_res_1d (1:nbpb), sfx_res         , jpi, jpj, npb(1:nbpb) )
337
338            CALL tab_2d_1d( nbpb, hfx_thd_1d (1:nbpb), hfx_thd         , jpi, jpj, npb(1:nbpb) )
339            CALL tab_2d_1d( nbpb, hfx_spr_1d (1:nbpb), hfx_spr         , jpi, jpj, npb(1:nbpb) )
340            CALL tab_2d_1d( nbpb, hfx_sum_1d (1:nbpb), hfx_sum         , jpi, jpj, npb(1:nbpb) )
341            CALL tab_2d_1d( nbpb, hfx_bom_1d (1:nbpb), hfx_bom         , jpi, jpj, npb(1:nbpb) )
342            CALL tab_2d_1d( nbpb, hfx_bog_1d (1:nbpb), hfx_bog         , jpi, jpj, npb(1:nbpb) )
343            CALL tab_2d_1d( nbpb, hfx_dif_1d (1:nbpb), hfx_dif         , jpi, jpj, npb(1:nbpb) )
344            CALL tab_2d_1d( nbpb, hfx_opw_1d (1:nbpb), hfx_opw         , jpi, jpj, npb(1:nbpb) )
345            CALL tab_2d_1d( nbpb, hfx_snw_1d (1:nbpb), hfx_snw         , jpi, jpj, npb(1:nbpb) )
346            CALL tab_2d_1d( nbpb, hfx_sub_1d (1:nbpb), hfx_sub         , jpi, jpj, npb(1:nbpb) )
347            CALL tab_2d_1d( nbpb, hfx_err_1d (1:nbpb), hfx_err         , jpi, jpj, npb(1:nbpb) )
348            CALL tab_2d_1d( nbpb, hfx_res_1d (1:nbpb), hfx_res         , jpi, jpj, npb(1:nbpb) )
349            CALL tab_2d_1d( nbpb, hfx_err_rem_1d (1:nbpb), hfx_err_rem , jpi, jpj, npb(1:nbpb) )
350
351            !--------------------------------
352            ! 4.3) Thermodynamic processes
353            !--------------------------------
354
355            !--------------------------------------!
356            ! --- Ice/Snow Temperature profile --- !
357            !--------------------------------------!
358            CALL lim_thd_dif( 1, nbpb )
359
360            !---------------------------------!
361            ! --- Ice/Snow thickness ---      !
362            !---------------------------------!
363            CALL lim_thd_dh( 1, nbpb )   
364
365            ! --- Ice enthalpy remapping --- !
366            CALL lim_thd_ent( 1, nbpb, q_i_1d(1:nbpb,:) ) 
367                                           
368            !---------------------------------!
369            ! --- Ice salinity ---            !
370            !---------------------------------!
371            CALL lim_thd_sal( 1, nbpb )   
372
373            !---------------------------------!
374            ! --- temperature update ---      !
375            !---------------------------------!
376            CALL lim_thd_temp( 1, nbpb )
377
378            !------------------------------------!
379            ! --- lateral melting if monocat --- !
380            !------------------------------------!
381            IF ( ( ( nn_monocat == 1 ) .OR. ( nn_monocat == 4 ) ) .AND. ( jpl == 1 ) ) THEN
382               CALL lim_thd_lam( 1, nbpb )
383            END IF
384
385            !--------------------------------
386            ! 4.4) Move 1D to 2D vectors
387            !--------------------------------
388
389               CALL tab_1d_2d( nbpb, at_i          , npb, at_i_1d    (1:nbpb)   , jpi, jpj )
390               CALL tab_1d_2d( nbpb, ht_i(:,:,jl)  , npb, ht_i_1d    (1:nbpb)   , jpi, jpj )
391               CALL tab_1d_2d( nbpb, ht_s(:,:,jl)  , npb, ht_s_1d    (1:nbpb)   , jpi, jpj )
392               CALL tab_1d_2d( nbpb, a_i (:,:,jl)  , npb, a_i_1d     (1:nbpb)   , jpi, jpj )
393               CALL tab_1d_2d( nbpb, t_su(:,:,jl)  , npb, t_su_1d    (1:nbpb)   , jpi, jpj )
394               CALL tab_1d_2d( nbpb, sm_i(:,:,jl)  , npb, sm_i_1d    (1:nbpb)   , jpi, jpj )
395            DO jk = 1, nlay_s
396               CALL tab_1d_2d( nbpb, t_s(:,:,jk,jl), npb, t_s_1d     (1:nbpb,jk), jpi, jpj)
397               CALL tab_1d_2d( nbpb, e_s(:,:,jk,jl), npb, q_s_1d     (1:nbpb,jk), jpi, jpj)
398            END DO
399            DO jk = 1, nlay_i
400               CALL tab_1d_2d( nbpb, t_i(:,:,jk,jl), npb, t_i_1d     (1:nbpb,jk), jpi, jpj)
401               CALL tab_1d_2d( nbpb, e_i(:,:,jk,jl), npb, q_i_1d     (1:nbpb,jk), jpi, jpj)
402               CALL tab_1d_2d( nbpb, s_i(:,:,jk,jl), npb, s_i_1d     (1:nbpb,jk), jpi, jpj)
403            END DO
404               CALL tab_1d_2d( nbpb, qlead         , npb, qlead_1d  (1:nbpb)   , jpi, jpj )
405
406               CALL tab_1d_2d( nbpb, wfx_snw       , npb, wfx_snw_1d(1:nbpb)   , jpi, jpj )
407               CALL tab_1d_2d( nbpb, wfx_sub       , npb, wfx_sub_1d(1:nbpb)   , jpi, jpj )
408
409               CALL tab_1d_2d( nbpb, wfx_bog       , npb, wfx_bog_1d(1:nbpb)   , jpi, jpj )
410               CALL tab_1d_2d( nbpb, wfx_bom       , npb, wfx_bom_1d(1:nbpb)   , jpi, jpj )
411               CALL tab_1d_2d( nbpb, wfx_sum       , npb, wfx_sum_1d(1:nbpb)   , jpi, jpj )
412               CALL tab_1d_2d( nbpb, wfx_sni       , npb, wfx_sni_1d(1:nbpb)   , jpi, jpj )
413               CALL tab_1d_2d( nbpb, wfx_res       , npb, wfx_res_1d(1:nbpb)   , jpi, jpj )
414               CALL tab_1d_2d( nbpb, wfx_spr       , npb, wfx_spr_1d(1:nbpb)   , jpi, jpj )
415
416               CALL tab_1d_2d( nbpb, sfx_bog       , npb, sfx_bog_1d(1:nbpb)   , jpi, jpj )
417               CALL tab_1d_2d( nbpb, sfx_bom       , npb, sfx_bom_1d(1:nbpb)   , jpi, jpj )
418               CALL tab_1d_2d( nbpb, sfx_sum       , npb, sfx_sum_1d(1:nbpb)   , jpi, jpj )
419               CALL tab_1d_2d( nbpb, sfx_sni       , npb, sfx_sni_1d(1:nbpb)   , jpi, jpj )
420               CALL tab_1d_2d( nbpb, sfx_res       , npb, sfx_res_1d(1:nbpb)   , jpi, jpj )
421               CALL tab_1d_2d( nbpb, sfx_bri       , npb, sfx_bri_1d(1:nbpb)   , jpi, jpj )
422
423              CALL tab_1d_2d( nbpb, hfx_thd       , npb, hfx_thd_1d(1:nbpb)   , jpi, jpj )
424              CALL tab_1d_2d( nbpb, hfx_spr       , npb, hfx_spr_1d(1:nbpb)   , jpi, jpj )
425              CALL tab_1d_2d( nbpb, hfx_sum       , npb, hfx_sum_1d(1:nbpb)   , jpi, jpj )
426              CALL tab_1d_2d( nbpb, hfx_bom       , npb, hfx_bom_1d(1:nbpb)   , jpi, jpj )
427              CALL tab_1d_2d( nbpb, hfx_bog       , npb, hfx_bog_1d(1:nbpb)   , jpi, jpj )
428              CALL tab_1d_2d( nbpb, hfx_dif       , npb, hfx_dif_1d(1:nbpb)   , jpi, jpj )
429              CALL tab_1d_2d( nbpb, hfx_opw       , npb, hfx_opw_1d(1:nbpb)   , jpi, jpj )
430              CALL tab_1d_2d( nbpb, hfx_snw       , npb, hfx_snw_1d(1:nbpb)   , jpi, jpj )
431              CALL tab_1d_2d( nbpb, hfx_sub       , npb, hfx_sub_1d(1:nbpb)   , jpi, jpj )
432              CALL tab_1d_2d( nbpb, hfx_err       , npb, hfx_err_1d(1:nbpb)   , jpi, jpj )
433              CALL tab_1d_2d( nbpb, hfx_res       , npb, hfx_res_1d(1:nbpb)   , jpi, jpj )
434              CALL tab_1d_2d( nbpb, hfx_err_rem   , npb, hfx_err_rem_1d(1:nbpb), jpi, jpj )
435            !
436              CALL tab_1d_2d( nbpb, qns_ice(:,:,jl), npb, qns_ice_1d(1:nbpb) , jpi, jpj)
437              CALL tab_1d_2d( nbpb, ftr_ice(:,:,jl), npb, ftr_ice_1d(1:nbpb) , jpi, jpj )
438            !
439            IF( lk_mpp )   CALL mpp_comm_free( ncomm_ice ) !RB necessary ??
440         ENDIF
441         !
442      END DO
443
444      !------------------------------------------------------------------------------!
445      ! 5) Global variables, diagnostics
446      !------------------------------------------------------------------------------!
447
448      !------------------------
449      ! Ice heat content             
450      !------------------------
451      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
452      DO jl = 1, jpl
453         DO jk = 1, nlay_i
454            e_i(:,:,jk,jl) = e_i(:,:,jk,jl) * a_i(:,:,jl) * ht_i(:,:,jl) / REAL( nlay_i )
455         END DO
456      END DO
457
458      !------------------------
459      ! Snow heat content             
460      !------------------------
461      ! Enthalpies are global variables we have to readjust the units (heat content in J/m2)
462      DO jl = 1, jpl
463         DO jk = 1, nlay_s
464            e_s(:,:,jk,jl) = e_s(:,:,jk,jl) * a_i(:,:,jl) * ht_s(:,:,jl) / REAL( nlay_s )
465         END DO
466      END DO
467 
468      !------------------------
469      ! Ice natural aging             
470      !------------------------
471      oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice /rday
472
473      !----------------------------------
474      ! Change thickness to volume
475      !----------------------------------
476      CALL lim_var_eqv2glo
477
478      !--------------------------------------------
479      ! 5.4) Diagnostic thermodynamic growth rates
480      !--------------------------------------------
481      IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 1, ' - ice thermodyn. - ' )   ! control print
482
483      IF(ln_ctl) THEN            ! Control print
484         CALL prt_ctl_info(' ')
485         CALL prt_ctl_info(' - Cell values : ')
486         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
487         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_thd  : cell area :')
488         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_thd  : at_i      :')
489         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_thd  : vt_i      :')
490         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_thd  : vt_s      :')
491         DO jl = 1, jpl
492            CALL prt_ctl_info(' ')
493            CALL prt_ctl_info(' - Category : ', ivar1=jl)
494            CALL prt_ctl_info('   ~~~~~~~~~~')
495            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_thd  : a_i      : ')
496            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_thd  : ht_i     : ')
497            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_thd  : ht_s     : ')
498            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_thd  : v_i      : ')
499            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_thd  : v_s      : ')
500            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_thd  : e_s      : ')
501            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_thd  : t_su     : ')
502            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_thd  : t_snow   : ')
503            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_thd  : sm_i     : ')
504            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_thd  : smv_i    : ')
505            DO jk = 1, nlay_i
506               CALL prt_ctl_info(' ')
507               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
508               CALL prt_ctl_info('   ~~~~~~~')
509               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_thd  : t_i      : ')
510               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_thd  : e_i      : ')
511            END DO
512         END DO
513      ENDIF
514      !
515      !
516      CALL wrk_dealloc( jpi, jpj, zqsr, zqns )
517
518      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
519      !------------------------------------------------------------------------------|
520      !  1) Transport of ice between thickness categories.                           |
521      !------------------------------------------------------------------------------|
522      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
523
524      ! Given thermodynamic growth rates, transport ice between thickness categories.
525      IF( jpl > 1 )   CALL lim_itd_th_rem( 1, jpl, kt )
526      !
527      CALL lim_var_glo2eqv    ! only for info
528      CALL lim_var_agg(1)
529
530      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limitd_th_rem', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
531      IF( ln_limdiahsb ) CALL lim_cons_hsm(0, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
532      !------------------------------------------------------------------------------|
533      !  3) Add frazil ice growing in leads.
534      !------------------------------------------------------------------------------|
535      CALL lim_thd_lac
536      CALL lim_var_glo2eqv    ! only for info
537     
538      ! conservation test
539      IF( ln_limdiahsb ) CALL lim_cons_hsm(1, 'limthd_lac', zvi_b, zsmv_b, zei_b, zfw_b, zfs_b, zft_b)
540
541      IF(ln_ctl) THEN   ! Control print
542         CALL prt_ctl_info(' ')
543         CALL prt_ctl_info(' - Cell values : ')
544         CALL prt_ctl_info('   ~~~~~~~~~~~~~ ')
545         CALL prt_ctl(tab2d_1=e12t , clinfo1=' lim_itd_th  : cell area :')
546         CALL prt_ctl(tab2d_1=at_i , clinfo1=' lim_itd_th  : at_i      :')
547         CALL prt_ctl(tab2d_1=vt_i , clinfo1=' lim_itd_th  : vt_i      :')
548         CALL prt_ctl(tab2d_1=vt_s , clinfo1=' lim_itd_th  : vt_s      :')
549         DO jl = 1, jpl
550            CALL prt_ctl_info(' ')
551            CALL prt_ctl_info(' - Category : ', ivar1=jl)
552            CALL prt_ctl_info('   ~~~~~~~~~~')
553            CALL prt_ctl(tab2d_1=a_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : a_i      : ')
554            CALL prt_ctl(tab2d_1=ht_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_i     : ')
555            CALL prt_ctl(tab2d_1=ht_s  (:,:,jl)   , clinfo1= ' lim_itd_th  : ht_s     : ')
556            CALL prt_ctl(tab2d_1=v_i   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_i      : ')
557            CALL prt_ctl(tab2d_1=v_s   (:,:,jl)   , clinfo1= ' lim_itd_th  : v_s      : ')
558            CALL prt_ctl(tab2d_1=e_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : e_s      : ')
559            CALL prt_ctl(tab2d_1=t_su  (:,:,jl)   , clinfo1= ' lim_itd_th  : t_su     : ')
560            CALL prt_ctl(tab2d_1=t_s   (:,:,1,jl) , clinfo1= ' lim_itd_th  : t_snow   : ')
561            CALL prt_ctl(tab2d_1=sm_i  (:,:,jl)   , clinfo1= ' lim_itd_th  : sm_i     : ')
562            CALL prt_ctl(tab2d_1=smv_i (:,:,jl)   , clinfo1= ' lim_itd_th  : smv_i    : ')
563            DO jk = 1, nlay_i
564               CALL prt_ctl_info(' ')
565               CALL prt_ctl_info(' - Layer : ', ivar1=jk)
566               CALL prt_ctl_info('   ~~~~~~~')
567               CALL prt_ctl(tab2d_1=t_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : t_i      : ')
568               CALL prt_ctl(tab2d_1=e_i(:,:,jk,jl) , clinfo1= ' lim_itd_th  : e_i      : ')
569            END DO
570         END DO
571      ENDIF
572      !
573      IF( nn_timing == 1 )  CALL timing_stop('limthd')
574
575   END SUBROUTINE lim_thd 
576
577   SUBROUTINE lim_thd_temp( kideb, kiut )
578      !!-----------------------------------------------------------------------
579      !!                   ***  ROUTINE lim_thd_temp ***
580      !!                 
581      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
582      !!
583      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
584      !!-------------------------------------------------------------------
585      INTEGER, INTENT(in) ::   kideb, kiut   ! bounds for the spatial loop
586      !!
587      INTEGER  ::   ji, jk   ! dummy loop indices
588      REAL(wp) ::   ztmelts, zaaa, zbbb, zccc, zdiscrim  ! local scalar
589      !!-------------------------------------------------------------------
590      ! Recover ice temperature
591      DO jk = 1, nlay_i
592         DO ji = kideb, kiut
593            ztmelts       =  -tmut * s_i_1d(ji,jk) + rtt
594            ! Conversion q(S,T) -> T (second order equation)
595            zaaa          =  cpic
596            zbbb          =  ( rcp - cpic ) * ( ztmelts - rtt ) + q_i_1d(ji,jk) / rhoic - lfus
597            zccc          =  lfus * ( ztmelts - rtt )
598            zdiscrim      =  SQRT( MAX( zbbb * zbbb - 4._wp * zaaa * zccc, 0._wp ) )
599            t_i_1d(ji,jk) =  rtt - ( zbbb + zdiscrim ) / ( 2._wp * zaaa )
600           
601            ! mask temperature
602            rswitch       =  1._wp - MAX( 0._wp , SIGN( 1._wp , - ht_i_1d(ji) ) ) 
603            t_i_1d(ji,jk) =  rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rtt
604         END DO
605      END DO
606
607   END SUBROUTINE lim_thd_temp
608
609   SUBROUTINE lim_thd_lam( kideb, kiut )
610      !!-----------------------------------------------------------------------
611      !!                   ***  ROUTINE lim_thd_lam ***
612      !!                 
613      !! ** Purpose :   Lateral melting in case monocategory
614      !!                          ( dA = A/2h dh )
615      !!-----------------------------------------------------------------------
616      INTEGER, INTENT(in) ::   kideb, kiut        ! bounds for the spatial loop
617      INTEGER             ::   ji                 ! dummy loop indices
618      REAL(wp)            ::   zhi_bef            ! ice thickness before thermo
619      REAL(wp)            ::   zdh_mel, zda_mel   ! net melting
620      REAL(wp)            ::   zv                 ! ice volume
621
622      DO ji = kideb, kiut
623         zdh_mel = MIN( 0._wp, dh_i_surf(ji) + dh_i_bott(ji) + dh_snowice(ji) )
624         IF( zdh_mel < 0._wp )  THEN
625            zv         = a_i_1d(ji) * ht_i_1d(ji)
626            ! lateral melting = concentration change
627            zhi_bef     = ht_i_1d(ji) - zdh_mel
628            zda_mel     =  a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi10 ) )
629            a_i_1d(ji)  = MAX( 0._wp, a_i_1d(ji) + zda_mel ) 
630            ! adjust thickness
631            rswitch     = 1._wp - MAX( 0._wp , SIGN( 1._wp , - a_i_1d(ji) + epsi20 ) )
632            ht_i_1d(ji) = rswitch * zv / MAX( a_i_1d(ji), epsi20 )
633            ! retrieve total concentration
634            at_i_1d(ji) = a_i_1d(ji)
635         END IF
636      END DO
637     
638   END SUBROUTINE lim_thd_lam
639
640   SUBROUTINE lim_thd_init
641      !!-----------------------------------------------------------------------
642      !!                   ***  ROUTINE lim_thd_init ***
643      !!                 
644      !! ** Purpose :   Physical constants and parameters linked to the ice
645      !!              thermodynamics
646      !!
647      !! ** Method  :   Read the namicethd namelist and check the ice-thermo
648      !!              parameter values called at the first timestep (nit000)
649      !!
650      !! ** input   :   Namelist namicether
651      !!-------------------------------------------------------------------
652      INTEGER  ::   ios                 ! Local integer output status for namelist read
653      NAMELIST/namicethd/ rn_hnewice, ln_frazil, rn_maxfrazb, rn_vfrazb, rn_Cfrazb,                       &
654         &                rn_himin, parsub, rn_betas, rn_kappa_i, nn_conv_dif, rn_terr_dif, nn_ice_thcon, &
655         &                nn_monocat
656      !!-------------------------------------------------------------------
657      !
658      IF(lwp) THEN
659         WRITE(numout,*)
660         WRITE(numout,*) 'lim_thd : Ice Thermodynamics'
661         WRITE(numout,*) '~~~~~~~'
662      ENDIF
663      !
664      REWIND( numnam_ice_ref )              ! Namelist namicethd in reference namelist : Ice thermodynamics
665      READ  ( numnam_ice_ref, namicethd, IOSTAT = ios, ERR = 901)
666901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in reference namelist', lwp )
667
668      REWIND( numnam_ice_cfg )              ! Namelist namicethd in configuration namelist : Ice thermodynamics
669      READ  ( numnam_ice_cfg, namicethd, IOSTAT = ios, ERR = 902 )
670902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicethd in configuration namelist', lwp )
671      IF(lwm) WRITE ( numoni, namicethd )
672      !
673      IF ( ( jpl > 1 ) .AND. ( nn_monocat == 1 ) ) THEN
674         nn_monocat = 0
675         IF(lwp) WRITE(numout, *) '   nn_monocat must be 0 in multi-category case '
676      ENDIF
677
678      IF( lk_cpl .AND. parsub /= 0.0 )   CALL ctl_stop( 'In coupled mode, use parsub = 0. or send dqla' )
679      !
680      IF(lwp) THEN                          ! control print
681         WRITE(numout,*)
682         WRITE(numout,*)'   Namelist of ice parameters for ice thermodynamic computation '
683         WRITE(numout,*)'      ice thick. for lateral accretion                        rn_hnewice   = ', rn_hnewice
684         WRITE(numout,*)'      Frazil ice thickness as a function of wind or not       ln_frazil    = ', ln_frazil
685         WRITE(numout,*)'      Maximum proportion of frazil ice collecting at bottom   rn_maxfrazb  = ', rn_maxfrazb
686         WRITE(numout,*)'      Thresold relative drift speed for collection of frazil  rn_vfrazb    = ', rn_vfrazb
687         WRITE(numout,*)'      Squeezing coefficient for collection of frazil          rn_Cfrazb    = ', rn_Cfrazb
688         WRITE(numout,*)'      minimum ice thickness                                   rn_himin     = ', rn_himin 
689         WRITE(numout,*)'      numerical carac. of the scheme for diffusion in ice '
690         WRITE(numout,*)'      switch for snow sublimation  (=1) or not (=0)           parsub       = ', parsub 
691         WRITE(numout,*)'      coefficient for ice-lead partition of snowfall          rn_betas     = ', rn_betas
692         WRITE(numout,*)'      extinction radiation parameter in sea ice               rn_kappa_i   = ', rn_kappa_i
693         WRITE(numout,*)'      maximal n. of iter. for heat diffusion computation      nn_conv_dif  = ', nn_conv_dif
694         WRITE(numout,*)'      maximal err. on T for heat diffusion computation        rn_terr_dif  = ', rn_terr_dif
695         WRITE(numout,*)'      switch for comp. of thermal conductivity in the ice     nn_ice_thcon = ', nn_ice_thcon
696         WRITE(numout,*)'      check heat conservation in the ice/snow                 con_i        = ', con_i
697         WRITE(numout,*)'      virtual ITD mono-category parameterizations (1) or not  nn_monocat   = ', nn_monocat
698      ENDIF
699      !
700   END SUBROUTINE lim_thd_init
701
702#else
703   !!----------------------------------------------------------------------
704   !!   Default option         Dummy module          NO  LIM3 sea-ice model
705   !!----------------------------------------------------------------------
706#endif
707
708   !!======================================================================
709END MODULE limthd
Note: See TracBrowser for help on using the repository browser.