source: branches/2015/dev_r5094_UKMO_ISFCLEAN/NEMOGCM/NEMO/OPA_SRC/TRA/traadv_tvd.F90 @ 5098

Last change on this file since 5098 was 5098, checked in by mathiot, 6 years ago

add wmask, wumask, wvmask and restore loop order and add flag to ignore specific isf code if no isf

  • Property svn:keywords set to Id
File size: 31.9 KB
Line 
1MODULE traadv_tvd
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_tvd  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!==============================================================================
6   !! History :  OPA  !  1995-12  (L. Mortier)  Original code
7   !!                 !  2000-01  (H. Loukos)  adapted to ORCA
8   !!                 !  2000-10  (MA Foujols E.Kestenare)  include file not routine
9   !!                 !  2000-12  (E. Kestenare M. Levy)  fix bug in trtrd indexes
10   !!                 !  2001-07  (E. Durand G. Madec)  adaptation to ORCA config
11   !!            8.5  !  2002-06  (G. Madec)  F90: Free form and module
12   !!    NEMO    1.0  !  2004-01  (A. de Miranda, G. Madec, J.M. Molines ): advective bbl
13   !!            2.0  !  2008-04  (S. Cravatte) add the i-, j- & k- trends computation
14   !!             -   !  2009-11  (V. Garnier) Surface pressure gradient organization
15   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
16   !!----------------------------------------------------------------------
17
18   !!----------------------------------------------------------------------
19   !!   tra_adv_tvd   : update the tracer trend with the 3D advection trends using a TVD scheme
20   !!   nonosc        : compute monotonic tracer fluxes by a non-oscillatory algorithm
21   !!----------------------------------------------------------------------
22   USE oce            ! ocean dynamics and active tracers
23   USE dom_oce        ! ocean space and time domain
24   USE trc_oce        ! share passive tracers/Ocean variables
25   USE trd_oce        ! trends: ocean variables
26   USE trdtra         ! tracers trends
27   USE dynspg_oce     ! choice/control of key cpp for surface pressure gradient
28   USE diaptr         ! poleward transport diagnostics
29   !
30   USE lib_mpp        ! MPP library
31   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
32   USE in_out_manager ! I/O manager
33   USE wrk_nemo       ! Memory Allocation
34   USE timing         ! Timing
35   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   tra_adv_tvd        ! routine called by traadv.F90
41   PUBLIC   tra_adv_tvd_zts    ! routine called by traadv.F90
42
43   LOGICAL ::   l_trd   ! flag to compute trends
44
45   !! * Substitutions
46#  include "domzgr_substitute.h90"
47#  include "vectopt_loop_substitute.h90"
48   !!----------------------------------------------------------------------
49   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
50   !! $Id$
51   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
52   !!----------------------------------------------------------------------
53CONTAINS
54
55   SUBROUTINE tra_adv_tvd ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
56      &                                       ptb, ptn, pta, kjpt )
57      !!----------------------------------------------------------------------
58      !!                  ***  ROUTINE tra_adv_tvd  ***
59      !!
60      !! **  Purpose :   Compute the now trend due to total advection of
61      !!       tracers and add it to the general trend of tracer equations
62      !!
63      !! **  Method  :   TVD scheme, i.e. 2nd order centered scheme with
64      !!       corrected flux (monotonic correction)
65      !!       note: - this advection scheme needs a leap-frog time scheme
66      !!
67      !! ** Action : - update (pta) with the now advective tracer trends
68      !!             - save the trends
69      !!----------------------------------------------------------------------
70      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
71      !
72      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
76      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
77      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
78      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
79      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
80      !
81      INTEGER  ::   ji, jj, jk, jn           ! dummy loop indices
82      INTEGER  ::   ik 
83      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
84      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
85      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
86      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz
87      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
88      !!----------------------------------------------------------------------
89      !
90      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd')
91      !
92      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz )
93      !
94      IF( kt == kit000 )  THEN
95         IF(lwp) WRITE(numout,*)
96         IF(lwp) WRITE(numout,*) 'tra_adv_tvd : TVD advection scheme on ', cdtype
97         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
98         !
99         l_trd = .FALSE.
100         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
101      ENDIF
102      !
103      IF( l_trd )  THEN
104         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
105         ztrdx(:,:,:) = 0.e0   ;    ztrdy(:,:,:) = 0.e0   ;   ztrdz(:,:,:) = 0.e0
106      ENDIF
107      !
108      zwi(:,:,:) = 0.e0 ; 
109      !
110      !                                                          ! ===========
111      DO jn = 1, kjpt                                            ! tracer loop
112         !                                                       ! ===========
113         ! 1. Bottom and k=1 value : flux set to zero
114         ! ----------------------------------
115         zwx(:,:,jpk) = 0.e0    ;    zwz(:,:,jpk) = 0.e0
116         zwy(:,:,jpk) = 0.e0    ;    zwi(:,:,jpk) = 0.e0
117         
118         zwz(:,:,1  ) = 0._wp
119         ! 2. upstream advection with initial mass fluxes & intermediate update
120         ! --------------------------------------------------------------------
121         ! upstream tracer flux in the i and j direction
122         DO jk = 1, jpkm1
123            DO jj = 1, jpjm1
124               DO ji = 1, fs_jpim1   ! vector opt.
125                  ! upstream scheme
126                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
127                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
128                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
129                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
130                  zwx(ji,jj,jk) = 0.5 * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
131                  zwy(ji,jj,jk) = 0.5 * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
132               END DO
133            END DO
134         END DO
135
136         ! upstream tracer flux in the k direction
137         ! Interior value
138         DO jk = 2, jpkm1
139            DO jj = 1, jpj
140               DO ji = 1, jpi
141                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
142                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
143                  zwz(ji,jj,jk) = 0.5 * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) ) * wmask(ji,jj,jk)
144               END DO
145            END DO
146         END DO
147         ! Surface value
148         IF( lk_vvl ) THEN   
149            DO jj = 1, jpj
150               DO ji = 1, jpi
151                  zwz(ji,jj, mikt(ji,jj) ) = 0.e0          ! volume variable
152               END DO
153            END DO
154         ELSE               
155            DO jj = 1, jpj
156               DO ji = 1, jpi
157                  zwz(ji,jj, mikt(ji,jj) ) = pwn(ji,jj,mikt(ji,jj)) * ptb(ji,jj,mikt(ji,jj),jn)   ! linear free surface
158               END DO
159            END DO   
160         ENDIF
161
162         ! total advective trend
163         DO jk = 1, jpkm1
164            z2dtt = p2dt(jk)
165            DO jj = 2, jpjm1
166               DO ji = fs_2, fs_jpim1   ! vector opt.
167                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
168                  ! total intermediate advective trends
169                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
170                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
171                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
172                  ! update and guess with monotonic sheme
173                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra   * tmask(ji,jj,jk)
174                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
175               END DO
176            END DO
177         END DO
178         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
179         CALL lbc_lnk( zwi, 'T', 1. ) 
180
181         !                                 ! trend diagnostics (contribution of upstream fluxes)
182         IF( l_trd )  THEN 
183            ! store intermediate advective trends
184            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
185         END IF
186         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
187         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
188           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
189           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
190         ENDIF
191
192         ! 3. antidiffusive flux : high order minus low order
193         ! --------------------------------------------------
194         ! antidiffusive flux on i and j
195         DO jk = 1, jpkm1
196            DO jj = 1, jpjm1
197               DO ji = 1, fs_jpim1   ! vector opt.
198                  zwx(ji,jj,jk) = 0.5 * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) ) - zwx(ji,jj,jk)
199                  zwy(ji,jj,jk) = 0.5 * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) ) - zwy(ji,jj,jk)
200               END DO
201            END DO
202         END DO
203     
204         ! antidiffusive flux on k
205         ! Interior value
206         DO jk = 2, jpkm1                   
207            DO jj = 1, jpj
208               DO ji = 1, jpi
209                  zwz(ji,jj,jk) = 0.5 * pwn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj,jk-1,jn) ) - zwz(ji,jj,jk)
210               END DO
211            END DO
212         END DO
213         ! surface value
214         DO jj = 1, jpj
215            DO ji = 1, jpi
216               zwz(ji,jj,mikt(ji,jj)) = 0.e0
217            END DO
218         END DO
219         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
220         CALL lbc_lnk( zwz, 'W',  1. )
221
222         ! 4. monotonicity algorithm
223         ! -------------------------
224         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
225
226
227         ! 5. final trend with corrected fluxes
228         ! ------------------------------------
229         DO jk = 1, jpkm1
230            DO jj = 2, jpjm1
231               DO ji = fs_2, fs_jpim1   ! vector opt. 
232                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
233                  ! total advective trends
234                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
235                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
236                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
237                  ! add them to the general tracer trends
238                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra * tmask(ji,jj,jk)
239               END DO
240            END DO
241         END DO
242
243         !                                 ! trend diagnostics (contribution of upstream fluxes)
244         IF( l_trd )  THEN
245            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
246            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
247            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
248           
249            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
250            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
251            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
252         END IF
253         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
254         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
255           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
256           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
257         ENDIF
258         !
259      END DO
260      !
261                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz )
262      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
263      !
264      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd')
265      !
266   END SUBROUTINE tra_adv_tvd
267
268   SUBROUTINE tra_adv_tvd_zts ( kt, kit000, cdtype, p2dt, pun, pvn, pwn,      &
269      &                                       ptb, ptn, pta, kjpt )
270      !!----------------------------------------------------------------------
271      !!                  ***  ROUTINE tra_adv_tvd_zts  ***
272      !!
273      !! **  Purpose :   Compute the now trend due to total advection of
274      !!       tracers and add it to the general trend of tracer equations
275      !!
276      !! **  Method  :   TVD ZTS scheme, i.e. 2nd order centered scheme with
277      !!       corrected flux (monotonic correction). This version use sub-
278      !!       timestepping for the vertical advection which increases stability
279      !!       when vertical metrics are small.
280      !!       note: - this advection scheme needs a leap-frog time scheme
281      !!
282      !! ** Action : - update (pta) with the now advective tracer trends
283      !!             - save the trends
284      !!----------------------------------------------------------------------
285      USE oce     , ONLY:   zwx => ua        , zwy => va          ! (ua,va) used as workspace
286      !
287      INTEGER                              , INTENT(in   ) ::   kt              ! ocean time-step index
288      INTEGER                              , INTENT(in   ) ::   kit000          ! first time step index
289      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
290      INTEGER                              , INTENT(in   ) ::   kjpt            ! number of tracers
291      REAL(wp), DIMENSION(        jpk     ), INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
292      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ) ::   pun, pvn, pwn   ! 3 ocean velocity components
293      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb, ptn        ! before and now tracer fields
294      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta             ! tracer trend
295      !
296      REAL(wp), DIMENSION( jpk )                           ::   zts             ! length of sub-timestep for vertical advection
297      REAL(wp), DIMENSION( jpk )                           ::   zr_p2dt         ! reciprocal of tracer timestep
298      INTEGER  ::   ji, jj, jk, jl, jn       ! dummy loop indices 
299      INTEGER  ::   jnzts = 5       ! number of sub-timesteps for vertical advection
300      INTEGER  ::   jtb, jtn, jta   ! sub timestep pointers for leap-frog/euler forward steps
301      INTEGER  ::   jtaken          ! toggle for collecting appropriate fluxes from sub timesteps
302      REAL(wp) ::   z_rzts          ! Fractional length of Euler forward sub-timestep for vertical advection
303      REAL(wp) ::   z2dtt, zbtr, ztra        ! local scalar
304      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk   !   -      -
305      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk   !   -      -
306      REAL(wp), POINTER, DIMENSION(:,:  ) :: zwx_sav , zwy_sav
307      REAL(wp), POINTER, DIMENSION(:,:,:) :: zwi, zwz, zhdiv, zwz_sav, zwzts
308      REAL(wp), POINTER, DIMENSION(:,:,:) :: ztrdx, ztrdy, ztrdz
309      REAL(wp), POINTER, DIMENSION(:,:,:,:) :: ztrs
310      !!----------------------------------------------------------------------
311      !
312      IF( nn_timing == 1 )  CALL timing_start('tra_adv_tvd_zts')
313      !
314      CALL wrk_alloc( jpi, jpj, zwx_sav, zwy_sav )
315      CALL wrk_alloc( jpi, jpj, jpk, zwi, zwz , zhdiv, zwz_sav, zwzts )
316      CALL wrk_alloc( jpi, jpj, jpk, 3, ztrs )
317      !
318      IF( kt == kit000 )  THEN
319         IF(lwp) WRITE(numout,*)
320         IF(lwp) WRITE(numout,*) 'tra_adv_tvd_zts : TVD ZTS advection scheme on ', cdtype
321         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
322      ENDIF
323      !
324      l_trd = .FALSE.
325      IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) ) l_trd = .TRUE.
326      !
327      IF( l_trd )  THEN
328         CALL wrk_alloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
329         ztrdx(:,:,:) = 0._wp  ;    ztrdy(:,:,:) = 0._wp  ;   ztrdz(:,:,:) = 0._wp
330      ENDIF
331      !
332      zwi(:,:,:) = 0._wp
333      z_rzts = 1._wp / REAL( jnzts, wp )
334      zr_p2dt(:) = 1._wp / p2dt(:)
335      !
336      !                                                          ! ===========
337      DO jn = 1, kjpt                                            ! tracer loop
338         !                                                       ! ===========
339         ! 1. Bottom value : flux set to zero
340         ! ----------------------------------
341         zwx(:,:,jpk) = 0._wp   ;    zwz(:,:,jpk) = 0._wp
342         zwy(:,:,jpk) = 0._wp   ;    zwi(:,:,jpk) = 0._wp
343
344         ! 2. upstream advection with initial mass fluxes & intermediate update
345         ! --------------------------------------------------------------------
346         ! upstream tracer flux in the i and j direction
347         DO jk = 1, jpkm1
348            DO jj = 1, jpjm1
349               DO ji = 1, fs_jpim1   ! vector opt.
350                  ! upstream scheme
351                  zfp_ui = pun(ji,jj,jk) + ABS( pun(ji,jj,jk) )
352                  zfm_ui = pun(ji,jj,jk) - ABS( pun(ji,jj,jk) )
353                  zfp_vj = pvn(ji,jj,jk) + ABS( pvn(ji,jj,jk) )
354                  zfm_vj = pvn(ji,jj,jk) - ABS( pvn(ji,jj,jk) )
355                  zwx(ji,jj,jk) = 0.5_wp * ( zfp_ui * ptb(ji,jj,jk,jn) + zfm_ui * ptb(ji+1,jj  ,jk,jn) )
356                  zwy(ji,jj,jk) = 0.5_wp * ( zfp_vj * ptb(ji,jj,jk,jn) + zfm_vj * ptb(ji  ,jj+1,jk,jn) )
357               END DO
358            END DO
359         END DO
360
361         ! upstream tracer flux in the k direction
362         ! Surface value
363         IF( lk_vvl ) THEN   ;   zwz(:,:, 1 ) = 0._wp                        ! volume variable
364         ELSE                ;   zwz(:,:, 1 ) = pwn(:,:,1) * ptb(:,:,1,jn)   ! linear free surface
365         ENDIF
366         ! Interior value
367         DO jk = 2, jpkm1
368            DO jj = 1, jpj
369               DO ji = 1, jpi
370                  zfp_wk = pwn(ji,jj,jk) + ABS( pwn(ji,jj,jk) )
371                  zfm_wk = pwn(ji,jj,jk) - ABS( pwn(ji,jj,jk) )
372                  zwz(ji,jj,jk) = 0.5_wp * ( zfp_wk * ptb(ji,jj,jk,jn) + zfm_wk * ptb(ji,jj,jk-1,jn) )
373               END DO
374            END DO
375         END DO
376
377         ! total advective trend
378         DO jk = 1, jpkm1
379            z2dtt = p2dt(jk)
380            DO jj = 2, jpjm1
381               DO ji = fs_2, fs_jpim1   ! vector opt.
382                  zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
383                  ! total intermediate advective trends
384                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
385                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
386                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
387                  ! update and guess with monotonic sheme
388                  pta(ji,jj,jk,jn) =   pta(ji,jj,jk,jn)         + ztra
389                  zwi(ji,jj,jk)    = ( ptb(ji,jj,jk,jn) + z2dtt * ztra ) * tmask(ji,jj,jk)
390               END DO
391            END DO
392         END DO
393         !                             ! Lateral boundary conditions on zwi  (unchanged sign)
394         CALL lbc_lnk( zwi, 'T', 1. ) 
395
396         !                                 ! trend diagnostics (contribution of upstream fluxes)
397         IF( l_trd )  THEN 
398            ! store intermediate advective trends
399            ztrdx(:,:,:) = zwx(:,:,:)   ;    ztrdy(:,:,:) = zwy(:,:,:)  ;   ztrdz(:,:,:) = zwz(:,:,:)
400         END IF
401         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
402         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
403           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) )
404           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) )
405         ENDIF
406
407         ! 3. antidiffusive flux : high order minus low order
408         ! --------------------------------------------------
409         ! antidiffusive flux on i and j
410
411
412         DO jk = 1, jpkm1
413
414            DO jj = 1, jpjm1
415               DO ji = 1, fs_jpim1   ! vector opt.
416                  zwx_sav(ji,jj) = zwx(ji,jj,jk)
417                  zwy_sav(ji,jj) = zwy(ji,jj,jk)
418
419                  zwx(ji,jj,jk) = 0.5_wp * pun(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji+1,jj,jk,jn) )
420                  zwy(ji,jj,jk) = 0.5_wp * pvn(ji,jj,jk) * ( ptn(ji,jj,jk,jn) + ptn(ji,jj+1,jk,jn) )
421               END DO
422            END DO
423
424            DO jj = 2, jpjm1         ! partial horizontal divergence
425               DO ji = fs_2, fs_jpim1
426                  zhdiv(ji,jj,jk) = (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk)   &
427                     &               + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk)  )
428               END DO
429            END DO
430
431            DO jj = 1, jpjm1
432               DO ji = 1, fs_jpim1   ! vector opt.
433                  zwx(ji,jj,jk) = zwx(ji,jj,jk)  - zwx_sav(ji,jj)
434                  zwy(ji,jj,jk) = zwy(ji,jj,jk)  - zwy_sav(ji,jj)
435               END DO
436            END DO
437         END DO
438     
439         ! antidiffusive flux on k
440         zwz(:,:,1) = 0._wp        ! Surface value
441         zwz_sav(:,:,:) = zwz(:,:,:)
442         !
443         ztrs(:,:,:,1) = ptb(:,:,:,jn)
444         zwzts(:,:,:) = 0._wp
445
446         DO jl = 1, jnzts                   ! Start of sub timestepping loop
447
448            IF( jl == 1 ) THEN              ! Euler forward to kick things off
449              jtb = 1   ;   jtn = 1   ;   jta = 2
450              zts(:) = p2dt(:) * z_rzts
451              jtaken = MOD( jnzts + 1 , 2)  ! Toggle to collect every second flux
452                                            ! starting at jl =1 if jnzts is odd;
453                                            ! starting at jl =2 otherwise
454            ELSEIF( jl == 2 ) THEN          ! First leapfrog step
455              jtb = 1   ;   jtn = 2   ;   jta = 3
456              zts(:) = 2._wp * p2dt(:) * z_rzts
457            ELSE                            ! Shuffle pointers for subsequent leapfrog steps
458              jtb = MOD(jtb,3) + 1
459              jtn = MOD(jtn,3) + 1
460              jta = MOD(jta,3) + 1
461            ENDIF
462            DO jk = 2, jpkm1          ! Interior value
463               DO jj = 2, jpjm1
464                  DO ji = fs_2, fs_jpim1
465                     zwz(ji,jj,jk) = 0.5_wp * pwn(ji,jj,jk) * ( ztrs(ji,jj,jk,jtn) + ztrs(ji,jj,jk-1,jtn) )
466                     IF( jtaken == 0 ) zwzts(ji,jj,jk) = zwzts(ji,jj,jk) + zwz(ji,jj,jk)*zts(jk)           ! Accumulate time-weighted vertcal flux
467                  END DO
468               END DO
469            END DO
470
471            jtaken = MOD( jtaken + 1 , 2 )
472
473            DO jk = 2, jpkm1          ! Interior value
474               DO jj = 2, jpjm1
475                  DO ji = fs_2, fs_jpim1
476                     zbtr = 1._wp / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
477                     ! total advective trends
478                     ztra = - zbtr * (  zhdiv(ji,jj,jk) + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
479                     ztrs(ji,jj,jk,jta) = ztrs(ji,jj,jk,jtb) + zts(jk) * ztra
480                  END DO
481               END DO
482            END DO
483
484         END DO
485
486         DO jk = 2, jpkm1          ! Anti-diffusive vertical flux using average flux from the sub-timestepping
487            DO jj = 2, jpjm1
488               DO ji = fs_2, fs_jpim1
489                  zwz(ji,jj,jk) = zwzts(ji,jj,jk) * zr_p2dt(jk) - zwz_sav(ji,jj,jk)
490               END DO
491            END DO
492         END DO
493         CALL lbc_lnk( zwx, 'U', -1. )   ;   CALL lbc_lnk( zwy, 'V', -1. )         ! Lateral bondary conditions
494         CALL lbc_lnk( zwz, 'W',  1. )
495
496         ! 4. monotonicity algorithm
497         ! -------------------------
498         CALL nonosc( ptb(:,:,:,jn), zwx, zwy, zwz, zwi, p2dt )
499
500
501         ! 5. final trend with corrected fluxes
502         ! ------------------------------------
503         DO jk = 1, jpkm1
504            DO jj = 2, jpjm1
505               DO ji = fs_2, fs_jpim1   ! vector opt. 
506                  zbtr = 1. / ( e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) )
507                  ! total advective trends
508                  ztra = - zbtr * (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
509                     &             + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
510                     &             + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) )
511                  ! add them to the general tracer trends
512                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + ztra
513               END DO
514            END DO
515         END DO
516
517         !                                 ! trend diagnostics (contribution of upstream fluxes)
518         IF( l_trd )  THEN
519            ztrdx(:,:,:) = ztrdx(:,:,:) + zwx(:,:,:)  ! <<< Add to previously computed
520            ztrdy(:,:,:) = ztrdy(:,:,:) + zwy(:,:,:)  ! <<< Add to previously computed
521            ztrdz(:,:,:) = ztrdz(:,:,:) + zwz(:,:,:)  ! <<< Add to previously computed
522           
523            CALL trd_tra( kt, cdtype, jn, jptra_xad, ztrdx, pun, ptn(:,:,:,jn) )   
524            CALL trd_tra( kt, cdtype, jn, jptra_yad, ztrdy, pvn, ptn(:,:,:,jn) ) 
525            CALL trd_tra( kt, cdtype, jn, jptra_zad, ztrdz, pwn, ptn(:,:,:,jn) ) 
526         END IF
527         !                                 ! "Poleward" heat and salt transports (contribution of upstream fluxes)
528         IF( cdtype == 'TRA' .AND. ln_diaptr .AND. ( MOD( kt, nn_fptr ) == 0 ) ) THEN 
529           IF( jn == jp_tem )  htr_adv(:) = ptr_vj( zwy(:,:,:) ) + htr_adv(:)
530           IF( jn == jp_sal )  str_adv(:) = ptr_vj( zwy(:,:,:) ) + str_adv(:)
531         ENDIF
532         !
533      END DO
534      !
535                   CALL wrk_dealloc( jpi, jpj, jpk, zwi, zwz, zhdiv, zwz_sav, zwzts )
536                   CALL wrk_dealloc( jpi, jpj, jpk, 3, ztrs )
537                   CALL wrk_dealloc( jpi, jpj, zwx_sav, zwy_sav )
538      IF( l_trd )  CALL wrk_dealloc( jpi, jpj, jpk, ztrdx, ztrdy, ztrdz )
539      !
540      IF( nn_timing == 1 )  CALL timing_stop('tra_adv_tvd_zts')
541      !
542   END SUBROUTINE tra_adv_tvd_zts
543
544   SUBROUTINE nonosc( pbef, paa, pbb, pcc, paft, p2dt )
545      !!---------------------------------------------------------------------
546      !!                    ***  ROUTINE nonosc  ***
547      !!     
548      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
549      !!       scheme and the before field by a nonoscillatory algorithm
550      !!
551      !! **  Method  :   ... ???
552      !!       warning : pbef and paft must be masked, but the boundaries
553      !!       conditions on the fluxes are not necessary zalezak (1979)
554      !!       drange (1995) multi-dimensional forward-in-time and upstream-
555      !!       in-space based differencing for fluid
556      !!----------------------------------------------------------------------
557      REAL(wp), DIMENSION(jpk)         , INTENT(in   ) ::   p2dt            ! vertical profile of tracer time-step
558      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(in   ) ::   pbef, paft      ! before & after field
559      REAL(wp), DIMENSION (jpi,jpj,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
560      !
561      INTEGER  ::   ji, jj, jk   ! dummy loop indices
562      INTEGER  ::   ikm1         ! local integer
563      REAL(wp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn, z2dtt   ! local scalars
564      REAL(wp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
565      REAL(wp), POINTER, DIMENSION(:,:,:) :: zbetup, zbetdo, zbup, zbdo
566      !!----------------------------------------------------------------------
567      !
568      IF( nn_timing == 1 )  CALL timing_start('nonosc')
569      !
570      CALL wrk_alloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
571      !
572      zbig  = 1.e+40_wp
573      zrtrn = 1.e-15_wp
574      zbetup(:,:,:) = 0._wp   ;   zbetdo(:,:,:) = 0._wp
575
576      ! Search local extrema
577      ! --------------------
578      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
579      zbup = MAX( pbef * tmask - zbig * ( 1._wp - tmask ),   &
580         &        paft * tmask - zbig * ( 1._wp - tmask )  )
581      zbdo = MIN( pbef * tmask + zbig * ( 1._wp - tmask ),   &
582         &        paft * tmask + zbig * ( 1._wp - tmask )  )
583
584      DO jk = 1, jpkm1
585         DO jj = 2, jpjm1
586            DO ji = fs_2, fs_jpim1   ! vector opt.
587               ikm1 = MAX(jk-1,1)
588               z2dtt = p2dt(jk)
589               
590               ! search maximum in neighbourhood
591               zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
592                  &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
593                  &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
594                  &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
595
596               ! search minimum in neighbourhood
597               zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
598                  &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
599                  &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
600                  &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
601
602               ! positive part of the flux
603               zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
604                  & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
605                  & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
606
607               ! negative part of the flux
608               zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
609                  & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
610                  & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
611
612               ! up & down beta terms
613               zbt = e1t(ji,jj) * e2t(ji,jj) * fse3t(ji,jj,jk) / z2dtt
614               zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
615               zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
616            END DO
617         END DO
618      END DO
619      CALL lbc_lnk( zbetup, 'T', 1. )   ;   CALL lbc_lnk( zbetdo, 'T', 1. )   ! lateral boundary cond. (unchanged sign)
620
621      ! 3. monotonic flux in the i & j direction (paa & pbb)
622      ! ----------------------------------------
623      DO jk = 1, jpkm1
624         DO jj = 2, jpjm1
625            DO ji = fs_2, fs_jpim1   ! vector opt.
626               zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
627               zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
628               zcu =       ( 0.5  + SIGN( 0.5 , paa(ji,jj,jk) ) )
629               paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
630
631               zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
632               zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
633               zcv =       ( 0.5  + SIGN( 0.5 , pbb(ji,jj,jk) ) )
634               pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
635
636      ! monotonic flux in the k direction, i.e. pcc
637      ! -------------------------------------------
638               za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
639               zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
640               zc =       ( 0.5  + SIGN( 0.5 , pcc(ji,jj,jk+1) ) )
641               pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
642            END DO
643         END DO
644      END DO
645      CALL lbc_lnk( paa, 'U', -1. )   ;   CALL lbc_lnk( pbb, 'V', -1. )   ! lateral boundary condition (changed sign)
646      !
647      CALL wrk_dealloc( jpi, jpj, jpk, zbetup, zbetdo, zbup, zbdo )
648      !
649      IF( nn_timing == 1 )  CALL timing_stop('nonosc')
650      !
651   END SUBROUTINE nonosc
652
653   !!======================================================================
654END MODULE traadv_tvd
Note: See TracBrowser for help on using the repository browser.