New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
obs_readmdt.F90 in branches/2015/dev_r5072_UKMO2_OBS_simplification/NEMOGCM/NEMO/OPA_SRC/OBS – NEMO

source: branches/2015/dev_r5072_UKMO2_OBS_simplification/NEMOGCM/NEMO/OPA_SRC/OBS/obs_readmdt.F90 @ 5682

Last change on this file since 5682 was 5682, checked in by mattmartin, 9 years ago

OBS simplification changes committed to branch after running SETTE tests to make sure we get the same results as the trunk for ORCA2_LIM_OBS.
  • Property svn:keywords set to Id
File size: 9.9 KB
Line 
1MODULE obs_readmdt
2   !!======================================================================
3   !!                       ***  MODULE obs_readmdt  ***
4   !! Observation diagnostics: Read the MDT for SLA data (skeleton for now)
5   !!======================================================================
6   !! History :      ! 2007-03 (K. Mogensen) Initial skeleton version
7   !!                ! 2007-04 (E. Remy) migration and improvement from OPAVAR
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   obs_rea_mdt    : Driver for reading MDT
12   !!   obs_offset_mdt : Remove the offset between the model MDT and the used one
13   !!----------------------------------------------------------------------
14   USE wrk_nemo         ! Memory Allocation
15   USE par_kind         ! Precision variables
16   USE par_oce          ! Domain parameters
17   USE in_out_manager   ! I/O manager
18   USE obs_surf_def     ! Surface observation definitions
19   USE obs_inter_sup    ! Interpolation support routines
20   USE obs_inter_h2d    ! 2D interpolation
21   USE obs_utils        ! Various observation tools
22   USE iom_nf90         ! IOM NetCDF
23   USE netcdf           ! NetCDF library
24   USE lib_mpp          ! MPP library
25   USE dom_oce, ONLY : &                  ! Domain variables
26      &                    tmask, tmask_i, e1t, e2t, gphit, glamt
27   USE obs_const, ONLY :   obfillflt      ! Fillvalue
28   USE oce      , ONLY :   sshn           ! Model variables
29
30   IMPLICIT NONE
31   PRIVATE
32   
33   PUBLIC   obs_rea_mdt     ! called by dia_obs_init
34   PUBLIC   obs_offset_mdt  ! called by obs_rea_mdt
35
36   INTEGER , PUBLIC :: nn_msshc    = 1         ! MDT correction scheme
37   REAL(wp), PUBLIC :: rn_mdtcorr   = 1.61_wp  ! User specified MDT correction
38   REAL(wp), PUBLIC :: rn_mdtcutoff = 65.0_wp  ! MDT cutoff for computed correction
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
42   !! $Id$
43   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE obs_rea_mdt( sladata, k2dint )
48      !!---------------------------------------------------------------------
49      !!
50      !!                   *** ROUTINE obs_rea_mdt ***
51      !!
52      !! ** Purpose : Read from file the MDT data (skeleton)
53      !!
54      !! ** Method  :
55      !!
56      !! ** Action  :
57      !!----------------------------------------------------------------------
58      USE iom
59      !
60      TYPE(obs_surf), INTENT(inout) ::   sladata   ! SLA data
61      INTEGER       , INTENT(in)    ::   k2dint    ! ?
62      !
63      CHARACTER(LEN=12), PARAMETER ::   cpname  = 'obs_rea_mdt'
64      CHARACTER(LEN=20), PARAMETER ::   mdtname = 'slaReferenceLevel.nc'
65
66      INTEGER ::   jobs                ! Obs loop variable
67      INTEGER ::   jpimdt, jpjmdt      ! Number of grid point in lat/lon for the MDT
68      INTEGER ::   iico, ijco          ! Grid point indicies
69      INTEGER ::   i_nx_id, i_ny_id, i_file_id, i_var_id, i_stat
70      INTEGER ::   nummdt
71      !
72      REAL(wp), DIMENSION(1)     ::   zext, zobsmask
73      REAL(wp), DIMENSION(2,2,1) ::   zweig
74      !
75      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   zmask, zmdtl, zglam, zgphi
76      INTEGER , DIMENSION(:,:,:), ALLOCATABLE ::   igrdi, igrdj
77      !
78      REAL(wp), POINTER, DIMENSION(:,:) ::  z_mdt, mdtmask
79         
80      REAL(wp) :: zlam, zphi, zfill, zinfill    ! local scalar
81      !!----------------------------------------------------------------------
82
83      CALL wrk_alloc(jpi,jpj,z_mdt,mdtmask) 
84
85      IF(lwp)WRITE(numout,*) 
86      IF(lwp)WRITE(numout,*) ' obs_rea_mdt : Read MDT for referencing altimeter anomalies'
87      IF(lwp)WRITE(numout,*) ' ------------- '
88      CALL FLUSH(numout)
89
90      CALL iom_open( mdtname, nummdt )       ! Open the file
91      !                                      ! Get the MDT data
92      CALL iom_get ( nummdt, jpdom_data, 'sossheig', z_mdt(:,:), 1 )
93      CALL iom_close(nummdt)                 ! Close the file
94     
95      ! Read in the fill value
96      zinfill = 0.0
97      i_stat = nf90_open( mdtname, nf90_nowrite, nummdt )
98      i_stat = nf90_inq_varid( nummdt, 'sossheig', i_var_id )
99      i_stat = nf90_get_att( nummdt, i_var_id, "_FillValue",zinfill)
100      zfill = zinfill
101      i_stat = nf90_close( nummdt )
102
103      ! setup mask based on tmask and MDT mask
104      ! set mask to 0 where the MDT is set to fillvalue
105      WHERE(z_mdt(:,:) /= zfill)   ;   mdtmask(:,:) = tmask(:,:,1)
106      ELSE WHERE                   ;   mdtmask(:,:) = 0
107      END WHERE
108
109      ! Remove the offset between the MDT used with the sla and the model MDT
110      IF( nn_msshc == 1 .OR. nn_msshc == 2 )   CALL obs_offset_mdt( z_mdt, zfill )
111
112      ! Intepolate the MDT already on the model grid at the observation point
113 
114      ALLOCATE( &
115         & igrdi(2,2,sladata%nsurf), &
116         & igrdj(2,2,sladata%nsurf), &
117         & zglam(2,2,sladata%nsurf), &
118         & zgphi(2,2,sladata%nsurf), &
119         & zmask(2,2,sladata%nsurf), &
120         & zmdtl(2,2,sladata%nsurf)  &
121         & )
122         
123      DO jobs = 1, sladata%nsurf
124
125         igrdi(1,1,jobs) = sladata%mi(jobs)-1
126         igrdj(1,1,jobs) = sladata%mj(jobs)-1
127         igrdi(1,2,jobs) = sladata%mi(jobs)-1
128         igrdj(1,2,jobs) = sladata%mj(jobs)
129         igrdi(2,1,jobs) = sladata%mi(jobs)
130         igrdj(2,1,jobs) = sladata%mj(jobs)-1
131         igrdi(2,2,jobs) = sladata%mi(jobs)
132         igrdj(2,2,jobs) = sladata%mj(jobs)
133
134      END DO
135
136      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, igrdi, igrdj, glamt  , zglam )
137      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, igrdi, igrdj, gphit  , zgphi )
138      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, igrdi, igrdj, mdtmask, zmask )
139      CALL obs_int_comm_2d( 2, 2, sladata%nsurf, igrdi, igrdj, z_mdt  , zmdtl )
140
141      DO jobs = 1, sladata%nsurf
142           
143         zlam = sladata%rlam(jobs)
144         zphi = sladata%rphi(jobs)
145
146         CALL obs_int_h2d_init( 1, 1, k2dint, zlam, zphi,         &
147            &                   zglam(:,:,jobs), zgphi(:,:,jobs), &
148            &                   zmask(:,:,jobs), zweig, zobsmask )
149           
150         CALL obs_int_h2d( 1, 1, zweig, zmdtl(:,:,jobs),  zext )
151 
152         sladata%rext(jobs,2) = zext(1)
153
154! mark any masked data with a QC flag
155         IF( zobsmask(1) == 0 )   sladata%nqc(jobs) = 11
156
157         END DO
158         
159      DEALLOCATE( &
160         & igrdi, &
161         & igrdj, &
162         & zglam, &
163         & zgphi, &
164         & zmask, &
165         & zmdtl  &
166         & )
167
168      CALL wrk_dealloc(jpi,jpj,z_mdt,mdtmask) 
169      IF(lwp)WRITE(numout,*) ' ------------- '
170      CALL FLUSH(numout)
171      !
172   END SUBROUTINE obs_rea_mdt
173
174
175   SUBROUTINE obs_offset_mdt( mdt, zfill )
176      !!---------------------------------------------------------------------
177      !!
178      !!                   *** ROUTINE obs_offset_mdt ***
179      !!
180      !! ** Purpose : Compute a correction term for the MDT on the model grid
181      !!             !!!!! IF it is on the model grid
182      !!
183      !! ** Method  : Compute the mean difference between the model and the
184      !!              used MDT and remove the offset.
185      !!
186      !! ** Action  :
187      !!----------------------------------------------------------------------
188      REAL(wp), DIMENSION(jpi,jpj), INTENT(inout) ::   mdt     ! MDT used on the model grid
189      REAL(wp)                    , INTENT(in   ) ::   zfill 
190      !
191      INTEGER  :: ji, jj
192      REAL(wp) :: zdxdy, zarea, zeta1, zeta2, zcorr_mdt, zcorr_bcketa, zcorr     ! local scalar
193      REAL(wp), POINTER, DIMENSION(:,:) :: zpromsk
194      CHARACTER(LEN=14), PARAMETER ::   cpname = 'obs_offset_mdt'
195      !!----------------------------------------------------------------------
196
197      CALL wrk_alloc( jpi,jpj, zpromsk )
198
199      !  Initialize the local mask, for domain projection
200      !  Also exclude mdt points which are set to missing data
201
202      DO ji = 1, jpi
203        DO jj = 1, jpj
204           zpromsk(ji,jj) = tmask_i(ji,jj)
205           IF (    ( gphit(ji,jj) .GT.  rn_mdtcutoff ) &
206              &.OR.( gphit(ji,jj) .LT. -rn_mdtcutoff ) &
207              &.OR.( mdt(ji,jj) .EQ. zfill ) ) &
208              &        zpromsk(ji,jj) = 0.0
209        END DO
210      END DO 
211
212      ! Compute MSSH mean over [0,360] x [-rn_mdtcutoff,rn_mdtcutoff]
213
214      zarea = 0.0
215      zeta1 = 0.0
216      zeta2 = 0.0
217
218      DO jj = 1, jpj
219         DO ji = 1, jpi
220          zdxdy = e1t(ji,jj) * e2t(ji,jj) * zpromsk(ji,jj)
221          zarea = zarea + zdxdy
222          zeta1 = zeta1 + mdt(ji,jj) * zdxdy
223          zeta2 = zeta2 + sshn (ji,jj) * zdxdy
224        END DO     
225      END DO
226
227      IF( lk_mpp)   CALL mpp_sum( zeta1 )
228      IF( lk_mpp)   CALL mpp_sum( zeta2 )
229      IF( lk_mpp)   CALL mpp_sum( zarea )
230     
231      zcorr_mdt    = zeta1 / zarea
232      zcorr_bcketa = zeta2 / zarea
233
234      !  Define correction term
235
236      zcorr = zcorr_mdt - zcorr_bcketa
237
238      !  Correct spatial mean of the MSSH
239
240      IF( nn_msshc == 1 )   mdt(:,:) = mdt(:,:) - zcorr 
241
242      ! User defined value : 1.6 m for the Rio MDT compared to ORCA2 MDT
243
244      IF( nn_msshc == 2 )   mdt(:,:) = mdt(:,:) - rn_mdtcorr
245
246      IF(lwp) THEN
247         WRITE(numout,*)
248         WRITE(numout,*) ' obs_readmdt : rn_mdtcutoff     = ', rn_mdtcutoff
249         WRITE(numout,*) ' -----------   zcorr_mdt     = ', zcorr_mdt
250         WRITE(numout,*) '               zcorr_bcketa  = ', zcorr_bcketa
251         WRITE(numout,*) '               zcorr         = ', zcorr
252         WRITE(numout,*) '               nn_msshc        = ', nn_msshc
253      ENDIF
254
255      IF ( nn_msshc == 0 ) WRITE(numout,*) '           MSSH correction is not applied'
256      IF ( nn_msshc == 1 ) WRITE(numout,*) '           MSSH correction is applied'
257      IF ( nn_msshc == 2 ) WRITE(numout,*) '           User defined MSSH correction' 
258
259      CALL wrk_dealloc( jpi,jpj, zpromsk )
260      !
261   END SUBROUTINE obs_offset_mdt
262 
263   !!======================================================================
264END MODULE obs_readmdt
Note: See TracBrowser for help on using the repository browser.