source: branches/2015/dev_r5094_UKMO_ISFCLEAN/NEMOGCM/NEMO/OPA_SRC/TRA/zpshde.F90 @ 5098

Last change on this file since 5098 was 5098, checked in by mathiot, 6 years ago

add wmask, wumask, wvmask and restore loop order and add flag to ignore specific isf code if no isf

  • Property svn:keywords set to Id
File size: 33.2 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE wrk_nemo        ! Memory allocation
25   USE timing          ! Timing
26
27   IMPLICIT NONE
28   PRIVATE
29
30   PUBLIC   zps_hde     ! routine called by step.F90
31   PUBLIC   zps_hde_isf ! routine called by step.F90
32
33   !! * Substitutions
34#  include "domzgr_substitute.h90"
35#  include "vectopt_loop_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
38   !! $Id$
39   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
44      &                          prd, pgru, pgrv    )
45      !!----------------------------------------------------------------------
46      !!                     ***  ROUTINE zps_hde  ***
47      !!                   
48      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
49      !!      at u- and v-points with a linear interpolation for z-coordinate
50      !!      with partial steps.
51      !!
52      !! ** Method  :   In z-coord with partial steps, scale factors on last
53      !!      levels are different for each grid point, so that T, S and rd
54      !!      points are not at the same depth as in z-coord. To have horizontal
55      !!      gradients again, we interpolate T and S at the good depth :
56      !!      Linear interpolation of T, S   
57      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
58      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
59      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
60      !!         This formulation computes the two cases:
61      !!                 CASE 1                   CASE 2 
62      !!         k-1  ___ ___________   k-1   ___ ___________
63      !!                    Ti  T~                  T~  Ti+1
64      !!                  _____                        _____
65      !!         k        |   |Ti+1     k           Ti |   |
66      !!                  |   |____                ____|   |
67      !!              ___ |   |   |           ___  |   |   |
68      !!                 
69      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
70      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
71      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
72      !!          or
73      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
74      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
75      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
76      !!          Idem for di(s) and dj(s)         
77      !!
78      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
79      !!      depth zh from interpolated T and S for the different formulations
80      !!      of the equation of state (eos).
81      !!      Gradient formulation for rho :
82      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
83      !!
84      !! ** Action  : compute for top and bottom interfaces
85      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
86      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
87      !!----------------------------------------------------------------------
88      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
89      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
90      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
91      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
92      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
93      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv      ! hor. grad of prd at u- & v-pts (bottom)
94      !
95      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
96      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
97      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv, zdzwu, zdzwv, zdzwuip1, zdzwvjp1  ! temporary scalars
98      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
99      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
100      !!----------------------------------------------------------------------
101      !
102      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde')
103      !
104      pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
105      zti (:,:,:)=0.0_wp ; ztj (:,:,:)=0.0_wp ;
106      zhi (:,:  )=0.0_wp ; zhj (:,:  )=0.0_wp ;
107      !
108      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
109         !
110         DO jj = 1, jpjm1
111            DO ji = 1, jpim1
112               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
113               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
114               ! (ISF) case partial step top and bottom in adjacent cell in vertical
115               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
116               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
117               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
118               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
119               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
120               !
121               ! i- direction
122               IF( ze3wu >= 0._wp ) THEN      ! case 1
123                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
124                  ! interpolated values of tracers
125                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
126                  ! gradient of  tracers
127                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
128               ELSE                           ! case 2
129                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
130                  ! interpolated values of tracers
131                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
132                  ! gradient of tracers
133                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
134               ENDIF
135               !
136               ! j- direction
137               IF( ze3wv >= 0._wp ) THEN      ! case 1
138                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
139                  ! interpolated values of tracers
140                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
141                  ! gradient of tracers
142                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
143               ELSE                           ! case 2
144                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
145                  ! interpolated values of tracers
146                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
147                  ! gradient of tracers
148                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
149               ENDIF
150            END DO
151         END DO
152         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
153         !
154      END DO
155
156      ! horizontal derivative of density anomalies (rd)
157      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
158         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
159         DO jj = 1, jpjm1
160            DO ji = 1, jpim1
161               iku = mbku(ji,jj)
162               ikv = mbkv(ji,jj)
163               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
164               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
165
166               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) - ze3wu     ! i-direction: case 1
167               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) + ze3wu    ! -     -      case 2
168               ENDIF
169               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) - ze3wv    ! j-direction: case 1
170               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) + ze3wv    ! -     -      case 2
171               ENDIF
172            END DO
173         END DO
174         
175         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
176         ! step and store it in  zri, zrj for each  case
177         CALL eos( zti, zhi, zri ) 
178         CALL eos( ztj, zhj, zrj )
179
180         ! Gradient of density at the last level
181         DO jj = 1, jpjm1
182            DO ji = 1, jpim1
183               iku = mbku(ji,jj) ; ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
184               ikv = mbkv(ji,jj) ; ikvm1 = MAX( ikv - 1 , 1 )    ! last and before last ocean level at u- & v-points
185               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
186               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
187               IF( ze3wu >= 0._wp ) THEN ; pgru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
188               ELSE                      ; pgru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
189               ENDIF
190               IF( ze3wv >= 0._wp ) THEN ; pgrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
191               ELSE                      ; pgrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
192               ENDIF
193            END DO
194         END DO
195         CALL lbc_lnk( pgru   , 'U', -1. )   ;   CALL lbc_lnk( pgrv   , 'V', -1. )   ! Lateral boundary conditions
196         !
197      END IF
198      !
199      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde')
200      !
201   END SUBROUTINE zps_hde
202   !
203   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv,   &
204      &                          prd, pgru, pgrv, pmru, pmrv, pgzu, pgzv, pge3ru, pge3rv,  &
205      &                   pgtui, pgtvi, pgrui, pgrvi, pmrui, pmrvi, pgzui, pgzvi, pge3rui, pge3rvi )
206      !!----------------------------------------------------------------------
207      !!                     ***  ROUTINE zps_hde  ***
208      !!                   
209      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
210      !!      at u- and v-points with a linear interpolation for z-coordinate
211      !!      with partial steps.
212      !!
213      !! ** Method  :   In z-coord with partial steps, scale factors on last
214      !!      levels are different for each grid point, so that T, S and rd
215      !!      points are not at the same depth as in z-coord. To have horizontal
216      !!      gradients again, we interpolate T and S at the good depth :
217      !!      Linear interpolation of T, S   
218      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
219      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
220      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
221      !!         This formulation computes the two cases:
222      !!                 CASE 1                   CASE 2 
223      !!         k-1  ___ ___________   k-1   ___ ___________
224      !!                    Ti  T~                  T~  Ti+1
225      !!                  _____                        _____
226      !!         k        |   |Ti+1     k           Ti |   |
227      !!                  |   |____                ____|   |
228      !!              ___ |   |   |           ___  |   |   |
229      !!                 
230      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
231      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
232      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
233      !!          or
234      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
235      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
236      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
237      !!          Idem for di(s) and dj(s)         
238      !!
239      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
240      !!      depth zh from interpolated T and S for the different formulations
241      !!      of the equation of state (eos).
242      !!      Gradient formulation for rho :
243      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
244      !!
245      !! ** Action  : compute for top and bottom interfaces
246      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
247      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
248      !!              - pmru, pmrv, pmrui, pmrvi: horizontal sum of rho at u- & v- point (used in dynhpg with vvl)
249      !!              - pgzu, pgzv, pgzui, pgzvi: horizontal gradient of z at u- and v- point (used in dynhpg with vvl)
250      !!              - pge3ru, pge3rv, pge3rui, pge3rvi: horizontal gradient of rho weighted by local e3w at u- & v-points
251      !!----------------------------------------------------------------------
252      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
253      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
254      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
255      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
256      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi  ! hor. grad. of stra at u- & v-pts (ISF)
257      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
258      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv      ! hor. grad of prd at u- & v-pts (bottom)
259      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pmru, pmrv      ! hor. sum  of prd at u- & v-pts (bottom)
260      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgzu, pgzv      ! hor. grad of z   at u- & v-pts (bottom)
261      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pge3ru, pge3rv  ! hor. grad of prd weighted by local e3w at u- & v-pts (bottom)
262      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi      ! hor. grad of prd at u- & v-pts (top)
263      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pmrui, pmrvi      ! hor. sum  of prd at u- & v-pts (top)
264      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgzui, pgzvi      ! hor. grad of z   at u- & v-pts (top)
265      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pge3rui, pge3rvi  ! hor. grad of prd weighted by local e3w at u- & v-pts (top)
266      !
267      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
268      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
269      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv, zdzwu, zdzwv, zdzwuip1, zdzwvjp1  ! temporary scalars
270      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
271      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
272      !!----------------------------------------------------------------------
273      !
274      IF( nn_timing == 1 )  CALL timing_start( 'zps_hde_isf')
275      !
276      pgtu(:,:,:)=0.0_wp ; pgtv(:,:,:)=0.0_wp ;
277      pgtui(:,:,:)=0.0_wp ; pgtvi(:,:,:)=0.0_wp ;
278      zti (:,:,:)=0.0_wp ; ztj (:,:,:)=0.0_wp ;
279      zhi (:,:  )=0.0_wp ; zhj (:,:  )=0.0_wp ;
280      !
281      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
282         !
283         DO jj = 1, jpjm1
284            DO ji = 1, jpim1
285               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
286               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
287               ! (ISF) case partial step top and bottom in adjacent cell in vertical
288               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
289               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
290               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
291               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
292               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
293               !
294               ! i- direction
295               IF( ze3wu >= 0._wp ) THEN      ! case 1
296                  zmaxu =  ze3wu / fse3w(ji+1,jj,iku)
297                  ! interpolated values of tracers
298                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
299                  ! gradient of  tracers
300                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
301               ELSE                           ! case 2
302                  zmaxu = -ze3wu / fse3w(ji,jj,iku)
303                  ! interpolated values of tracers
304                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
305                  ! gradient of tracers
306                  pgtu(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
307               ENDIF
308               !
309               ! j- direction
310               IF( ze3wv >= 0._wp ) THEN      ! case 1
311                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv)
312                  ! interpolated values of tracers
313                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
314                  ! gradient of tracers
315                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
316               ELSE                           ! case 2
317                  zmaxv =  -ze3wv / fse3w(ji,jj,ikv)
318                  ! interpolated values of tracers
319                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
320                  ! gradient of tracers
321                  pgtv(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
322               ENDIF
323            END DO
324         END DO
325         CALL lbc_lnk( pgtu(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtv(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
326         !
327      END DO
328
329      ! horizontal derivative of density anomalies (rd)
330      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
331         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
332         pgzu(:,:)=0.0_wp   ; pgzv(:,:)=0.0_wp ;
333         pmru(:,:)=0.0_wp   ; pmru(:,:)=0.0_wp ;
334         pge3ru(:,:)=0.0_wp ; pge3rv(:,:)=0.0_wp ;
335         DO jj = 1, jpjm1
336            DO ji = 1, jpim1
337               iku = mbku(ji,jj)
338               ikv = mbkv(ji,jj)
339               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
340               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
341
342               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) - ze3wu     ! i-direction: case 1
343               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) + ze3wu    ! -     -      case 2
344               ENDIF
345               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) - ze3wv    ! j-direction: case 1
346               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) + ze3wv    ! -     -      case 2
347               ENDIF
348            END DO
349         END DO
350         
351         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
352         ! step and store it in  zri, zrj for each  case
353         CALL eos( zti, zhi, zri ) 
354         CALL eos( ztj, zhj, zrj )
355
356         ! Gradient of density at the last level
357         DO jj = 1, jpjm1
358            DO ji = 1, jpim1
359               iku = mbku(ji,jj) ; ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
360               ikv = mbkv(ji,jj) ; ikvm1 = MAX( ikv - 1 , 1 )    ! last and before last ocean level at u- & v-points
361               ze3wu  = (gdept_0(ji+1,jj,iku) - gdepw_0(ji+1,jj,iku)) - (gdept_0(ji,jj,iku) - gdepw_0(ji,jj,iku))
362               ze3wv  = (gdept_0(ji,jj+1,ikv) - gdepw_0(ji,jj+1,ikv)) - (gdept_0(ji,jj,ikv) - gdepw_0(ji,jj,ikv))
363               IF( ze3wu >= 0._wp ) THEN
364                  pgzu(ji,jj) = (fsde3w(ji+1,jj,iku) - ze3wu) - fsde3w(ji,jj,iku)
365                  pgru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) - prd(ji,jj,iku) )   ! i: 1
366                  pmru(ji,jj) = umask(ji,jj,iku) * ( zri(ji  ,jj) + prd(ji,jj,iku) )   ! i: 1
367                  pge3ru(ji,jj) = umask(ji,jj,iku)                                                                  &
368                                * ( (fse3w(ji+1,jj,iku) - ze3wu )* ( zri(ji  ,jj    ) + prd(ji+1,jj,ikum1) + 2._wp) &
369                                   - fse3w(ji  ,jj,iku)          * ( prd(ji  ,jj,iku) + prd(ji  ,jj,ikum1) + 2._wp) )  ! j: 2
370               ELSE 
371                  pgzu(ji,jj) = fsde3w(ji+1,jj,iku) - (fsde3w(ji,jj,iku) + ze3wu)
372                  pgru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) - zri(ji,jj) )   ! i: 2
373                  pmru(ji,jj) = umask(ji,jj,iku) * ( prd(ji+1,jj,iku) + zri(ji,jj) )   ! i: 2
374                  pge3ru(ji,jj) = umask(ji,jj,iku)                                                                  &
375                                * (  fse3w(ji+1,jj,iku)          * ( prd(ji+1,jj,iku) + prd(ji+1,jj,ikum1) + 2._wp) &
376                                   -(fse3w(ji  ,jj,iku) + ze3wu) * ( zri(ji  ,jj    ) + prd(ji  ,jj,ikum1) + 2._wp) )  ! j: 2
377               ENDIF
378               IF( ze3wv >= 0._wp ) THEN
379                  pgzv(ji,jj) = (fsde3w(ji,jj+1,ikv) - ze3wv) - fsde3w(ji,jj,ikv) 
380                  pgrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )   ! j: 1
381                  pmrv(ji,jj) = vmask(ji,jj,ikv) * ( zrj(ji,jj  ) + prd(ji,jj,ikv) )   ! j: 1
382                  pge3rv(ji,jj) = vmask(ji,jj,ikv)                                                                  &
383                                * ( (fse3w(ji,jj+1,ikv) - ze3wv )* ( zrj(ji,jj      ) + prd(ji,jj+1,ikvm1) + 2._wp) &
384                                   - fse3w(ji,jj  ,ikv)          * ( prd(ji,jj  ,ikv) + prd(ji,jj  ,ikvm1) + 2._wp) )  ! j: 2
385               ELSE
386                  pgzv(ji,jj) = fsde3w(ji,jj+1,ikv) - (fsde3w(ji,jj,ikv) + ze3wv)
387                  pgrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )   ! j: 2
388                  pmrv(ji,jj) = vmask(ji,jj,ikv) * ( prd(ji,jj+1,ikv) + zrj(ji,jj) )   ! j: 2
389                  pge3rv(ji,jj) = vmask(ji,jj,ikv)                                                                  &
390                                * (  fse3w(ji,jj+1,ikv)          * ( prd(ji,jj+1,ikv) + prd(ji,jj+1,ikvm1) + 2._wp) &
391                                   -(fse3w(ji,jj  ,ikv) + ze3wv) * ( zrj(ji,jj      ) + prd(ji,jj  ,ikvm1) + 2._wp) )  ! j: 2
392               ENDIF
393            END DO
394         END DO
395         CALL lbc_lnk( pgru   , 'U', -1. )   ;   CALL lbc_lnk( pgrv   , 'V', -1. )   ! Lateral boundary conditions
396         CALL lbc_lnk( pmru   , 'U',  1. )   ;   CALL lbc_lnk( pmrv   , 'V',  1. )   ! Lateral boundary conditions
397         CALL lbc_lnk( pgzu   , 'U', -1. )   ;   CALL lbc_lnk( pgzv   , 'V', -1. )   ! Lateral boundary conditions
398         CALL lbc_lnk( pge3ru , 'U', -1. )   ;   CALL lbc_lnk( pge3rv , 'V', -1. )   ! Lateral boundary conditions
399         !
400      END IF
401         ! (ISH)  compute grui and gruvi
402      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
403         DO jj = 1, jpjm1
404            DO ji = 1, jpim1
405               iku = miku(ji,jj)   ;  ikup1 = miku(ji,jj) + 1
406               ikv = mikv(ji,jj)   ;  ikvp1 = mikv(ji,jj) + 1
407               !
408               ! (ISF) case partial step top and bottom in adjacent cell in vertical
409               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
410               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
411               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
412               ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku)) 
413               ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
414               ! i- direction
415               IF( ze3wu >= 0._wp ) THEN      ! case 1
416                  zmaxu = ze3wu / fse3w(ji+1,jj,iku+1)
417                  ! interpolated values of tracers
418                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,iku+1,jn) - pta(ji+1,jj,iku,jn) )
419                  ! gradient of tracers
420                  pgtui(ji,jj,jn) = umask(ji,jj,iku) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
421               ELSE                           ! case 2
422                  zmaxu = - ze3wu / fse3w(ji,jj,iku+1)
423                  ! interpolated values of tracers
424                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,iku+1,jn) - pta(ji,jj,iku,jn) )
425                  ! gradient of  tracers
426                  pgtui(ji,jj,jn) = umask(ji,jj,iku) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
427               ENDIF
428               !
429               ! j- direction
430               IF( ze3wv >= 0._wp ) THEN      ! case 1
431                  zmaxv =  ze3wv / fse3w(ji,jj+1,ikv+1)
432                  ! interpolated values of tracers
433                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikv+1,jn) - pta(ji,jj+1,ikv,jn) )
434                  ! gradient of tracers
435                  pgtvi(ji,jj,jn) = vmask(ji,jj,ikv) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
436               ELSE                           ! case 2
437                  zmaxv =  - ze3wv / fse3w(ji,jj,ikv+1)
438                  ! interpolated values of tracers
439                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikv+1,jn) - pta(ji,jj,ikv,jn) )
440                  ! gradient of tracers
441                  pgtvi(ji,jj,jn) = vmask(ji,jj,ikv) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
442               ENDIF
443            END DO!!
444         END DO!!
445         CALL lbc_lnk( pgtui(:,:,jn), 'U', -1. )   ;   CALL lbc_lnk( pgtvi(:,:,jn), 'V', -1. )   ! Lateral boundary cond.
446         !
447      END DO
448
449      ! horizontal derivative of density anomalies (rd)
450      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
451         pgrui(:,:)  =0.0_wp ; pgrvi(:,:)  =0.0_wp ;
452         pgzui(:,:)  =0.0_wp ; pgzvi(:,:)  =0.0_wp ;
453         pmrui(:,:)  =0.0_wp ; pmrui(:,:)  =0.0_wp ;
454         pge3rui(:,:)=0.0_wp ; pge3rvi(:,:)=0.0_wp ;
455
456         DO jj = 1, jpjm1
457            DO ji = 1, jpim1
458               iku = miku(ji,jj)
459               ikv = mikv(ji,jj)
460               ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
461               ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
462
463               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = fsdept(ji+1,jj,iku) + ze3wu    ! i-direction: case 1
464               ELSE                        ;   zhi(ji,jj) = fsdept(ji  ,jj,iku) - ze3wu    ! -     -      case 2
465               ENDIF
466               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = fsdept(ji,jj+1,ikv) + ze3wv    ! j-direction: case 1
467               ELSE                        ;   zhj(ji,jj) = fsdept(ji,jj  ,ikv) - ze3wv    ! -     -      case 2
468               ENDIF
469            END DO
470         END DO
471
472         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
473         ! step and store it in  zri, zrj for each  case
474         CALL eos( zti, zhi, zri ) 
475         CALL eos( ztj, zhj, zrj )
476
477         ! Gradient of density at the last level
478         DO jj = 1, jpjm1
479            DO ji = 1, jpim1
480               iku = miku(ji,jj) ; ikup1 = miku(ji,jj) + 1
481               ikv = mikv(ji,jj) ; ikvp1 = mikv(ji,jj) + 1
482               ze3wu  = (gdepw_0(ji+1,jj,iku+1) - gdept_0(ji+1,jj,iku)) - (gdepw_0(ji,jj,iku+1) - gdept_0(ji,jj,iku))
483               ze3wv  = (gdepw_0(ji,jj+1,ikv+1) - gdept_0(ji,jj+1,ikv)) - (gdepw_0(ji,jj,ikv+1) - gdept_0(ji,jj,ikv))
484               IF( ze3wu >= 0._wp ) THEN
485                 pgzui  (ji,jj) = (fsde3w(ji+1,jj,iku) + ze3wu) - fsde3w(ji,jj,iku)
486                 pgrui  (ji,jj) = umask(ji,jj,iku)   * ( zri(ji,jj) - prd(ji,jj,iku) )          ! i: 1
487                 pmrui  (ji,jj) = umask(ji,jj,iku)   * ( zri(ji,jj) + prd(ji,jj,iku) )          ! i: 1
488                 pge3rui(ji,jj) = umask(ji,jj,iku+1)                                                                  &
489                                * ( (fse3w(ji+1,jj,iku+1) - ze3wu) * (zri(ji,jj    ) + prd(ji+1,jj,iku+1) + 2._wp)   &
490                                   - fse3w(ji  ,jj,iku+1)          * (prd(ji,jj,iku) + prd(ji  ,jj,iku+1) + 2._wp)   ) ! i: 1
491               ELSE
492                 pgzui  (ji,jj) = fsde3w(ji+1,jj,iku) - (fsde3w(ji,jj,iku) - ze3wu)
493                 pgrui  (ji,jj) = umask(ji,jj,iku)   * ( prd(ji+1,jj,iku) - zri(ji,jj) )      ! i: 2
494                 pmrui  (ji,jj) = umask(ji,jj,iku)   * ( prd(ji+1,jj,iku) + zri(ji,jj) )      ! i: 2
495                 pge3rui(ji,jj) = umask(ji,jj,iku+1)                                                                   &
496                                * (  fse3w(ji+1,jj,iku+1)          * (prd(ji+1,jj,iku) + prd(ji+1,jj,iku+1) + 2._wp)  &
497                                   -(fse3w(ji  ,jj,iku+1) + ze3wu) * (zri(ji,jj      ) + prd(ji  ,jj,iku+1) + 2._wp)  )     ! i: 2
498               ENDIF
499               IF( ze3wv >= 0._wp ) THEN
500                 pgzvi  (ji,jj) = (fsde3w(ji,jj+1,ikv) + ze3wv) - fsde3w(ji,jj,ikv) 
501                 pgrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( zrj(ji,jj  ) - prd(ji,jj,ikv) )        ! j: 1
502                 pmrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( zrj(ji,jj  ) + prd(ji,jj,ikv) )        ! j: 1
503                 pge3rvi(ji,jj) = vmask(ji,jj,ikv+1)                                                                  & 
504                                * ( (fse3w(ji,jj+1,ikv+1) - ze3wv) * ( zrj(ji,jj    ) + prd(ji,jj+1,ikv+1) + 2._wp)  &
505                                   - fse3w(ji,jj  ,ikv+1)          * ( prd(ji,jj,ikv) + prd(ji,jj  ,ikv+1) + 2._wp)  ) ! j: 1
506                                  ! + 2 due to the formulation in density and not in anomalie in hpg sco
507               ELSE
508                 pgzvi  (ji,jj) = fsde3w(ji,jj+1,ikv) - (fsde3w(ji,jj,ikv) - ze3wv)
509                 pgrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( prd(ji,jj+1,ikv) - zrj(ji,jj) )     ! j: 2
510                 pmrvi  (ji,jj) = vmask(ji,jj,ikv)   * ( prd(ji,jj+1,ikv) + zrj(ji,jj) )     ! j: 2
511                 pge3rvi(ji,jj) = vmask(ji,jj,ikv+1)                                                                   &
512                                * (  fse3w(ji,jj+1,ikv+1)          * ( prd(ji,jj+1,ikv) + prd(ji,jj+1,ikv+1) + 2._wp) &
513                                   -(fse3w(ji,jj  ,ikv+1) + ze3wv) * ( zrj(ji,jj      ) + prd(ji,jj  ,ikv+1) + 2._wp) )  ! j: 2
514               ENDIF
515            END DO
516         END DO
517         CALL lbc_lnk( pgrui   , 'U', -1. )   ;   CALL lbc_lnk( pgrvi   , 'V', -1. )   ! Lateral boundary conditions
518         CALL lbc_lnk( pmrui   , 'U',  1. )   ;   CALL lbc_lnk( pmrvi   , 'V',  1. )   ! Lateral boundary conditions
519         CALL lbc_lnk( pgzui   , 'U', -1. )   ;   CALL lbc_lnk( pgzvi   , 'V', -1. )   ! Lateral boundary conditions
520         CALL lbc_lnk( pge3rui , 'U', -1. )   ;   CALL lbc_lnk( pge3rvi , 'V', -1. )   ! Lateral boundary conditions
521         !
522      END IF 
523      !
524      IF( nn_timing == 1 )  CALL timing_stop( 'zps_hde_isf')
525      !
526   END SUBROUTINE zps_hde_isf
527   !!======================================================================
528END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.