New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaar5.F90 in branches/2015/dev_r5056_CMCC4_simplification/NEMOGCM/NEMO/OPA_SRC/DIA – NEMO

source: branches/2015/dev_r5056_CMCC4_simplification/NEMOGCM/NEMO/OPA_SRC/DIA/diaar5.F90 @ 5282

Last change on this file since 5282 was 5282, checked in by diovino, 9 years ago

Dev. branch CMCC4_simplification ticket #1456

  • Property svn:keywords set to Id
File size: 12.2 KB
Line 
1MODULE diaar5
2   !!======================================================================
3   !!                       ***  MODULE  diaar5  ***
4   !! AR5 diagnostics
5   !!======================================================================
6   !! History :  3.2  !  2009-11  (S. Masson)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
8   !!----------------------------------------------------------------------
9#if defined key_diaar5   || defined key_esopa
10   !!----------------------------------------------------------------------
11   !!   'key_diaar5'  :                           activate ar5 diagnotics
12   !!----------------------------------------------------------------------
13   !!   dia_ar5       : AR5 diagnostics
14   !!   dia_ar5_init  : initialisation of AR5 diagnostics
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and active tracers
17   USE dom_oce        ! ocean space and time domain
18   USE eosbn2         ! equation of state                (eos_bn2 routine)
19   USE lib_mpp        ! distribued memory computing library
20   USE iom            ! I/O manager library
21   USE timing         ! preformance summary
22   USE wrk_nemo       ! working arrays
23   USE fldread        ! type FLD_N
24   USE phycst         ! physical constant
25   USE in_out_manager  ! I/O manager
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   dia_ar5        ! routine called in step.F90 module
31   PUBLIC   dia_ar5_init   ! routine called in opa.F90 module
32   PUBLIC   dia_ar5_alloc  ! routine called in nemogcm.F90 module
33
34   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .TRUE.   ! coupled flag
35
36   REAL(wp)                         ::   vol0         ! ocean volume (interior domain)
37   REAL(wp)                         ::   area_tot     ! total ocean surface (interior domain)
38   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   area         ! cell surface (interior domain)
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:  ) ::   thick0       ! ocean thickness (interior domain)
40   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   sn0          ! initial salinity
41     
42   !! * Substitutions
43#  include "domzgr_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
46   !! $Id$
47   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   FUNCTION dia_ar5_alloc()
52      !!----------------------------------------------------------------------
53      !!                    ***  ROUTINE dia_ar5_alloc  ***
54      !!----------------------------------------------------------------------
55      INTEGER :: dia_ar5_alloc
56      !!----------------------------------------------------------------------
57      !
58      ALLOCATE( area(jpi,jpj), thick0(jpi,jpj) , sn0(jpi,jpj,jpk) , STAT=dia_ar5_alloc )
59      !
60      IF( lk_mpp             )   CALL mpp_sum ( dia_ar5_alloc )
61      IF( dia_ar5_alloc /= 0 )   CALL ctl_warn('dia_ar5_alloc: failed to allocate arrays')
62      !
63   END FUNCTION dia_ar5_alloc
64
65
66   SUBROUTINE dia_ar5( kt )
67      !!----------------------------------------------------------------------
68      !!                    ***  ROUTINE dia_ar5  ***
69      !!
70      !! ** Purpose :   compute and output some AR5 diagnostics
71      !!----------------------------------------------------------------------
72      !
73      INTEGER, INTENT( in ) ::   kt   ! ocean time-step index
74      !
75      INTEGER  ::   ji, jj, jk                      ! dummy loop arguments
76      REAL(wp) ::   zvolssh, zvol, zssh_steric, zztmp, zarho, ztemp, zsal, zmass
77      !
78      REAL(wp), POINTER, DIMENSION(:,:)     :: zarea_ssh , zbotpres       ! 2D workspace
79      REAL(wp), POINTER, DIMENSION(:,:,:)   :: zrhd , zrhop               ! 3D workspace
80      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztsn                       ! 4D workspace
81      !!--------------------------------------------------------------------
82      IF( nn_timing == 1 )   CALL timing_start('dia_ar5')
83 
84      CALL wrk_alloc( jpi , jpj              , zarea_ssh , zbotpres )
85      CALL wrk_alloc( jpi , jpj , jpk        , zrhd      , zrhop    )
86      CALL wrk_alloc( jpi , jpj , jpk , jpts , ztsn                 )
87
88      CALL iom_put( 'cellthc', fse3t(:,:,:) )
89
90      zarea_ssh(:,:) = area(:,:) * sshn(:,:)
91
92      !                                         ! total volume of liquid seawater
93      zvolssh = SUM( zarea_ssh(:,:) ) 
94      IF( lk_mpp )   CALL mpp_sum( zvolssh )
95      zvol = vol0 + zvolssh
96     
97      CALL iom_put( 'voltot', zvol               )
98      CALL iom_put( 'sshtot', zvolssh / area_tot )
99
100      !                     
101      ztsn(:,:,:,jp_tem) = tsn(:,:,:,jp_tem)                    ! thermosteric ssh
102      ztsn(:,:,:,jp_sal) = sn0(:,:,:)
103      CALL eos( ztsn, zrhd, fsdept_n(:,:,:) )                       ! now in situ density using initial salinity
104      !
105      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
106      DO jk = 1, jpkm1
107         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
108      END DO
109      IF( .NOT.lk_vvl ) THEN
110         DO ji=1,jpi
111            DO jj=1,jpj
112               zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
113            END DO
114         END DO
115      END IF
116      !                                         
117      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
118      IF( lk_mpp )   CALL mpp_sum( zarho )
119      zssh_steric = - zarho / area_tot
120      CALL iom_put( 'sshthster', zssh_steric )
121     
122      !                                         ! steric sea surface height
123      CALL eos( tsn, zrhd, zrhop, fsdept_n(:,:,:) )                 ! now in situ and potential density
124      zrhop(:,:,jpk) = 0._wp
125      CALL iom_put( 'rhop', zrhop )
126      !
127      zbotpres(:,:) = 0._wp                        ! no atmospheric surface pressure, levitating sea-ice
128      DO jk = 1, jpkm1
129         zbotpres(:,:) = zbotpres(:,:) + fse3t(:,:,jk) * zrhd(:,:,jk)
130      END DO
131      IF( .NOT.lk_vvl ) THEN
132         DO ji=1,jpi
133            DO jj=1,jpj
134               zbotpres(ji,jj) = zbotpres(ji,jj) + sshn(ji,jj) * zrhd(ji,jj,mikt(ji,jj)) + riceload(ji,jj)
135            END DO
136         END DO
137      END IF
138      !   
139      zarho = SUM( area(:,:) * zbotpres(:,:) ) 
140      IF( lk_mpp )   CALL mpp_sum( zarho )
141      zssh_steric = - zarho / area_tot
142      CALL iom_put( 'sshsteric', zssh_steric )
143     
144      !                                         ! ocean bottom pressure
145      zztmp = rau0 * grav * 1.e-4_wp               ! recover pressure from pressure anomaly and cover to dbar = 1.e4 Pa
146      zbotpres(:,:) = zztmp * ( zbotpres(:,:) + sshn(:,:) + thick0(:,:) )
147      CALL iom_put( 'botpres', zbotpres )
148
149      !                                         ! Mean density anomalie, temperature and salinity
150      ztemp = 0._wp
151      zsal  = 0._wp
152      DO jk = 1, jpkm1
153         DO jj = 1, jpj
154            DO ji = 1, jpi
155               zztmp = area(ji,jj) * fse3t(ji,jj,jk)
156               ztemp = ztemp + zztmp * tsn(ji,jj,jk,jp_tem)
157               zsal  = zsal  + zztmp * tsn(ji,jj,jk,jp_sal)
158            END DO
159         END DO
160      END DO
161      IF( .NOT.lk_vvl ) THEN
162         DO ji=1,jpi
163            DO jj=1,jpj
164               ztemp = ztemp + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_tem) 
165               zsal  = zsal  + zarea_ssh(ji,jj) * tsn(ji,jj,mikt(ji,jj),jp_sal) 
166            END DO
167         END DO
168      ENDIF
169      IF( lk_mpp ) THEN 
170         CALL mpp_sum( ztemp )
171         CALL mpp_sum( zsal  )
172      END IF
173      !
174      zmass = rau0 * ( zarho + zvol )                 ! total mass of liquid seawater
175      ztemp = ztemp / zvol                            ! potential temperature in liquid seawater
176      zsal  = zsal  / zvol                            ! Salinity of liquid seawater
177      !
178      CALL iom_put( 'masstot', zmass )
179      CALL iom_put( 'temptot', ztemp )
180      CALL iom_put( 'saltot' , zsal  )
181      !
182      CALL wrk_dealloc( jpi , jpj              , zarea_ssh , zbotpres )
183      CALL wrk_dealloc( jpi , jpj , jpk        , zrhd      , zrhop    )
184      CALL wrk_dealloc( jpi , jpj , jpk , jpts , ztsn                 )
185      !
186      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5')
187      !
188   END SUBROUTINE dia_ar5
189
190
191   SUBROUTINE dia_ar5_init
192      !!----------------------------------------------------------------------
193      !!                  ***  ROUTINE dia_ar5_init  ***
194      !!                   
195      !! ** Purpose :   initialization for AR5 diagnostic computation
196      !!----------------------------------------------------------------------
197      INTEGER  ::   inum
198      INTEGER  ::   ik
199      INTEGER  ::   ji, jj, jk  ! dummy loop indices
200      REAL(wp) ::   zztmp 
201      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::   zsaldta   ! Jan/Dec levitus salinity
202      ! reading initial file
203      LOGICAL  ::   ln_tsd_init      !: T & S data flag
204      LOGICAL  ::   ln_tsd_tradmp    !: internal damping toward input data flag
205      CHARACTER(len=100)            ::   cn_dir
206      TYPE(FLD_N)                   ::  sn_tem,sn_sal
207      INTEGER  ::   ios=0
208
209      NAMELIST/namtsd/ ln_tsd_init,ln_tsd_tradmp,cn_dir,sn_tem,sn_sal
210      !
211
212      REWIND( numnam_ref )              ! Namelist namtsd in reference namelist :
213      READ  ( numnam_ref, namtsd, IOSTAT = ios, ERR = 901)
214901   IF( ios /= 0 ) CALL ctl_nam ( ios , ' namtsd in reference namelist for dia_ar5', lwp )
215      REWIND( numnam_cfg )              ! Namelist namtsd in configuration namelist : Parameters of the run
216      READ  ( numnam_cfg, namtsd, IOSTAT = ios, ERR = 902 )
217902   IF( ios /= 0 ) CALL ctl_nam ( ios , ' namtsd in configuration namelist for dia_ar5', lwp )
218      IF(lwm) WRITE ( numond, namtsd )
219      !
220      !!----------------------------------------------------------------------
221      !
222      IF( nn_timing == 1 )   CALL timing_start('dia_ar5_init')
223      !
224      CALL wrk_alloc( jpi , jpj , jpk, jpts, zsaldta )
225      !                                      ! allocate dia_ar5 arrays
226      IF( dia_ar5_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'dia_ar5_init : unable to allocate arrays' )
227
228      area(:,:) = e1t(:,:) * e2t(:,:) * tmask_i(:,:)
229
230      area_tot = SUM( area(:,:) )   ;   IF( lk_mpp )   CALL mpp_sum( area_tot )
231
232      vol0        = 0._wp
233      thick0(:,:) = 0._wp
234      DO jk = 1, jpkm1
235         vol0        = vol0        + SUM( area (:,:) * tmask(:,:,jk) * e3t_0(:,:,jk) )
236         thick0(:,:) = thick0(:,:) +    tmask_i(:,:) * tmask(:,:,jk) * e3t_0(:,:,jk)
237      END DO
238      IF( lk_mpp )   CALL mpp_sum( vol0 )
239
240      CALL iom_open ( TRIM( cn_dir )//TRIM(sn_sal%clname), inum )
241      CALL iom_get  ( inum, jpdom_data, TRIM(sn_sal%clvar), zsaldta(:,:,:,1), 1  )
242      CALL iom_get  ( inum, jpdom_data, TRIM(sn_sal%clvar), zsaldta(:,:,:,2), 12 )
243      CALL iom_close( inum )
244      sn0(:,:,:) = 0.5_wp * ( zsaldta(:,:,:,1) + zsaldta(:,:,:,2) )       
245      sn0(:,:,:) = sn0(:,:,:) * tmask(:,:,:)
246      IF( ln_zps ) THEN               ! z-coord. partial steps
247         DO jj = 1, jpj               ! interpolation of salinity at the last ocean level (i.e. the partial step)
248            DO ji = 1, jpi
249               ik = mbkt(ji,jj)
250               IF( ik > 1 ) THEN
251                  zztmp = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
252                  sn0(ji,jj,ik) = ( 1._wp - zztmp ) * sn0(ji,jj,ik) + zztmp * sn0(ji,jj,ik-1)
253               ENDIF
254            END DO
255         END DO
256      ENDIF
257      !
258      CALL wrk_dealloc( jpi , jpj , jpk, jpts, zsaldta )
259      !
260      IF( nn_timing == 1 )   CALL timing_stop('dia_ar5_init')
261      !
262   END SUBROUTINE dia_ar5_init
263
264#else
265   !!----------------------------------------------------------------------
266   !!   Default option :                                         NO diaar5
267   !!----------------------------------------------------------------------
268   LOGICAL, PUBLIC, PARAMETER :: lk_diaar5 = .FALSE.   ! coupled flag
269CONTAINS
270   SUBROUTINE dia_ar5_init    ! Dummy routine
271   END SUBROUTINE dia_ar5_init
272   SUBROUTINE dia_ar5( kt )   ! Empty routine
273      INTEGER ::   kt
274      WRITE(*,*) 'dia_ar5: You should not have seen this print! error?', kt
275   END SUBROUTINE dia_ar5
276#endif
277
278   !!======================================================================
279END MODULE diaar5
Note: See TracBrowser for help on using the repository browser.