New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5834

Last change on this file since 5834 was 5834, checked in by mathiot, 8 years ago

Ice shelf branch: cosmetic changes

  • Property svn:keywords set to Id
File size: 63.3 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE iom
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
135      REAL(wp) ::   znad
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
138      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
139      !!
140      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
141         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
142      !!----------------------------------------------------------------------
143      !
144      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
145      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
146901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
147
148      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
149      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
150902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
151      IF(lwm) WRITE ( numond, namdyn_hpg )
152      !
153      IF(lwp) THEN                   ! Control print
154         WRITE(numout,*)
155         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
156         WRITE(numout,*) '~~~~~~~~~~~~'
157         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
158         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
159         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
162         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
163         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
164         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
165      ENDIF
166      !
167      IF( ln_hpg_djc )   &
168         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
169                           & currently disabled (bugs under investigation). Please select &
170                           & either  ln_hpg_sco or  ln_hpg_prj instead')
171      !
172      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
173         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
174                           & the standard jacobian formulation hpg_sco or &
175                           & the pressure jacobian formulation hpg_prj')
176
177      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
178         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
179      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
180         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
181      !
182      !                               ! Set nhpg from ln_hpg_... flags
183      IF( ln_hpg_zco )   nhpg = 0
184      IF( ln_hpg_zps )   nhpg = 1
185      IF( ln_hpg_sco )   nhpg = 2
186      IF( ln_hpg_djc )   nhpg = 3
187      IF( ln_hpg_prj )   nhpg = 4
188      IF( ln_hpg_isf )   nhpg = 5
189      !
190      !                               ! Consistency check
191      ioptio = 0
192      IF( ln_hpg_zco )   ioptio = ioptio + 1
193      IF( ln_hpg_zps )   ioptio = ioptio + 1
194      IF( ln_hpg_sco )   ioptio = ioptio + 1
195      IF( ln_hpg_djc )   ioptio = ioptio + 1
196      IF( ln_hpg_prj )   ioptio = ioptio + 1
197      IF( ln_hpg_isf )   ioptio = ioptio + 1
198      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
199      !
200      ! initialisation of ice shelf load
201      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
202      IF (       ln_isfcav ) THEN
203         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
204         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
205         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
206         !
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
209         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
210
211         ! To use density and not density anomaly
212         znad=1._wp
213         
214         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
215         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
216
217         ! compute density of the water displaced by the ice shelf
218         DO jk = 1, jpk
219            CALL eos(ztstop(:,:,:),fsdept_n(:,:,jk),zrhd(:,:,jk))
220         END DO
221     
222         ! compute rhd at the ice/oce interface (ice shelf side)
223         CALL eos(ztstop,risfdep,zrhdtop_isf)
224
225         ! Surface value + ice shelf gradient
226         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
227         ! divided by 2 later
228         ziceload = 0._wp
229         DO jj = 1, jpj
230            DO ji = 1, jpi   ! vector opt.
231               ikt=mikt(ji,jj)
232               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
233               DO jk=2,ikt-1
234                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
235                     &                              * (1._wp - tmask(ji,jj,jk))
236               END DO
237               IF (ikt .GE. 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
238                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
239            END DO
240         END DO
241         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
242
243         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
244         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
245         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
246      END IF
247      !
248   END SUBROUTINE dyn_hpg_init
249
250
251   SUBROUTINE hpg_zco( kt )
252      !!---------------------------------------------------------------------
253      !!                  ***  ROUTINE hpg_zco  ***
254      !!
255      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
256      !!      The now hydrostatic pressure gradient at a given level, jk,
257      !!      is computed by taking the vertical integral of the in-situ
258      !!      density gradient along the model level from the suface to that
259      !!      level:    zhpi = grav .....
260      !!                zhpj = grav .....
261      !!      add it to the general momentum trend (ua,va).
262      !!            ua = ua - 1/e1u * zhpi
263      !!            va = va - 1/e2v * zhpj
264      !!
265      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
266      !!----------------------------------------------------------------------
267      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
268      !!
269      INTEGER  ::   ji, jj, jk       ! dummy loop indices
270      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
271      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
272      !!----------------------------------------------------------------------
273      !
274      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
275      !
276      IF( kt == nit000 ) THEN
277         IF(lwp) WRITE(numout,*)
278         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
279         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
280      ENDIF
281
282      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
283
284      ! Surface value
285      DO jj = 2, jpjm1
286         DO ji = fs_2, fs_jpim1   ! vector opt.
287            zcoef1 = zcoef0 * fse3w(ji,jj,1)
288            ! hydrostatic pressure gradient
289            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
290            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
291            ! add to the general momentum trend
292            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
293            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
294         END DO
295      END DO
296
297      !
298      ! interior value (2=<jk=<jpkm1)
299      DO jk = 2, jpkm1
300         DO jj = 2, jpjm1
301            DO ji = fs_2, fs_jpim1   ! vector opt.
302               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
303               ! hydrostatic pressure gradient
304               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
305                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
306                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
307
308               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
309                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
310                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
311               ! add to the general momentum trend
312               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
313               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
314            END DO
315         END DO
316      END DO
317      !
318      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
319      !
320   END SUBROUTINE hpg_zco
321
322
323   SUBROUTINE hpg_zps( kt )
324      !!---------------------------------------------------------------------
325      !!                 ***  ROUTINE hpg_zps  ***
326      !!
327      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
328      !!
329      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
330      !!----------------------------------------------------------------------
331      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
332      !!
333      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
334      INTEGER  ::   iku, ikv                         ! temporary integers
335      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
336      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
337      !!----------------------------------------------------------------------
338      !
339      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
340      !
341      IF( kt == nit000 ) THEN
342         IF(lwp) WRITE(numout,*)
343         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
344         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
345      ENDIF
346
347
348      ! Local constant initialization
349      zcoef0 = - grav * 0.5_wp
350
351      !  Surface value (also valid in partial step case)
352      DO jj = 2, jpjm1
353         DO ji = fs_2, fs_jpim1   ! vector opt.
354            zcoef1 = zcoef0 * fse3w(ji,jj,1)
355            ! hydrostatic pressure gradient
356            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
357            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
358            ! add to the general momentum trend
359            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
360            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
361         END DO
362      END DO
363
364
365      ! interior value (2=<jk=<jpkm1)
366      DO jk = 2, jpkm1
367         DO jj = 2, jpjm1
368            DO ji = fs_2, fs_jpim1   ! vector opt.
369               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
370               ! hydrostatic pressure gradient
371               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
372                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
373                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
374
375               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
376                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
377                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
378               ! add to the general momentum trend
379               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
380               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
381            END DO
382         END DO
383      END DO
384
385
386      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
387      DO jj = 2, jpjm1
388         DO ji = 2, jpim1
389            iku = mbku(ji,jj)
390            ikv = mbkv(ji,jj)
391            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
392            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
393            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
394               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
395               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
396                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
397               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
398            ENDIF
399            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
400               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
401               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
402                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
403               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
404            ENDIF
405         END DO
406      END DO
407      !
408      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
409      !
410   END SUBROUTINE hpg_zps
411
412   SUBROUTINE hpg_sco( kt )
413      !!---------------------------------------------------------------------
414      !!                  ***  ROUTINE hpg_sco  ***
415      !!
416      !! ** Method  :   s-coordinate case. Jacobian scheme.
417      !!      The now hydrostatic pressure gradient at a given level, jk,
418      !!      is computed by taking the vertical integral of the in-situ
419      !!      density gradient along the model level from the suface to that
420      !!      level. s-coordinates (ln_sco): a corrective term is added
421      !!      to the horizontal pressure gradient :
422      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
423      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
424      !!      add it to the general momentum trend (ua,va).
425      !!         ua = ua - 1/e1u * zhpi
426      !!         va = va - 1/e2v * zhpj
427      !!
428      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
429      !!----------------------------------------------------------------------
430      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
431      !!
432      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
433      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
434      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
435      !!----------------------------------------------------------------------
436      !
437      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
438      !
439      IF( kt == nit000 ) THEN
440         IF(lwp) WRITE(numout,*)
441         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
442         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
443      ENDIF
444
445      ! Local constant initialization
446      zcoef0 = - grav * 0.5_wp
447      ! To use density and not density anomaly
448      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
449      ELSE                 ;     znad = 0._wp         ! Fixed volume
450      ENDIF
451
452      ! Surface value
453      DO jj = 2, jpjm1
454         DO ji = fs_2, fs_jpim1   ! vector opt.
455            ! hydrostatic pressure gradient along s-surfaces
456            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
457               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
458            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
459               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
460            ! s-coordinate pressure gradient correction
461            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
462               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
463            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
464               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
465            ! add to the general momentum trend
466            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
467            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
468         END DO
469      END DO
470
471      ! interior value (2=<jk=<jpkm1)
472      DO jk = 2, jpkm1
473         DO jj = 2, jpjm1
474            DO ji = fs_2, fs_jpim1   ! vector opt.
475               ! hydrostatic pressure gradient along s-surfaces
476               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
477                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
478                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
479               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
480                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
481                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
482               ! s-coordinate pressure gradient correction
483               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
484                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
485               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
486                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
487               ! add to the general momentum trend
488               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
489               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
490            END DO
491         END DO
492      END DO
493      !
494      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
495      !
496   END SUBROUTINE hpg_sco
497
498   SUBROUTINE hpg_isf( kt )
499      !!---------------------------------------------------------------------
500      !!                  ***  ROUTINE hpg_sco  ***
501      !!
502      !! ** Method  :   s-coordinate case. Jacobian scheme.
503      !!      The now hydrostatic pressure gradient at a given level, jk,
504      !!      is computed by taking the vertical integral of the in-situ
505      !!      density gradient along the model level from the suface to that
506      !!      level. s-coordinates (ln_sco): a corrective term is added
507      !!      to the horizontal pressure gradient :
508      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
509      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
510      !!      add it to the general momentum trend (ua,va).
511      !!         ua = ua - 1/e1u * zhpi
512      !!         va = va - 1/e2v * zhpj
513      !!      iceload is added and partial cell case are added to the top and bottom
514      !!     
515      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
516      !!----------------------------------------------------------------------
517      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
518      !!
519      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
520      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
521      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
522      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
523      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce, zpshpi, zpshpj
524      !!----------------------------------------------------------------------
525      !
526      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
527      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
528      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce, zpshpi, zpshpj) 
529      !
530      ! Local constant initialization
531      zcoef0 = - grav * 0.5_wp
532   
533      ! To use density and not density anomaly
534      znad=1._wp
535
536      ! iniitialised to 0. zhpi zhpi
537      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
538
539      ! compute rhd at the ice/oce interface (ocean side) usefull to reduce unrealistic water current if homogene water
540!  TO BE DISCUSS do we compute density at w point for the ocean/ice atmosphere
541!      DO ji=1,jpi
542!        DO jj=1,jpj
543!          ikt=mikt(ji,jj)
544!          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
545!          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
546!        END DO
547!      END DO
548!      CALL eos(ztstop,risfdep,zrhdtop_oce)
549
550!==================================================================================     
551!===== Compute surface value =====================================================
552!==================================================================================
553      DO jj = 2, jpjm1
554         DO ji = fs_2, fs_jpim1   ! vector opt.
555            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
556            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
557            ! we assume ISF is in isostatic equilibrium
558            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,iktp1i) * ( znad + rhd(ji+1,jj  ,iktp1i) )   &
559               &                                  - fse3w(ji  ,jj  ,ikt   ) * ( znad + rhd(ji  ,jj  ,ikt   ) )   &
560               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                       ) 
561            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,iktp1j) * ( znad + rhd(ji  ,jj+1,iktp1j) )   &
562               &                                  - fse3w(ji  ,jj  ,ikt   ) * ( znad + rhd(ji  ,jj  ,ikt   ) )   &
563               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj) )                      ) 
564!            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj  ,iktp1i)                                    &
565!               &                                  * ( 2._wp * znad + rhd(ji+1,jj  ,iktp1i) + zrhdtop_oce(ji+1,jj  ) )   &
566!               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
567!               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
568!               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                              )
569!            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji  ,jj+1,iktp1j)                                    &
570!               &                                  * ( 2._wp * znad + rhd(ji  ,jj+1,iktp1j) + zrhdtop_oce(ji  ,jj+1) )   &
571!               &                                  - 0.5_wp * fse3w(ji  ,jj  ,ikt   )                                    &
572!               &                                  * ( 2._wp * znad + rhd(ji  ,jj  ,ikt   ) + zrhdtop_oce(ji  ,jj  ) )   &
573!               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj) )                             )
574            ! s-coordinate pressure gradient correction (=0 if z coordinate)
575            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
576               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
577            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
578               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
579            ! add to the general momentum trend
580            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
581            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
582         END DO
583      END DO
584
585!==================================================================================     
586!===== Compute interior value =====================================================
587!==================================================================================
588      ! interior value (2=<jk=<jpkm1)
589      DO jk = 2, jpkm1
590         DO jj = 2, jpjm1
591            DO ji = fs_2, fs_jpim1   ! vector opt.
592               ! hydrostatic pressure gradient along s-surfaces
593               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
594                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
595                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
596               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
597                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
598                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
599               ! s-coordinate pressure gradient correction
600               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
601                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
602               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
603                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
604               ! add to the general momentum trend
605               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
606               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
607            END DO
608         END DO
609      END DO
610      !
611      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
612      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
613      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce, zpshpi, zpshpj)
614      !
615   END SUBROUTINE hpg_isf
616
617
618   SUBROUTINE hpg_djc( kt )
619      !!---------------------------------------------------------------------
620      !!                  ***  ROUTINE hpg_djc  ***
621      !!
622      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
623      !!
624      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
625      !!----------------------------------------------------------------------
626      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
627      !!
628      INTEGER  ::   ji, jj, jk          ! dummy loop indices
629      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
630      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
631      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
632      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
633      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
634      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
635      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
636      !!----------------------------------------------------------------------
637      !
638      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
639      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
640      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
641      !
642
643      IF( kt == nit000 ) THEN
644         IF(lwp) WRITE(numout,*)
645         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
646         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
647      ENDIF
648
649      ! Local constant initialization
650      zcoef0 = - grav * 0.5_wp
651      z1_10  = 1._wp / 10._wp
652      z1_12  = 1._wp / 12._wp
653
654      !----------------------------------------------------------------------------------------
655      !  compute and store in provisional arrays elementary vertical and horizontal differences
656      !----------------------------------------------------------------------------------------
657
658!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
659
660      DO jk = 2, jpkm1
661         DO jj = 2, jpjm1
662            DO ji = fs_2, fs_jpim1   ! vector opt.
663               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
664               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
665               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
666               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
667               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
668               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
669            END DO
670         END DO
671      END DO
672
673      !-------------------------------------------------------------------------
674      ! compute harmonic averages using eq. 5.18
675      !-------------------------------------------------------------------------
676      zep = 1.e-15
677
678!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
679!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
680
681      DO jk = 2, jpkm1
682         DO jj = 2, jpjm1
683            DO ji = fs_2, fs_jpim1   ! vector opt.
684               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
685
686               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
687               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
688
689               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
690               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
691
692               IF( cffw > zep) THEN
693                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
694                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
695               ELSE
696                  drhow(ji,jj,jk) = 0._wp
697               ENDIF
698
699               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
700                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
701
702               IF( cffu > zep ) THEN
703                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
704                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
705               ELSE
706                  drhou(ji,jj,jk ) = 0._wp
707               ENDIF
708
709               IF( cffx > zep ) THEN
710                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
711                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
712               ELSE
713                  dzu(ji,jj,jk) = 0._wp
714               ENDIF
715
716               IF( cffv > zep ) THEN
717                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
718                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
719               ELSE
720                  drhov(ji,jj,jk) = 0._wp
721               ENDIF
722
723               IF( cffy > zep ) THEN
724                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
725                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
726               ELSE
727                  dzv(ji,jj,jk) = 0._wp
728               ENDIF
729
730            END DO
731         END DO
732      END DO
733
734      !----------------------------------------------------------------------------------
735      ! apply boundary conditions at top and bottom using 5.36-5.37
736      !----------------------------------------------------------------------------------
737      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
738      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
739      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
740
741      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
742      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
743      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
744
745
746      !--------------------------------------------------------------
747      ! Upper half of top-most grid box, compute and store
748      !-------------------------------------------------------------
749
750!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
751!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
752
753      DO jj = 2, jpjm1
754         DO ji = fs_2, fs_jpim1   ! vector opt.
755            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
756               &                   * (  rhd(ji,jj,1)                                    &
757               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
758               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
759               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
760         END DO
761      END DO
762
763!!bug gm    : here also, simplification is possible
764!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
765
766      DO jk = 2, jpkm1
767         DO jj = 2, jpjm1
768            DO ji = fs_2, fs_jpim1   ! vector opt.
769
770               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
771                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
772                  &            - grav * z1_10 * (                                                                     &
773                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
774                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
775                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
776                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
777                  &                             )
778
779               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
780                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
781                  &            - grav* z1_10 * (                                                                      &
782                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
783                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
784                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
785                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
786                  &                            )
787
788               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
789                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
790                  &            - grav* z1_10 * (                                                                      &
791                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
792                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
793                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
794                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
795                  &                            )
796
797            END DO
798         END DO
799      END DO
800      CALL lbc_lnk(rho_k,'W',1.)
801      CALL lbc_lnk(rho_i,'U',1.)
802      CALL lbc_lnk(rho_j,'V',1.)
803
804
805      ! ---------------
806      !  Surface value
807      ! ---------------
808      DO jj = 2, jpjm1
809         DO ji = fs_2, fs_jpim1   ! vector opt.
810            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
811            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
812            ! add to the general momentum trend
813            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
814            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
815         END DO
816      END DO
817
818      ! ----------------
819      !  interior value   (2=<jk=<jpkm1)
820      ! ----------------
821      DO jk = 2, jpkm1
822         DO jj = 2, jpjm1
823            DO ji = fs_2, fs_jpim1   ! vector opt.
824               ! hydrostatic pressure gradient along s-surfaces
825               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
826                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
827                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
828               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
829                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
830                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
831               ! add to the general momentum trend
832               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
833               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
834            END DO
835         END DO
836      END DO
837      !
838      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
839      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
840      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
841      !
842   END SUBROUTINE hpg_djc
843
844
845   SUBROUTINE hpg_prj( kt )
846      !!---------------------------------------------------------------------
847      !!                  ***  ROUTINE hpg_prj  ***
848      !!
849      !! ** Method  :   s-coordinate case.
850      !!      A Pressure-Jacobian horizontal pressure gradient method
851      !!      based on the constrained cubic-spline interpolation for
852      !!      all vertical coordinate systems
853      !!
854      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
855      !!----------------------------------------------------------------------
856      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
857      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
858      !!
859      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
860      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
861      !!
862      !! The local variables for the correction term
863      INTEGER  :: jk1, jis, jid, jjs, jjd
864      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
865      REAL(wp) :: zrhdt1
866      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
867      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
868      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
869      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
870      !!----------------------------------------------------------------------
871      !
872      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
873      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
874      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
875      !
876      IF( kt == nit000 ) THEN
877         IF(lwp) WRITE(numout,*)
878         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
879         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
880      ENDIF
881
882      !!----------------------------------------------------------------------
883      ! Local constant initialization
884      zcoef0 = - grav
885      znad = 0.0_wp
886      IF( lk_vvl ) znad = 1._wp
887
888      ! Clean 3-D work arrays
889      zhpi(:,:,:) = 0._wp
890      zrhh(:,:,:) = rhd(:,:,:)
891
892      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
893      DO jj = 1, jpj
894        DO ji = 1, jpi
895          jk = mbathy(ji,jj)
896          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
897          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
898          ELSE IF(jk < jpkm1) THEN
899             DO jkk = jk+1, jpk
900                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
901                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
902             END DO
903          ENDIF
904        END DO
905      END DO
906
907      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
908      DO jj = 1, jpj
909         DO ji = 1, jpi
910            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
911         END DO
912      END DO
913
914      DO jk = 2, jpk
915         DO jj = 1, jpj
916            DO ji = 1, jpi
917               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
918            END DO
919         END DO
920      END DO
921
922      fsp(:,:,:) = zrhh (:,:,:)
923      xsp(:,:,:) = zdept(:,:,:)
924
925      ! Construct the vertical density profile with the
926      ! constrained cubic spline interpolation
927      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
928      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
929
930      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
931      DO jj = 2, jpj
932        DO ji = 2, jpi
933          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
934                                         bsp(ji,jj,1),   csp(ji,jj,1), &
935                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
936
937          ! assuming linear profile across the top half surface layer
938          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
939        END DO
940      END DO
941
942      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
943      DO jk = 2, jpkm1
944        DO jj = 2, jpj
945          DO ji = 2, jpi
946            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
947                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
948                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
949                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
950          END DO
951        END DO
952      END DO
953
954      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
955
956      ! Prepare zsshu_n and zsshv_n
957      DO jj = 2, jpjm1
958        DO ji = 2, jpim1
959          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
960                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
961          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
962                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
963        END DO
964      END DO
965
966      DO jj = 2, jpjm1
967        DO ji = 2, jpim1
968          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
969          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
970        END DO
971      END DO
972
973      DO jk = 2, jpkm1
974        DO jj = 2, jpjm1
975          DO ji = 2, jpim1
976            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
977            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
978          END DO
979        END DO
980      END DO
981
982      DO jk = 1, jpkm1
983        DO jj = 2, jpjm1
984          DO ji = 2, jpim1
985            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
986            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
987          END DO
988        END DO
989      END DO
990
991      DO jk = 1, jpkm1
992        DO jj = 2, jpjm1
993          DO ji = 2, jpim1
994            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
995            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
996            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
997            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
998          END DO
999        END DO
1000      END DO
1001
1002
1003      DO jk = 1, jpkm1
1004        DO jj = 2, jpjm1
1005          DO ji = 2, jpim1
1006            zpwes = 0._wp; zpwed = 0._wp
1007            zpnss = 0._wp; zpnsd = 0._wp
1008            zuijk = zu(ji,jj,jk)
1009            zvijk = zv(ji,jj,jk)
1010
1011            !!!!!     for u equation
1012            IF( jk <= mbku(ji,jj) ) THEN
1013               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1014                 jis = ji + 1; jid = ji
1015               ELSE
1016                 jis = ji;     jid = ji +1
1017               ENDIF
1018
1019               ! integrate the pressure on the shallow side
1020               jk1 = jk
1021               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1022                 IF( jk1 == mbku(ji,jj) ) THEN
1023                   zuijk = -zdept(jis,jj,jk1)
1024                   EXIT
1025                 ENDIF
1026                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1027                 zpwes = zpwes +                                    &
1028                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1029                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1030                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1031                 jk1 = jk1 + 1
1032               END DO
1033
1034               ! integrate the pressure on the deep side
1035               jk1 = jk
1036               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1037                 IF( jk1 == 1 ) THEN
1038                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1039                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1040                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1041                                                     dsp(jid,jj,1)) * zdeps
1042                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1043                   EXIT
1044                 ENDIF
1045                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1046                 zpwed = zpwed +                                        &
1047                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1048                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1049                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1050                 jk1 = jk1 - 1
1051               END DO
1052
1053               ! update the momentum trends in u direction
1054
1055               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1056               IF( lk_vvl ) THEN
1057                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1058                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1059                ELSE
1060                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1061               ENDIF
1062
1063               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1064               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1065            ENDIF
1066
1067            !!!!!     for v equation
1068            IF( jk <= mbkv(ji,jj) ) THEN
1069               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1070                 jjs = jj + 1; jjd = jj
1071               ELSE
1072                 jjs = jj    ; jjd = jj + 1
1073               ENDIF
1074
1075               ! integrate the pressure on the shallow side
1076               jk1 = jk
1077               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1078                 IF( jk1 == mbkv(ji,jj) ) THEN
1079                   zvijk = -zdept(ji,jjs,jk1)
1080                   EXIT
1081                 ENDIF
1082                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1083                 zpnss = zpnss +                                      &
1084                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1085                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1086                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1087                 jk1 = jk1 + 1
1088               END DO
1089
1090               ! integrate the pressure on the deep side
1091               jk1 = jk
1092               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1093                 IF( jk1 == 1 ) THEN
1094                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1095                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1096                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1097                                                     dsp(ji,jjd,1) ) * zdeps
1098                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1099                   EXIT
1100                 ENDIF
1101                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1102                 zpnsd = zpnsd +                                        &
1103                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1104                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1105                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1106                 jk1 = jk1 - 1
1107               END DO
1108
1109
1110               ! update the momentum trends in v direction
1111
1112               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1113               IF( lk_vvl ) THEN
1114                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1115                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1116               ELSE
1117                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1118               ENDIF
1119
1120               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1121               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1122            ENDIF
1123
1124
1125           END DO
1126        END DO
1127      END DO
1128      !
1129      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1130      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1131      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1132      !
1133   END SUBROUTINE hpg_prj
1134
1135
1136   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1137      !!----------------------------------------------------------------------
1138      !!                 ***  ROUTINE cspline  ***
1139      !!
1140      !! ** Purpose :   constrained cubic spline interpolation
1141      !!
1142      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1143      !!
1144      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1145      !!----------------------------------------------------------------------
1146      IMPLICIT NONE
1147      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1148      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1149                                                                    ! the interpoated function
1150      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1151                                                                    ! 2: Linear
1152      !
1153      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1154      INTEGER  ::   jpi, jpj, jpkm1
1155      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1156      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1157      REAL(wp) ::   zdf(size(fsp,3))
1158      !!----------------------------------------------------------------------
1159
1160      jpi   = size(fsp,1)
1161      jpj   = size(fsp,2)
1162      jpkm1 = size(fsp,3) - 1
1163
1164
1165      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1166         DO ji = 1, jpi
1167            DO jj = 1, jpj
1168           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1169           !    DO jk = 2, jpkm1-1
1170           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1171           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1172           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1173           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1174           !
1175           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1176           !
1177           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1178           !           zdf(jk) = 0._wp
1179           !       ELSE
1180           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1181           !       ENDIF
1182           !    END DO
1183
1184           !!Simply geometric average
1185               DO jk = 2, jpkm1-1
1186                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1187                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1188
1189                  IF(zdf1 * zdf2 <= 0._wp) THEN
1190                     zdf(jk) = 0._wp
1191                  ELSE
1192                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1193                  ENDIF
1194               END DO
1195
1196               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1197                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1198               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1199                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1200                          & 0.5_wp * zdf(jpkm1 - 1)
1201
1202               DO jk = 1, jpkm1 - 1
1203                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1204                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1205                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1206                 zddf1  = -2._wp * ztmp1 + ztmp2
1207                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1208                 zddf2  =  2._wp * ztmp1 - ztmp2
1209
1210                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1211                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1212                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1213                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1214                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1215                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1216                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1217                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1218                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1219               END DO
1220            END DO
1221         END DO
1222
1223      ELSE IF (polynomial_type == 2) THEN     ! Linear
1224         DO ji = 1, jpi
1225            DO jj = 1, jpj
1226               DO jk = 1, jpkm1-1
1227                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1228                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1229
1230                  dsp(ji,jj,jk) = 0._wp
1231                  csp(ji,jj,jk) = 0._wp
1232                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1233                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1234               END DO
1235            END DO
1236         END DO
1237
1238      ELSE
1239           CALL ctl_stop( 'invalid polynomial type in cspline' )
1240      ENDIF
1241
1242   END SUBROUTINE cspline
1243
1244
1245   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1246      !!----------------------------------------------------------------------
1247      !!                 ***  ROUTINE interp1  ***
1248      !!
1249      !! ** Purpose :   1-d linear interpolation
1250      !!
1251      !! ** Method  :   interpolation is straight forward
1252      !!                extrapolation is also permitted (no value limit)
1253      !!----------------------------------------------------------------------
1254      IMPLICIT NONE
1255      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1256      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1257      REAL(wp)             ::  zdeltx
1258      !!----------------------------------------------------------------------
1259
1260      zdeltx = xr - xl
1261      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1262        f = 0.5_wp * (fl + fr)
1263      ELSE
1264        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1265      ENDIF
1266
1267   END FUNCTION interp1
1268
1269
1270   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1271      !!----------------------------------------------------------------------
1272      !!                 ***  ROUTINE interp1  ***
1273      !!
1274      !! ** Purpose :   1-d constrained cubic spline interpolation
1275      !!
1276      !! ** Method  :  cubic spline interpolation
1277      !!
1278      !!----------------------------------------------------------------------
1279      IMPLICIT NONE
1280      REAL(wp), INTENT(in) ::  x, a, b, c, d
1281      REAL(wp)             ::  f ! value from the interpolation
1282      !!----------------------------------------------------------------------
1283
1284      f = a + x* ( b + x * ( c + d * x ) )
1285
1286   END FUNCTION interp2
1287
1288
1289   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1290      !!----------------------------------------------------------------------
1291      !!                 ***  ROUTINE interp1  ***
1292      !!
1293      !! ** Purpose :   Calculate the first order of deriavtive of
1294      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1295      !!
1296      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1297      !!
1298      !!----------------------------------------------------------------------
1299      IMPLICIT NONE
1300      REAL(wp), INTENT(in) ::  x, a, b, c, d
1301      REAL(wp)             ::  f ! value from the interpolation
1302      !!----------------------------------------------------------------------
1303
1304      f = b + x * ( 2._wp * c + 3._wp * d * x)
1305
1306   END FUNCTION interp3
1307
1308
1309   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1310      !!----------------------------------------------------------------------
1311      !!                 ***  ROUTINE interp1  ***
1312      !!
1313      !! ** Purpose :   1-d constrained cubic spline integration
1314      !!
1315      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1316      !!
1317      !!----------------------------------------------------------------------
1318      IMPLICIT NONE
1319      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1320      REAL(wp)             ::  za1, za2, za3
1321      REAL(wp)             ::  f                   ! integration result
1322      !!----------------------------------------------------------------------
1323
1324      za1 = 0.5_wp * b
1325      za2 = c / 3.0_wp
1326      za3 = 0.25_wp * d
1327
1328      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1329         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1330
1331   END FUNCTION integ_spline
1332
1333   !!======================================================================
1334END MODULE dynhpg
1335
Note: See TracBrowser for help on using the repository browser.