source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/OPA_SRC/BDY/bdyice_lim.F90 @ 5079

Last change on this file since 5079 was 5079, checked in by clem, 6 years ago

LIM3: solve ticket #1421

File size: 17.9 KB
Line 
1MODULE bdyice_lim
2   !!======================================================================
3   !!                       ***  MODULE  bdyice_lim  ***
4   !! Unstructured Open Boundary Cond. :  Open boundary conditions for sea-ice (LIM2 and LIM3)
5   !!======================================================================
6   !!  History :  3.3  !  2010-09 (D. Storkey)  Original code
7   !!             3.4  !  2011    (D. Storkey)  rewrite in preparation for OBC-BDY merge
8   !!              -   !  2012-01 (C. Rousset)  add lim3 and remove useless jk loop
9   !!----------------------------------------------------------------------
10#if defined   key_bdy   &&  ( defined key_lim2 || defined key_lim3 )
11   !!----------------------------------------------------------------------
12   !!   'key_bdy'            and                 Unstructured Open Boundary Conditions
13   !!   'key_lim2'                                                 LIM-2 sea ice model
14   !!   'key_lim3'                                                 LIM-3 sea ice model
15   !!----------------------------------------------------------------------
16   !!   bdy_ice_lim        : Application of open boundaries to ice
17   !!   bdy_ice_frs        : Application of Flow Relaxation Scheme
18   !!----------------------------------------------------------------------
19   USE timing          ! Timing
20   USE phycst          ! physical constant
21   USE eosbn2          ! equation of state
22   USE oce             ! ocean dynamics and tracers variables
23#if defined key_lim2
24   USE par_ice_2
25   USE ice_2           ! LIM_2 ice variables
26   USE dom_ice_2       ! sea-ice domain
27#elif defined key_lim3
28   USE ice             ! LIM_3 ice variables
29   USE dom_ice         ! sea-ice domain
30#endif
31   USE par_oce         ! ocean parameters
32   USE dom_oce         ! ocean space and time domain variables
33   USE sbc_oce         ! Surface boundary condition: ocean fields
34   USE bdy_oce         ! ocean open boundary conditions
35   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
36   USE in_out_manager  ! write to numout file
37   USE lib_mpp         ! distributed memory computing
38   USE lib_fortran     ! to use key_nosignedzero
39
40   IMPLICIT NONE
41   PRIVATE
42
43   PUBLIC   bdy_ice_lim    ! routine called in sbcmod
44   PUBLIC   bdy_ice_lim_dyn ! routine called in limrhg
45
46   !!----------------------------------------------------------------------
47   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
48   !! $Id: bdyice.F90 2715 2011-03-30 15:58:35Z rblod $
49   !! Software governed by the CeCILL licence (NEMOGCM/NEMO_CeCILL.txt)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE bdy_ice_lim( kt )
54      !!----------------------------------------------------------------------
55      !!                  ***  SUBROUTINE bdy_ice_lim  ***
56      !!
57      !! ** Purpose : - Apply open boundary conditions for ice (LIM2 and LIM3)
58      !!
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT( in ) :: kt     ! Main time step counter
61      INTEGER               :: ib_bdy ! Loop index
62
63      DO ib_bdy=1, nb_bdy
64
65         SELECT CASE( cn_ice_lim(ib_bdy) )
66         CASE('none')
67            CYCLE
68         CASE('frs')
69            CALL bdy_ice_frs( idx_bdy(ib_bdy), dta_bdy(ib_bdy), kt, ib_bdy )
70         CASE DEFAULT
71            CALL ctl_stop( 'bdy_ice_lim : unrecognised option for open boundaries for ice fields' )
72         END SELECT
73
74      END DO
75
76   END SUBROUTINE bdy_ice_lim
77
78   SUBROUTINE bdy_ice_frs( idx, dta, kt, ib_bdy )
79      !!------------------------------------------------------------------------------
80      !!                 ***  SUBROUTINE bdy_ice_frs  ***
81      !!                   
82      !! ** Purpose : Apply the Flow Relaxation Scheme for sea-ice fields in the case
83      !!              of unstructured open boundaries.
84      !!
85      !! Reference : Engedahl H., 1995: Use of the flow relaxation scheme in a three-
86      !!             dimensional baroclinic ocean model with realistic topography. Tellus, 365-382.
87      !!------------------------------------------------------------------------------
88      TYPE(OBC_INDEX), INTENT(in) ::   idx  ! OBC indices
89      TYPE(OBC_DATA),  INTENT(in) ::   dta  ! OBC external data
90      INTEGER,         INTENT(in) ::   kt   ! main time-step counter
91      INTEGER,         INTENT(in) ::   ib_bdy  ! BDY set index      !!
92
93      INTEGER  ::   jpbound            ! 0 = incoming ice
94                                       ! 1 = outgoing ice
95      INTEGER  ::   jb, jk, jgrd, jl   ! dummy loop indices
96      INTEGER  ::   ji, jj, ii, ij     ! local scalar
97      REAL(wp) ::   zwgt, zwgt1        ! local scalar
98      REAL(wp) ::   ztmelts, zdh
99
100      !!------------------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 ) CALL timing_start('bdy_ice_frs')
103      !
104      jgrd = 1      ! Everything is at T-points here
105      !
106#if defined key_lim2
107      DO jb = 1, idx%nblen(jgrd)
108         ji    = idx%nbi(jb,jgrd)
109         jj    = idx%nbj(jb,jgrd)
110         zwgt  = idx%nbw(jb,jgrd)
111         zwgt1 = 1.e0 - idx%nbw(jb,jgrd)
112         frld (ji,jj) = ( frld (ji,jj) * zwgt1 + dta%frld (jb) * zwgt ) * tmask(ji,jj,1)     ! Leads fraction
113         hicif(ji,jj) = ( hicif(ji,jj) * zwgt1 + dta%hicif(jb) * zwgt ) * tmask(ji,jj,1)     ! Ice depth
114         hsnif(ji,jj) = ( hsnif(ji,jj) * zwgt1 + dta%hsnif(jb) * zwgt ) * tmask(ji,jj,1)     ! Snow depth
115      END DO
116
117      CALL lbc_bdy_lnk( frld,  'T', 1., ib_bdy )                                         ! lateral boundary conditions
118      CALL lbc_bdy_lnk( hicif, 'T', 1., ib_bdy )
119      CALL lbc_bdy_lnk( hsnif, 'T', 1., ib_bdy )
120
121      vt_i(:,:) = hicif(:,:) * frld(:,:)
122      vt_s(:,:) = hsnif(:,:) * frld(:,:)
123      !
124#elif defined key_lim3
125
126      DO jl = 1, jpl
127         DO jb = 1, idx%nblen(jgrd)
128            ji    = idx%nbi(jb,jgrd)
129            jj    = idx%nbj(jb,jgrd)
130            zwgt  = idx%nbw(jb,jgrd)
131            zwgt1 = 1.e0 - idx%nbw(jb,jgrd)
132            a_i (ji,jj,jl) = ( a_i (ji,jj,jl) * zwgt1 + dta%a_i (jb,jl) * zwgt ) * tmask(ji,jj,1)  ! Leads fraction
133            ht_i(ji,jj,jl) = ( ht_i(ji,jj,jl) * zwgt1 + dta%ht_i(jb,jl) * zwgt ) * tmask(ji,jj,1)  ! Ice depth
134            ht_s(ji,jj,jl) = ( ht_s(ji,jj,jl) * zwgt1 + dta%ht_s(jb,jl) * zwgt ) * tmask(ji,jj,1)  ! Snow depth
135
136            ! -----------------
137            ! Pathological case
138            ! -----------------
139            ! In case a) snow load would be in excess or b) ice is coming into a warmer environment that would lead to
140            ! very large transformation from snow to ice (see limthd_dh.F90)
141
142            ! Then, a) transfer the snow excess into the ice (different from limthd_dh)
143            zdh = MAX( 0._wp, ( rhosn * ht_s(ji,jj,jl) + ( rhoic - rau0 ) * ht_i(ji,jj,jl) ) * r1_rau0 )
144            ! Or, b) transfer all the snow into ice (if incoming ice is likely to melt as it comes into a warmer environment)
145            !zdh = MAX( 0._wp, ht_s(ji,jj,jl) * rhosn / rhoic )
146
147            ! recompute ht_i, ht_s
148            ht_i(ji,jj,jl) = MIN( hi_max(jl), ht_i(ji,jj,jl) + zdh )
149            ht_s(ji,jj,jl) = MAX( 0._wp, ht_s(ji,jj,jl) - zdh * rhoic / rhosn ) 
150
151         ENDDO
152         CALL lbc_bdy_lnk(  a_i(:,:,jl), 'T', 1., ib_bdy )
153         CALL lbc_bdy_lnk( ht_i(:,:,jl), 'T', 1., ib_bdy )
154         CALL lbc_bdy_lnk( ht_s(:,:,jl), 'T', 1., ib_bdy )
155      ENDDO
156      ! retrieve at_i
157      at_i(:,:) = 0._wp
158      DO jl = 1, jpl
159         at_i(:,:) = a_i(:,:,jl) + at_i(:,:)
160      END DO
161
162      DO jl = 1, jpl
163         DO jb = 1, idx%nblen(jgrd)
164            ji    = idx%nbi(jb,jgrd)
165            jj    = idx%nbj(jb,jgrd)
166
167            ! condition on ice thickness depends on the ice velocity
168            ! if velocity is outward (strictly), then ice thickness, volume... must be equal to adjacent values
169            jpbound = 0; ii = ji; ij = jj;
170
171            IF ( u_ice(ji+1,jj  ) < 0. .AND. umask(ji-1,jj  ,1) == 0. ) jpbound = 1; ii = ji+1; ij = jj
172            IF ( u_ice(ji-1,jj  ) > 0. .AND. umask(ji+1,jj  ,1) == 0. ) jpbound = 1; ii = ji-1; ij = jj
173            IF ( v_ice(ji  ,jj+1) < 0. .AND. vmask(ji  ,jj-1,1) == 0. ) jpbound = 1; ii = ji  ; ij = jj+1
174            IF ( v_ice(ji  ,jj-1) > 0. .AND. vmask(ji  ,jj+1,1) == 0. ) jpbound = 1; ii = ji  ; ij = jj-1
175
176            rswitch = 1.0 - MAX( 0.0_wp , SIGN ( 1.0_wp , - at_i(ii,ij) + 0.01 ) ) ! 0 if no ice
177
178            ! concentration and thickness
179            a_i (ji,jj,jl) = a_i (ii,ij,jl) * rswitch
180            ht_i(ji,jj,jl) = ht_i(ii,ij,jl) * rswitch
181            ht_s(ji,jj,jl) = ht_s(ii,ij,jl) * rswitch
182
183            ! Ice and snow volumes
184            v_i(ji,jj,jl) = ht_i(ji,jj,jl) * a_i(ji,jj,jl)
185            v_s(ji,jj,jl) = ht_s(ji,jj,jl) * a_i(ji,jj,jl)
186
187            SELECT CASE( jpbound )
188
189            CASE( 0 ) ! velocity is inward
190
191               ! Ice salinity, age, temperature
192               sm_i(ji,jj,jl)   = rswitch * rn_ice_sal(ib_bdy)  + ( 1.0 - rswitch ) * s_i_min
193               o_i(ji,jj,jl)    = rswitch * rn_ice_age(ib_bdy)  + ( 1.0 - rswitch )
194               t_su(ji,jj,jl)   = rswitch * rn_ice_tem(ib_bdy)  + ( 1.0 - rswitch ) * rn_ice_tem(ib_bdy)
195               DO jk = 1, nlay_s
196                  t_s(ji,jj,jk,jl) = rswitch * rn_ice_tem(ib_bdy) + ( 1.0 - rswitch ) * rt0
197               END DO
198               DO jk = 1, nlay_i
199                  t_i(ji,jj,jk,jl) = rswitch * rn_ice_tem(ib_bdy) + ( 1.0 - rswitch ) * rt0 
200                  s_i(ji,jj,jk,jl) = rswitch * rn_ice_sal(ib_bdy) + ( 1.0 - rswitch ) * s_i_min
201               END DO
202               
203            CASE( 1 ) ! velocity is outward
204 
205               ! Ice salinity, age, temperature
206               sm_i(ji,jj,jl)   = rswitch * sm_i(ii,ij,jl)  + ( 1.0 - rswitch ) * s_i_min
207               o_i(ji,jj,jl)    = rswitch * o_i(ii,ij,jl)   + ( 1.0 - rswitch )
208               t_su(ji,jj,jl)   = rswitch * t_su(ii,ij,jl)  + ( 1.0 - rswitch ) * rt0
209               DO jk = 1, nlay_s
210                  t_s(ji,jj,jk,jl) = rswitch * t_s(ii,ij,jk,jl) + ( 1.0 - rswitch ) * rt0
211               END DO
212               DO jk = 1, nlay_i
213                  t_i(ji,jj,jk,jl) = rswitch * t_i(ii,ij,jk,jl) + ( 1.0 - rswitch ) * rt0
214                  s_i(ji,jj,jk,jl) = rswitch * s_i(ii,ij,jk,jl) + ( 1.0 - rswitch ) * s_i_min
215               END DO
216
217            END SELECT
218
219            ! if salinity is constant, then overwrite rn_ice_sal
220            IF( num_sal == 1 ) THEN
221               sm_i(ji,jj,jl)   = bulk_sal
222               s_i (ji,jj,:,jl) = bulk_sal
223            ENDIF
224
225            ! contents
226            smv_i(ji,jj,jl)  = MIN( sm_i(ji,jj,jl) , sss_m(ji,jj) ) * v_i(ji,jj,jl)
227            oa_i(ji,jj,jl)   = o_i(ji,jj,jl) * a_i(ji,jj,jl)
228            DO jk = 1, nlay_s
229               ! Snow energy of melting
230               e_s(ji,jj,jk,jl) = rswitch * rhosn * ( cpic * ( rt0 - t_s(ji,jj,jk,jl) ) + lfus )
231               ! Multiply by volume, so that heat content in J/m2
232               e_s(ji,jj,jk,jl) = e_s(ji,jj,jk,jl) * v_s(ji,jj,jl) / nlay_s
233            END DO
234            DO jk = 1, nlay_i
235               ztmelts          = - tmut * s_i(ji,jj,jk,jl) + rt0 !Melting temperature in K                 
236               ! heat content per unit volume
237               e_i(ji,jj,jk,jl) = rswitch * rhoic * &
238                  (   cpic    * ( ztmelts - t_i(ji,jj,jk,jl) ) &
239                  +   lfus    * ( 1.0 - (ztmelts-rt0) / MIN((t_i(ji,jj,jk,jl)-rt0),-epsi20) ) &
240                  - rcp      * ( ztmelts - rt0 ) )
241               ! Mutliply by ice volume, and divide by number of layers to get heat content in J/m2
242               e_i(ji,jj,jk,jl) = e_i(ji,jj,jk,jl) * a_i(ji,jj,jl) * ht_i(ji,jj,jl) / nlay_i
243            END DO
244
245         END DO
246 
247         CALL lbc_bdy_lnk(  a_i(:,:,jl), 'T', 1., ib_bdy )
248         CALL lbc_bdy_lnk( ht_i(:,:,jl), 'T', 1., ib_bdy )
249         CALL lbc_bdy_lnk( ht_s(:,:,jl), 'T', 1., ib_bdy )
250         CALL lbc_bdy_lnk(  v_i(:,:,jl), 'T', 1., ib_bdy )
251         CALL lbc_bdy_lnk(  v_s(:,:,jl), 'T', 1., ib_bdy )
252 
253         CALL lbc_bdy_lnk( smv_i(:,:,jl), 'T', 1., ib_bdy )
254         CALL lbc_bdy_lnk(  sm_i(:,:,jl), 'T', 1., ib_bdy )
255         CALL lbc_bdy_lnk(  oa_i(:,:,jl), 'T', 1., ib_bdy )
256         CALL lbc_bdy_lnk(   o_i(:,:,jl), 'T', 1., ib_bdy )
257         CALL lbc_bdy_lnk(  t_su(:,:,jl), 'T', 1., ib_bdy )
258         DO jk = 1, nlay_s
259            CALL lbc_bdy_lnk(t_s(:,:,jk,jl), 'T', 1., ib_bdy )
260            CALL lbc_bdy_lnk(e_s(:,:,jk,jl), 'T', 1., ib_bdy )
261         END DO
262         DO jk = 1, nlay_i
263            CALL lbc_bdy_lnk(t_i(:,:,jk,jl), 'T', 1., ib_bdy )
264            CALL lbc_bdy_lnk(e_i(:,:,jk,jl), 'T', 1., ib_bdy )
265         END DO
266
267      END DO !jl
268   
269#endif
270      !     
271      IF( nn_timing == 1 ) CALL timing_stop('bdy_ice_frs')
272      !
273   END SUBROUTINE bdy_ice_frs
274
275
276   SUBROUTINE bdy_ice_lim_dyn( cd_type )
277      !!------------------------------------------------------------------------------
278      !!                 ***  SUBROUTINE bdy_ice_lim_dyn  ***
279      !!                   
280      !! ** Purpose : Apply dynamics boundary conditions for sea-ice in the cas of unstructured open boundaries.
281      !!              u_ice and v_ice are equal to the value of the adjacent grid point if this latter is not ice free
282      !!              if adjacent grid point is ice free, then u_ice and v_ice are equal to ocean velocities
283      !!
284      !! 2013-06 : C. Rousset
285      !!------------------------------------------------------------------------------
286      !!
287      CHARACTER(len=1), INTENT(in)  ::   cd_type   ! nature of velocity grid-points
288      INTEGER  ::   jb, jgrd   ! dummy loop indices
289      INTEGER  ::   ji, jj             ! local scalar
290      INTEGER  ::   ib_bdy ! Loop index
291      REAL(wp) ::   zmsk1, zmsk2, zflag
292     !!------------------------------------------------------------------------------
293      !
294      IF( nn_timing == 1 ) CALL timing_start('bdy_ice_lim_dyn')
295      !
296      DO ib_bdy=1, nb_bdy
297         !
298         SELECT CASE( cn_ice_lim(ib_bdy) )
299
300         CASE('none')
301
302            CYCLE
303           
304         CASE('frs')
305           
306
307            SELECT CASE ( cd_type )
308
309            CASE ( 'U' )
310               
311               jgrd = 2      ! u velocity
312               DO jb = 1, idx_bdy(ib_bdy)%nblen(jgrd)
313                  ji    = idx_bdy(ib_bdy)%nbi(jb,jgrd)
314                  jj    = idx_bdy(ib_bdy)%nbj(jb,jgrd)
315                  zflag = idx_bdy(ib_bdy)%flagu(jb,jgrd)
316                 
317                  IF ( ABS( zflag ) == 1. ) THEN  ! eastern and western boundaries
318                     ! one of the two zmsk is always 0 (because of zflag)
319                     zmsk1 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji+1,jj) ) ) ! 0 if no ice
320                     zmsk2 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji-1,jj) ) ) ! 0 if no ice
321                     
322                     ! u_ice = u_ice of the adjacent grid point except if this grid point is ice-free (then u_ice = u_oce)
323                     u_ice (ji,jj) = u_ice(ji+1,jj) * 0.5 * ABS( zflag + 1._wp ) * zmsk1 + &
324                        &            u_ice(ji-1,jj) * 0.5 * ABS( zflag - 1._wp ) * zmsk2 + &
325                        &            u_oce(ji  ,jj) * ( 1._wp - MIN( 1._wp, zmsk1 + zmsk2 ) )
326                  ELSE                             ! everywhere else
327                     !u_ice(ji,jj) = u_oce(ji,jj)
328                     u_ice(ji,jj) = 0._wp
329                  ENDIF
330                  ! mask ice velocities
331                  rswitch = 1.0 - MAX( 0.0_wp , SIGN ( 1.0_wp , - at_i(ji,jj) + 0.01 ) ) ! 0 if no ice
332                  u_ice(ji,jj) = rswitch * u_ice(ji,jj)
333                 
334               ENDDO
335
336               CALL lbc_bdy_lnk( u_ice(:,:), 'U', -1., ib_bdy )
337               
338            CASE ( 'V' )
339               
340               jgrd = 3      ! v velocity
341               DO jb = 1, idx_bdy(ib_bdy)%nblen(jgrd)
342                  ji    = idx_bdy(ib_bdy)%nbi(jb,jgrd)
343                  jj    = idx_bdy(ib_bdy)%nbj(jb,jgrd)
344                  zflag = idx_bdy(ib_bdy)%flagv(jb,jgrd)
345                 
346                  IF ( ABS( zflag ) == 1. ) THEN  ! northern and southern boundaries
347                     ! one of the two zmsk is always 0 (because of zflag)
348                     zmsk1 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji,jj+1) ) ) ! 0 if no ice
349                     zmsk2 = 1._wp - MAX( 0.0_wp, SIGN ( 1.0_wp , - vt_i(ji,jj-1) ) ) ! 0 if no ice
350                     
351                     ! u_ice = u_ice of the adjacent grid point except if this grid point is ice-free (then u_ice = u_oce)
352                     v_ice (ji,jj) = v_ice(ji,jj+1) * 0.5 * ABS( zflag + 1._wp ) * zmsk1 + &
353                        &            v_ice(ji,jj-1) * 0.5 * ABS( zflag - 1._wp ) * zmsk2 + &
354                        &            v_oce(ji,jj  ) * ( 1._wp - MIN( 1._wp, zmsk1 + zmsk2 ) )
355                  ELSE                             ! everywhere else
356                     !v_ice(ji,jj) = v_oce(ji,jj)
357                     v_ice(ji,jj) = 0._wp
358                  ENDIF
359                  ! mask ice velocities
360                  rswitch = 1.0 - MAX( 0.0_wp , SIGN ( 1.0_wp , - at_i(ji,jj) + 0.01 ) ) ! 0 if no ice
361                  v_ice(ji,jj) = rswitch * v_ice(ji,jj)
362                 
363               ENDDO
364               
365               CALL lbc_bdy_lnk( v_ice(:,:), 'V', -1., ib_bdy )
366               
367            END SELECT
368           
369         CASE DEFAULT
370            CALL ctl_stop( 'bdy_ice_lim_dyn : unrecognised option for open boundaries for ice fields' )
371         END SELECT
372         
373      ENDDO
374
375      IF( nn_timing == 1 ) CALL timing_stop('bdy_ice_lim_dyn')
376     
377    END SUBROUTINE bdy_ice_lim_dyn
378
379#else
380   !!---------------------------------------------------------------------------------
381   !!   Default option                                                    Empty module
382   !!---------------------------------------------------------------------------------
383CONTAINS
384   SUBROUTINE bdy_ice_lim( kt )      ! Empty routine
385      WRITE(*,*) 'bdy_ice_lim: You should not have seen this print! error?', kt
386   END SUBROUTINE bdy_ice_lim
387#endif
388
389   !!=================================================================================
390END MODULE bdyice_lim
Note: See TracBrowser for help on using the repository browser.