New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcnxt.F90 in branches/2015/dev_r5144_CMCC5_BDY_for_TOP/NEMOGCM/NEMO/TOP_SRC/TRP – NEMO

source: branches/2015/dev_r5144_CMCC5_BDY_for_TOP/NEMOGCM/NEMO/TOP_SRC/TRP/trcnxt.F90 @ 5160

Last change on this file since 5160 was 5160, checked in by lovato, 9 years ago

First implementation of BDY for TOP component, see #1441 (dev_r5144_CMCC5_BDY_for_TOP).
  • Property svn:keywords set to Id
File size: 7.5 KB
Line 
1MODULE trcnxt
2   !!======================================================================
3   !!                       ***  MODULE  trcnxt  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_nxt     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE trc             ! ocean passive tracers variables
30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE prtctl_trc      ! Print control for debbuging
32   USE trd_oce
33   USE trdtra
34   USE tranxt
35   USE trcbdy          ! BDY open boundaries
36   USE bdy_par, only: lk_bdy
37# if defined key_agrif
38   USE agrif_top_interp
39# endif
40
41   IMPLICIT NONE
42   PRIVATE
43
44   PUBLIC   trc_nxt          ! routine called by step.F90
45   PUBLIC   trc_nxt_alloc    ! routine called by nemogcm.F90
46
47   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:) ::   r2dt
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 3.3 , NEMO Consortium (2010)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   INTEGER FUNCTION trc_nxt_alloc()
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trc_nxt_alloc  ***
59      !!----------------------------------------------------------------------
60      ALLOCATE( r2dt(jpk), STAT=trc_nxt_alloc )
61      !
62      IF( trc_nxt_alloc /= 0 )   CALL ctl_warn('trc_nxt_alloc : failed to allocate array')
63      !
64   END FUNCTION trc_nxt_alloc
65
66
67   SUBROUTINE trc_nxt( kt )
68      !!----------------------------------------------------------------------
69      !!                   ***  ROUTINE trcnxt  ***
70      !!
71      !! ** Purpose :   Compute the passive tracers fields at the
72      !!      next time-step from their temporal trends and swap the fields.
73      !!
74      !! ** Method  :   Apply lateral boundary conditions on (ua,va) through
75      !!      call to lbc_lnk routine
76      !!   default:
77      !!      arrays swap
78      !!         (trn) = (tra) ; (tra) = (0,0)
79      !!         (trb) = (trn)
80      !!
81      !!   For Arakawa or TVD Scheme :
82      !!      A Asselin time filter applied on now tracers (trn) to avoid
83      !!      the divergence of two consecutive time-steps and tr arrays
84      !!      to prepare the next time_step:
85      !!         (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ]
86      !!         (trn) = (tra) ; (tra) = (0,0)
87      !!
88      !!
89      !! ** Action  : - update trb, trn
90      !!----------------------------------------------------------------------
91      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
92      !
93      INTEGER  ::   jk, jn   ! dummy loop indices
94      REAL(wp) ::   zfact            ! temporary scalar
95      CHARACTER (len=22) :: charout
96      REAL(wp), POINTER, DIMENSION(:,:,:,:) ::  ztrdt 
97      !!----------------------------------------------------------------------
98      !
99      IF( nn_timing == 1 )  CALL timing_start('trc_nxt')
100      !
101      IF( kt == nittrc000 .AND. lwp ) THEN
102         WRITE(numout,*)
103         WRITE(numout,*) 'trc_nxt : time stepping on passive tracers'
104      ENDIF
105
106      ! Update after tracer on domain lateral boundaries
107      DO jn = 1, jptra
108         CALL lbc_lnk( tra(:,:,:,jn), 'T', 1. )   
109      END DO
110
111
112      IF( lk_bdy )  CALL trc_bdy( kt )               ! BDY open boundaries
113
114#if defined key_agrif
115      CALL Agrif_trc                   ! AGRIF zoom boundaries
116#endif
117
118
119      ! set time step size (Euler/Leapfrog)
120      IF( neuler == 0 .AND. kt ==  nittrc000 ) THEN  ;  r2dt(:) =     rdttrc(:)   ! at nittrc000             (Euler)
121      ELSEIF( kt <= nittrc000 + 1 )            THEN  ;  r2dt(:) = 2.* rdttrc(:)   ! at nit000 or nit000+1 (Leapfrog)
122      ENDIF
123
124      ! trends computation initialisation
125      IF( l_trdtrc )  THEN
126         CALL wrk_alloc( jpi, jpj, jpk, jptra, ztrdt )  !* store now fields before applying the Asselin filter
127         ztrdt(:,:,:,:)  = trn(:,:,:,:)
128      ENDIF
129      ! Leap-Frog + Asselin filter time stepping
130      IF( neuler == 0 .AND. kt == nittrc000 ) THEN        ! Euler time-stepping at first time-step
131         !                                                ! (only swap)
132         DO jn = 1, jptra
133            DO jk = 1, jpkm1
134               trn(:,:,jk,jn) = tra(:,:,jk,jn)
135            END DO
136         END DO
137         !                                             
138      ELSE
139         ! Leap-Frog + Asselin filter time stepping
140         IF( lk_vvl ) THEN   ;   CALL tra_nxt_vvl( kt, nittrc000, 'TRC', trb, trn, tra, jptra )      ! variable volume level (vvl)
141         ELSE                ;   CALL tra_nxt_fix( kt, nittrc000, 'TRC', trb, trn, tra, jptra )      ! fixed    volume level
142         ENDIF
143      ENDIF
144
145      ! trends computation
146      IF( l_trdtrc ) THEN                                      ! trends
147         DO jn = 1, jptra
148            DO jk = 1, jpkm1
149               zfact = 1.e0 / r2dt(jk) 
150               ztrdt(:,:,jk,jn) = ( trb(:,:,jk,jn) - ztrdt(:,:,jk,jn) ) * zfact 
151               CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt )
152            END DO
153         END DO
154         CALL wrk_dealloc( jpi, jpj, jpk, jptra, ztrdt ) 
155      END IF
156      !
157      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
158         WRITE(charout, FMT="('nxt')")
159         CALL prt_ctl_trc_info(charout)
160         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
161      ENDIF
162      !
163      IF( nn_timing == 1 )  CALL timing_stop('trc_nxt')
164      !
165   END SUBROUTINE trc_nxt
166
167#else
168   !!----------------------------------------------------------------------
169   !!   Default option                                         Empty module
170   !!----------------------------------------------------------------------
171CONTAINS
172   SUBROUTINE trc_nxt( kt ) 
173      INTEGER, INTENT(in) :: kt
174      WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt
175   END SUBROUTINE trc_nxt
176#endif
177   !!======================================================================
178END MODULE trcnxt
Note: See TracBrowser for help on using the repository browser.