New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcice_lim.F90 in branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/OPA_SRC/SBC – NEMO

source: branches/2015/dev_r5044_CNRS_LIM3CLEAN/NEMOGCM/NEMO/OPA_SRC/SBC/sbcice_lim.F90 @ 5055

Last change on this file since 5055 was 5055, checked in by clem, 9 years ago

LIM3: removing par_ice and put jpl, nlay_i and nlay_s as namelist parameters

  • Property svn:keywords set to Id
File size: 31.2 KB
Line 
1MODULE sbcice_lim
2   !!======================================================================
3   !!                       ***  MODULE  sbcice_lim  ***
4   !! Surface module :  update the ocean surface boundary condition over ice
5   !!       &           covered area using LIM sea-ice model
6   !! Sea-Ice model  :  LIM-3 Sea ice model time-stepping
7   !!=====================================================================
8   !! History :  2.0  ! 2006-12  (M. Vancoppenolle) Original code
9   !!            3.0  ! 2008-02  (C. Talandier)  Surface module from icestp.F90
10   !!             -   ! 2008-04  (G. Madec)  sltyle and lim_ctl routine
11   !!            3.3  ! 2010-11  (G. Madec) ice-ocean stress always computed at each ocean time-step
12   !!            3.4  ! 2011-01  (A Porter)  dynamical allocation
13   !!             -   ! 2012-10  (C. Rousset)  add lim_diahsb
14   !!            3.6  ! 2014-07  (M. Vancoppenolle, G. Madec, O. Marti) revise coupled interface
15   !!----------------------------------------------------------------------
16#if defined key_lim3
17   !!----------------------------------------------------------------------
18   !!   'key_lim3' :                                  LIM 3.0 sea-ice model
19   !!----------------------------------------------------------------------
20   !!   sbc_ice_lim  : sea-ice model time-stepping and update ocean sbc over ice-covered area
21   !!----------------------------------------------------------------------
22   USE oce             ! ocean dynamics and tracers
23   USE dom_oce         ! ocean space and time domain
24   USE ice             ! LIM-3: ice variables
25   USE thd_ice         ! LIM-3: thermodynamical variables
26   USE dom_ice         ! LIM-3: ice domain
27
28   USE sbc_oce         ! Surface boundary condition: ocean fields
29   USE sbc_ice         ! Surface boundary condition: ice   fields
30   USE sbcblk_core     ! Surface boundary condition: CORE bulk
31   USE sbcblk_clio     ! Surface boundary condition: CLIO bulk
32   USE sbccpl          ! Surface boundary condition: coupled interface
33   USE albedo          ! ocean & ice albedo
34
35   USE phycst          ! Define parameters for the routines
36   USE eosbn2          ! equation of state
37   USE limdyn          ! Ice dynamics
38   USE limtrp          ! Ice transport
39   USE limthd          ! Ice thermodynamics
40   USE limitd_me       ! Mechanics on ice thickness distribution
41   USE limsbc          ! sea surface boundary condition
42   USE limdiahsb       ! Ice budget diagnostics
43   USE limwri          ! Ice outputs
44   USE limrst          ! Ice restarts
45   USE limupdate1      ! update of global variables
46   USE limupdate2      ! update of global variables
47   USE limvar          ! Ice variables switch
48
49   USE limmsh          ! LIM mesh
50   USE limistate       ! LIM initial state
51   USE limthd_sal      ! LIM ice thermodynamics: salinity
52
53   USE c1d             ! 1D vertical configuration
54   USE lbclnk          ! lateral boundary condition - MPP link
55   USE lib_mpp         ! MPP library
56   USE wrk_nemo        ! work arrays
57   USE timing          ! Timing
58   USE iom             ! I/O manager library
59   USE in_out_manager  ! I/O manager
60   USE prtctl          ! Print control
61   USE lib_fortran     !
62   USE limctl
63
64#if defined key_bdy 
65   USE bdyice_lim       ! unstructured open boundary data  (bdy_ice_lim routine)
66#endif
67
68   IMPLICIT NONE
69   PRIVATE
70
71   PUBLIC sbc_ice_lim  ! routine called by sbcmod.F90
72   PUBLIC sbc_lim_init ! routine called by sbcmod.F90
73   
74   !! * Substitutions
75#  include "domzgr_substitute.h90"
76#  include "vectopt_loop_substitute.h90"
77   !!----------------------------------------------------------------------
78   !! NEMO/OPA 4.0 , UCL NEMO Consortium (2011)
79   !! $Id$
80   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
81   !!----------------------------------------------------------------------
82CONTAINS
83
84   !!======================================================================
85
86   SUBROUTINE sbc_ice_lim( kt, kblk )
87      !!---------------------------------------------------------------------
88      !!                  ***  ROUTINE sbc_ice_lim  ***
89      !!                   
90      !! ** Purpose :   update the ocean surface boundary condition via the
91      !!                Louvain la Neuve Sea Ice Model time stepping
92      !!
93      !! ** Method  :   ice model time stepping
94      !!              - call the ice dynamics routine
95      !!              - call the ice advection/diffusion routine
96      !!              - call the ice thermodynamics routine
97      !!              - call the routine that computes mass and
98      !!                heat fluxes at the ice/ocean interface
99      !!              - save the outputs
100      !!              - save the outputs for restart when necessary
101      !!
102      !! ** Action  : - time evolution of the LIM sea-ice model
103      !!              - update all sbc variables below sea-ice:
104      !!                utau, vtau, taum, wndm, qns , qsr, emp , sfx
105      !!---------------------------------------------------------------------
106      INTEGER, INTENT(in) ::   kt      ! ocean time step
107      INTEGER, INTENT(in) ::   kblk    ! type of bulk (=3 CLIO, =4 CORE, =5 COUPLED)
108      !!
109      INTEGER  ::   jl                 ! dummy loop index
110      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_os, zalb_cs  ! ice albedo under overcast/clear sky
111      REAL(wp), POINTER, DIMENSION(:,:,:)   ::   zalb_ice          ! mean ice albedo (for coupled)
112      !!----------------------------------------------------------------------
113
114      IF( nn_timing == 1 )  CALL timing_start('sbc_ice_lim')
115
116      IF( MOD( kt-1, nn_fsbc ) == 0 ) THEN     !  Ice time-step only
117         !-----------------------!                                           
118         ! --- Bulk Formulae --- !                                           
119         !-----------------------!
120         u_oce(:,:) = ssu_m(:,:) * umask(:,:,1)      ! mean surface ocean current at ice velocity point
121         v_oce(:,:) = ssv_m(:,:) * vmask(:,:,1)      ! (C-grid dynamics :  U- & V-points as the ocean)
122         
123         ! masked sea surface freezing temperature [Kelvin] (set to rt0 over land)
124         t_bo(:,:) = ( eos_fzp( sss_m ) + rt0 ) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) ) 
125         !                                                                                     
126         ! Ice albedo
127         CALL wrk_alloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
128         CALL albedo_ice( t_su, ht_i, ht_s, zalb_cs, zalb_os )  ! cloud-sky and overcast-sky ice albedos
129
130         ! CORE and COUPLED bulk formulations
131         SELECT CASE( kblk )
132         CASE( jp_core , jp_cpl )
133
134            ! albedo depends on cloud fraction because of non-linear spectral effects
135            zalb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:)
136            ! In CLIO the cloud fraction is read in the climatology and the all-sky albedo
137            ! (zalb_ice) is computed within the bulk routine
138           
139         END SELECT
140         
141         ! Mask sea ice surface temperature (set to rt0 over land)
142         DO jl = 1, jpl
143            t_su(:,:,jl) = t_su(:,:,jl) * tmask(:,:,1) + rt0 * ( 1._wp - tmask(:,:,1) )
144         END DO
145     
146         ! Bulk formulae  - provides the following fields:
147         ! utau_ice, vtau_ice : surface ice stress                     (U- & V-points)   [N/m2]
148         ! qsr_ice , qns_ice  : solar & non solar heat flux over ice   (T-point)         [W/m2]
149         ! qla_ice            : latent heat flux over ice              (T-point)         [W/m2]
150         ! dqns_ice, dqla_ice : non solar & latent heat sensistivity   (T-point)         [W/m2]
151         ! tprecip , sprecip  : total & solid precipitation            (T-point)         [Kg/m2/s]
152         ! fr1_i0  , fr2_i0   : 1sr & 2nd fraction of qsr penetration in ice             [%]
153         !
154         SELECT CASE( kblk )
155         CASE( jp_clio )                                       ! CLIO bulk formulation
156            CALL blk_ice_clio( t_su , zalb_cs    , zalb_os    , zalb_ice  ,               &
157               &                      utau_ice   , vtau_ice   , qns_ice   , qsr_ice   ,   &
158               &                      qla_ice    , dqns_ice   , dqla_ice  ,               &
159               &                      tprecip    , sprecip    ,                           &
160               &                      fr1_i0     , fr2_i0     , cp_ice_msh, jpl  )
161            !         
162            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
163               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
164
165         CASE( jp_core )                                       ! CORE bulk formulation
166            CALL blk_ice_core( t_su , u_ice     , v_ice     , zalb_ice   ,               &
167               &                      utau_ice  , vtau_ice  , qns_ice    , qsr_ice   ,   &
168               &                      qla_ice   , dqns_ice  , dqla_ice   ,               &
169               &                      tprecip   , sprecip   ,                            &
170               &                      fr1_i0    , fr2_i0    , cp_ice_msh, jpl  )
171               !
172            IF( nn_limflx /= 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
173               &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
174            !
175         CASE ( jp_cpl )
176           
177            CALL sbc_cpl_ice_tau( utau_ice , vtau_ice )
178
179         END SELECT
180         
181         !------------------------------!
182         ! --- LIM-3 main time-step --- !
183         !------------------------------!
184         numit = numit + nn_fsbc                     ! Ice model time step
185         !
186         !                                           ! Store previous ice values
187         a_i_b  (:,:,:)   = a_i  (:,:,:)     ! ice area
188         e_i_b  (:,:,:,:) = e_i  (:,:,:,:)   ! ice thermal energy
189         v_i_b  (:,:,:)   = v_i  (:,:,:)     ! ice volume
190         v_s_b  (:,:,:)   = v_s  (:,:,:)     ! snow volume
191         e_s_b  (:,:,:,:) = e_s  (:,:,:,:)   ! snow thermal energy
192         smv_i_b(:,:,:)   = smv_i(:,:,:)     ! salt content
193         oa_i_b (:,:,:)   = oa_i (:,:,:)     ! areal age content
194         u_ice_b(:,:)     = u_ice(:,:)
195         v_ice_b(:,:)     = v_ice(:,:)
196
197                          CALL sbc_lim_diag0         ! set diag of mass, heat and salt fluxes to 0
198
199                          CALL lim_rst_opn( kt )     ! Open Ice restart file
200         !
201         ! ----------------------------------------------
202         ! ice dynamics and transport (except in 1D case)
203         ! ----------------------------------------------
204         IF( .NOT. lk_c1d ) THEN
205
206                          CALL lim_dyn( kt )              ! Ice dynamics    ( rheology/dynamics )
207
208                          CALL lim_trp( kt )              ! Ice transport   ( Advection/diffusion )
209
210         IF( nn_monocat /= 2 )   &
211            &             CALL lim_itd_me                 ! Mechanical redistribution ! (ridging/rafting)
212
213#if defined key_bdy
214                          ! bdy ice thermo
215                          CALL lim_var_glo2eqv            ! equivalent variables
216                          CALL bdy_ice_lim( kt )
217                          CALL lim_var_zapsmall
218                          CALL lim_var_agg(1)
219         IF( ln_nicep )   CALL lim_prt( kt, jiindx, jjindx, 1, ' - ice thermo bdy - ' )   ! control print
220#endif
221
222                          CALL lim_update1( kt )
223
224         ENDIF
225
226         !- Change old values for new values
227         u_ice_b(:,:)     = u_ice(:,:)
228         v_ice_b(:,:)     = v_ice(:,:)
229         a_i_b  (:,:,:)   = a_i  (:,:,:)
230         v_s_b  (:,:,:)   = v_s  (:,:,:)
231         v_i_b  (:,:,:)   = v_i  (:,:,:)
232         e_s_b  (:,:,:,:) = e_s  (:,:,:,:)
233         e_i_b  (:,:,:,:) = e_i  (:,:,:,:)
234         oa_i_b (:,:,:)   = oa_i (:,:,:)
235         smv_i_b(:,:,:)   = smv_i(:,:,:)
236 
237         ! ----------------------------------------------
238         ! ice thermodynamics
239         ! ----------------------------------------------
240                          CALL lim_var_glo2eqv            ! equivalent variables
241                          CALL lim_var_agg(1)             ! aggregate ice categories
242
243                          ! previous lead fraction and ice volume for flux calculations
244                          pfrld(:,:)   = 1._wp - at_i(:,:)
245                          phicif(:,:)  = vt_i(:,:)
246
247                          SELECT CASE( kblk )
248                             CASE ( jp_cpl )
249                             CALL sbc_cpl_ice_flx( p_frld=pfrld, palbi=zalb_ice, psst=sst_m, pist=t_su    )
250                             IF( nn_limflx == 2 )   CALL ice_lim_flx( t_su, zalb_ice, qns_ice, qsr_ice ,   &
251                          &                                           dqns_ice, qla_ice, dqla_ice, nn_limflx )
252                             ! Latent heat flux is forced to 0 in coupled: it is included in qns (non-solar heat flux)
253                             qla_ice  (:,:,:) = 0._wp
254                             dqla_ice (:,:,:) = 0._wp
255                          END SELECT
256                          !
257                          CALL lim_thd( kt )              ! Ice thermodynamics
258
259                          CALL lim_update2( kt )          ! Global variables update
260         !
261                          CALL lim_sbc_flx( kt )          ! Update surface ocean mass, heat and salt fluxes
262         !
263         IF(ln_limdiaout) CALL lim_diahsb                 ! Diagnostics and outputs
264
265                          CALL lim_wri( 1 )               ! Ice outputs
266
267         IF( kt == nit000 .AND. ln_rstart )   &
268            &             CALL iom_close( numrir )        ! close input ice restart file
269         !
270         IF( lrst_ice )   CALL lim_rst_write( kt )        ! Ice restart file
271                          CALL lim_var_glo2eqv            ! ???
272         !
273         IF( ln_nicep )   CALL lim_ctl( kt )              ! alerts in case of model crash
274         !
275         CALL wrk_dealloc( jpi,jpj,jpl, zalb_os, zalb_cs, zalb_ice )
276         !
277      ENDIF                                    ! End sea-ice time step only
278
279      !                                        !--------------------------!
280      !                                        !  at all ocean time step  !
281      !                                        !--------------------------!
282      !                                               
283      !                                              ! Update surface ocean stresses (only in ice-dynamic case)
284      !                                                   ! otherwise the atm.-ocean stresses are used everywhere
285      IF( ln_limdyn )     CALL lim_sbc_tau( kt, ub(:,:,1), vb(:,:,1) )  ! using before instantaneous surf. currents
286!!gm   remark, the ocean-ice stress is not saved in ice diag call above .....  find a solution!!!
287      !
288      IF( nn_timing == 1 )  CALL timing_stop('sbc_ice_lim')
289      !
290   END SUBROUTINE sbc_ice_lim
291   
292
293   SUBROUTINE sbc_lim_init
294      !!----------------------------------------------------------------------
295      !!                  ***  ROUTINE sbc_lim_init  ***
296      !!
297      !! ** purpose :   Allocate all the dynamic arrays of the LIM-3 modules
298      !!----------------------------------------------------------------------
299      INTEGER :: ierr
300      !!----------------------------------------------------------------------
301      IF(lwp) WRITE(numout,*)
302      IF(lwp) WRITE(numout,*) 'sbc_ice_lim : update ocean surface boudary condition' 
303      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   via Louvain la Neuve Ice Model (LIM-3) time stepping'
304      !
305                                       ! Open the reference and configuration namelist files and namelist output file
306      CALL ctl_opn( numnam_ice_ref, 'namelist_ice_ref',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp ) 
307      CALL ctl_opn( numnam_ice_cfg, 'namelist_ice_cfg',    'OLD',     'FORMATTED', 'SEQUENTIAL', -1, numout, lwp )
308      IF(lwm) CALL ctl_opn( numoni, 'output.namelist.ice', 'UNKNOWN', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, 1 )
309
310      CALL ice_run                     ! set some ice run parameters including jpl, nlay_i and nlay_s
311      !                                ! Allocate the ice arrays
312      ierr =        ice_alloc        ()      ! ice variables
313      ierr = ierr + dom_ice_alloc    ()      ! domain
314      ierr = ierr + sbc_ice_alloc    ()      ! surface forcing
315      ierr = ierr + thd_ice_alloc    ()      ! thermodynamics
316      ierr = ierr + lim_itd_me_alloc ()      ! ice thickness distribution - mechanics
317      !
318      IF( lk_mpp    )   CALL mpp_sum( ierr )
319      IF( ierr /= 0 )   CALL ctl_stop('STOP', 'sbc_lim_init : unable to allocate ice arrays')
320      !
321      !                                ! adequation jpk versus ice/snow layers/categories
322      IF( jpl > jpk .OR. (nlay_i+1) > jpk .OR. nlay_s > jpk )   &
323         &      CALL ctl_stop( 'STOP',                          &
324         &     'sbc_lim_init: the 3rd dimension of workspace arrays is too small.',   &
325         &     'use more ocean levels or less ice/snow layers/categories.' )
326      !
327      !
328      CALL lim_thd_init                ! set ice thermodynics parameters
329      !
330      CALL lim_thd_sal_init            ! set ice salinity parameters
331      !
332      CALL lim_msh                     ! ice mesh initialization
333      !
334      CALL lim_itd_init                ! ice thickness distribution initialization
335      !
336      CALL lim_itd_me_init             ! ice thickness distribution initialization for mecanical deformation
337      !                                ! Initial sea-ice state
338      IF( .NOT. ln_rstart ) THEN              ! start from rest: sea-ice deduced from sst
339         numit = 0
340         numit = nit000 - 1
341         CALL lim_istate
342      ELSE                                    ! start from a restart file
343         CALL lim_rst_read
344         numit = nit000 - 1
345      ENDIF
346      CALL lim_var_agg(1)
347      CALL lim_var_glo2eqv
348      !
349      CALL lim_sbc_init                 ! ice surface boundary condition   
350      !
351      fr_i(:,:)     = at_i(:,:)         ! initialisation of sea-ice fraction
352      tn_ice(:,:,:) = t_su(:,:,:)       ! initialisation of surface temp for coupled simu
353      !
354      nstart = numit  + nn_fsbc     
355      nitrun = nitend - nit000 + 1 
356      nlast  = numit  + nitrun 
357      !
358      IF( nstock == 0 )   nstock = nlast + 1
359      !
360   END SUBROUTINE sbc_lim_init
361
362
363   SUBROUTINE ice_run
364      !!-------------------------------------------------------------------
365      !!                  ***  ROUTINE ice_run ***
366      !!                 
367      !! ** Purpose :   Definition some run parameter for ice model
368      !!
369      !! ** Method  :   Read the namicerun namelist and check the parameter
370      !!              values called at the first timestep (nit000)
371      !!
372      !! ** input   :   Namelist namicerun
373      !!-------------------------------------------------------------------
374      INTEGER  ::   ios                 ! Local integer output status for namelist read
375      NAMELIST/namicerun/ jpl, nlay_i, nlay_s, cn_icerst_in, cn_icerst_out,   &
376         &                ln_limdyn, amax, ln_nicep, ln_limdiahsb, ln_limdiaout
377      !!-------------------------------------------------------------------
378      !                   
379      REWIND( numnam_ice_ref )              ! Namelist namicerun in reference namelist : Parameters for ice
380      READ  ( numnam_ice_ref, namicerun, IOSTAT = ios, ERR = 901)
381901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in reference namelist', lwp )
382
383      REWIND( numnam_ice_cfg )              ! Namelist namicerun in configuration namelist : Parameters for ice
384      READ  ( numnam_ice_cfg, namicerun, IOSTAT = ios, ERR = 902 )
385902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namicerun in configuration namelist', lwp )
386      IF(lwm) WRITE ( numoni, namicerun )
387      !
388      !
389      IF(lwp) THEN                        ! control print
390         WRITE(numout,*)
391         WRITE(numout,*) 'ice_run : ice share parameters for dynamics/advection/thermo of sea-ice'
392         WRITE(numout,*) ' ~~~~~~'
393         WRITE(numout,*) '   number of ice  categories                               = ', jpl
394         WRITE(numout,*) '   number of ice  layers                                   = ', nlay_i
395         WRITE(numout,*) '   number of snow layers                                   = ', nlay_s
396         WRITE(numout,*) '   switch for ice dynamics (1) or not (0)      ln_limdyn   = ', ln_limdyn
397         WRITE(numout,*) '   maximum ice concentration                               = ', amax
398         WRITE(numout,*) '   Several ice points in the ice or not in ocean.output    = ', ln_nicep
399         WRITE(numout,*) '   Diagnose heat/salt budget or not          ln_limdiahsb  = ', ln_limdiahsb
400         WRITE(numout,*) '   Output   heat/salt budget or not          ln_limdiaout  = ', ln_limdiaout
401      ENDIF
402      !
403      !IF( lk_mpp .AND. ln_nicep ) THEN
404      !   ln_nicep = .FALSE.
405      !   CALL ctl_warn( 'ice_run : specific control print for LIM3 desactivated with MPI' )
406      !ENDIF
407      IF( ln_nicep ) THEN      ! control print at a given point
408         jiindx = 15    ;   jjindx =  44
409         IF(lwp) WRITE(numout,*) ' The debugging point is : jiindx : ',jiindx, ' jjindx : ',jjindx
410      ENDIF
411      !
412      ! sea-ice timestep and inverse
413      rdt_ice   = nn_fsbc * rdttra(1) 
414      r1_rdtice = 1._wp / rdt_ice 
415      !
416   END SUBROUTINE ice_run
417
418
419   SUBROUTINE lim_itd_init
420      !!------------------------------------------------------------------
421      !!                ***  ROUTINE lim_itd_init ***
422      !!
423      !! ** Purpose :   Initializes the ice thickness distribution
424      !! ** Method  :   ...
425      !!    Note    : hi_max(jpl) is here set up to a value close to 7 m for
426      !!              limistate (only) and is changed to 99 m in sbc_lim_init
427      !!------------------------------------------------------------------
428      INTEGER  ::   jl                   ! dummy loop index
429      REAL(wp) ::   zc1, zc2, zc3, zx1   ! local scalars
430      REAL(wp) ::   zhmax, znum, zden, zalpha !
431      !!------------------------------------------------------------------
432
433      IF(lwp) WRITE(numout,*)
434      IF(lwp) WRITE(numout,*) 'lim_itd_init : Initialization of ice thickness distribution '
435      IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~'
436
437      !------------------------------------------------------------------------------!
438      ! 1) Ice thickness distribution parameters initialization   
439      !------------------------------------------------------------------------------!
440      IF(lwp) WRITE(numout,*) ' Number of ice categories jpl = ', jpl
441
442      !- Thickness categories boundaries
443      !----------------------------------
444      !  Clem - je sais pas encore dans quelle namelist les mettre, ca depend des chgts liés à bdy
445      nn_hibnd  = 2                !  thickness category boundaries: tanh function (1) h^(-alpha) (2)
446      rn_hibnd  = 2.5              !  mean thickness of the domain (used to compute category boundaries, nn_hibnd = 2 only)
447
448      hi_max(:) = 0._wp
449
450      SELECT CASE ( nn_hibnd  )       
451                                   !----------------------
452         CASE (1)                  ! tanh function (CICE)
453                                   !----------------------
454         zc1 =  3._wp / REAL( jpl, wp )
455         zc2 = 10._wp * zc1
456         zc3 =  3._wp
457
458         DO jl = 1, jpl
459            zx1 = REAL( jl-1, wp ) / REAL( jpl, wp )
460            hi_max(jl) = hi_max(jl-1) + zc1 + zc2 * (1._wp + TANH( zc3 * (zx1 - 1._wp ) ) )
461         END DO
462
463                                   !----------------------
464         CASE (2)                  ! h^(-alpha) function
465                                   !----------------------
466         zalpha = 0.05             ! exponent of the transform function
467
468         zhmax  = 3.*rn_hibnd
469
470         DO jl = 1, jpl 
471            znum = jpl * ( zhmax+1 )**zalpha
472            zden = ( jpl - jl ) * ( zhmax+1 )**zalpha + jl
473            hi_max(jl) = ( znum / zden )**(1./zalpha) - 1
474         END DO
475
476      END SELECT
477
478      DO jl = 1, jpl
479         hi_mean(jl) = ( hi_max(jl) + hi_max(jl-1) ) * 0.5_wp
480      END DO
481      ! Set hi_max(jpl) to a big value to ensure that all ice is thinner than hi_max(jpl)
482      hi_max(jpl) = 99._wp
483
484      IF(lwp) WRITE(numout,*) ' Thickness category boundaries '
485      IF(lwp) WRITE(numout,*) ' hi_max ', hi_max(0:jpl)
486      !
487   END SUBROUTINE lim_itd_init
488
489   
490   SUBROUTINE ice_lim_flx( ptn_ice, palb_ice, pqns_ice, pqsr_ice,   &
491         &                          pdqn_ice, pqla_ice, pdql_ice, k_limflx )
492      !!---------------------------------------------------------------------
493      !!                  ***  ROUTINE sbc_ice_lim  ***
494      !!                   
495      !! ** Purpose :   update the ice surface boundary condition by averaging and / or
496      !!                redistributing fluxes on ice categories                   
497      !!
498      !! ** Method  :   average then redistribute
499      !!
500      !! ** Action  :   
501      !!---------------------------------------------------------------------
502      INTEGER                   , INTENT(in   ) ::   k_limflx   ! =-1 do nothing; =0 average ;
503                                                                ! =1 average and redistribute ; =2 redistribute
504      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   ptn_ice    ! ice surface temperature
505      REAL(wp), DIMENSION(:,:,:), INTENT(in   ) ::   palb_ice   ! ice albedo
506      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqns_ice   ! non solar flux
507      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqsr_ice   ! net solar flux
508      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdqn_ice   ! non solar flux sensitivity
509      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pqla_ice   ! latent heat flux
510      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   pdql_ice   ! latent heat flux sensitivity
511      !
512      INTEGER  ::   jl      ! dummy loop index
513      !
514      REAL(wp), POINTER, DIMENSION(:,:) :: zalb_m    ! Mean albedo over all categories
515      REAL(wp), POINTER, DIMENSION(:,:) :: ztem_m    ! Mean temperature over all categories
516      !
517      REAL(wp), POINTER, DIMENSION(:,:) :: z_qsr_m   ! Mean solar heat flux over all categories
518      REAL(wp), POINTER, DIMENSION(:,:) :: z_qns_m   ! Mean non solar heat flux over all categories
519      REAL(wp), POINTER, DIMENSION(:,:) :: z_qla_m   ! Mean latent heat flux over all categories
520      REAL(wp), POINTER, DIMENSION(:,:) :: z_dqn_m   ! Mean d(qns)/dT over all categories
521      REAL(wp), POINTER, DIMENSION(:,:) :: z_dql_m   ! Mean d(qla)/dT over all categories
522      !!----------------------------------------------------------------------
523
524      IF( nn_timing == 1 )  CALL timing_start('ice_lim_flx')
525      !
526      !
527      SELECT CASE( k_limflx )                              !==  averaged on all ice categories  ==!
528      CASE( 0 , 1 )
529         CALL wrk_alloc( jpi,jpj, z_qsr_m, z_qns_m, z_qla_m, z_dqn_m, z_dql_m)
530         !
531         z_qns_m(:,:) = fice_ice_ave ( pqns_ice (:,:,:) )
532         z_qsr_m(:,:) = fice_ice_ave ( pqsr_ice (:,:,:) )
533         z_dqn_m(:,:) = fice_ice_ave ( pdqn_ice (:,:,:) )
534         z_qla_m(:,:) = fice_ice_ave ( pqla_ice (:,:,:) )
535         z_dql_m(:,:) = fice_ice_ave ( pdql_ice (:,:,:) )
536         DO jl = 1, jpl
537            pdqn_ice(:,:,jl) = z_dqn_m(:,:)
538            pdql_ice(:,:,jl) = z_dql_m(:,:)
539         END DO
540         !
541         DO jl = 1, jpl
542            pqns_ice(:,:,jl) = z_qns_m(:,:)
543            pqsr_ice(:,:,jl) = z_qsr_m(:,:)
544            pqla_ice(:,:,jl) = z_qla_m(:,:)
545         END DO
546         !
547         CALL wrk_dealloc( jpi,jpj, z_qsr_m, z_qns_m, z_qla_m, z_dqn_m, z_dql_m)
548      END SELECT
549
550      SELECT CASE( k_limflx )                              !==  redistribution on all ice categories  ==!
551      CASE( 1 , 2 )
552         CALL wrk_alloc( jpi,jpj, zalb_m, ztem_m )
553         !
554         zalb_m(:,:) = fice_ice_ave ( palb_ice (:,:,:) ) 
555         ztem_m(:,:) = fice_ice_ave ( ptn_ice  (:,:,:) ) 
556         DO jl = 1, jpl
557            pqns_ice(:,:,jl) = pqns_ice(:,:,jl) + pdqn_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
558            pqla_ice(:,:,jl) = pqla_ice(:,:,jl) + pdql_ice(:,:,jl) * (ptn_ice(:,:,jl) - ztem_m(:,:))
559            pqsr_ice(:,:,jl) = pqsr_ice(:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) 
560         END DO
561         !
562         CALL wrk_dealloc( jpi,jpj, zalb_m, ztem_m )
563      END SELECT
564      !
565      IF( nn_timing == 1 )  CALL timing_stop('ice_lim_flx')
566      !
567   END SUBROUTINE ice_lim_flx
568
569   SUBROUTINE sbc_lim_diag0
570      !!----------------------------------------------------------------------
571      !!                  ***  ROUTINE sbc_lim_flx0  ***
572      !!
573      !! ** purpose :  set ice-ocean and ice-atm. fluxes to zeros at the beggining
574      !!               of the time step
575      !!----------------------------------------------------------------------
576      sfx    (:,:) = 0._wp   ;
577      sfx_bri(:,:) = 0._wp   ; 
578      sfx_sni(:,:) = 0._wp   ;   sfx_opw(:,:) = 0._wp
579      sfx_bog(:,:) = 0._wp   ;   sfx_dyn(:,:) = 0._wp
580      sfx_bom(:,:) = 0._wp   ;   sfx_sum(:,:) = 0._wp
581      sfx_res(:,:) = 0._wp
582     
583      wfx_snw(:,:) = 0._wp   ;   wfx_ice(:,:) = 0._wp
584      wfx_sni(:,:) = 0._wp   ;   wfx_opw(:,:) = 0._wp
585      wfx_bog(:,:) = 0._wp   ;   wfx_dyn(:,:) = 0._wp
586      wfx_bom(:,:) = 0._wp   ;   wfx_sum(:,:) = 0._wp
587      wfx_res(:,:) = 0._wp   ;   wfx_sub(:,:) = 0._wp
588      wfx_spr(:,:) = 0._wp   ;   
589     
590      hfx_in (:,:) = 0._wp   ;   hfx_out(:,:) = 0._wp
591      hfx_thd(:,:) = 0._wp   ;   
592      hfx_snw(:,:) = 0._wp   ;   hfx_opw(:,:) = 0._wp
593      hfx_bog(:,:) = 0._wp   ;   hfx_dyn(:,:) = 0._wp
594      hfx_bom(:,:) = 0._wp   ;   hfx_sum(:,:) = 0._wp
595      hfx_res(:,:) = 0._wp   ;   hfx_sub(:,:) = 0._wp
596      hfx_spr(:,:) = 0._wp   ;   hfx_dif(:,:) = 0._wp 
597      hfx_err(:,:) = 0._wp   ;   hfx_err_rem(:,:) = 0._wp
598
599      afx_tot(:,:) = 0._wp   ;
600      afx_dyn(:,:) = 0._wp   ;   afx_thd(:,:) = 0._wp
601     
602   END SUBROUTINE sbc_lim_diag0
603     
604   FUNCTION fice_cell_ave ( ptab )
605      !!--------------------------------------------------------------------------
606      !! * Compute average over categories, for grid cell (ice covered and free ocean)
607      !!--------------------------------------------------------------------------
608      REAL (wp), DIMENSION (jpi,jpj) :: fice_cell_ave
609      REAL (wp), DIMENSION (jpi,jpj,jpl), INTENT (in) :: ptab
610      INTEGER :: jl ! Dummy loop index
611     
612      fice_cell_ave (:,:) = 0.0_wp
613     
614      DO jl = 1, jpl
615         fice_cell_ave (:,:) = fice_cell_ave (:,:) + a_i (:,:,jl) * ptab (:,:,jl)
616      END DO
617     
618   END FUNCTION fice_cell_ave
619   
620   
621   FUNCTION fice_ice_ave ( ptab )
622      !!--------------------------------------------------------------------------
623      !! * Compute average over categories, for ice covered part of grid cell
624      !!--------------------------------------------------------------------------
625      REAL (kind=wp), DIMENSION (jpi,jpj) :: fice_ice_ave
626      REAL (kind=wp), DIMENSION (jpi,jpj,jpl), INTENT(in) :: ptab
627
628      fice_ice_ave (:,:) = 0.0_wp
629      WHERE ( at_i (:,:) .GT. 0.0_wp ) fice_ice_ave (:,:) = fice_cell_ave ( ptab (:,:,:)) / at_i (:,:)
630
631   END FUNCTION fice_ice_ave
632
633
634#else
635   !!----------------------------------------------------------------------
636   !!   Default option           Dummy module      NO LIM 3.0 sea-ice model
637   !!----------------------------------------------------------------------
638CONTAINS
639   SUBROUTINE sbc_ice_lim ( kt, kblk )     ! Dummy routine
640      WRITE(*,*) 'sbc_ice_lim: You should not have seen this print! error?', kt, kblk
641   END SUBROUTINE sbc_ice_lim
642#endif
643
644   !!======================================================================
645END MODULE sbcice_lim
Note: See TracBrowser for help on using the repository browser.