source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5944

Last change on this file since 5944 was 5944, checked in by mathiot, 5 years ago

ISF: change related to reviewers comments

  • Property svn:keywords set to Id
File size: 62.5 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38   !
39   USE in_out_manager  ! I/O manager
40   USE prtctl          ! Print control
41   USE lbclnk          ! lateral boundary condition
42   USE lib_mpp         ! MPP library
43   USE eosbn2          ! compute density
44   USE wrk_nemo        ! Memory Allocation
45   USE timing          ! Timing
46   USE iom
47
48   IMPLICIT NONE
49   PRIVATE
50
51   PUBLIC   dyn_hpg        ! routine called by step module
52   PUBLIC   dyn_hpg_init   ! routine called by opa module
53
54   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
55   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
56   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
57   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
58   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
59   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
60   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
61   LOGICAL , PUBLIC ::   ln_dynhpg_imp   !: semi-implicite hpg flag
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
135      REAL(wp) ::   znad
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
138      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
139      !!
140      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
141         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf, ln_dynhpg_imp
142      !!----------------------------------------------------------------------
143      !
144      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
145      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
146901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
147
148      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
149      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
150902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
151      IF(lwm) WRITE ( numond, namdyn_hpg )
152      !
153      IF(lwp) THEN                   ! Control print
154         WRITE(numout,*)
155         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
156         WRITE(numout,*) '~~~~~~~~~~~~'
157         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
158         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
159         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
162         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
163         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
164         WRITE(numout,*) '      time stepping: centered (F) or semi-implicit (T)  ln_dynhpg_imp = ', ln_dynhpg_imp
165      ENDIF
166      !
167      IF( ln_hpg_djc )   &
168         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
169                           & currently disabled (bugs under investigation). Please select &
170                           & either  ln_hpg_sco or  ln_hpg_prj instead')
171      !
172      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
173         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
174                           & the standard jacobian formulation hpg_sco or &
175                           & the pressure jacobian formulation hpg_prj')
176
177      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
178         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
179      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
180         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
181      !
182      !                               ! Set nhpg from ln_hpg_... flags
183      IF( ln_hpg_zco )   nhpg = 0
184      IF( ln_hpg_zps )   nhpg = 1
185      IF( ln_hpg_sco )   nhpg = 2
186      IF( ln_hpg_djc )   nhpg = 3
187      IF( ln_hpg_prj )   nhpg = 4
188      IF( ln_hpg_isf )   nhpg = 5
189      !
190      !                               ! Consistency check
191      ioptio = 0
192      IF( ln_hpg_zco )   ioptio = ioptio + 1
193      IF( ln_hpg_zps )   ioptio = ioptio + 1
194      IF( ln_hpg_sco )   ioptio = ioptio + 1
195      IF( ln_hpg_djc )   ioptio = ioptio + 1
196      IF( ln_hpg_prj )   ioptio = ioptio + 1
197      IF( ln_hpg_isf )   ioptio = ioptio + 1
198      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
199      !
200      ! initialisation of ice shelf load
201      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
202      IF (       ln_isfcav ) THEN
203         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
204         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
205         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
206         !
207         IF(lwp) WRITE(numout,*)
208         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
209         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
210
211         ! To use density and not density anomaly
212         znad=1._wp
213         
214         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
215         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
216
217         ! compute density of the water displaced by the ice shelf
218         DO jk = 1, jpk
219            CALL eos(ztstop(:,:,:),fsdept_n(:,:,jk),zrhd(:,:,jk))
220         END DO
221     
222         ! compute rhd at the ice/oce interface (ice shelf side)
223         CALL eos(ztstop,risfdep,zrhdtop_isf)
224
225         ! Surface value + ice shelf gradient
226         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
227         ! divided by 2 later
228         ziceload = 0._wp
229         DO jj = 1, jpj
230            DO ji = 1, jpi
231               ikt=mikt(ji,jj)
232               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
233               DO jk=2,ikt-1
234                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
235                     &                              * (1._wp - tmask(ji,jj,jk))
236               END DO
237               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
238                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
239            END DO
240         END DO
241         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
242
243         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
244         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
245         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
246      END IF
247      !
248   END SUBROUTINE dyn_hpg_init
249
250
251   SUBROUTINE hpg_zco( kt )
252      !!---------------------------------------------------------------------
253      !!                  ***  ROUTINE hpg_zco  ***
254      !!
255      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
256      !!      The now hydrostatic pressure gradient at a given level, jk,
257      !!      is computed by taking the vertical integral of the in-situ
258      !!      density gradient along the model level from the suface to that
259      !!      level:    zhpi = grav .....
260      !!                zhpj = grav .....
261      !!      add it to the general momentum trend (ua,va).
262      !!            ua = ua - 1/e1u * zhpi
263      !!            va = va - 1/e2v * zhpj
264      !!
265      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
266      !!----------------------------------------------------------------------
267      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
268      !!
269      INTEGER  ::   ji, jj, jk       ! dummy loop indices
270      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
271      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
272      !!----------------------------------------------------------------------
273      !
274      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
275      !
276      IF( kt == nit000 ) THEN
277         IF(lwp) WRITE(numout,*)
278         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
279         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
280      ENDIF
281
282      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
283
284      ! Surface value
285      DO jj = 2, jpjm1
286         DO ji = fs_2, fs_jpim1   ! vector opt.
287            zcoef1 = zcoef0 * fse3w(ji,jj,1)
288            ! hydrostatic pressure gradient
289            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
290            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
291            ! add to the general momentum trend
292            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
293            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
294         END DO
295      END DO
296
297      !
298      ! interior value (2=<jk=<jpkm1)
299      DO jk = 2, jpkm1
300         DO jj = 2, jpjm1
301            DO ji = fs_2, fs_jpim1   ! vector opt.
302               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
303               ! hydrostatic pressure gradient
304               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
305                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
306                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
307
308               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
309                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
310                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
311               ! add to the general momentum trend
312               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
313               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
314            END DO
315         END DO
316      END DO
317      !
318      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
319      !
320   END SUBROUTINE hpg_zco
321
322
323   SUBROUTINE hpg_zps( kt )
324      !!---------------------------------------------------------------------
325      !!                 ***  ROUTINE hpg_zps  ***
326      !!
327      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
328      !!
329      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
330      !!----------------------------------------------------------------------
331      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
332      !!
333      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
334      INTEGER  ::   iku, ikv                         ! temporary integers
335      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
336      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
337      !!----------------------------------------------------------------------
338      !
339      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
340      !
341      IF( kt == nit000 ) THEN
342         IF(lwp) WRITE(numout,*)
343         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
344         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
345      ENDIF
346
347
348      ! Local constant initialization
349      zcoef0 = - grav * 0.5_wp
350
351      !  Surface value (also valid in partial step case)
352      DO jj = 2, jpjm1
353         DO ji = fs_2, fs_jpim1   ! vector opt.
354            zcoef1 = zcoef0 * fse3w(ji,jj,1)
355            ! hydrostatic pressure gradient
356            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
357            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
358            ! add to the general momentum trend
359            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
360            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
361         END DO
362      END DO
363
364
365      ! interior value (2=<jk=<jpkm1)
366      DO jk = 2, jpkm1
367         DO jj = 2, jpjm1
368            DO ji = fs_2, fs_jpim1   ! vector opt.
369               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
370               ! hydrostatic pressure gradient
371               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
372                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
373                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
374
375               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
376                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
377                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
378               ! add to the general momentum trend
379               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
380               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
381            END DO
382         END DO
383      END DO
384
385
386      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
387      DO jj = 2, jpjm1
388         DO ji = 2, jpim1
389            iku = mbku(ji,jj)
390            ikv = mbkv(ji,jj)
391            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
392            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
393            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
394               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
395               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
396                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
397               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
398            ENDIF
399            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
400               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
401               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
402                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
403               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
404            ENDIF
405         END DO
406      END DO
407      !
408      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
409      !
410   END SUBROUTINE hpg_zps
411
412   SUBROUTINE hpg_sco( kt )
413      !!---------------------------------------------------------------------
414      !!                  ***  ROUTINE hpg_sco  ***
415      !!
416      !! ** Method  :   s-coordinate case. Jacobian scheme.
417      !!      The now hydrostatic pressure gradient at a given level, jk,
418      !!      is computed by taking the vertical integral of the in-situ
419      !!      density gradient along the model level from the suface to that
420      !!      level. s-coordinates (ln_sco): a corrective term is added
421      !!      to the horizontal pressure gradient :
422      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
423      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
424      !!      add it to the general momentum trend (ua,va).
425      !!         ua = ua - 1/e1u * zhpi
426      !!         va = va - 1/e2v * zhpj
427      !!
428      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
429      !!----------------------------------------------------------------------
430      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
431      !!
432      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
433      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
434      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
435      !!----------------------------------------------------------------------
436      !
437      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
438      !
439      IF( kt == nit000 ) THEN
440         IF(lwp) WRITE(numout,*)
441         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
442         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
443      ENDIF
444
445      ! Local constant initialization
446      zcoef0 = - grav * 0.5_wp
447      ! To use density and not density anomaly
448      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
449      ELSE                 ;     znad = 0._wp         ! Fixed volume
450      ENDIF
451
452      ! Surface value
453      DO jj = 2, jpjm1
454         DO ji = fs_2, fs_jpim1   ! vector opt.
455            ! hydrostatic pressure gradient along s-surfaces
456            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
457               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
458            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
459               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
460            ! s-coordinate pressure gradient correction
461            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
462               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
463            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
464               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
465            ! add to the general momentum trend
466            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
467            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
468         END DO
469      END DO
470
471      ! interior value (2=<jk=<jpkm1)
472      DO jk = 2, jpkm1
473         DO jj = 2, jpjm1
474            DO ji = fs_2, fs_jpim1   ! vector opt.
475               ! hydrostatic pressure gradient along s-surfaces
476               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
477                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
478                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
479               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
480                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
481                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
482               ! s-coordinate pressure gradient correction
483               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
484                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
485               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
486                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
487               ! add to the general momentum trend
488               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
489               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
490            END DO
491         END DO
492      END DO
493      !
494      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
495      !
496   END SUBROUTINE hpg_sco
497
498   SUBROUTINE hpg_isf( kt )
499      !!---------------------------------------------------------------------
500      !!                  ***  ROUTINE hpg_isf  ***
501      !!
502      !! ** Method  :   s-coordinate case. Jacobian scheme.
503      !!      The now hydrostatic pressure gradient at a given level, jk,
504      !!      is computed by taking the vertical integral of the in-situ
505      !!      density gradient along the model level from the suface to that
506      !!      level. s-coordinates (ln_sco): a corrective term is added
507      !!      to the horizontal pressure gradient :
508      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
509      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
510      !!      add it to the general momentum trend (ua,va).
511      !!         ua = ua - 1/e1u * zhpi
512      !!         va = va - 1/e2v * zhpj
513      !!      iceload is added and partial cell case are added to the top and bottom
514      !!     
515      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
516      !!----------------------------------------------------------------------
517      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
518      !!
519      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
520      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
521      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
522      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
523      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce
524      !!----------------------------------------------------------------------
525      !
526      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
527      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
528      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce )
529      !
530      ! Local constant initialization
531      zcoef0 = - grav * 0.5_wp
532   
533      ! To use density and not density anomaly
534      znad=1._wp
535
536      ! iniitialised to 0. zhpi zhpi
537      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
538
539      ! compute rhd at the ice/oce interface (ocean side)
540      ! usefull to reduce residual current in the test case ISOMIP with no melting
541      DO ji=1,jpi
542        DO jj=1,jpj
543          ikt=mikt(ji,jj)
544          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
545          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
546        END DO
547      END DO
548      CALL eos(ztstop,risfdep,zrhdtop_oce)
549
550!==================================================================================     
551!===== Compute surface value =====================================================
552!==================================================================================
553      DO jj = 2, jpjm1
554         DO ji = fs_2, fs_jpim1   ! vector opt.
555            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
556            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
557            ! we assume ISF is in isostatic equilibrium
558            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj,iktp1i)                                    &
559               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
560               &                                  - 0.5_wp * fse3w(ji,jj,ikt)                                         &
561               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
562               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
563            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji,jj+1,iktp1j)                                    &
564               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
565               &                                  - 0.5_wp * fse3w(ji,jj,ikt)                                         & 
566               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
567               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
568            ! s-coordinate pressure gradient correction (=0 if z coordinate)
569            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
570               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
571            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
572               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
573            ! add to the general momentum trend
574            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
575            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
576         END DO
577      END DO
578
579!==================================================================================     
580!===== Compute interior value =====================================================
581!==================================================================================
582      ! interior value (2=<jk=<jpkm1)
583      DO jk = 2, jpkm1
584         DO jj = 2, jpjm1
585            DO ji = fs_2, fs_jpim1   ! vector opt.
586               ! hydrostatic pressure gradient along s-surfaces
587               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
588                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
589                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
590               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
591                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
592                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
593               ! s-coordinate pressure gradient correction
594               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
595                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
596               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
597                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
598               ! add to the general momentum trend
599               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
600               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
601            END DO
602         END DO
603      END DO
604      !
605      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
606      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
607      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce )
608      !
609   END SUBROUTINE hpg_isf
610
611
612   SUBROUTINE hpg_djc( kt )
613      !!---------------------------------------------------------------------
614      !!                  ***  ROUTINE hpg_djc  ***
615      !!
616      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
617      !!
618      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
619      !!----------------------------------------------------------------------
620      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
621      !!
622      INTEGER  ::   ji, jj, jk          ! dummy loop indices
623      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
624      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
625      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
626      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
627      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
628      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
629      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
630      !!----------------------------------------------------------------------
631      !
632      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
633      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
634      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
635      !
636
637      IF( kt == nit000 ) THEN
638         IF(lwp) WRITE(numout,*)
639         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
640         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
641      ENDIF
642
643      ! Local constant initialization
644      zcoef0 = - grav * 0.5_wp
645      z1_10  = 1._wp / 10._wp
646      z1_12  = 1._wp / 12._wp
647
648      !----------------------------------------------------------------------------------------
649      !  compute and store in provisional arrays elementary vertical and horizontal differences
650      !----------------------------------------------------------------------------------------
651
652!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
653
654      DO jk = 2, jpkm1
655         DO jj = 2, jpjm1
656            DO ji = fs_2, fs_jpim1   ! vector opt.
657               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
658               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
659               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
660               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
661               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
662               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
663            END DO
664         END DO
665      END DO
666
667      !-------------------------------------------------------------------------
668      ! compute harmonic averages using eq. 5.18
669      !-------------------------------------------------------------------------
670      zep = 1.e-15
671
672!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
673!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
674
675      DO jk = 2, jpkm1
676         DO jj = 2, jpjm1
677            DO ji = fs_2, fs_jpim1   ! vector opt.
678               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
679
680               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
681               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
682
683               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
684               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
685
686               IF( cffw > zep) THEN
687                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
688                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
689               ELSE
690                  drhow(ji,jj,jk) = 0._wp
691               ENDIF
692
693               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
694                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
695
696               IF( cffu > zep ) THEN
697                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
698                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
699               ELSE
700                  drhou(ji,jj,jk ) = 0._wp
701               ENDIF
702
703               IF( cffx > zep ) THEN
704                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
705                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
706               ELSE
707                  dzu(ji,jj,jk) = 0._wp
708               ENDIF
709
710               IF( cffv > zep ) THEN
711                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
712                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
713               ELSE
714                  drhov(ji,jj,jk) = 0._wp
715               ENDIF
716
717               IF( cffy > zep ) THEN
718                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
719                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
720               ELSE
721                  dzv(ji,jj,jk) = 0._wp
722               ENDIF
723
724            END DO
725         END DO
726      END DO
727
728      !----------------------------------------------------------------------------------
729      ! apply boundary conditions at top and bottom using 5.36-5.37
730      !----------------------------------------------------------------------------------
731      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
732      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
733      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
734
735      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
736      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
737      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
738
739
740      !--------------------------------------------------------------
741      ! Upper half of top-most grid box, compute and store
742      !-------------------------------------------------------------
743
744!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
745!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
746
747      DO jj = 2, jpjm1
748         DO ji = fs_2, fs_jpim1   ! vector opt.
749            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
750               &                   * (  rhd(ji,jj,1)                                    &
751               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
752               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
753               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
754         END DO
755      END DO
756
757!!bug gm    : here also, simplification is possible
758!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
759
760      DO jk = 2, jpkm1
761         DO jj = 2, jpjm1
762            DO ji = fs_2, fs_jpim1   ! vector opt.
763
764               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
765                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
766                  &            - grav * z1_10 * (                                                                     &
767                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
768                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
769                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
770                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
771                  &                             )
772
773               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
774                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
775                  &            - grav* z1_10 * (                                                                      &
776                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
777                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
778                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
779                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
780                  &                            )
781
782               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
783                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
784                  &            - grav* z1_10 * (                                                                      &
785                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
786                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
787                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
788                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
789                  &                            )
790
791            END DO
792         END DO
793      END DO
794      CALL lbc_lnk(rho_k,'W',1.)
795      CALL lbc_lnk(rho_i,'U',1.)
796      CALL lbc_lnk(rho_j,'V',1.)
797
798
799      ! ---------------
800      !  Surface value
801      ! ---------------
802      DO jj = 2, jpjm1
803         DO ji = fs_2, fs_jpim1   ! vector opt.
804            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
805            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
806            ! add to the general momentum trend
807            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
808            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
809         END DO
810      END DO
811
812      ! ----------------
813      !  interior value   (2=<jk=<jpkm1)
814      ! ----------------
815      DO jk = 2, jpkm1
816         DO jj = 2, jpjm1
817            DO ji = fs_2, fs_jpim1   ! vector opt.
818               ! hydrostatic pressure gradient along s-surfaces
819               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
820                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
821                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
822               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
823                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
824                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
825               ! add to the general momentum trend
826               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
827               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
828            END DO
829         END DO
830      END DO
831      !
832      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
833      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
834      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
835      !
836   END SUBROUTINE hpg_djc
837
838
839   SUBROUTINE hpg_prj( kt )
840      !!---------------------------------------------------------------------
841      !!                  ***  ROUTINE hpg_prj  ***
842      !!
843      !! ** Method  :   s-coordinate case.
844      !!      A Pressure-Jacobian horizontal pressure gradient method
845      !!      based on the constrained cubic-spline interpolation for
846      !!      all vertical coordinate systems
847      !!
848      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
849      !!----------------------------------------------------------------------
850      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
851      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
852      !!
853      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
854      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
855      !!
856      !! The local variables for the correction term
857      INTEGER  :: jk1, jis, jid, jjs, jjd
858      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
859      REAL(wp) :: zrhdt1
860      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
861      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
862      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
863      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
864      !!----------------------------------------------------------------------
865      !
866      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
867      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
868      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
869      !
870      IF( kt == nit000 ) THEN
871         IF(lwp) WRITE(numout,*)
872         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
873         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
874      ENDIF
875
876      !!----------------------------------------------------------------------
877      ! Local constant initialization
878      zcoef0 = - grav
879      znad = 0.0_wp
880      IF( lk_vvl ) znad = 1._wp
881
882      ! Clean 3-D work arrays
883      zhpi(:,:,:) = 0._wp
884      zrhh(:,:,:) = rhd(:,:,:)
885
886      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
887      DO jj = 1, jpj
888        DO ji = 1, jpi
889          jk = mbathy(ji,jj)
890          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
891          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
892          ELSE IF(jk < jpkm1) THEN
893             DO jkk = jk+1, jpk
894                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
895                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
896             END DO
897          ENDIF
898        END DO
899      END DO
900
901      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
902      DO jj = 1, jpj
903         DO ji = 1, jpi
904            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
905         END DO
906      END DO
907
908      DO jk = 2, jpk
909         DO jj = 1, jpj
910            DO ji = 1, jpi
911               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
912            END DO
913         END DO
914      END DO
915
916      fsp(:,:,:) = zrhh (:,:,:)
917      xsp(:,:,:) = zdept(:,:,:)
918
919      ! Construct the vertical density profile with the
920      ! constrained cubic spline interpolation
921      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
922      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
923
924      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
925      DO jj = 2, jpj
926        DO ji = 2, jpi
927          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
928                                         bsp(ji,jj,1),   csp(ji,jj,1), &
929                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
930
931          ! assuming linear profile across the top half surface layer
932          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
933        END DO
934      END DO
935
936      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
937      DO jk = 2, jpkm1
938        DO jj = 2, jpj
939          DO ji = 2, jpi
940            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
941                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
942                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
943                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
944          END DO
945        END DO
946      END DO
947
948      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
949
950      ! Prepare zsshu_n and zsshv_n
951      DO jj = 2, jpjm1
952        DO ji = 2, jpim1
953          zsshu_n(ji,jj) = (e12u(ji,jj) * sshn(ji,jj) + e12u(ji+1, jj) * sshn(ji+1,jj)) * &
954                         & r1_e12u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
955          zsshv_n(ji,jj) = (e12v(ji,jj) * sshn(ji,jj) + e12v(ji+1, jj) * sshn(ji,jj+1)) * &
956                         & r1_e12v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
957        END DO
958      END DO
959
960      DO jj = 2, jpjm1
961        DO ji = 2, jpim1
962          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
963          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
964        END DO
965      END DO
966
967      DO jk = 2, jpkm1
968        DO jj = 2, jpjm1
969          DO ji = 2, jpim1
970            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
971            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
972          END DO
973        END DO
974      END DO
975
976      DO jk = 1, jpkm1
977        DO jj = 2, jpjm1
978          DO ji = 2, jpim1
979            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
980            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
981          END DO
982        END DO
983      END DO
984
985      DO jk = 1, jpkm1
986        DO jj = 2, jpjm1
987          DO ji = 2, jpim1
988            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
989            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
990            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
991            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
992          END DO
993        END DO
994      END DO
995
996
997      DO jk = 1, jpkm1
998        DO jj = 2, jpjm1
999          DO ji = 2, jpim1
1000            zpwes = 0._wp; zpwed = 0._wp
1001            zpnss = 0._wp; zpnsd = 0._wp
1002            zuijk = zu(ji,jj,jk)
1003            zvijk = zv(ji,jj,jk)
1004
1005            !!!!!     for u equation
1006            IF( jk <= mbku(ji,jj) ) THEN
1007               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1008                 jis = ji + 1; jid = ji
1009               ELSE
1010                 jis = ji;     jid = ji +1
1011               ENDIF
1012
1013               ! integrate the pressure on the shallow side
1014               jk1 = jk
1015               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1016                 IF( jk1 == mbku(ji,jj) ) THEN
1017                   zuijk = -zdept(jis,jj,jk1)
1018                   EXIT
1019                 ENDIF
1020                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1021                 zpwes = zpwes +                                    &
1022                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1023                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1024                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1025                 jk1 = jk1 + 1
1026               END DO
1027
1028               ! integrate the pressure on the deep side
1029               jk1 = jk
1030               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1031                 IF( jk1 == 1 ) THEN
1032                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1033                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1034                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1035                                                     dsp(jid,jj,1)) * zdeps
1036                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1037                   EXIT
1038                 ENDIF
1039                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1040                 zpwed = zpwed +                                        &
1041                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1042                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1043                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1044                 jk1 = jk1 - 1
1045               END DO
1046
1047               ! update the momentum trends in u direction
1048
1049               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1050               IF( lk_vvl ) THEN
1051                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1052                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1053                ELSE
1054                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1055               ENDIF
1056
1057               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1058               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1059            ENDIF
1060
1061            !!!!!     for v equation
1062            IF( jk <= mbkv(ji,jj) ) THEN
1063               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1064                 jjs = jj + 1; jjd = jj
1065               ELSE
1066                 jjs = jj    ; jjd = jj + 1
1067               ENDIF
1068
1069               ! integrate the pressure on the shallow side
1070               jk1 = jk
1071               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1072                 IF( jk1 == mbkv(ji,jj) ) THEN
1073                   zvijk = -zdept(ji,jjs,jk1)
1074                   EXIT
1075                 ENDIF
1076                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1077                 zpnss = zpnss +                                      &
1078                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1079                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1080                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1081                 jk1 = jk1 + 1
1082               END DO
1083
1084               ! integrate the pressure on the deep side
1085               jk1 = jk
1086               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1087                 IF( jk1 == 1 ) THEN
1088                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1089                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1090                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1091                                                     dsp(ji,jjd,1) ) * zdeps
1092                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1093                   EXIT
1094                 ENDIF
1095                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1096                 zpnsd = zpnsd +                                        &
1097                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1098                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1099                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1100                 jk1 = jk1 - 1
1101               END DO
1102
1103
1104               ! update the momentum trends in v direction
1105
1106               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1107               IF( lk_vvl ) THEN
1108                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1109                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1110               ELSE
1111                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1112               ENDIF
1113
1114               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1115               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1116            ENDIF
1117
1118
1119           END DO
1120        END DO
1121      END DO
1122      !
1123      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1124      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1125      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1126      !
1127   END SUBROUTINE hpg_prj
1128
1129
1130   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1131      !!----------------------------------------------------------------------
1132      !!                 ***  ROUTINE cspline  ***
1133      !!
1134      !! ** Purpose :   constrained cubic spline interpolation
1135      !!
1136      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1137      !!
1138      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1139      !!----------------------------------------------------------------------
1140      IMPLICIT NONE
1141      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1142      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1143                                                                    ! the interpoated function
1144      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1145                                                                    ! 2: Linear
1146      !
1147      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1148      INTEGER  ::   jpi, jpj, jpkm1
1149      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1150      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1151      REAL(wp) ::   zdf(size(fsp,3))
1152      !!----------------------------------------------------------------------
1153
1154      jpi   = size(fsp,1)
1155      jpj   = size(fsp,2)
1156      jpkm1 = size(fsp,3) - 1
1157
1158
1159      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1160         DO ji = 1, jpi
1161            DO jj = 1, jpj
1162           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1163           !    DO jk = 2, jpkm1-1
1164           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1165           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1166           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1167           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1168           !
1169           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1170           !
1171           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1172           !           zdf(jk) = 0._wp
1173           !       ELSE
1174           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1175           !       ENDIF
1176           !    END DO
1177
1178           !!Simply geometric average
1179               DO jk = 2, jpkm1-1
1180                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1181                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1182
1183                  IF(zdf1 * zdf2 <= 0._wp) THEN
1184                     zdf(jk) = 0._wp
1185                  ELSE
1186                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1187                  ENDIF
1188               END DO
1189
1190               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1191                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1192               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1193                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1194                          & 0.5_wp * zdf(jpkm1 - 1)
1195
1196               DO jk = 1, jpkm1 - 1
1197                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1198                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1199                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1200                 zddf1  = -2._wp * ztmp1 + ztmp2
1201                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1202                 zddf2  =  2._wp * ztmp1 - ztmp2
1203
1204                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1205                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1206                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1207                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1208                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1209                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1210                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1211                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1212                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1213               END DO
1214            END DO
1215         END DO
1216
1217      ELSE IF (polynomial_type == 2) THEN     ! Linear
1218         DO ji = 1, jpi
1219            DO jj = 1, jpj
1220               DO jk = 1, jpkm1-1
1221                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1222                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1223
1224                  dsp(ji,jj,jk) = 0._wp
1225                  csp(ji,jj,jk) = 0._wp
1226                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1227                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1228               END DO
1229            END DO
1230         END DO
1231
1232      ELSE
1233           CALL ctl_stop( 'invalid polynomial type in cspline' )
1234      ENDIF
1235
1236   END SUBROUTINE cspline
1237
1238
1239   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1240      !!----------------------------------------------------------------------
1241      !!                 ***  ROUTINE interp1  ***
1242      !!
1243      !! ** Purpose :   1-d linear interpolation
1244      !!
1245      !! ** Method  :   interpolation is straight forward
1246      !!                extrapolation is also permitted (no value limit)
1247      !!----------------------------------------------------------------------
1248      IMPLICIT NONE
1249      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1250      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1251      REAL(wp)             ::  zdeltx
1252      !!----------------------------------------------------------------------
1253
1254      zdeltx = xr - xl
1255      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1256        f = 0.5_wp * (fl + fr)
1257      ELSE
1258        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1259      ENDIF
1260
1261   END FUNCTION interp1
1262
1263
1264   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1265      !!----------------------------------------------------------------------
1266      !!                 ***  ROUTINE interp1  ***
1267      !!
1268      !! ** Purpose :   1-d constrained cubic spline interpolation
1269      !!
1270      !! ** Method  :  cubic spline interpolation
1271      !!
1272      !!----------------------------------------------------------------------
1273      IMPLICIT NONE
1274      REAL(wp), INTENT(in) ::  x, a, b, c, d
1275      REAL(wp)             ::  f ! value from the interpolation
1276      !!----------------------------------------------------------------------
1277
1278      f = a + x* ( b + x * ( c + d * x ) )
1279
1280   END FUNCTION interp2
1281
1282
1283   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1284      !!----------------------------------------------------------------------
1285      !!                 ***  ROUTINE interp1  ***
1286      !!
1287      !! ** Purpose :   Calculate the first order of deriavtive of
1288      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1289      !!
1290      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1291      !!
1292      !!----------------------------------------------------------------------
1293      IMPLICIT NONE
1294      REAL(wp), INTENT(in) ::  x, a, b, c, d
1295      REAL(wp)             ::  f ! value from the interpolation
1296      !!----------------------------------------------------------------------
1297
1298      f = b + x * ( 2._wp * c + 3._wp * d * x)
1299
1300   END FUNCTION interp3
1301
1302
1303   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1304      !!----------------------------------------------------------------------
1305      !!                 ***  ROUTINE interp1  ***
1306      !!
1307      !! ** Purpose :   1-d constrained cubic spline integration
1308      !!
1309      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1310      !!
1311      !!----------------------------------------------------------------------
1312      IMPLICIT NONE
1313      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1314      REAL(wp)             ::  za1, za2, za3
1315      REAL(wp)             ::  f                   ! integration result
1316      !!----------------------------------------------------------------------
1317
1318      za1 = 0.5_wp * b
1319      za2 = c / 3.0_wp
1320      za3 = 0.25_wp * d
1321
1322      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1323         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1324
1325   END FUNCTION integ_spline
1326
1327   !!======================================================================
1328END MODULE dynhpg
1329
Note: See TracBrowser for help on using the repository browser.