New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
floblk.F90 in branches/2015/dev_r5072_UKMO2_OBS_simplification/NEMOGCM/NEMO/OPA_SRC/FLO – NEMO

source: branches/2015/dev_r5072_UKMO2_OBS_simplification/NEMOGCM/NEMO/OPA_SRC/FLO/floblk.F90 @ 5974

Last change on this file since 5974 was 5974, checked in by timgraham, 8 years ago

Upgrade to head of trunk (r5936)

  • Property svn:keywords set to Id
File size: 17.9 KB
Line 
1MODULE floblk
2   !!======================================================================
3   !!                     ***  MODULE  floblk  ***
4   !! Ocean floats :   trajectory computation
5   !!======================================================================
6#if   defined key_floats
7   !!----------------------------------------------------------------------
8   !!   'key_floats'                                     float trajectories
9   !!----------------------------------------------------------------------
10   !!    flotblk     : compute float trajectories with Blanke algorithme
11   !!----------------------------------------------------------------------
12   USE flo_oce         ! ocean drifting floats
13   USE oce             ! ocean dynamics and tracers
14   USE dom_oce         ! ocean space and time domain
15   USE phycst          ! physical constants
16   USE in_out_manager  ! I/O manager
17   USE lib_mpp         ! distribued memory computing library
18   USE wrk_nemo        ! working array
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   flo_blk    ! routine called by floats.F90
24
25   !! * Substitutions
26#  include "domzgr_substitute.h90"
27   !!----------------------------------------------------------------------
28   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
29   !! $Id$
30   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
31   !!----------------------------------------------------------------------
32CONTAINS
33
34   SUBROUTINE flo_blk( kt )
35      !!---------------------------------------------------------------------
36      !!                  ***  ROUTINE flo_blk  ***
37      !!           
38      !! ** Purpose :   Compute the geographical position,latitude, longitude
39      !!      and depth of each float at each time step.
40      !!
41      !! ** Method  :   The position of a float is computed with Bruno Blanke
42      !!      algorithm. We need to know the velocity field, the old positions
43      !!      of the floats and the grid defined on the domain.
44      !!----------------------------------------------------------------------
45      INTEGER, INTENT( in  ) ::   kt ! ocean time step
46      !!
47      INTEGER :: jfl              ! dummy loop arguments
48      INTEGER :: ind, ifin, iloop
49      REAL(wp)   ::       &
50         zuinfl,zvinfl,zwinfl,      &     ! transport across the input face
51         zuoutfl,zvoutfl,zwoutfl,   &     ! transport across the ouput face
52         zvol,                      &     ! volume of the mesh
53         zsurfz,                    &     ! surface of the face of the mesh
54         zind
55
56      REAL(wp), DIMENSION ( 2 )  ::   zsurfx, zsurfy   ! surface of the face of the mesh
57
58      INTEGER  , POINTER, DIMENSION ( : )  ::   iil, ijl, ikl                   ! index of nearest mesh
59      INTEGER  , POINTER, DIMENSION ( : )  ::   iiloc , ijloc             
60      INTEGER  , POINTER, DIMENSION ( : )  ::   iiinfl, ijinfl, ikinfl          ! index of input mesh of the float.
61      INTEGER  , POINTER, DIMENSION ( : )  ::   iioutfl, ijoutfl, ikoutfl       ! index of output mesh of the float.
62      REAL(wp) , POINTER, DIMENSION ( : )  ::   zgifl, zgjfl, zgkfl             ! position of floats, index on
63      !                                                                         ! velocity mesh.
64      REAL(wp) , POINTER, DIMENSION ( : )  ::    ztxfl, ztyfl, ztzfl            ! time for a float to quit the mesh
65      !                                                                         ! across one of the face x,y and z
66      REAL(wp) , POINTER, DIMENSION ( : )  ::    zttfl                          ! time for a float to quit the mesh
67      REAL(wp) , POINTER, DIMENSION ( : )  ::    zagefl                         ! time during which, trajectorie of
68      !                                                                         ! the float has been computed
69      REAL(wp) , POINTER, DIMENSION ( : )  ::   zagenewfl                       ! new age of float after calculation
70      !                                                                         ! of new position
71      REAL(wp) , POINTER, DIMENSION ( : )  ::   zufl, zvfl, zwfl                ! interpolated vel. at float position
72      REAL(wp) , POINTER, DIMENSION ( : )  ::   zudfl, zvdfl, zwdfl             ! velocity diff input/output of mesh
73      REAL(wp) , POINTER, DIMENSION ( : )  ::   zgidfl, zgjdfl, zgkdfl          ! direction index of float
74      !!---------------------------------------------------------------------
75      CALL wrk_alloc( jpnfl , iil   , ijl   , ikl   , iiloc  ,  ijloc           )
76      CALL wrk_alloc( jpnfl , iiinfl, ijinfl, ikinfl, iioutfl, ijoutfl, ikoutfl )
77      CALL wrk_alloc( jpnfl , zgifl , zgjfl , zgkfl , ztxfl  , ztyfl  , ztzfl   , zttfl , zagefl, zagenewfl) 
78      CALL wrk_alloc( jpnfl , zufl  , zvfl  , zwfl  , zudfl  , zvdfl  , zwdfl   , zgidfl, zgjdfl, zgkdfl   )
79
80      IF( kt == nit000 ) THEN
81         IF(lwp) WRITE(numout,*)
82         IF(lwp) WRITE(numout,*) 'flo_blk : compute Blanke trajectories for floats '
83         IF(lwp) WRITE(numout,*) '~~~~~~~ '
84      ENDIF
85
86      ! Initialisation of parameters
87     
88      DO jfl = 1, jpnfl
89         ! ages of floats are put at zero
90         zagefl(jfl) = 0.
91         ! index on the velocity grid
92         ! We considere k coordinate negative, with this transformation
93         ! the computation in the 3 direction is the same.
94         zgifl(jfl) = tpifl(jfl) - 0.5
95         zgjfl(jfl) = tpjfl(jfl) - 0.5
96         zgkfl(jfl) = MIN(-1.,-(tpkfl(jfl)))
97         ! surface drift every 10 days
98         IF( ln_argo ) THEN
99            IF( MOD(kt,150) >= 146 .OR. MOD(kt,150) == 0 )  zgkfl(jfl) = -1.
100         ENDIF
101         ! index of T mesh
102         iil(jfl) = 1 + INT(zgifl(jfl))
103         ijl(jfl) = 1 + INT(zgjfl(jfl))
104         ikl(jfl) =     INT(zgkfl(jfl))
105      END DO
106       
107      iloop = 0
108222   DO jfl = 1, jpnfl
109# if   defined key_mpp_mpi
110         IF( (iil(jfl) >= (mig(nldi)-jpizoom+1)) .AND. (iil(jfl) <= (mig(nlei)-jpizoom+1)) .AND.   &
111             (ijl(jfl) >= (mjg(nldj)-jpjzoom+1)) .AND. (ijl(jfl) <= (mjg(nlej)-jpjzoom+1)) ) THEN
112            iiloc(jfl) = iil(jfl) - (mig(1)-jpizoom+1) + 1
113            ijloc(jfl) = ijl(jfl) - (mjg(1)-jpjzoom+1) + 1
114# else
115            iiloc(jfl) = iil(jfl)
116            ijloc(jfl) = ijl(jfl)
117# endif
118           
119            ! compute the transport across the mesh where the float is.           
120!!bug (gm) change e3t into fse3. but never checked
121            zsurfx(1) = e2u(iiloc(jfl)-1,ijloc(jfl)  ) * fse3u(iiloc(jfl)-1,ijloc(jfl)  ,-ikl(jfl))
122            zsurfx(2) = e2u(iiloc(jfl)  ,ijloc(jfl)  ) * fse3u(iiloc(jfl)  ,ijloc(jfl)  ,-ikl(jfl))
123            zsurfy(1) = e1v(iiloc(jfl)  ,ijloc(jfl)-1) * fse3v(iiloc(jfl)  ,ijloc(jfl)-1,-ikl(jfl))
124            zsurfy(2) = e1v(iiloc(jfl)  ,ijloc(jfl)  ) * fse3v(iiloc(jfl)  ,ijloc(jfl)  ,-ikl(jfl))
125
126            ! for a isobar float zsurfz is put to zero. The vertical velocity will be zero too.
127            zsurfz =          e1e2t(iiloc(jfl),ijloc(jfl))
128            zvol   = zsurfz * fse3t(iiloc(jfl),ijloc(jfl),-ikl(jfl))
129
130            !
131            zuinfl =( ub(iiloc(jfl)-1,ijloc(jfl),-ikl(jfl)) + un(iiloc(jfl)-1,ijloc(jfl),-ikl(jfl)) )/2.*zsurfx(1)
132            zuoutfl=( ub(iiloc(jfl)  ,ijloc(jfl),-ikl(jfl)) + un(iiloc(jfl)  ,ijloc(jfl),-ikl(jfl)) )/2.*zsurfx(2)
133            zvinfl =( vb(iiloc(jfl),ijloc(jfl)-1,-ikl(jfl)) + vn(iiloc(jfl),ijloc(jfl)-1,-ikl(jfl)) )/2.*zsurfy(1)
134            zvoutfl=( vb(iiloc(jfl),ijloc(jfl)  ,-ikl(jfl)) + vn(iiloc(jfl),ijloc(jfl)  ,-ikl(jfl)) )/2.*zsurfy(2)
135            zwinfl =-(wb(iiloc(jfl),ijloc(jfl),-(ikl(jfl)-1))    &
136               &   +  wn(iiloc(jfl),ijloc(jfl),-(ikl(jfl)-1)) )/2. *  zsurfz*nisobfl(jfl)
137            zwoutfl=-(wb(iiloc(jfl),ijloc(jfl),- ikl(jfl)   )   &
138               &   +  wn(iiloc(jfl),ijloc(jfl),- ikl(jfl)   ) )/2. *  zsurfz*nisobfl(jfl)
139           
140            ! interpolation of velocity field on the float initial position           
141            zufl(jfl)=  zuinfl  + ( zgifl(jfl) - float(iil(jfl)-1) ) * ( zuoutfl - zuinfl)
142            zvfl(jfl)=  zvinfl  + ( zgjfl(jfl) - float(ijl(jfl)-1) ) * ( zvoutfl - zvinfl)
143            zwfl(jfl)=  zwinfl  + ( zgkfl(jfl) - float(ikl(jfl)-1) ) * ( zwoutfl - zwinfl)
144           
145            ! faces of input and output
146            ! u-direction
147            IF( zufl(jfl) < 0. ) THEN
148               iioutfl(jfl) = iil(jfl) - 1.
149               iiinfl (jfl) = iil(jfl)
150               zind   = zuinfl
151               zuinfl = zuoutfl
152               zuoutfl= zind
153            ELSE
154               iioutfl(jfl) = iil(jfl)
155               iiinfl (jfl) = iil(jfl) - 1
156            ENDIF
157            ! v-direction       
158            IF( zvfl(jfl) < 0. ) THEN
159               ijoutfl(jfl) = ijl(jfl) - 1.
160               ijinfl (jfl) = ijl(jfl)
161               zind    = zvinfl
162               zvinfl  = zvoutfl
163               zvoutfl = zind
164            ELSE
165               ijoutfl(jfl) = ijl(jfl)
166               ijinfl (jfl) = ijl(jfl) - 1.
167            ENDIF
168            ! w-direction
169            IF( zwfl(jfl) < 0. ) THEN
170               ikoutfl(jfl) = ikl(jfl) - 1.
171               ikinfl (jfl) = ikl(jfl)
172               zind    = zwinfl
173               zwinfl  = zwoutfl
174               zwoutfl = zind
175            ELSE
176               ikoutfl(jfl) = ikl(jfl)
177               ikinfl (jfl) = ikl(jfl) - 1.
178            ENDIF
179           
180            ! compute the time to go out the mesh across a face
181            ! u-direction
182            zudfl (jfl) = zuoutfl - zuinfl
183            zgidfl(jfl) = float(iioutfl(jfl) - iiinfl(jfl))
184            IF( zufl(jfl)*zuoutfl <= 0. ) THEN
185               ztxfl(jfl) = 1.E99
186            ELSE
187               IF( ABS(zudfl(jfl)) >= 1.E-5 ) THEN
188                  ztxfl(jfl)= zgidfl(jfl)/zudfl(jfl) * LOG(zuoutfl/zufl (jfl))
189               ELSE
190                  ztxfl(jfl)=(float(iioutfl(jfl))-zgifl(jfl))/zufl(jfl)
191               ENDIF
192               IF( (ABS(zgifl(jfl)-float(iiinfl (jfl))) <=  1.E-7) .OR.   &
193                   (ABS(zgifl(jfl)-float(iioutfl(jfl))) <=  1.E-7) ) THEN
194                  ztxfl(jfl)=(zgidfl(jfl))/zufl(jfl)
195               ENDIF
196            ENDIF
197            ! v-direction
198            zvdfl (jfl) = zvoutfl - zvinfl
199            zgjdfl(jfl) = float(ijoutfl(jfl)-ijinfl(jfl))
200            IF( zvfl(jfl)*zvoutfl <= 0. ) THEN
201               ztyfl(jfl) = 1.E99
202            ELSE
203               IF( ABS(zvdfl(jfl)) >= 1.E-5 ) THEN
204                  ztyfl(jfl) = zgjdfl(jfl)/zvdfl(jfl) * LOG(zvoutfl/zvfl (jfl))
205               ELSE
206                  ztyfl(jfl) = (float(ijoutfl(jfl)) - zgjfl(jfl))/zvfl(jfl)
207               ENDIF
208               IF( (ABS(zgjfl(jfl)-float(ijinfl (jfl))) <= 1.E-7) .OR.   &
209                   (ABS(zgjfl(jfl)-float(ijoutfl(jfl))) <=  1.E-7) ) THEN
210                  ztyfl(jfl) = (zgjdfl(jfl)) / zvfl(jfl)
211               ENDIF
212            ENDIF
213            ! w-direction       
214            IF( nisobfl(jfl) == 1. ) THEN
215               zwdfl (jfl) = zwoutfl - zwinfl
216               zgkdfl(jfl) = float(ikoutfl(jfl) - ikinfl(jfl))
217               IF( zwfl(jfl)*zwoutfl <= 0. ) THEN
218                  ztzfl(jfl) = 1.E99
219               ELSE
220                  IF( ABS(zwdfl(jfl)) >= 1.E-5 ) THEN
221                     ztzfl(jfl) = zgkdfl(jfl)/zwdfl(jfl) * LOG(zwoutfl/zwfl (jfl))
222                  ELSE
223                     ztzfl(jfl) = (float(ikoutfl(jfl)) - zgkfl(jfl))/zwfl(jfl)
224                  ENDIF
225                  IF( (ABS(zgkfl(jfl)-float(ikinfl (jfl))) <=  1.E-7) .OR.   &
226                      (ABS(zgkfl(jfl)-float(ikoutfl(jfl))) <= 1.E-7) ) THEN
227                     ztzfl(jfl) = (zgkdfl(jfl)) / zwfl(jfl)
228                  ENDIF
229               ENDIF
230            ENDIF
231           
232            ! the time to go leave the mesh is the smallest time
233                   
234            IF( nisobfl(jfl) == 1. ) THEN
235               zttfl(jfl) = MIN(ztxfl(jfl),ztyfl(jfl),ztzfl(jfl))
236            ELSE
237               zttfl(jfl) = MIN(ztxfl(jfl),ztyfl(jfl))
238            ENDIF
239            ! new age of the FLOAT
240            zagenewfl(jfl) = zagefl(jfl) + zttfl(jfl)*zvol
241            ! test to know if the "age" of the float is not bigger than the
242            ! time step
243            IF( zagenewfl(jfl) > rdt ) THEN
244               zttfl(jfl) = (rdt-zagefl(jfl)) / zvol
245               zagenewfl(jfl) = rdt
246            ENDIF
247           
248            ! In the "minimal" direction we compute the index of new mesh
249            ! on i-direction
250            IF( ztxfl(jfl) <=  zttfl(jfl) ) THEN
251               zgifl(jfl) = float(iioutfl(jfl))
252               ind = iioutfl(jfl)
253               IF( iioutfl(jfl) >= iiinfl(jfl) ) THEN
254                  iioutfl(jfl) = iioutfl(jfl) + 1
255               ELSE
256                  iioutfl(jfl) = iioutfl(jfl) - 1
257               ENDIF
258               iiinfl(jfl) = ind
259            ELSE
260               IF( ABS(zudfl(jfl)) >= 1.E-5 ) THEN
261                  zgifl(jfl) = zgifl(jfl) + zgidfl(jfl)*zufl(jfl)    &
262                     &       * ( EXP( zudfl(jfl)/zgidfl(jfl)*zttfl(jfl) ) - 1. ) /  zudfl(jfl)
263               ELSE
264                  zgifl(jfl) = zgifl(jfl) + zufl(jfl) * zttfl(jfl)
265               ENDIF
266            ENDIF
267            ! on j-direction
268            IF( ztyfl(jfl) <= zttfl(jfl) ) THEN
269               zgjfl(jfl) = float(ijoutfl(jfl))
270               ind = ijoutfl(jfl)
271               IF( ijoutfl(jfl) >= ijinfl(jfl) ) THEN
272                  ijoutfl(jfl) = ijoutfl(jfl) + 1
273               ELSE
274                  ijoutfl(jfl) = ijoutfl(jfl) - 1
275               ENDIF
276               ijinfl(jfl) = ind
277            ELSE
278               IF( ABS(zvdfl(jfl)) >= 1.E-5 ) THEN
279                  zgjfl(jfl) = zgjfl(jfl)+zgjdfl(jfl)*zvfl(jfl)   &
280                     &       * ( EXP(zvdfl(jfl)/zgjdfl(jfl)*zttfl(jfl)) - 1. ) /  zvdfl(jfl)
281               ELSE
282                  zgjfl(jfl) = zgjfl(jfl)+zvfl(jfl)*zttfl(jfl)
283               ENDIF
284            ENDIF
285            ! on k-direction
286            IF( nisobfl(jfl) == 1. ) THEN
287               IF( ztzfl(jfl) <= zttfl(jfl) ) THEN
288                  zgkfl(jfl) = float(ikoutfl(jfl))
289                  ind = ikoutfl(jfl)
290                  IF( ikoutfl(jfl) >= ikinfl(jfl) ) THEN
291                     ikoutfl(jfl) = ikoutfl(jfl)+1
292                  ELSE
293                     ikoutfl(jfl) = ikoutfl(jfl)-1
294                  ENDIF
295                  ikinfl(jfl) = ind
296               ELSE
297                  IF( ABS(zwdfl(jfl)) >= 1.E-5 ) THEN
298                     zgkfl(jfl) = zgkfl(jfl)+zgkdfl(jfl)*zwfl(jfl)    &
299                        &       * ( EXP(zwdfl(jfl)/zgkdfl(jfl)*zttfl(jfl)) - 1. ) /  zwdfl(jfl)
300                  ELSE
301                     zgkfl(jfl) = zgkfl(jfl)+zwfl(jfl)*zttfl(jfl)
302                  ENDIF
303               ENDIF
304            ENDIF
305           
306            ! coordinate of the new point on the temperature grid
307           
308            iil(jfl) = MAX(iiinfl(jfl),iioutfl(jfl))
309            ijl(jfl) = MAX(ijinfl(jfl),ijoutfl(jfl))
310            IF( nisobfl(jfl) ==  1 ) ikl(jfl) = MAX(ikinfl(jfl),ikoutfl(jfl))
311!!Alexcadm   write(*,*)'PE ',narea,
312!!Alexcadm     .    iiinfl(jfl),iioutfl(jfl),ijinfl(jfl)
313!!Alexcadm     .     ,ijoutfl(jfl),ikinfl(jfl),
314!!Alexcadm     .    ikoutfl(jfl),ztxfl(jfl),ztyfl(jfl)
315!!Alexcadm     .     ,ztzfl(jfl),zgifl(jfl),
316!!Alexcadm     .  zgjfl(jfl)
317!!Alexcadm  IF (jfl == 910) write(*,*)'Flotteur 910',
318!!Alexcadm     .    iiinfl(jfl),iioutfl(jfl),ijinfl(jfl)
319!!Alexcadm     .     ,ijoutfl(jfl),ikinfl(jfl),
320!!Alexcadm     .    ikoutfl(jfl),ztxfl(jfl),ztyfl(jfl)
321!!Alexcadm     .     ,ztzfl(jfl),zgifl(jfl),
322!!Alexcadm     .  zgjfl(jfl)
323            ! reinitialisation of the age of FLOAT
324            zagefl(jfl) = zagenewfl(jfl)
325# if   defined key_mpp_mpi
326         ELSE
327            ! we put zgifl, zgjfl, zgkfl, zagefl
328            zgifl (jfl) = 0.
329            zgjfl (jfl) = 0.
330            zgkfl (jfl) = 0.
331            zagefl(jfl) = 0.
332            iil(jfl) = 0
333            ijl(jfl) = 0
334         ENDIF
335# endif
336      END DO
337     
338      ! synchronisation
339      IF( lk_mpp )   CALL mpp_sum( zgifl , jpnfl )   ! sums over the global domain
340      IF( lk_mpp )   CALL mpp_sum( zgjfl , jpnfl )
341      IF( lk_mpp )   CALL mpp_sum( zgkfl , jpnfl )
342      IF( lk_mpp )   CALL mpp_sum( zagefl, jpnfl )
343      IF( lk_mpp )   CALL mpp_sum( iil   , jpnfl )
344      IF( lk_mpp )   CALL mpp_sum( ijl   , jpnfl )
345     
346      ! Test to know if a  float hasn't integrated enought time
347      IF( ln_argo ) THEN
348         ifin = 1
349         DO jfl = 1, jpnfl
350            IF( zagefl(jfl) < rdt )   ifin = 0
351            tpifl(jfl) = zgifl(jfl) + 0.5
352            tpjfl(jfl) = zgjfl(jfl) + 0.5
353         END DO
354      ELSE
355         ifin = 1
356         DO jfl = 1, jpnfl
357            IF( zagefl(jfl) < rdt )   ifin = 0
358            tpifl(jfl) = zgifl(jfl) + 0.5
359            tpjfl(jfl) = zgjfl(jfl) + 0.5
360            IF( nisobfl(jfl) == 1 ) tpkfl(jfl) = -(zgkfl(jfl))
361         END DO
362      ENDIF
363!!Alexcadm  IF (lwp) write(numout,*) '---------'
364!!Alexcadm  IF (lwp) write(numout,*) 'before Erika:',tpifl(880),tpjfl(880),
365!!Alexcadm     .       tpkfl(880),zufl(880),zvfl(880),zwfl(880)
366!!Alexcadm  IF (lwp) write(numout,*) 'first Erika:',tpifl(900),tpjfl(900),
367!!Alexcadm     .       tpkfl(900),zufl(900),zvfl(900),zwfl(900)
368!!Alexcadm  IF (lwp) write(numout,*) 'last Erika:',tpifl(jpnfl),tpjfl(jpnfl),
369!!Alexcadm     .       tpkfl(jpnfl),zufl(jpnfl),zvfl(jpnfl),zwfl(jpnfl)
370      IF( ifin == 0 ) THEN
371         iloop = iloop + 1 
372         GO TO 222
373      ENDIF
374      !
375      CALL wrk_dealloc( jpnfl , iil   , ijl   , ikl   , iiloc  ,  ijloc           )
376      CALL wrk_dealloc( jpnfl , iiinfl, ijinfl, ikinfl, iioutfl, ijoutfl, ikoutfl )
377      CALL wrk_dealloc( jpnfl , zgifl , zgjfl , zgkfl , ztxfl  , ztyfl  , ztzfl   , zttfl , zagefl, zagenewfl) 
378      CALL wrk_dealloc( jpnfl , zufl  , zvfl  , zwfl  , zudfl  , zvdfl  , zwdfl   , zgidfl, zgjdfl, zgkdfl   )
379      !
380   END SUBROUTINE flo_blk
381
382#  else
383   !!----------------------------------------------------------------------
384   !!   Default option                                         Empty module
385   !!----------------------------------------------------------------------
386CONTAINS
387   SUBROUTINE flo_blk                  ! Empty routine
388   END SUBROUTINE flo_blk 
389#endif
390   
391   !!======================================================================
392END MODULE floblk 
Note: See TracBrowser for help on using the repository browser.