source: branches/2015/dev_r5094_UKMO_ISFCLEAN/NEMOGCM/NEMO/OPA_SRC/SBC/sbcssm.F90 @ 5111

Last change on this file since 5111 was 5111, checked in by mathiot, 6 years ago

add some missing if ln_isfcav, test of option compatibility with ln_isfcav + small documentation

  • Property svn:keywords set to Id
File size: 11.9 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   sbc_ssm        : calculate sea surface mean currents, temperature, 
12   !!                    and salinity over nn_fsbc time-step
13   !!----------------------------------------------------------------------
14   USE oce             ! ocean dynamics and tracers
15   USE dom_oce         ! ocean space and time domain
16   USE sbc_oce         ! surface boundary condition: ocean fields
17   USE sbcapr          ! surface boundary condition: atmospheric pressure
18   USE eosbn2          ! equation of state and related derivatives
19   !
20   USE in_out_manager  ! I/O manager
21   USE prtctl          ! Print control
22   USE iom             ! IOM library
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   sbc_ssm         ! routine called by step.F90
28   PUBLIC   sbc_ssm_init    ! routine called by sbcmod.F90
29
30   LOGICAL, SAVE  ::   l_ssm_mean = .FALSE.       ! keep track of whether means have been read
31                                                  ! from restart file
32   
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35   !!----------------------------------------------------------------------
36   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
37   !! $Id$
38   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
39   !!----------------------------------------------------------------------
40CONTAINS
41
42   SUBROUTINE sbc_ssm( kt )
43      !!---------------------------------------------------------------------
44      !!                     ***  ROUTINE sbc_oce  ***
45      !!                     
46      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
47      !!                condition computation
48      !!               
49      !! ** Method  :   compute mean surface velocity (2 components at U and
50      !!      V-points) [m/s], temperature [Celcius] and salinity [psu] over
51      !!      the periode (kt - nn_fsbc) to kt
52      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
53      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
54      !!---------------------------------------------------------------------
55      INTEGER, INTENT(in) ::   kt   ! ocean time step
56      !
57      INTEGER  ::   ji, jj               ! loop index
58      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
59      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
60      REAL(wp), DIMENSION(jpi,jpj)      :: zub, zvb,zdep
61      !!---------------------------------------------------------------------
62     
63      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
64      DO jj = 1, jpj
65         DO ji = 1, jpi
66            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
67            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
68         END DO
69      END DO
70      zub(:,:)        = ub (:,:,1       )
71      zvb(:,:)        = vb (:,:,1       )
72      !
73      IF( lk_vvl ) THEN
74         zdep(:,:) = fse3t_n(:,:,1)
75      ENDIF
76      !                                                   ! ---------------------------------------- !
77      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
78         !                                                ! ---------------------------------------- !
79         ssu_m(:,:) = zub(:,:)
80         ssv_m(:,:) = zvb(:,:)
81         IF( ln_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
82         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
83         ENDIF
84         sss_m(:,:) = zts(:,:,jp_sal)
85         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
86         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
87         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
88         ENDIF
89         !
90         IF( lk_vvl )   fse3t_m(:,:) = zdep(:,:)
91         !
92      ELSE
93         !                                                ! ----------------------------------------------- !
94         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
95            !                                             ! ----------------------------------------------- !
96            IF(lwp) WRITE(numout,*)
97            IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields initialised to instantaneous values'
98            zcoef = REAL( nn_fsbc - 1, wp )
99            ssu_m(:,:) = zcoef * zub(:,:)
100            ssv_m(:,:) = zcoef * zvb(:,:)
101            IF( ln_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
102            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
103            ENDIF
104            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
105            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
106            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
107            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
108            ENDIF
109            !
110            IF( lk_vvl )   fse3t_m(:,:) = zcoef * zdep(:,:)
111            !                                             ! ---------------------------------------- !
112         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
113            !                                             ! ---------------------------------------- !
114            ssu_m(:,:) = 0.e0      ! reset to zero ocean mean sbc fields
115            ssv_m(:,:) = 0.e0
116            sst_m(:,:) = 0.e0
117            sss_m(:,:) = 0.e0
118            ssh_m(:,:) = 0.e0
119            IF( lk_vvl )   fse3t_m(:,:) = 0.e0
120         ENDIF
121         !                                                ! ---------------------------------------- !
122         !                                                !        Cumulate at each time step        !
123         !                                                ! ---------------------------------------- !
124         ssu_m(:,:) = ssu_m(:,:) + zub(:,:)
125         ssv_m(:,:) = ssv_m(:,:) + zvb(:,:)
126         IF( ln_useCT )  THEN    ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
127         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
128         ENDIF
129         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
130         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
131         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
132         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
133         ENDIF
134         !
135         IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) + zdep(:,:)
136
137         !                                                ! ---------------------------------------- !
138         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
139            !                                             ! ---------------------------------------- !
140            zcoef = 1. / REAL( nn_fsbc, wp )
141            sst_m(:,:) = sst_m(:,:) * zcoef           ! mean SST             [Celcius]
142            sss_m(:,:) = sss_m(:,:) * zcoef           ! mean SSS             [psu]
143            ssu_m(:,:) = ssu_m(:,:) * zcoef           ! mean suface current  [m/s]
144            ssv_m(:,:) = ssv_m(:,:) * zcoef           !
145            ssh_m(:,:) = ssh_m(:,:) * zcoef           ! mean SSH             [m]
146            IF( lk_vvl )   fse3t_m(:,:) = fse3t_m(:,:) * zcoef   ! mean vertical scale factor [m]
147            !
148         ENDIF
149         !                                                ! ---------------------------------------- !
150         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
151            !                                             ! ---------------------------------------- !
152            IF(lwp) WRITE(numout,*)
153            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
154               &                    'at it= ', kt,' date= ', ndastp
155            IF(lwp) WRITE(numout,*) '~~~~~~~'
156            zf_sbc = REAL( nn_fsbc, wp )
157            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc )    ! sbc frequency
158            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m  )    ! sea surface mean fields
159            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m  )
160            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m  )
161            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m  )
162            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m  )
163            IF( lk_vvl ) THEN
164               CALL iom_rstput( kt, nitrst, numrow, 'fse3t_m'  , fse3t_m(:,:)  )
165            END IF
166            !
167         ENDIF
168         !
169      ENDIF
170      !
171   END SUBROUTINE sbc_ssm
172
173   SUBROUTINE sbc_ssm_init
174      !!----------------------------------------------------------------------
175      !!                  ***  ROUTINE sbc_ssm_init  ***
176      !!
177      !! ** Purpose :   Initialisation of the sbc data
178      !!
179      !! ** Action  : - read parameters
180      !!----------------------------------------------------------------------
181      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
182      !!----------------------------------------------------------------------
183
184      IF( nn_fsbc == 1 ) THEN
185         !
186         IF(lwp) WRITE(numout,*)
187         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields, nn_fsbc=1 : instantaneous values'
188         IF(lwp) WRITE(numout,*) '~~~~~~~ '
189         !
190      ELSE
191         !               
192         IF(lwp) WRITE(numout,*)
193         IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields'
194         IF(lwp) WRITE(numout,*) '~~~~~~~ '
195         !
196         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
197            l_ssm_mean = .TRUE.
198            CALL iom_get( numror               , 'nn_fsbc', zf_sbc )   ! sbc frequency of previous run
199            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m  )   ! sea surface mean velocity    (T-point)
200            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m  )   !   "         "    velocity    (V-point)
201            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m  )   !   "         "    temperature (T-point)
202            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m  )   !   "         "    salinity    (T-point)
203            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m  )   !   "         "    height      (T-point)
204            IF( lk_vvl ) CALL iom_get( numror, jpdom_autoglo, 'fse3t_m', fse3t_m(:,:) )
205            !
206            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
207               IF(lwp) WRITE(numout,*) '~~~~~~~   restart with a change in the frequency of mean ',   &
208                  &                    'from ', zf_sbc, ' to ', nn_fsbc 
209               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
210               ssu_m(:,:) = zcoef * ssu_m(:,:) 
211               ssv_m(:,:) = zcoef * ssv_m(:,:)
212               sst_m(:,:) = zcoef * sst_m(:,:)
213               sss_m(:,:) = zcoef * sss_m(:,:)
214               ssh_m(:,:) = zcoef * ssh_m(:,:)
215               IF( lk_vvl ) fse3t_m(:,:) = zcoef * fse3t_m(:,:)
216            ELSE
217               IF(lwp) WRITE(numout,*) '~~~~~~~   mean fields read in the ocean restart file'
218            ENDIF
219         ENDIF
220      ENDIF
221      !
222   END SUBROUTINE sbc_ssm_init
223
224   !!======================================================================
225END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.