source: branches/2015/dev_r5094_UKMO_ISFCLEAN/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5098

Last change on this file since 5098 was 5098, checked in by mathiot, 6 years ago

add wmask, wumask, wvmask and restore loop order and add flag to ignore specific isf code if no isf

  • Property svn:keywords set to Id
File size: 69.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   dyn_hpg        ! routine called by step module
51   PUBLIC   dyn_hpg_init   ! routine called by opa module
52
53   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
54   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
55   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
56   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
57   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
58   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
59   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
60   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
61
62   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
63
64   !! * Substitutions
65#  include "domzgr_substitute.h90"
66#  include "vectopt_loop_substitute.h90"
67   !!----------------------------------------------------------------------
68   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
69   !! $Id$
70   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
71   !!----------------------------------------------------------------------
72CONTAINS
73
74   SUBROUTINE dyn_hpg( kt )
75      !!---------------------------------------------------------------------
76      !!                  ***  ROUTINE dyn_hpg  ***
77      !!
78      !! ** Method  :   Call the hydrostatic pressure gradient routine
79      !!              using the scheme defined in the namelist
80      !!
81      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
82      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
83      !!----------------------------------------------------------------------
84      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
85      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
86      !!----------------------------------------------------------------------
87      !
88      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
89      !
90      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
91         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
92         ztrdu(:,:,:) = ua(:,:,:)
93         ztrdv(:,:,:) = va(:,:,:)
94      ENDIF
95      !
96      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
97      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
98      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
99      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
100      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
101      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
102      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
103      END SELECT
104      !
105      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
106         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
107         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
108         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
109         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
110      ENDIF
111      !
112      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
113         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
114      !
115      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
116      !
117   END SUBROUTINE dyn_hpg
118
119
120   SUBROUTINE dyn_hpg_init
121      !!----------------------------------------------------------------------
122      !!                 ***  ROUTINE dyn_hpg_init  ***
123      !!
124      !! ** Purpose :   initializations for the hydrostatic pressure gradient
125      !!              computation and consistency control
126      !!
127      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
128      !!      with the type of vertical coordinate used (zco, zps, sco)
129      !!----------------------------------------------------------------------
130      INTEGER ::   ioptio = 0      ! temporary integer
131      INTEGER ::   ios             ! Local integer output status for namelist read
132      !!
133      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
134         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
135      !!----------------------------------------------------------------------
136      !
137      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
138      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
139901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
140
141      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
142      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
143902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
144      IF(lwm) WRITE ( numond, namdyn_hpg )
145      !
146      IF(lwp) THEN                   ! Control print
147         WRITE(numout,*)
148         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
149         WRITE(numout,*) '~~~~~~~~~~~~'
150         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
151         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
152         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
153         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
154         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
155         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
156         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
157         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
158      ENDIF
159      !
160      IF( ln_hpg_djc )   &
161         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
162                           & currently disabled (bugs under investigation). Please select &
163                           & either  ln_hpg_sco or  ln_hpg_prj instead')
164      !
165      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
166         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
167                           & the standard jacobian formulation hpg_sco or &
168                           & the pressure jacobian formulation hpg_prj')
169      !
170      !                               ! Set nhpg from ln_hpg_... flags
171      IF( ln_hpg_zco )   nhpg = 0
172      IF( ln_hpg_zps )   nhpg = 1
173      IF( ln_hpg_sco )   nhpg = 2
174      IF( ln_hpg_djc )   nhpg = 3
175      IF( ln_hpg_prj )   nhpg = 4
176      IF( ln_hpg_isf )   nhpg = 5
177      !
178      !                               ! Consistency check
179      ioptio = 0
180      IF( ln_hpg_zco )   ioptio = ioptio + 1
181      IF( ln_hpg_zps )   ioptio = ioptio + 1
182      IF( ln_hpg_sco )   ioptio = ioptio + 1
183      IF( ln_hpg_djc )   ioptio = ioptio + 1
184      IF( ln_hpg_prj )   ioptio = ioptio + 1
185      IF( ln_hpg_isf )   ioptio = ioptio + 1
186      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
187      IF( ( .NOT. ln_hpg_isf ) .AND. ln_isfcav )   &
188          &  CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
189      !
190   END SUBROUTINE dyn_hpg_init
191
192
193   SUBROUTINE hpg_zco( kt )
194      !!---------------------------------------------------------------------
195      !!                  ***  ROUTINE hpg_zco  ***
196      !!
197      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
198      !!      The now hydrostatic pressure gradient at a given level, jk,
199      !!      is computed by taking the vertical integral of the in-situ
200      !!      density gradient along the model level from the suface to that
201      !!      level:    zhpi = grav .....
202      !!                zhpj = grav .....
203      !!      add it to the general momentum trend (ua,va).
204      !!            ua = ua - 1/e1u * zhpi
205      !!            va = va - 1/e2v * zhpj
206      !!
207      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
208      !!----------------------------------------------------------------------
209      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
210      !!
211      INTEGER  ::   ji, jj, jk       ! dummy loop indices
212      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
213      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
214      !!----------------------------------------------------------------------
215      !
216      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
217      !
218      IF( kt == nit000 ) THEN
219         IF(lwp) WRITE(numout,*)
220         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
221         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
222      ENDIF
223
224      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
225
226      ! Surface value
227      DO jj = 2, jpjm1
228         DO ji = fs_2, fs_jpim1   ! vector opt.
229            zcoef1 = zcoef0 * fse3w(ji,jj,1)
230            ! hydrostatic pressure gradient
231            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
232            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
233            ! add to the general momentum trend
234            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
235            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
236         END DO
237      END DO
238
239      !
240      ! interior value (2=<jk=<jpkm1)
241      DO jk = 2, jpkm1
242         DO jj = 2, jpjm1
243            DO ji = fs_2, fs_jpim1   ! vector opt.
244               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
245               ! hydrostatic pressure gradient
246               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
247                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
248                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
249
250               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
251                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
252                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
253               ! add to the general momentum trend
254               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
255               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
256            END DO
257         END DO
258      END DO
259      !
260      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
261      !
262   END SUBROUTINE hpg_zco
263
264
265   SUBROUTINE hpg_zps( kt )
266      !!---------------------------------------------------------------------
267      !!                 ***  ROUTINE hpg_zps  ***
268      !!
269      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
270      !!
271      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
272      !!----------------------------------------------------------------------
273      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
274      !!
275      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
276      INTEGER  ::   iku, ikv                         ! temporary integers
277      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
278      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
279      !!----------------------------------------------------------------------
280      !
281      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
282      !
283      IF( kt == nit000 ) THEN
284         IF(lwp) WRITE(numout,*)
285         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
286         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
287      ENDIF
288
289
290      ! Local constant initialization
291      zcoef0 = - grav * 0.5_wp
292
293      !  Surface value (also valid in partial step case)
294      DO jj = 2, jpjm1
295         DO ji = fs_2, fs_jpim1   ! vector opt.
296            zcoef1 = zcoef0 * fse3w(ji,jj,1)
297            ! hydrostatic pressure gradient
298            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
299            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
300            ! add to the general momentum trend
301            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
302            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
303         END DO
304      END DO
305
306
307      ! interior value (2=<jk=<jpkm1)
308      DO jk = 2, jpkm1
309         DO jj = 2, jpjm1
310            DO ji = fs_2, fs_jpim1   ! vector opt.
311               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
312               ! hydrostatic pressure gradient
313               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
314                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
315                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
316
317               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
318                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
319                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
320               ! add to the general momentum trend
321               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
322               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
323            END DO
324         END DO
325      END DO
326
327
328      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
329      DO jj = 2, jpjm1
330         DO ji = 2, jpim1
331            iku = mbku(ji,jj)
332            ikv = mbkv(ji,jj)
333            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
334            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
335            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
336               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
337               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
338                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
339               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
340            ENDIF
341            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
342               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
343               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
344                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
345               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
346            ENDIF
347         END DO
348      END DO
349      !
350      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
351      !
352   END SUBROUTINE hpg_zps
353
354   SUBROUTINE hpg_sco( kt )
355      !!---------------------------------------------------------------------
356      !!                  ***  ROUTINE hpg_sco  ***
357      !!
358      !! ** Method  :   s-coordinate case. Jacobian scheme.
359      !!      The now hydrostatic pressure gradient at a given level, jk,
360      !!      is computed by taking the vertical integral of the in-situ
361      !!      density gradient along the model level from the suface to that
362      !!      level. s-coordinates (ln_sco): a corrective term is added
363      !!      to the horizontal pressure gradient :
364      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
365      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
366      !!      add it to the general momentum trend (ua,va).
367      !!         ua = ua - 1/e1u * zhpi
368      !!         va = va - 1/e2v * zhpj
369      !!
370      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
371      !!----------------------------------------------------------------------
372      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
373      !!
374      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
375      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
376      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
377      !!----------------------------------------------------------------------
378      !
379      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
380      !
381      IF( kt == nit000 ) THEN
382         IF(lwp) WRITE(numout,*)
383         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
384         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
385      ENDIF
386
387      ! Local constant initialization
388      zcoef0 = - grav * 0.5_wp
389      ! To use density and not density anomaly
390      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
391      ELSE                 ;     znad = 0._wp         ! Fixed volume
392      ENDIF
393
394      ! Surface value
395      DO jj = 2, jpjm1
396         DO ji = fs_2, fs_jpim1   ! vector opt.
397            ! hydrostatic pressure gradient along s-surfaces
398            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
399               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
400            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
401               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
402            ! s-coordinate pressure gradient correction
403            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
404               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
405            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
406               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
407            ! add to the general momentum trend
408            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
409            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
410         END DO
411      END DO
412
413      ! interior value (2=<jk=<jpkm1)
414      DO jk = 2, jpkm1
415         DO jj = 2, jpjm1
416            DO ji = fs_2, fs_jpim1   ! vector opt.
417               ! hydrostatic pressure gradient along s-surfaces
418               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
419                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
420                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
421               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
422                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
423                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
424               ! s-coordinate pressure gradient correction
425               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
426                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
427               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
428                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
429               ! add to the general momentum trend
430               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
431               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
432            END DO
433         END DO
434      END DO
435      !
436      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
437      !
438   END SUBROUTINE hpg_sco
439
440   SUBROUTINE hpg_isf( kt )
441      !!---------------------------------------------------------------------
442      !!                  ***  ROUTINE hpg_sco  ***
443      !!
444      !! ** Method  :   s-coordinate case. Jacobian scheme.
445      !!      The now hydrostatic pressure gradient at a given level, jk,
446      !!      is computed by taking the vertical integral of the in-situ
447      !!      density gradient along the model level from the suface to that
448      !!      level. s-coordinates (ln_sco): a corrective term is added
449      !!      to the horizontal pressure gradient :
450      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
451      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
452      !!      add it to the general momentum trend (ua,va).
453      !!         ua = ua - 1/e1u * zhpi
454      !!         va = va - 1/e2v * zhpj
455      !!      iceload is added and partial cell case are added to the top and bottom
456      !!     
457      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
458      !!----------------------------------------------------------------------
459      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
460      !!
461      INTEGER  ::   ji, jj, jk, iku, ikv, ikt, iktp1i, iktp1j                 ! dummy loop indices
462      REAL(wp) ::   zcoef0, zuap, zvap, znad, ze3wu, ze3wv, zuapint, zvapint, zhpjint, zhpiint, zdzwt, zdzwtjp1, zdzwtip1             ! temporary scalars
463      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj, zrhd
464      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
465      REAL(wp), POINTER, DIMENSION(:,:)     ::  ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj
466      !!----------------------------------------------------------------------
467      !
468      CALL wrk_alloc( jpi,jpj, 2, ztstop) 
469      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
470      CALL wrk_alloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj) 
471      !
472     IF( kt == nit000 ) THEN
473         IF(lwp) WRITE(numout,*)
474         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
475         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
476      ENDIF
477
478      ! Local constant initialization
479      zcoef0 = - grav * 0.5_wp
480      ! To use density and not density anomaly
481!      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
482!      ELSE                 ;     znad = 0._wp         ! Fixed volume
483!      ENDIF
484      znad=1._wp
485      ! iniitialised to 0. zhpi zhpi
486      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
487
488!==================================================================================     
489!=====Compute iceload and contribution of the half first wet layer =================
490!===================================================================================
491
492      ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
493      ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
494
495      ! compute density of the water displaced by the ice shelf
496      zrhd = rhd ! save rhd
497      DO jk = 1, jpk
498           zdept(:,:)=gdept_1d(jk)
499           CALL eos(ztstop(:,:,:),zdept(:,:),rhd(:,:,jk))
500      END DO
501      WHERE ( tmask(:,:,:) == 1._wp)
502        rhd(:,:,:) = zrhd(:,:,:) ! replace wet cell by the saved rhd
503      END WHERE
504     
505      ! compute rhd at the ice/oce interface (ice shelf side)
506      CALL eos(ztstop,risfdep,zrhdtop_isf)
507
508      ! compute rhd at the ice/oce interface (ocean side)
509      DO ji=1,jpi
510        DO jj=1,jpj
511          ikt=mikt(ji,jj)
512          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
513          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
514        END DO
515      END DO
516      CALL eos(ztstop,risfdep,zrhdtop_oce)
517      !
518      ! Surface value + ice shelf gradient
519      ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
520      ziceload = 0._wp
521      DO jj = 1, jpj
522         DO ji = 1, jpi   ! vector opt.
523            ikt=mikt(ji,jj)
524            ziceload(ji,jj) = ziceload(ji,jj) + (znad + rhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
525            DO jk=2,ikt-1
526               ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + rhd(ji,jj,jk-1) + rhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
527                  &                              * (1._wp - tmask(ji,jj,jk))
528            END DO
529            IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + rhd(ji,jj,ikt-1)) &
530                               &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
531         END DO
532      END DO
533      riceload(:,:) = 0.0_wp ; riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
534      ! compute zp from z=0 to first T wet point (correction due to zps not yet applied)
535      DO jj = 2, jpjm1
536         DO ji = fs_2, fs_jpim1   ! vector opt.
537            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
538            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
539            ! we assume ISF is in isostatic equilibrium
540            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
541               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
542               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
543               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
544               &                                  + ( ziceload(ji+1,jj) - ziceload(ji,jj))                              ) 
545            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
546               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
547               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    & 
548               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
549               &                                  + ( ziceload(ji,jj+1) - ziceload(ji,jj) )                             ) 
550            ! s-coordinate pressure gradient correction (=0 if z coordinate)
551            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
552               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
553            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
554               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
555            ! add to the general momentum trend
556            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
557            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
558         END DO
559      END DO
560!==================================================================================     
561!===== Compute partial cell contribution for the top cell =========================
562!==================================================================================
563      DO jj = 2, jpjm1
564         DO ji = fs_2, fs_jpim1   ! vector opt.
565            iku = miku(ji,jj) ; 
566            zpshpi(ji,jj)=0.0_wp ; zpshpj(ji,jj)=0.0_wp
567            ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
568            ! u direction
569            IF ( iku .GT. 1 ) THEN
570               ! case iku
571               zhpi(ji,jj,iku)   =  zcoef0 / e1u(ji,jj) * ze3wu                                            &
572                      &                                 * ( rhd    (ji+1,jj,iku) + rhd   (ji,jj,iku)       &
573                      &                                   + SIGN(1._wp,ze3wu) * grui(ji,jj) + 2._wp * znad )
574               ! corrective term ( = 0 if z coordinate )
575               zuap              = -zcoef0 * ( arui(ji,jj) + 2._wp * znad ) * gzui(ji,jj) / e1u(ji,jj)
576               ! zhpi will be added in interior loop
577               ua(ji,jj,iku)     = ua(ji,jj,iku) + zuap
578               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
579               IF (mbku(ji,jj) == iku + 1) zpshpi(ji,jj)  = zhpi(ji,jj,iku)
580
581               ! case iku + 1 (remove the zphi term added in the interior loop and compute the one corrected for zps)
582               zhpiint        =  zcoef0 / e1u(ji,jj)                                                               &   
583                  &           * (  fse3w(ji+1,jj  ,iku+1) * ( (rhd(ji+1,jj,iku+1) + znad)                          &
584                  &                                         + (rhd(ji+1,jj,iku  ) + znad) ) * tmask(ji+1,jj,iku)   &
585                  &              - fse3w(ji  ,jj  ,iku+1) * ( (rhd(ji  ,jj,iku+1) + znad)                          &
586                  &                                         + (rhd(ji  ,jj,iku  ) + znad) ) * tmask(ji  ,jj,iku)   )
587               zhpi(ji,jj,iku+1) =  zcoef0 / e1u(ji,jj) * ge3rui(ji,jj) - zhpiint 
588            END IF
589               
590            ! v direction
591            ikv = mikv(ji,jj)
592            ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
593            IF ( ikv .GT. 1 ) THEN
594               ! case ikv
595               zhpj(ji,jj,ikv)   =  zcoef0 / e2v(ji,jj) * ze3wv                                            &
596                     &                                  * ( rhd(ji,jj+1,ikv) + rhd   (ji,jj,ikv)           &
597                     &                                    + SIGN(1._wp,ze3wv) * grvi(ji,jj) + 2._wp * znad )
598               ! corrective term ( = 0 if z coordinate )
599               zvap              = -zcoef0 * ( arvi(ji,jj) + 2._wp * znad ) * gzvi(ji,jj) / e2v(ji,jj)
600               ! zhpi will be added in interior loop
601               va(ji,jj,ikv)      = va(ji,jj,ikv) + zvap
602               ! in case of 2 cell water column, need to save the pressure gradient to compute the bottom pressure 
603               IF (mbkv(ji,jj) == ikv + 1)  zpshpj(ji,jj)  =  zhpj(ji,jj,ikv) 
604               
605               ! case ikv + 1 (remove the zphj term added in the interior loop and compute the one corrected for zps)
606               zhpjint        =  zcoef0 / e2v(ji,jj)                                                              &
607                  &           * (  fse3w(ji  ,jj+1,ikv+1) * ( (rhd(ji,jj+1,ikv+1) + znad)                         &
608                  &                                       + (rhd(ji,jj+1,ikv  ) + znad) ) * tmask(ji,jj+1,ikv)    &
609                  &              - fse3w(ji  ,jj  ,ikv+1) * ( (rhd(ji,jj  ,ikv+1) + znad)                         &
610                  &                                       + (rhd(ji,jj  ,ikv  ) + znad) ) * tmask(ji,jj  ,ikv)  )
611               zhpj(ji,jj,ikv+1) =  zcoef0 / e2v(ji,jj) * ge3rvi(ji,jj) - zhpjint
612            END IF
613         END DO
614      END DO
615
616!==================================================================================     
617!===== Compute interior value =====================================================
618!==================================================================================
619
620      DO jj = 2, jpjm1
621         DO ji = fs_2, fs_jpim1   ! vector opt.
622            iku=miku(ji,jj); ikv=mikv(ji,jj)
623            DO jk = 2, jpkm1
624               ! hydrostatic pressure gradient along s-surfaces
625               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
626               zhpi(ji,jj,jk) = zhpi(ji,jj,jk) + zhpi(ji,jj,jk-1)                                                              &
627                  &                            + zcoef0 / e1u(ji,jj)                                                           &
628                  &                                     * ( fse3w(ji+1,jj  ,jk) * ( (rhd(ji+1,jj,jk  ) + znad)                 &
629                  &                                                     + (rhd(ji+1,jj,jk-1) + znad) ) * tmask(ji+1,jj,jk-1)   &
630                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji  ,jj,jk  ) + znad)                 &
631                  &                                                     + (rhd(ji  ,jj,jk-1) + znad) ) * tmask(ji  ,jj,jk-1)   ) 
632               ! s-coordinate pressure gradient correction
633               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
634               zuap = - zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                    &
635                  &            * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj) * umask(ji,jj,jk-1)
636               ua(ji,jj,jk) = ua(ji,jj,jk) + ( zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
637
638               ! hydrostatic pressure gradient along s-surfaces
639               ! zhpi is masked for the first wet cell  (contribution already done in the upper bloc)
640               zhpj(ji,jj,jk) = zhpj(ji,jj,jk) + zhpj(ji,jj,jk-1)                                                              &
641                  &                            + zcoef0 / e2v(ji,jj)                                                           &
642                  &                                     * ( fse3w(ji  ,jj+1,jk) * ( (rhd(ji,jj+1,jk  ) + znad)                 &
643                  &                                                     + (rhd(ji,jj+1,jk-1) + znad) ) * tmask(ji,jj+1,jk-1)   &
644                  &                                       - fse3w(ji  ,jj  ,jk) * ( (rhd(ji,jj  ,jk  ) + znad)                 &
645                  &                                                     + (rhd(ji,jj  ,jk-1) + znad) ) * tmask(ji,jj  ,jk-1)   )
646               ! s-coordinate pressure gradient correction
647               ! corrective term, we mask this term for the first wet level beneath the ice shelf (contribution done in the upper bloc)
648               zvap = - zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )                     &
649                  &            * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj) * vmask(ji,jj,jk-1)
650               ! add to the general momentum trend
651               va(ji,jj,jk) = va(ji,jj,jk) + ( zhpj(ji,jj,jk) + zvap ) * vmask(ji,jj,jk)
652            END DO
653         END DO
654      END DO
655
656!==================================================================================     
657!===== Compute bottom cell contribution (partial cell) ============================
658!==================================================================================
659
660      DO jj = 2, jpjm1
661         DO ji = 2, jpim1
662            iku = mbku(ji,jj)
663            ikv = mbkv(ji,jj)
664
665            IF (iku .GT. 1) THEN
666               ! remove old value (interior case)
667               zuap            = -zcoef0 * ( rhd   (ji+1,jj  ,iku) + rhd   (ji,jj,iku) + 2._wp * znad )   &
668                     &                   * ( fsde3w(ji+1,jj  ,iku) - fsde3w(ji,jj,iku) ) / e1u(ji,jj)
669               ua(ji,jj,iku)   = ua(ji,jj,iku) - zhpi(ji,jj,iku) - zuap
670               ! put new value
671               ! -zpshpi to avoid double contribution of the partial step in the top layer
672               zuap            = -zcoef0 * ( aru(ji,jj) + 2._wp * znad ) * gzu(ji,jj)  / e1u(ji,jj)
673               zhpi(ji,jj,iku) =  zhpi(ji,jj,iku-1) + zcoef0 / e1u(ji,jj) * ge3ru(ji,jj) - zpshpi(ji,jj) 
674               ua(ji,jj,iku)   =  ua(ji,jj,iku) + zhpi(ji,jj,iku) + zuap
675            END IF
676            ! v direction
677            IF (ikv .GT. 1) THEN
678               ! remove old value (interior case)
679               zvap            = -zcoef0 * ( rhd   (ji  ,jj+1,ikv) + rhd   (ji,jj,ikv) + 2._wp * znad )   &
680                     &                   * ( fsde3w(ji  ,jj+1,ikv) - fsde3w(ji,jj,ikv) )   / e2v(ji,jj)
681               va(ji,jj,ikv)   = va(ji,jj,ikv) - zhpj(ji,jj,ikv) - zvap
682               ! put new value
683               ! -zpshpj to avoid double contribution of the partial step in the top layer
684               zvap            = -zcoef0 * ( arv(ji,jj) + 2._wp * znad ) * gzv(ji,jj)     / e2v(ji,jj)
685               zhpj(ji,jj,ikv) =  zhpj(ji,jj,ikv-1) + zcoef0 / e2v(ji,jj) * ge3rv(ji,jj) - zpshpj(ji,jj)   
686               va(ji,jj,ikv)   =  va(ji,jj,ikv) + zhpj(ji,jj,ikv) + zvap
687            END IF
688         END DO
689      END DO
690     
691      ! set back to original density value into the ice shelf cell (maybe useless because it is masked)
692      rhd = zrhd
693      !
694      CALL wrk_dealloc( jpi,jpj,2, ztstop)
695      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj, zrhd)
696      CALL wrk_dealloc( jpi,jpj, ze3w, zp, zrhdtop_isf, zrhdtop_oce, ziceload, zdept, zpshpi, zpshpj)
697      !
698   END SUBROUTINE hpg_isf
699
700
701   SUBROUTINE hpg_djc( kt )
702      !!---------------------------------------------------------------------
703      !!                  ***  ROUTINE hpg_djc  ***
704      !!
705      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
706      !!
707      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
708      !!----------------------------------------------------------------------
709      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
710      !!
711      INTEGER  ::   ji, jj, jk          ! dummy loop indices
712      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
713      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
714      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
715      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
716      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
717      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
718      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
719      !!----------------------------------------------------------------------
720      !
721      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
722      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
723      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
724      !
725
726      IF( kt == nit000 ) THEN
727         IF(lwp) WRITE(numout,*)
728         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
729         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
730      ENDIF
731
732      ! Local constant initialization
733      zcoef0 = - grav * 0.5_wp
734      z1_10  = 1._wp / 10._wp
735      z1_12  = 1._wp / 12._wp
736
737      !----------------------------------------------------------------------------------------
738      !  compute and store in provisional arrays elementary vertical and horizontal differences
739      !----------------------------------------------------------------------------------------
740
741!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
742
743      DO jk = 2, jpkm1
744         DO jj = 2, jpjm1
745            DO ji = fs_2, fs_jpim1   ! vector opt.
746               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
747               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
748               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
749               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
750               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
751               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
752            END DO
753         END DO
754      END DO
755
756      !-------------------------------------------------------------------------
757      ! compute harmonic averages using eq. 5.18
758      !-------------------------------------------------------------------------
759      zep = 1.e-15
760
761!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
762!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
763
764      DO jk = 2, jpkm1
765         DO jj = 2, jpjm1
766            DO ji = fs_2, fs_jpim1   ! vector opt.
767               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
768
769               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
770               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
771
772               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
773               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
774
775               IF( cffw > zep) THEN
776                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
777                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
778               ELSE
779                  drhow(ji,jj,jk) = 0._wp
780               ENDIF
781
782               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
783                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
784
785               IF( cffu > zep ) THEN
786                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
787                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
788               ELSE
789                  drhou(ji,jj,jk ) = 0._wp
790               ENDIF
791
792               IF( cffx > zep ) THEN
793                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
794                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
795               ELSE
796                  dzu(ji,jj,jk) = 0._wp
797               ENDIF
798
799               IF( cffv > zep ) THEN
800                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
801                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
802               ELSE
803                  drhov(ji,jj,jk) = 0._wp
804               ENDIF
805
806               IF( cffy > zep ) THEN
807                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
808                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
809               ELSE
810                  dzv(ji,jj,jk) = 0._wp
811               ENDIF
812
813            END DO
814         END DO
815      END DO
816
817      !----------------------------------------------------------------------------------
818      ! apply boundary conditions at top and bottom using 5.36-5.37
819      !----------------------------------------------------------------------------------
820      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
821      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
822      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
823
824      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
825      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
826      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
827
828
829      !--------------------------------------------------------------
830      ! Upper half of top-most grid box, compute and store
831      !-------------------------------------------------------------
832
833!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
834!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
835
836      DO jj = 2, jpjm1
837         DO ji = fs_2, fs_jpim1   ! vector opt.
838            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
839               &                   * (  rhd(ji,jj,1)                                    &
840               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
841               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
842               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
843         END DO
844      END DO
845
846!!bug gm    : here also, simplification is possible
847!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
848
849      DO jk = 2, jpkm1
850         DO jj = 2, jpjm1
851            DO ji = fs_2, fs_jpim1   ! vector opt.
852
853               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
854                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
855                  &            - grav * z1_10 * (                                                                     &
856                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
857                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
858                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
859                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
860                  &                             )
861
862               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
863                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
864                  &            - grav* z1_10 * (                                                                      &
865                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
866                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
867                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
868                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
869                  &                            )
870
871               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
872                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
873                  &            - grav* z1_10 * (                                                                      &
874                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
875                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
876                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
877                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
878                  &                            )
879
880            END DO
881         END DO
882      END DO
883      CALL lbc_lnk(rho_k,'W',1.)
884      CALL lbc_lnk(rho_i,'U',1.)
885      CALL lbc_lnk(rho_j,'V',1.)
886
887
888      ! ---------------
889      !  Surface value
890      ! ---------------
891      DO jj = 2, jpjm1
892         DO ji = fs_2, fs_jpim1   ! vector opt.
893            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
894            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
895            ! add to the general momentum trend
896            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
897            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
898         END DO
899      END DO
900
901      ! ----------------
902      !  interior value   (2=<jk=<jpkm1)
903      ! ----------------
904      DO jk = 2, jpkm1
905         DO jj = 2, jpjm1
906            DO ji = fs_2, fs_jpim1   ! vector opt.
907               ! hydrostatic pressure gradient along s-surfaces
908               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
909                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
910                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
911               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
912                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
913                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
914               ! add to the general momentum trend
915               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
916               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
917            END DO
918         END DO
919      END DO
920      !
921      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
922      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
923      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
924      !
925   END SUBROUTINE hpg_djc
926
927
928   SUBROUTINE hpg_prj( kt )
929      !!---------------------------------------------------------------------
930      !!                  ***  ROUTINE hpg_prj  ***
931      !!
932      !! ** Method  :   s-coordinate case.
933      !!      A Pressure-Jacobian horizontal pressure gradient method
934      !!      based on the constrained cubic-spline interpolation for
935      !!      all vertical coordinate systems
936      !!
937      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
938      !!----------------------------------------------------------------------
939      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
940      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
941      !!
942      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
943      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
944      !!
945      !! The local variables for the correction term
946      INTEGER  :: jk1, jis, jid, jjs, jjd
947      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
948      REAL(wp) :: zrhdt1
949      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
950      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
951      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
952      !!----------------------------------------------------------------------
953      !
954      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
955      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
956      !
957      IF( kt == nit000 ) THEN
958         IF(lwp) WRITE(numout,*)
959         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
960         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
961      ENDIF
962
963      !!----------------------------------------------------------------------
964      ! Local constant initialization
965      zcoef0 = - grav
966      znad = 0.0_wp
967      IF( lk_vvl ) znad = 1._wp
968
969      ! Clean 3-D work arrays
970      zhpi(:,:,:) = 0._wp
971      zrhh(:,:,:) = rhd(:,:,:)
972
973      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
974      DO jj = 1, jpj
975        DO ji = 1, jpi
976          jk = mbathy(ji,jj)
977          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
978          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
979          ELSE IF(jk < jpkm1) THEN
980             DO jkk = jk+1, jpk
981                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
982                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
983             END DO
984          ENDIF
985        END DO
986      END DO
987
988      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
989      DO jj = 1, jpj
990         DO ji = 1, jpi
991            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
992         END DO
993      END DO
994
995      DO jk = 2, jpk
996         DO jj = 1, jpj
997            DO ji = 1, jpi
998               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
999            END DO
1000         END DO
1001      END DO
1002
1003      fsp(:,:,:) = zrhh (:,:,:)
1004      xsp(:,:,:) = zdept(:,:,:)
1005
1006      ! Construct the vertical density profile with the
1007      ! constrained cubic spline interpolation
1008      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
1009      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
1010
1011      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1012      DO jj = 2, jpj
1013        DO ji = 2, jpi
1014          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
1015                                         bsp(ji,jj,1),   csp(ji,jj,1), &
1016                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
1017
1018          ! assuming linear profile across the top half surface layer
1019          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
1020        END DO
1021      END DO
1022
1023      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1024      DO jk = 2, jpkm1
1025        DO jj = 2, jpj
1026          DO ji = 2, jpi
1027            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
1028                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
1029                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
1030                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
1031          END DO
1032        END DO
1033      END DO
1034
1035      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1036      DO jj = 2, jpjm1
1037        DO ji = 2, jpim1
1038          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshu_n for ztilde compilation
1039          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - sshn(ji,jj) * znad)    ! probable bug: changed from sshv_n for ztilde compilation
1040        END DO
1041      END DO
1042
1043      DO jk = 2, jpkm1
1044        DO jj = 2, jpjm1
1045          DO ji = 2, jpim1
1046            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
1047            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
1048          END DO
1049        END DO
1050      END DO
1051
1052      DO jk = 1, jpkm1
1053        DO jj = 2, jpjm1
1054          DO ji = 2, jpim1
1055            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
1056            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
1057          END DO
1058        END DO
1059      END DO
1060
1061      DO jk = 1, jpkm1
1062        DO jj = 2, jpjm1
1063          DO ji = 2, jpim1
1064            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1065            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
1066            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1067            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
1068          END DO
1069        END DO
1070      END DO
1071
1072
1073      DO jk = 1, jpkm1
1074        DO jj = 2, jpjm1
1075          DO ji = 2, jpim1
1076            zpwes = 0._wp; zpwed = 0._wp
1077            zpnss = 0._wp; zpnsd = 0._wp
1078            zuijk = zu(ji,jj,jk)
1079            zvijk = zv(ji,jj,jk)
1080
1081            !!!!!     for u equation
1082            IF( jk <= mbku(ji,jj) ) THEN
1083               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1084                 jis = ji + 1; jid = ji
1085               ELSE
1086                 jis = ji;     jid = ji +1
1087               ENDIF
1088
1089               ! integrate the pressure on the shallow side
1090               jk1 = jk
1091               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1092                 IF( jk1 == mbku(ji,jj) ) THEN
1093                   zuijk = -zdept(jis,jj,jk1)
1094                   EXIT
1095                 ENDIF
1096                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1097                 zpwes = zpwes +                                    &
1098                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1099                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1100                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1101                 jk1 = jk1 + 1
1102               END DO
1103
1104               ! integrate the pressure on the deep side
1105               jk1 = jk
1106               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1107                 IF( jk1 == 1 ) THEN
1108                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1109                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1110                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1111                                                     dsp(jid,jj,1)) * zdeps
1112                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1113                   EXIT
1114                 ENDIF
1115                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1116                 zpwed = zpwed +                                        &
1117                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1118                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1119                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1120                 jk1 = jk1 - 1
1121               END DO
1122
1123               ! update the momentum trends in u direction
1124
1125               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1126               IF( lk_vvl ) THEN
1127                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1128                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1129                ELSE
1130                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1131               ENDIF
1132
1133               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1134               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1135            ENDIF
1136
1137            !!!!!     for v equation
1138            IF( jk <= mbkv(ji,jj) ) THEN
1139               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1140                 jjs = jj + 1; jjd = jj
1141               ELSE
1142                 jjs = jj    ; jjd = jj + 1
1143               ENDIF
1144
1145               ! integrate the pressure on the shallow side
1146               jk1 = jk
1147               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1148                 IF( jk1 == mbkv(ji,jj) ) THEN
1149                   zvijk = -zdept(ji,jjs,jk1)
1150                   EXIT
1151                 ENDIF
1152                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1153                 zpnss = zpnss +                                      &
1154                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1155                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1156                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1157                 jk1 = jk1 + 1
1158               END DO
1159
1160               ! integrate the pressure on the deep side
1161               jk1 = jk
1162               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1163                 IF( jk1 == 1 ) THEN
1164                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1165                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1166                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1167                                                     dsp(ji,jjd,1) ) * zdeps
1168                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1169                   EXIT
1170                 ENDIF
1171                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1172                 zpnsd = zpnsd +                                        &
1173                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1174                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1175                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1176                 jk1 = jk1 - 1
1177               END DO
1178
1179
1180               ! update the momentum trends in v direction
1181
1182               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1183               IF( lk_vvl ) THEN
1184                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1185                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1186               ELSE
1187                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1188               ENDIF
1189
1190               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1191               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1192            ENDIF
1193
1194
1195           END DO
1196        END DO
1197      END DO
1198      !
1199      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1200      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1201      !
1202   END SUBROUTINE hpg_prj
1203
1204
1205   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1206      !!----------------------------------------------------------------------
1207      !!                 ***  ROUTINE cspline  ***
1208      !!
1209      !! ** Purpose :   constrained cubic spline interpolation
1210      !!
1211      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1212      !!
1213      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1214      !!----------------------------------------------------------------------
1215      IMPLICIT NONE
1216      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1217      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1218                                                                    ! the interpoated function
1219      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1220                                                                    ! 2: Linear
1221      !
1222      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1223      INTEGER  ::   jpi, jpj, jpkm1
1224      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1225      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1226      REAL(wp) ::   zdf(size(fsp,3))
1227      !!----------------------------------------------------------------------
1228
1229      jpi   = size(fsp,1)
1230      jpj   = size(fsp,2)
1231      jpkm1 = size(fsp,3) - 1
1232
1233
1234      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1235         DO ji = 1, jpi
1236            DO jj = 1, jpj
1237           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1238           !    DO jk = 2, jpkm1-1
1239           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1240           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1241           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1242           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1243           !
1244           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1245           !
1246           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1247           !           zdf(jk) = 0._wp
1248           !       ELSE
1249           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1250           !       ENDIF
1251           !    END DO
1252
1253           !!Simply geometric average
1254               DO jk = 2, jpkm1-1
1255                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1256                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1257
1258                  IF(zdf1 * zdf2 <= 0._wp) THEN
1259                     zdf(jk) = 0._wp
1260                  ELSE
1261                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1262                  ENDIF
1263               END DO
1264
1265               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1266                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1267               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1268                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1269                          & 0.5_wp * zdf(jpkm1 - 1)
1270
1271               DO jk = 1, jpkm1 - 1
1272                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1273                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1274                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1275                 zddf1  = -2._wp * ztmp1 + ztmp2
1276                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1277                 zddf2  =  2._wp * ztmp1 - ztmp2
1278
1279                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1280                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1281                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1282                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1283                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1284                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1285                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1286                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1287                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1288               END DO
1289            END DO
1290         END DO
1291
1292      ELSE IF (polynomial_type == 2) THEN     ! Linear
1293         DO ji = 1, jpi
1294            DO jj = 1, jpj
1295               DO jk = 1, jpkm1-1
1296                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1297                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1298
1299                  dsp(ji,jj,jk) = 0._wp
1300                  csp(ji,jj,jk) = 0._wp
1301                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1302                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1303               END DO
1304            END DO
1305         END DO
1306
1307      ELSE
1308           CALL ctl_stop( 'invalid polynomial type in cspline' )
1309      ENDIF
1310
1311   END SUBROUTINE cspline
1312
1313
1314   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1315      !!----------------------------------------------------------------------
1316      !!                 ***  ROUTINE interp1  ***
1317      !!
1318      !! ** Purpose :   1-d linear interpolation
1319      !!
1320      !! ** Method  :   interpolation is straight forward
1321      !!                extrapolation is also permitted (no value limit)
1322      !!----------------------------------------------------------------------
1323      IMPLICIT NONE
1324      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1325      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1326      REAL(wp)             ::  zdeltx
1327      !!----------------------------------------------------------------------
1328
1329      zdeltx = xr - xl
1330      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1331        f = 0.5_wp * (fl + fr)
1332      ELSE
1333        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1334      ENDIF
1335
1336   END FUNCTION interp1
1337
1338
1339   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1340      !!----------------------------------------------------------------------
1341      !!                 ***  ROUTINE interp1  ***
1342      !!
1343      !! ** Purpose :   1-d constrained cubic spline interpolation
1344      !!
1345      !! ** Method  :  cubic spline interpolation
1346      !!
1347      !!----------------------------------------------------------------------
1348      IMPLICIT NONE
1349      REAL(wp), INTENT(in) ::  x, a, b, c, d
1350      REAL(wp)             ::  f ! value from the interpolation
1351      !!----------------------------------------------------------------------
1352
1353      f = a + x* ( b + x * ( c + d * x ) )
1354
1355   END FUNCTION interp2
1356
1357
1358   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1359      !!----------------------------------------------------------------------
1360      !!                 ***  ROUTINE interp1  ***
1361      !!
1362      !! ** Purpose :   Calculate the first order of deriavtive of
1363      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1364      !!
1365      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1366      !!
1367      !!----------------------------------------------------------------------
1368      IMPLICIT NONE
1369      REAL(wp), INTENT(in) ::  x, a, b, c, d
1370      REAL(wp)             ::  f ! value from the interpolation
1371      !!----------------------------------------------------------------------
1372
1373      f = b + x * ( 2._wp * c + 3._wp * d * x)
1374
1375   END FUNCTION interp3
1376
1377
1378   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1379      !!----------------------------------------------------------------------
1380      !!                 ***  ROUTINE interp1  ***
1381      !!
1382      !! ** Purpose :   1-d constrained cubic spline integration
1383      !!
1384      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1385      !!
1386      !!----------------------------------------------------------------------
1387      IMPLICIT NONE
1388      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1389      REAL(wp)             ::  za1, za2, za3
1390      REAL(wp)             ::  f                   ! integration result
1391      !!----------------------------------------------------------------------
1392
1393      za1 = 0.5_wp * b
1394      za2 = c / 3.0_wp
1395      za3 = 0.25_wp * d
1396
1397      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1398         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1399
1400   END FUNCTION integ_spline
1401
1402   !!======================================================================
1403END MODULE dynhpg
1404
Note: See TracBrowser for help on using the repository browser.