New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynhpg.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/DYN/dynhpg.F90 @ 5956

Last change on this file since 5956 was 5956, checked in by mathiot, 8 years ago

ISF : merged trunk (5936) into branch
  • Property svn:keywords set to Id
File size: 62.5 KB
Line 
1MODULE dynhpg
2   !!======================================================================
3   !!                       ***  MODULE  dynhpg  ***
4   !! Ocean dynamics:  hydrostatic pressure gradient trend
5   !!======================================================================
6   !! History :  OPA  !  1987-09  (P. Andrich, M.-A. Foujols)  hpg_zco: Original code
7   !!            5.0  !  1991-11  (G. Madec)
8   !!            7.0  !  1996-01  (G. Madec)  hpg_sco: Original code for s-coordinates
9   !!            8.0  !  1997-05  (G. Madec)  split dynber into dynkeg and dynhpg
10   !!            8.5  !  2002-07  (G. Madec)  F90: Free form and module
11   !!            8.5  !  2002-08  (A. Bozec)  hpg_zps: Original code
12   !!   NEMO     1.0  !  2005-10  (A. Beckmann, B.W. An)  various s-coordinate options
13   !!                 !         Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14   !!             -   !  2005-11  (G. Madec) style & small optimisation
15   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
16   !!            3.4  !  2011-11  (H. Liu) hpg_prj: Original code for s-coordinates
17   !!                 !           (A. Coward) suppression of hel, wdj and rot options
18   !!            3.6  !  2014-11  (P. Mathiot) hpg_isf: original code for ice shelf cavity
19   !!----------------------------------------------------------------------
20
21   !!----------------------------------------------------------------------
22   !!   dyn_hpg      : update the momentum trend with the now horizontal
23   !!                  gradient of the hydrostatic pressure
24   !!   dyn_hpg_init : initialisation and control of options
25   !!       hpg_zco  : z-coordinate scheme
26   !!       hpg_zps  : z-coordinate plus partial steps (interpolation)
27   !!       hpg_sco  : s-coordinate (standard jacobian formulation)
28   !!       hpg_isf  : s-coordinate (sco formulation) adapted to ice shelf
29   !!       hpg_djc  : s-coordinate (Density Jacobian with Cubic polynomial)
30   !!       hpg_prj  : s-coordinate (Pressure Jacobian with Cubic polynomial)
31   !!----------------------------------------------------------------------
32   USE oce             ! ocean dynamics and tracers
33   USE sbc_oce         ! surface variable (only for the flag with ice shelf)
34   USE dom_oce         ! ocean space and time domain
35   USE phycst          ! physical constants
36   USE trd_oce         ! trends: ocean variables
37   USE trddyn          ! trend manager: dynamics
38!jc   USE zpshde          ! partial step: hor. derivative     (zps_hde routine)
39   !
40   USE in_out_manager  ! I/O manager
41   USE prtctl          ! Print control
42   USE lbclnk          ! lateral boundary condition
43   USE lib_mpp         ! MPP library
44   USE eosbn2          ! compute density
45   USE wrk_nemo        ! Memory Allocation
46   USE timing          ! Timing
47   USE iom
48
49   IMPLICIT NONE
50   PRIVATE
51
52   PUBLIC   dyn_hpg        ! routine called by step module
53   PUBLIC   dyn_hpg_init   ! routine called by opa module
54
55   !                                    !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56   LOGICAL , PUBLIC ::   ln_hpg_zco      !: z-coordinate - full steps
57   LOGICAL , PUBLIC ::   ln_hpg_zps      !: z-coordinate - partial steps (interpolation)
58   LOGICAL , PUBLIC ::   ln_hpg_sco      !: s-coordinate (standard jacobian formulation)
59   LOGICAL , PUBLIC ::   ln_hpg_djc      !: s-coordinate (Density Jacobian with Cubic polynomial)
60   LOGICAL , PUBLIC ::   ln_hpg_prj      !: s-coordinate (Pressure Jacobian scheme)
61   LOGICAL , PUBLIC ::   ln_hpg_isf      !: s-coordinate similar to sco modify for isf
62
63   INTEGER , PUBLIC ::   nhpg  =  0   ! = 0 to 7, type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
64
65   !! * Substitutions
66#  include "domzgr_substitute.h90"
67#  include "vectopt_loop_substitute.h90"
68   !!----------------------------------------------------------------------
69   !! NEMO/OPA 3.3 , NEMO Consortium (2010)
70   !! $Id$
71   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
72   !!----------------------------------------------------------------------
73CONTAINS
74
75   SUBROUTINE dyn_hpg( kt )
76      !!---------------------------------------------------------------------
77      !!                  ***  ROUTINE dyn_hpg  ***
78      !!
79      !! ** Method  :   Call the hydrostatic pressure gradient routine
80      !!              using the scheme defined in the namelist
81      !!
82      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
83      !!             - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
84      !!----------------------------------------------------------------------
85      INTEGER, INTENT(in) ::   kt   ! ocean time-step index
86      REAL(wp), POINTER, DIMENSION(:,:,:) ::  ztrdu, ztrdv
87      !!----------------------------------------------------------------------
88      !
89      IF( nn_timing == 1 )  CALL timing_start('dyn_hpg')
90      !
91      IF( l_trddyn ) THEN                    ! Temporary saving of ua and va trends (l_trddyn)
92         CALL wrk_alloc( jpi,jpj,jpk, ztrdu, ztrdv )
93         ztrdu(:,:,:) = ua(:,:,:)
94         ztrdv(:,:,:) = va(:,:,:)
95      ENDIF
96      !
97      SELECT CASE ( nhpg )      ! Hydrostatic pressure gradient computation
98      CASE (  0 )   ;   CALL hpg_zco    ( kt )      ! z-coordinate
99      CASE (  1 )   ;   CALL hpg_zps    ( kt )      ! z-coordinate plus partial steps (interpolation)
100      CASE (  2 )   ;   CALL hpg_sco    ( kt )      ! s-coordinate (standard jacobian formulation)
101      CASE (  3 )   ;   CALL hpg_djc    ( kt )      ! s-coordinate (Density Jacobian with Cubic polynomial)
102      CASE (  4 )   ;   CALL hpg_prj    ( kt )      ! s-coordinate (Pressure Jacobian scheme)
103      CASE (  5 )   ;   CALL hpg_isf    ( kt )      ! s-coordinate similar to sco modify for ice shelf
104      END SELECT
105      !
106      IF( l_trddyn ) THEN      ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
107         ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
108         ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
109         CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
110         CALL wrk_dealloc( jpi,jpj,jpk, ztrdu, ztrdv )
111      ENDIF
112      !
113      IF(ln_ctl)   CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg  - Ua: ', mask1=umask,   &
114         &                       tab3d_2=va, clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
115      !
116      IF( nn_timing == 1 )  CALL timing_stop('dyn_hpg')
117      !
118   END SUBROUTINE dyn_hpg
119
120
121   SUBROUTINE dyn_hpg_init
122      !!----------------------------------------------------------------------
123      !!                 ***  ROUTINE dyn_hpg_init  ***
124      !!
125      !! ** Purpose :   initializations for the hydrostatic pressure gradient
126      !!              computation and consistency control
127      !!
128      !! ** Action  :   Read the namelist namdyn_hpg and check the consistency
129      !!      with the type of vertical coordinate used (zco, zps, sco)
130      !!----------------------------------------------------------------------
131      INTEGER ::   ioptio = 0      ! temporary integer
132      INTEGER ::   ios             ! Local integer output status for namelist read
133      !!
134      INTEGER  ::   ji, jj, jk, ikt    ! dummy loop indices      ISF
135      REAL(wp) ::   znad
136      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop, zrhd ! hypothesys on isf density
137      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_isf  ! density at bottom of ISF
138      REAL(wp), POINTER, DIMENSION(:,:)     ::  ziceload     ! density at bottom of ISF
139      !!
140      NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco,     &
141         &                 ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
142      !!----------------------------------------------------------------------
143      !
144      REWIND( numnam_ref )              ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
145      READ  ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
146901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
147
148      REWIND( numnam_cfg )              ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
149      READ  ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
150902   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
151      IF(lwm) WRITE ( numond, namdyn_hpg )
152      !
153      IF(lwp) THEN                   ! Control print
154         WRITE(numout,*)
155         WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
156         WRITE(numout,*) '~~~~~~~~~~~~'
157         WRITE(numout,*) '   Namelist namdyn_hpg : choice of hpg scheme'
158         WRITE(numout,*) '      z-coord. - full steps                             ln_hpg_zco    = ', ln_hpg_zco
159         WRITE(numout,*) '      z-coord. - partial steps (interpolation)          ln_hpg_zps    = ', ln_hpg_zps
160         WRITE(numout,*) '      s-coord. (standard jacobian formulation)          ln_hpg_sco    = ', ln_hpg_sco
161         WRITE(numout,*) '      s-coord. (standard jacobian formulation) for isf  ln_hpg_isf    = ', ln_hpg_isf
162         WRITE(numout,*) '      s-coord. (Density Jacobian: Cubic polynomial)     ln_hpg_djc    = ', ln_hpg_djc
163         WRITE(numout,*) '      s-coord. (Pressure Jacobian: Cubic polynomial)    ln_hpg_prj    = ', ln_hpg_prj
164      ENDIF
165      !
166      IF( ln_hpg_djc )   &
167         &   CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method &
168                           & currently disabled (bugs under investigation). Please select &
169                           & either  ln_hpg_sco or  ln_hpg_prj instead')
170      !
171      IF( lk_vvl .AND. .NOT. (ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) )   &
172         &   CALL ctl_stop('dyn_hpg_init : variable volume key_vvl requires:&
173                           & the standard jacobian formulation hpg_sco or &
174                           & the pressure jacobian formulation hpg_prj')
175
176      IF(       ln_hpg_isf .AND. .NOT. ln_isfcav )   &
177         &   CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
178      IF( .NOT. ln_hpg_isf .AND.       ln_isfcav )   &
179         &   CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
180      !
181      !                               ! Set nhpg from ln_hpg_... flags
182      IF( ln_hpg_zco )   nhpg = 0
183      IF( ln_hpg_zps )   nhpg = 1
184      IF( ln_hpg_sco )   nhpg = 2
185      IF( ln_hpg_djc )   nhpg = 3
186      IF( ln_hpg_prj )   nhpg = 4
187      IF( ln_hpg_isf )   nhpg = 5
188      !
189      !                               ! Consistency check
190      ioptio = 0
191      IF( ln_hpg_zco )   ioptio = ioptio + 1
192      IF( ln_hpg_zps )   ioptio = ioptio + 1
193      IF( ln_hpg_sco )   ioptio = ioptio + 1
194      IF( ln_hpg_djc )   ioptio = ioptio + 1
195      IF( ln_hpg_prj )   ioptio = ioptio + 1
196      IF( ln_hpg_isf )   ioptio = ioptio + 1
197      IF( ioptio /= 1 )   CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
198      !
199      ! initialisation of ice shelf load
200      IF ( .NOT. ln_isfcav ) riceload(:,:)=0.0
201      IF (       ln_isfcav ) THEN
202         CALL wrk_alloc( jpi,jpj, 2,  ztstop) 
203         CALL wrk_alloc( jpi,jpj,jpk, zrhd  )
204         CALL wrk_alloc( jpi,jpj,     zrhdtop_isf, ziceload) 
205         !
206         IF(lwp) WRITE(numout,*)
207         IF(lwp) WRITE(numout,*) 'dyn:hpg_isf : hydrostatic pressure gradient trend for ice shelf'
208         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~' 
209
210         ! To use density and not density anomaly
211         znad=1._wp
212         
213         ! assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
214         ztstop(:,:,1)=-1.9_wp ; ztstop(:,:,2)=34.4_wp
215
216         ! compute density of the water displaced by the ice shelf
217         DO jk = 1, jpk
218            CALL eos(ztstop(:,:,:),fsdept_n(:,:,jk),zrhd(:,:,jk))
219         END DO
220     
221         ! compute rhd at the ice/oce interface (ice shelf side)
222         CALL eos(ztstop,risfdep,zrhdtop_isf)
223
224         ! Surface value + ice shelf gradient
225         ! compute pressure due to ice shelf load (used to compute hpgi/j for all the level from 1 to miku/v)
226         ! divided by 2 later
227         ziceload = 0._wp
228         DO jj = 1, jpj
229            DO ji = 1, jpi
230               ikt=mikt(ji,jj)
231               ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * fse3w(ji,jj,1) * (1._wp - tmask(ji,jj,1))
232               DO jk=2,ikt-1
233                  ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * fse3w(ji,jj,jk) &
234                     &                              * (1._wp - tmask(ji,jj,jk))
235               END DO
236               IF (ikt  >=  2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
237                                  &                              * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
238            END DO
239         END DO
240         riceload(:,:)=ziceload(:,:)  ! need to be saved for diaar5
241
242         CALL wrk_dealloc( jpi,jpj, 2,  ztstop) 
243         CALL wrk_dealloc( jpi,jpj,jpk, zrhd  )
244         CALL wrk_dealloc( jpi,jpj,     zrhdtop_isf, ziceload) 
245      END IF
246      !
247   END SUBROUTINE dyn_hpg_init
248
249
250   SUBROUTINE hpg_zco( kt )
251      !!---------------------------------------------------------------------
252      !!                  ***  ROUTINE hpg_zco  ***
253      !!
254      !! ** Method  :   z-coordinate case, levels are horizontal surfaces.
255      !!      The now hydrostatic pressure gradient at a given level, jk,
256      !!      is computed by taking the vertical integral of the in-situ
257      !!      density gradient along the model level from the suface to that
258      !!      level:    zhpi = grav .....
259      !!                zhpj = grav .....
260      !!      add it to the general momentum trend (ua,va).
261      !!            ua = ua - 1/e1u * zhpi
262      !!            va = va - 1/e2v * zhpj
263      !!
264      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
265      !!----------------------------------------------------------------------
266      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
267      !!
268      INTEGER  ::   ji, jj, jk       ! dummy loop indices
269      REAL(wp) ::   zcoef0, zcoef1   ! temporary scalars
270      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
271      !!----------------------------------------------------------------------
272      !
273      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
274      !
275      IF( kt == nit000 ) THEN
276         IF(lwp) WRITE(numout,*)
277         IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
278         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate case '
279      ENDIF
280
281      zcoef0 = - grav * 0.5_wp      ! Local constant initialization
282
283      ! Surface value
284      DO jj = 2, jpjm1
285         DO ji = fs_2, fs_jpim1   ! vector opt.
286            zcoef1 = zcoef0 * fse3w(ji,jj,1)
287            ! hydrostatic pressure gradient
288            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
289            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
290            ! add to the general momentum trend
291            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
292            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
293         END DO
294      END DO
295
296      !
297      ! interior value (2=<jk=<jpkm1)
298      DO jk = 2, jpkm1
299         DO jj = 2, jpjm1
300            DO ji = fs_2, fs_jpim1   ! vector opt.
301               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
302               ! hydrostatic pressure gradient
303               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
304                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) )   &
305                  &                       - ( rhd(ji  ,jj,jk)+rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
306
307               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
308                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) )   &
309                  &                       - ( rhd(ji,jj,  jk)+rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
310               ! add to the general momentum trend
311               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
312               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
313            END DO
314         END DO
315      END DO
316      !
317      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
318      !
319   END SUBROUTINE hpg_zco
320
321
322   SUBROUTINE hpg_zps( kt )
323      !!---------------------------------------------------------------------
324      !!                 ***  ROUTINE hpg_zps  ***
325      !!
326      !! ** Method  :   z-coordinate plus partial steps case.  blahblah...
327      !!
328      !! ** Action  : - Update (ua,va) with the now hydrastatic pressure trend
329      !!----------------------------------------------------------------------
330      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
331      !!
332      INTEGER  ::   ji, jj, jk                       ! dummy loop indices
333      INTEGER  ::   iku, ikv                         ! temporary integers
334      REAL(wp) ::   zcoef0, zcoef1, zcoef2, zcoef3   ! temporary scalars
335      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
336      !!----------------------------------------------------------------------
337      !
338      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
339      !
340      IF( kt == nit000 ) THEN
341         IF(lwp) WRITE(numout,*)
342         IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
343         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   z-coordinate with partial steps - vector optimization'
344      ENDIF
345
346      ! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
347!jc      CALL zps_hde    ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
348
349      ! Local constant initialization
350      zcoef0 = - grav * 0.5_wp
351
352      !  Surface value (also valid in partial step case)
353      DO jj = 2, jpjm1
354         DO ji = fs_2, fs_jpim1   ! vector opt.
355            zcoef1 = zcoef0 * fse3w(ji,jj,1)
356            ! hydrostatic pressure gradient
357            zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj  ,1) - rhd(ji,jj,1) ) / e1u(ji,jj)
358            zhpj(ji,jj,1) = zcoef1 * ( rhd(ji  ,jj+1,1) - rhd(ji,jj,1) ) / e2v(ji,jj)
359            ! add to the general momentum trend
360            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
361            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
362         END DO
363      END DO
364
365
366      ! interior value (2=<jk=<jpkm1)
367      DO jk = 2, jpkm1
368         DO jj = 2, jpjm1
369            DO ji = fs_2, fs_jpim1   ! vector opt.
370               zcoef1 = zcoef0 * fse3w(ji,jj,jk)
371               ! hydrostatic pressure gradient
372               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)   &
373                  &           + zcoef1 * (  ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) )   &
374                  &                       - ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) )  ) / e1u(ji,jj)
375
376               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)   &
377                  &           + zcoef1 * (  ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) )   &
378                  &                       - ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) )  ) / e2v(ji,jj)
379               ! add to the general momentum trend
380               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
381               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
382            END DO
383         END DO
384      END DO
385
386
387      ! partial steps correction at the last level  (use gru & grv computed in zpshde.F90)
388      DO jj = 2, jpjm1
389         DO ji = 2, jpim1
390            iku = mbku(ji,jj)
391            ikv = mbkv(ji,jj)
392            zcoef2 = zcoef0 * MIN( fse3w(ji,jj,iku), fse3w(ji+1,jj  ,iku) )
393            zcoef3 = zcoef0 * MIN( fse3w(ji,jj,ikv), fse3w(ji  ,jj+1,ikv) )
394            IF( iku > 1 ) THEN            ! on i-direction (level 2 or more)
395               ua  (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku)         ! subtract old value
396               zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1)                   &   ! compute the new one
397                  &            + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) / e1u(ji,jj)
398               ua  (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku)         ! add the new one to the general momentum trend
399            ENDIF
400            IF( ikv > 1 ) THEN            ! on j-direction (level 2 or more)
401               va  (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv)         ! subtract old value
402               zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1)                   &   ! compute the new one
403                  &            + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) / e2v(ji,jj)
404               va  (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv)         ! add the new one to the general momentum trend
405            ENDIF
406         END DO
407      END DO
408      !
409      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
410      !
411   END SUBROUTINE hpg_zps
412
413   SUBROUTINE hpg_sco( kt )
414      !!---------------------------------------------------------------------
415      !!                  ***  ROUTINE hpg_sco  ***
416      !!
417      !! ** Method  :   s-coordinate case. Jacobian scheme.
418      !!      The now hydrostatic pressure gradient at a given level, jk,
419      !!      is computed by taking the vertical integral of the in-situ
420      !!      density gradient along the model level from the suface to that
421      !!      level. s-coordinates (ln_sco): a corrective term is added
422      !!      to the horizontal pressure gradient :
423      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
424      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
425      !!      add it to the general momentum trend (ua,va).
426      !!         ua = ua - 1/e1u * zhpi
427      !!         va = va - 1/e2v * zhpj
428      !!
429      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
430      !!----------------------------------------------------------------------
431      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
432      !!
433      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
434      REAL(wp) ::   zcoef0, zuap, zvap, znad   ! temporary scalars
435      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
436      !!----------------------------------------------------------------------
437      !
438      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj )
439      !
440      IF( kt == nit000 ) THEN
441         IF(lwp) WRITE(numout,*)
442         IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
443         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, OPA original scheme used'
444      ENDIF
445
446      ! Local constant initialization
447      zcoef0 = - grav * 0.5_wp
448      ! To use density and not density anomaly
449      IF ( lk_vvl ) THEN   ;     znad = 1._wp          ! Variable volume
450      ELSE                 ;     znad = 0._wp         ! Fixed volume
451      ENDIF
452
453      ! Surface value
454      DO jj = 2, jpjm1
455         DO ji = fs_2, fs_jpim1   ! vector opt.
456            ! hydrostatic pressure gradient along s-surfaces
457            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( fse3w(ji+1,jj  ,1) * ( znad + rhd(ji+1,jj  ,1) )   &
458               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
459            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( fse3w(ji  ,jj+1,1) * ( znad + rhd(ji  ,jj+1,1) )   &
460               &                                  - fse3w(ji  ,jj  ,1) * ( znad + rhd(ji  ,jj  ,1) ) )
461            ! s-coordinate pressure gradient correction
462            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
463               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
464            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
465               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
466            ! add to the general momentum trend
467            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
468            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
469         END DO
470      END DO
471
472      ! interior value (2=<jk=<jpkm1)
473      DO jk = 2, jpkm1
474         DO jj = 2, jpjm1
475            DO ji = fs_2, fs_jpim1   ! vector opt.
476               ! hydrostatic pressure gradient along s-surfaces
477               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
478                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad )   &
479                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad )  )
480               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
481                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad )   &
482                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad )  )
483               ! s-coordinate pressure gradient correction
484               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
485                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
486               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
487                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
488               ! add to the general momentum trend
489               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
490               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
491            END DO
492         END DO
493      END DO
494      !
495      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj )
496      !
497   END SUBROUTINE hpg_sco
498
499   SUBROUTINE hpg_isf( kt )
500      !!---------------------------------------------------------------------
501      !!                  ***  ROUTINE hpg_isf  ***
502      !!
503      !! ** Method  :   s-coordinate case. Jacobian scheme.
504      !!      The now hydrostatic pressure gradient at a given level, jk,
505      !!      is computed by taking the vertical integral of the in-situ
506      !!      density gradient along the model level from the suface to that
507      !!      level. s-coordinates (ln_sco): a corrective term is added
508      !!      to the horizontal pressure gradient :
509      !!         zhpi = grav .....  + 1/e1u mi(rhd) di[ grav dep3w ]
510      !!         zhpj = grav .....  + 1/e2v mj(rhd) dj[ grav dep3w ]
511      !!      add it to the general momentum trend (ua,va).
512      !!         ua = ua - 1/e1u * zhpi
513      !!         va = va - 1/e2v * zhpj
514      !!      iceload is added and partial cell case are added to the top and bottom
515      !!     
516      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
517      !!----------------------------------------------------------------------
518      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
519      !!
520      INTEGER  ::   ji, jj, jk, ikt, iktp1i, iktp1j   ! dummy loop indices
521      REAL(wp) ::   zcoef0, zuap, zvap, znad          ! temporary scalars
522      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  zhpi, zhpj
523      REAL(wp), POINTER, DIMENSION(:,:,:)   ::  ztstop
524      REAL(wp), POINTER, DIMENSION(:,:)     ::  zrhdtop_oce
525      !!----------------------------------------------------------------------
526      !
527      CALL wrk_alloc( jpi,jpj,  2, ztstop) 
528      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zhpj)
529      CALL wrk_alloc( jpi,jpj,     zrhdtop_oce )
530      !
531      ! Local constant initialization
532      zcoef0 = - grav * 0.5_wp
533   
534      ! To use density and not density anomaly
535      znad=1._wp
536
537      ! iniitialised to 0. zhpi zhpi
538      zhpi(:,:,:)=0._wp ; zhpj(:,:,:)=0._wp
539
540      ! compute rhd at the ice/oce interface (ocean side)
541      ! usefull to reduce residual current in the test case ISOMIP with no melting
542      DO ji=1,jpi
543        DO jj=1,jpj
544          ikt=mikt(ji,jj)
545          ztstop(ji,jj,1)=tsn(ji,jj,ikt,1)
546          ztstop(ji,jj,2)=tsn(ji,jj,ikt,2)
547        END DO
548      END DO
549      CALL eos(ztstop,risfdep,zrhdtop_oce)
550
551!==================================================================================     
552!===== Compute surface value =====================================================
553!==================================================================================
554      DO jj = 2, jpjm1
555         DO ji = fs_2, fs_jpim1   ! vector opt.
556            ikt=mikt(ji,jj) ; iktp1i=mikt(ji+1,jj); iktp1j=mikt(ji,jj+1)
557            ! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
558            ! we assume ISF is in isostatic equilibrium
559            zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * fse3w(ji+1,jj,iktp1i)                                    &
560               &                                    * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) )   &
561               &                                  - 0.5_wp * fse3w(ji,jj,ikt)                                         &
562               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
563               &                                  + ( riceload(ji+1,jj) - riceload(ji,jj))                            ) 
564            zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * fse3w(ji,jj+1,iktp1j)                                    &
565               &                                    * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) )   &
566               &                                  - 0.5_wp * fse3w(ji,jj,ikt)                                         & 
567               &                                    * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) )          &
568               &                                  + ( riceload(ji,jj+1) - riceload(ji,jj))                            ) 
569            ! s-coordinate pressure gradient correction (=0 if z coordinate)
570            zuap = -zcoef0 * ( rhd   (ji+1,jj,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
571               &           * ( fsde3w(ji+1,jj,1) - fsde3w(ji,jj,1) ) / e1u(ji,jj)
572            zvap = -zcoef0 * ( rhd   (ji,jj+1,1) + rhd   (ji,jj,1) + 2._wp * znad )   &
573               &           * ( fsde3w(ji,jj+1,1) - fsde3w(ji,jj,1) ) / e2v(ji,jj)
574            ! add to the general momentum trend
575            ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
576            va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
577         END DO
578      END DO
579
580!==================================================================================     
581!===== Compute interior value =====================================================
582!==================================================================================
583      ! interior value (2=<jk=<jpkm1)
584      DO jk = 2, jpkm1
585         DO jj = 2, jpjm1
586            DO ji = fs_2, fs_jpim1   ! vector opt.
587               ! hydrostatic pressure gradient along s-surfaces
588               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj)   &
589                  &           * (  fse3w(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) * wmask(ji+1,jj,jk)   &
590                  &              - fse3w(ji  ,jj,jk) * ( rhd(ji  ,jj,jk) + rhd(ji  ,jj,jk-1) + 2*znad ) * wmask(ji  ,jj,jk)   )
591               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj)   &
592                  &           * (  fse3w(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) * wmask(ji,jj+1,jk)   &
593                  &              - fse3w(ji,jj  ,jk) * ( rhd(ji,jj,  jk) + rhd(ji,jj  ,jk-1) + 2*znad ) * wmask(ji,jj  ,jk)   )
594               ! s-coordinate pressure gradient correction
595               zuap = -zcoef0 * ( rhd   (ji+1,jj  ,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
596                  &           * ( fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk) ) / e1u(ji,jj)
597               zvap = -zcoef0 * ( rhd   (ji  ,jj+1,jk) + rhd   (ji,jj,jk) + 2._wp * znad )   &
598                  &           * ( fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk) ) / e2v(ji,jj)
599               ! add to the general momentum trend
600               ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
601               va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
602            END DO
603         END DO
604      END DO
605      !
606      CALL wrk_dealloc( jpi,jpj,2  , ztstop)
607      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zhpj)
608      CALL wrk_dealloc( jpi,jpj    , zrhdtop_oce )
609      !
610   END SUBROUTINE hpg_isf
611
612
613   SUBROUTINE hpg_djc( kt )
614      !!---------------------------------------------------------------------
615      !!                  ***  ROUTINE hpg_djc  ***
616      !!
617      !! ** Method  :   Density Jacobian with Cubic polynomial scheme
618      !!
619      !! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
620      !!----------------------------------------------------------------------
621      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
622      !!
623      INTEGER  ::   ji, jj, jk          ! dummy loop indices
624      REAL(wp) ::   zcoef0, zep, cffw   ! temporary scalars
625      REAL(wp) ::   z1_10, cffu, cffx   !    "         "
626      REAL(wp) ::   z1_12, cffv, cffy   !    "         "
627      REAL(wp), POINTER, DIMENSION(:,:,:) ::  zhpi, zhpj
628      REAL(wp), POINTER, DIMENSION(:,:,:) ::  dzx, dzy, dzz, dzu, dzv, dzw
629      REAL(wp), POINTER, DIMENSION(:,:,:) ::  drhox, drhoy, drhoz, drhou, drhov, drhow
630      REAL(wp), POINTER, DIMENSION(:,:,:) ::  rho_i, rho_j, rho_k
631      !!----------------------------------------------------------------------
632      !
633      CALL wrk_alloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
634      CALL wrk_alloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
635      CALL wrk_alloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
636      !
637
638      IF( kt == nit000 ) THEN
639         IF(lwp) WRITE(numout,*)
640         IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
641         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, density Jacobian with cubic polynomial scheme'
642      ENDIF
643
644      ! Local constant initialization
645      zcoef0 = - grav * 0.5_wp
646      z1_10  = 1._wp / 10._wp
647      z1_12  = 1._wp / 12._wp
648
649      !----------------------------------------------------------------------------------------
650      !  compute and store in provisional arrays elementary vertical and horizontal differences
651      !----------------------------------------------------------------------------------------
652
653!!bug gm   Not a true bug, but... dzz=e3w  for dzx, dzy verify what it is really
654
655      DO jk = 2, jpkm1
656         DO jj = 2, jpjm1
657            DO ji = fs_2, fs_jpim1   ! vector opt.
658               drhoz(ji,jj,jk) = rhd   (ji  ,jj  ,jk) - rhd   (ji,jj,jk-1)
659               dzz  (ji,jj,jk) = fsde3w(ji  ,jj  ,jk) - fsde3w(ji,jj,jk-1)
660               drhox(ji,jj,jk) = rhd   (ji+1,jj  ,jk) - rhd   (ji,jj,jk  )
661               dzx  (ji,jj,jk) = fsde3w(ji+1,jj  ,jk) - fsde3w(ji,jj,jk  )
662               drhoy(ji,jj,jk) = rhd   (ji  ,jj+1,jk) - rhd   (ji,jj,jk  )
663               dzy  (ji,jj,jk) = fsde3w(ji  ,jj+1,jk) - fsde3w(ji,jj,jk  )
664            END DO
665         END DO
666      END DO
667
668      !-------------------------------------------------------------------------
669      ! compute harmonic averages using eq. 5.18
670      !-------------------------------------------------------------------------
671      zep = 1.e-15
672
673!!bug  gm  drhoz not defined at level 1 and used (jk-1 with jk=2)
674!!bug  gm  idem for drhox, drhoy et ji=jpi and jj=jpj
675
676      DO jk = 2, jpkm1
677         DO jj = 2, jpjm1
678            DO ji = fs_2, fs_jpim1   ! vector opt.
679               cffw = 2._wp * drhoz(ji  ,jj  ,jk) * drhoz(ji,jj,jk-1)
680
681               cffu = 2._wp * drhox(ji+1,jj  ,jk) * drhox(ji,jj,jk  )
682               cffx = 2._wp * dzx  (ji+1,jj  ,jk) * dzx  (ji,jj,jk  )
683
684               cffv = 2._wp * drhoy(ji  ,jj+1,jk) * drhoy(ji,jj,jk  )
685               cffy = 2._wp * dzy  (ji  ,jj+1,jk) * dzy  (ji,jj,jk  )
686
687               IF( cffw > zep) THEN
688                  drhow(ji,jj,jk) = 2._wp *   drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1)   &
689                     &                    / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
690               ELSE
691                  drhow(ji,jj,jk) = 0._wp
692               ENDIF
693
694               dzw(ji,jj,jk) = 2._wp *   dzz(ji,jj,jk) * dzz(ji,jj,jk-1)   &
695                  &                  / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
696
697               IF( cffu > zep ) THEN
698                  drhou(ji,jj,jk) = 2._wp *   drhox(ji+1,jj,jk) * drhox(ji,jj,jk)   &
699                     &                    / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
700               ELSE
701                  drhou(ji,jj,jk ) = 0._wp
702               ENDIF
703
704               IF( cffx > zep ) THEN
705                  dzu(ji,jj,jk) = 2._wp *   dzx(ji+1,jj,jk) * dzx(ji,jj,jk)   &
706                     &                  / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
707               ELSE
708                  dzu(ji,jj,jk) = 0._wp
709               ENDIF
710
711               IF( cffv > zep ) THEN
712                  drhov(ji,jj,jk) = 2._wp *   drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk)   &
713                     &                    / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
714               ELSE
715                  drhov(ji,jj,jk) = 0._wp
716               ENDIF
717
718               IF( cffy > zep ) THEN
719                  dzv(ji,jj,jk) = 2._wp *   dzy(ji,jj+1,jk) * dzy(ji,jj,jk)   &
720                     &                  / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
721               ELSE
722                  dzv(ji,jj,jk) = 0._wp
723               ENDIF
724
725            END DO
726         END DO
727      END DO
728
729      !----------------------------------------------------------------------------------
730      ! apply boundary conditions at top and bottom using 5.36-5.37
731      !----------------------------------------------------------------------------------
732      drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:,  1  ) ) - 0.5_wp * drhow(:,:,  2  )
733      drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:,  1  ) ) - 0.5_wp * drhou(:,:,  2  )
734      drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:,  1  ) ) - 0.5_wp * drhov(:,:,  2  )
735
736      drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
737      drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
738      drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
739
740
741      !--------------------------------------------------------------
742      ! Upper half of top-most grid box, compute and store
743      !-------------------------------------------------------------
744
745!!bug gm   :  e3w-de3w = 0.5*e3w  ....  and de3w(2)-de3w(1)=e3w(2) ....   to be verified
746!          true if de3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
747
748      DO jj = 2, jpjm1
749         DO ji = fs_2, fs_jpim1   ! vector opt.
750            rho_k(ji,jj,1) = -grav * ( fse3w(ji,jj,1) - fsde3w(ji,jj,1) )               &
751               &                   * (  rhd(ji,jj,1)                                    &
752               &                     + 0.5_wp * ( rhd(ji,jj,2) - rhd(ji,jj,1) )         &
753               &                              * ( fse3w (ji,jj,1) - fsde3w(ji,jj,1) )   &
754               &                              / ( fsde3w(ji,jj,2) - fsde3w(ji,jj,1) )  )
755         END DO
756      END DO
757
758!!bug gm    : here also, simplification is possible
759!!bug gm    : optimisation: 1/10 and 1/12 the division should be done before the loop
760
761      DO jk = 2, jpkm1
762         DO jj = 2, jpjm1
763            DO ji = fs_2, fs_jpim1   ! vector opt.
764
765               rho_k(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj,jk) + rhd   (ji,jj,jk-1) )                                   &
766                  &                     * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) )                                   &
767                  &            - grav * z1_10 * (                                                                     &
768                  &     ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) )                                                     &
769                  &   * ( fsde3w(ji,jj,jk) - fsde3w(ji,jj,jk-1) - z1_12 * ( dzw  (ji,jj,jk) + dzw  (ji,jj,jk-1) ) )   &
770                  &   - ( dzw   (ji,jj,jk) - dzw   (ji,jj,jk-1) )                                                     &
771                  &   * ( rhd   (ji,jj,jk) - rhd   (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) )   &
772                  &                             )
773
774               rho_i(ji,jj,jk) = zcoef0 * ( rhd   (ji+1,jj,jk) + rhd   (ji,jj,jk) )                                   &
775                  &                     * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) )                                   &
776                  &            - grav* z1_10 * (                                                                      &
777                  &     ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) )                                                     &
778                  &   * ( fsde3w(ji+1,jj,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzu  (ji+1,jj,jk) + dzu  (ji,jj,jk) ) )   &
779                  &   - ( dzu   (ji+1,jj,jk) - dzu   (ji,jj,jk) )                                                     &
780                  &   * ( rhd   (ji+1,jj,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) )   &
781                  &                            )
782
783               rho_j(ji,jj,jk) = zcoef0 * ( rhd   (ji,jj+1,jk) + rhd   (ji,jj,jk) )                                   &
784                  &                     * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) )                                   &
785                  &            - grav* z1_10 * (                                                                      &
786                  &     ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) )                                                     &
787                  &   * ( fsde3w(ji,jj+1,jk) - fsde3w(ji,jj,jk) - z1_12 * ( dzv  (ji,jj+1,jk) + dzv  (ji,jj,jk) ) )   &
788                  &   - ( dzv   (ji,jj+1,jk) - dzv   (ji,jj,jk) )                                                     &
789                  &   * ( rhd   (ji,jj+1,jk) - rhd   (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) )   &
790                  &                            )
791
792            END DO
793         END DO
794      END DO
795      CALL lbc_lnk(rho_k,'W',1.)
796      CALL lbc_lnk(rho_i,'U',1.)
797      CALL lbc_lnk(rho_j,'V',1.)
798
799
800      ! ---------------
801      !  Surface value
802      ! ---------------
803      DO jj = 2, jpjm1
804         DO ji = fs_2, fs_jpim1   ! vector opt.
805            zhpi(ji,jj,1) = ( rho_k(ji+1,jj  ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) / e1u(ji,jj)
806            zhpj(ji,jj,1) = ( rho_k(ji  ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) / e2v(ji,jj)
807            ! add to the general momentum trend
808            ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
809            va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
810         END DO
811      END DO
812
813      ! ----------------
814      !  interior value   (2=<jk=<jpkm1)
815      ! ----------------
816      DO jk = 2, jpkm1
817         DO jj = 2, jpjm1
818            DO ji = fs_2, fs_jpim1   ! vector opt.
819               ! hydrostatic pressure gradient along s-surfaces
820               zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1)                                &
821                  &           + (  ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk  ) )    &
822                  &              - ( rho_i(ji  ,jj,jk) - rho_i(ji,jj,jk-1) )  ) / e1u(ji,jj)
823               zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1)                                &
824                  &           + (  ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk  ) )    &
825                  &               -( rho_j(ji,jj  ,jk) - rho_j(ji,jj,jk-1) )  ) / e2v(ji,jj)
826               ! add to the general momentum trend
827               ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
828               va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
829            END DO
830         END DO
831      END DO
832      !
833      CALL wrk_dealloc( jpi, jpj, jpk, dzx  , dzy  , dzz  , dzu  , dzv  , dzw   )
834      CALL wrk_dealloc( jpi, jpj, jpk, drhox, drhoy, drhoz, drhou, drhov, drhow )
835      CALL wrk_dealloc( jpi, jpj, jpk, rho_i, rho_j, rho_k,  zhpi,  zhpj        )
836      !
837   END SUBROUTINE hpg_djc
838
839
840   SUBROUTINE hpg_prj( kt )
841      !!---------------------------------------------------------------------
842      !!                  ***  ROUTINE hpg_prj  ***
843      !!
844      !! ** Method  :   s-coordinate case.
845      !!      A Pressure-Jacobian horizontal pressure gradient method
846      !!      based on the constrained cubic-spline interpolation for
847      !!      all vertical coordinate systems
848      !!
849      !! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
850      !!----------------------------------------------------------------------
851      INTEGER, PARAMETER  :: polynomial_type = 1    ! 1: cubic spline, 2: linear
852      INTEGER, INTENT(in) ::   kt                   ! ocean time-step index
853      !!
854      INTEGER  ::   ji, jj, jk, jkk                 ! dummy loop indices
855      REAL(wp) ::   zcoef0, znad                    ! temporary scalars
856      !!
857      !! The local variables for the correction term
858      INTEGER  :: jk1, jis, jid, jjs, jjd
859      REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
860      REAL(wp) :: zrhdt1
861      REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
862      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdept, zrhh
863      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp
864      REAL(wp), POINTER, DIMENSION(:,:)   ::   zsshu_n, zsshv_n
865      !!----------------------------------------------------------------------
866      !
867      CALL wrk_alloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
868      CALL wrk_alloc( jpi,jpj,jpk, zdept, zrhh )
869      CALL wrk_alloc( jpi,jpj, zsshu_n, zsshv_n )
870      !
871      IF( kt == nit000 ) THEN
872         IF(lwp) WRITE(numout,*)
873         IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
874         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   s-coordinate case, cubic spline pressure Jacobian'
875      ENDIF
876
877      !!----------------------------------------------------------------------
878      ! Local constant initialization
879      zcoef0 = - grav
880      znad = 0.0_wp
881      IF( lk_vvl ) znad = 1._wp
882
883      ! Clean 3-D work arrays
884      zhpi(:,:,:) = 0._wp
885      zrhh(:,:,:) = rhd(:,:,:)
886
887      ! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
888      DO jj = 1, jpj
889        DO ji = 1, jpi
890          jk = mbathy(ji,jj)
891          IF( jk <= 0 ) THEN; zrhh(ji,jj,:) = 0._wp
892          ELSE IF(jk == 1) THEN; zrhh(ji,jj, jk+1:jpk) = rhd(ji,jj,jk)
893          ELSE IF(jk < jpkm1) THEN
894             DO jkk = jk+1, jpk
895                zrhh(ji,jj,jkk) = interp1(fsde3w(ji,jj,jkk),   fsde3w(ji,jj,jkk-1), &
896                                         fsde3w(ji,jj,jkk-2), rhd(ji,jj,jkk-1), rhd(ji,jj,jkk-2))
897             END DO
898          ENDIF
899        END DO
900      END DO
901
902      ! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
903      DO jj = 1, jpj
904         DO ji = 1, jpi
905            zdept(ji,jj,1) = 0.5_wp * fse3w(ji,jj,1) - sshn(ji,jj) * znad
906         END DO
907      END DO
908
909      DO jk = 2, jpk
910         DO jj = 1, jpj
911            DO ji = 1, jpi
912               zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + fse3w(ji,jj,jk)
913            END DO
914         END DO
915      END DO
916
917      fsp(:,:,:) = zrhh (:,:,:)
918      xsp(:,:,:) = zdept(:,:,:)
919
920      ! Construct the vertical density profile with the
921      ! constrained cubic spline interpolation
922      ! rho(z) = asp + bsp*z + csp*z^2 + dsp*z^3
923      CALL cspline(fsp,xsp,asp,bsp,csp,dsp,polynomial_type)
924
925      ! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
926      DO jj = 2, jpj
927        DO ji = 2, jpi
928          zrhdt1 = zrhh(ji,jj,1) - interp3(zdept(ji,jj,1),asp(ji,jj,1), &
929                                         bsp(ji,jj,1),   csp(ji,jj,1), &
930                                         dsp(ji,jj,1) ) * 0.25_wp * fse3w(ji,jj,1)
931
932          ! assuming linear profile across the top half surface layer
933          zhpi(ji,jj,1) =  0.5_wp * fse3w(ji,jj,1) * zrhdt1
934        END DO
935      END DO
936
937      ! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
938      DO jk = 2, jpkm1
939        DO jj = 2, jpj
940          DO ji = 2, jpi
941            zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) +                          &
942                             integ_spline(zdept(ji,jj,jk-1), zdept(ji,jj,jk),&
943                                    asp(ji,jj,jk-1),    bsp(ji,jj,jk-1), &
944                                    csp(ji,jj,jk-1),    dsp(ji,jj,jk-1))
945          END DO
946        END DO
947      END DO
948
949      ! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
950
951      ! Prepare zsshu_n and zsshv_n
952      DO jj = 2, jpjm1
953        DO ji = 2, jpim1
954          zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
955                         & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp 
956          zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
957                         & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp 
958        END DO
959      END DO
960
961      DO jj = 2, jpjm1
962        DO ji = 2, jpim1
963          zu(ji,jj,1) = - ( fse3u(ji,jj,1) - zsshu_n(ji,jj) * znad) 
964          zv(ji,jj,1) = - ( fse3v(ji,jj,1) - zsshv_n(ji,jj) * znad)
965        END DO
966      END DO
967
968      DO jk = 2, jpkm1
969        DO jj = 2, jpjm1
970          DO ji = 2, jpim1
971            zu(ji,jj,jk) = zu(ji,jj,jk-1)- fse3u(ji,jj,jk)
972            zv(ji,jj,jk) = zv(ji,jj,jk-1)- fse3v(ji,jj,jk)
973          END DO
974        END DO
975      END DO
976
977      DO jk = 1, jpkm1
978        DO jj = 2, jpjm1
979          DO ji = 2, jpim1
980            zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * fse3u(ji,jj,jk)
981            zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * fse3v(ji,jj,jk)
982          END DO
983        END DO
984      END DO
985
986      DO jk = 1, jpkm1
987        DO jj = 2, jpjm1
988          DO ji = 2, jpim1
989            zu(ji,jj,jk) = min(zu(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
990            zu(ji,jj,jk) = max(zu(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji+1,jj,jk)))
991            zv(ji,jj,jk) = min(zv(ji,jj,jk), max(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
992            zv(ji,jj,jk) = max(zv(ji,jj,jk), min(-zdept(ji,jj,jk), -zdept(ji,jj+1,jk)))
993          END DO
994        END DO
995      END DO
996
997
998      DO jk = 1, jpkm1
999        DO jj = 2, jpjm1
1000          DO ji = 2, jpim1
1001            zpwes = 0._wp; zpwed = 0._wp
1002            zpnss = 0._wp; zpnsd = 0._wp
1003            zuijk = zu(ji,jj,jk)
1004            zvijk = zv(ji,jj,jk)
1005
1006            !!!!!     for u equation
1007            IF( jk <= mbku(ji,jj) ) THEN
1008               IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1009                 jis = ji + 1; jid = ji
1010               ELSE
1011                 jis = ji;     jid = ji +1
1012               ENDIF
1013
1014               ! integrate the pressure on the shallow side
1015               jk1 = jk
1016               DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1017                 IF( jk1 == mbku(ji,jj) ) THEN
1018                   zuijk = -zdept(jis,jj,jk1)
1019                   EXIT
1020                 ENDIF
1021                 zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1022                 zpwes = zpwes +                                    &
1023                      integ_spline(zdept(jis,jj,jk1), zdeps,            &
1024                             asp(jis,jj,jk1),    bsp(jis,jj,jk1), &
1025                             csp(jis,jj,jk1),    dsp(jis,jj,jk1))
1026                 jk1 = jk1 + 1
1027               END DO
1028
1029               ! integrate the pressure on the deep side
1030               jk1 = jk
1031               DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1032                 IF( jk1 == 1 ) THEN
1033                   zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1034                   zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1035                                                     bsp(jid,jj,1),   csp(jid,jj,1), &
1036                                                     dsp(jid,jj,1)) * zdeps
1037                   zpwed  = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1038                   EXIT
1039                 ENDIF
1040                 zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1041                 zpwed = zpwed +                                        &
1042                        integ_spline(zdeps,              zdept(jid,jj,jk1), &
1043                               asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1),  &
1044                               csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1045                 jk1 = jk1 - 1
1046               END DO
1047
1048               ! update the momentum trends in u direction
1049
1050               zdpdx1 = zcoef0 / e1u(ji,jj) * (zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk))
1051               IF( lk_vvl ) THEN
1052                 zdpdx2 = zcoef0 / e1u(ji,jj) * &
1053                         ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1054                ELSE
1055                 zdpdx2 = zcoef0 / e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1056               ENDIF
1057
1058               ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * &
1059               &           umask(ji,jj,jk) * tmask(ji,jj,jk) * tmask(ji+1,jj,jk)
1060            ENDIF
1061
1062            !!!!!     for v equation
1063            IF( jk <= mbkv(ji,jj) ) THEN
1064               IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1065                 jjs = jj + 1; jjd = jj
1066               ELSE
1067                 jjs = jj    ; jjd = jj + 1
1068               ENDIF
1069
1070               ! integrate the pressure on the shallow side
1071               jk1 = jk
1072               DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1073                 IF( jk1 == mbkv(ji,jj) ) THEN
1074                   zvijk = -zdept(ji,jjs,jk1)
1075                   EXIT
1076                 ENDIF
1077                 zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1078                 zpnss = zpnss +                                      &
1079                        integ_spline(zdept(ji,jjs,jk1), zdeps,            &
1080                               asp(ji,jjs,jk1),    bsp(ji,jjs,jk1), &
1081                               csp(ji,jjs,jk1),    dsp(ji,jjs,jk1) )
1082                 jk1 = jk1 + 1
1083               END DO
1084
1085               ! integrate the pressure on the deep side
1086               jk1 = jk
1087               DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1088                 IF( jk1 == 1 ) THEN
1089                   zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1090                   zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1091                                                     bsp(ji,jjd,1),   csp(ji,jjd,1), &
1092                                                     dsp(ji,jjd,1) ) * zdeps
1093                   zpnsd  = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1094                   EXIT
1095                 ENDIF
1096                 zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1097                 zpnsd = zpnsd +                                        &
1098                        integ_spline(zdeps,              zdept(ji,jjd,jk1), &
1099                               asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1100                               csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1101                 jk1 = jk1 - 1
1102               END DO
1103
1104
1105               ! update the momentum trends in v direction
1106
1107               zdpdy1 = zcoef0 / e2v(ji,jj) * (zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk))
1108               IF( lk_vvl ) THEN
1109                   zdpdy2 = zcoef0 / e2v(ji,jj) * &
1110                           ( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1111               ELSE
1112                   zdpdy2 = zcoef0 / e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1113               ENDIF
1114
1115               va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2)*&
1116               &              vmask(ji,jj,jk)*tmask(ji,jj,jk)*tmask(ji,jj+1,jk)
1117            ENDIF
1118
1119
1120           END DO
1121        END DO
1122      END DO
1123      !
1124      CALL wrk_dealloc( jpi,jpj,jpk, zhpi, zu, zv, fsp, xsp, asp, bsp, csp, dsp )
1125      CALL wrk_dealloc( jpi,jpj,jpk, zdept, zrhh )
1126      CALL wrk_dealloc( jpi,jpj, zsshu_n, zsshv_n )
1127      !
1128   END SUBROUTINE hpg_prj
1129
1130
1131   SUBROUTINE cspline(fsp, xsp, asp, bsp, csp, dsp, polynomial_type)
1132      !!----------------------------------------------------------------------
1133      !!                 ***  ROUTINE cspline  ***
1134      !!
1135      !! ** Purpose :   constrained cubic spline interpolation
1136      !!
1137      !! ** Method  :   f(x) = asp + bsp*x + csp*x^2 + dsp*x^3
1138      !!
1139      !! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1140      !!----------------------------------------------------------------------
1141      IMPLICIT NONE
1142      REAL(wp), DIMENSION(:,:,:), INTENT(in)  :: fsp, xsp           ! value and coordinate
1143      REAL(wp), DIMENSION(:,:,:), INTENT(out) :: asp, bsp, csp, dsp ! coefficients of
1144                                                                    ! the interpoated function
1145      INTEGER, INTENT(in) :: polynomial_type                        ! 1: cubic spline
1146                                                                    ! 2: Linear
1147      !
1148      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
1149      INTEGER  ::   jpi, jpj, jpkm1
1150      REAL(wp) ::   zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1151      REAL(wp) ::   zdxtmp1, zdxtmp2, zalpha
1152      REAL(wp) ::   zdf(size(fsp,3))
1153      !!----------------------------------------------------------------------
1154
1155      jpi   = size(fsp,1)
1156      jpj   = size(fsp,2)
1157      jpkm1 = size(fsp,3) - 1
1158
1159
1160      IF (polynomial_type == 1) THEN     ! Constrained Cubic Spline
1161         DO ji = 1, jpi
1162            DO jj = 1, jpj
1163           !!Fritsch&Butland's method, 1984 (preferred, but more computation)
1164           !    DO jk = 2, jpkm1-1
1165           !       zdxtmp1 = xsp(ji,jj,jk)   - xsp(ji,jj,jk-1)
1166           !       zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1167           !       zdf1    = ( fsp(ji,jj,jk)   - fsp(ji,jj,jk-1) ) / zdxtmp1
1168           !       zdf2    = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk)   ) / zdxtmp2
1169           !
1170           !       zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1171           !
1172           !       IF(zdf1 * zdf2 <= 0._wp) THEN
1173           !           zdf(jk) = 0._wp
1174           !       ELSE
1175           !         zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1176           !       ENDIF
1177           !    END DO
1178
1179           !!Simply geometric average
1180               DO jk = 2, jpkm1-1
1181                  zdf1 = (fsp(ji,jj,jk) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk) - xsp(ji,jj,jk-1))
1182                  zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk))
1183
1184                  IF(zdf1 * zdf2 <= 0._wp) THEN
1185                     zdf(jk) = 0._wp
1186                  ELSE
1187                     zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1188                  ENDIF
1189               END DO
1190
1191               zdf(1)     = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1192                          &          ( xsp(ji,jj,2) - xsp(ji,jj,1) ) -  0.5_wp * zdf(2)
1193               zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1194                          &          ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - &
1195                          & 0.5_wp * zdf(jpkm1 - 1)
1196
1197               DO jk = 1, jpkm1 - 1
1198                 zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1199                 ztmp1  = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1200                 ztmp2  =  6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1201                 zddf1  = -2._wp * ztmp1 + ztmp2
1202                 ztmp1  = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1203                 zddf2  =  2._wp * ztmp1 - ztmp2
1204
1205                 dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1206                 csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1207                 bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1208                               & csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1209                               & dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1210                               &                   xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1211                 asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1212                               &                (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1213                               &                 dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1214               END DO
1215            END DO
1216         END DO
1217
1218      ELSE IF (polynomial_type == 2) THEN     ! Linear
1219         DO ji = 1, jpi
1220            DO jj = 1, jpj
1221               DO jk = 1, jpkm1-1
1222                  zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1223                  ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1224
1225                  dsp(ji,jj,jk) = 0._wp
1226                  csp(ji,jj,jk) = 0._wp
1227                  bsp(ji,jj,jk) = ztmp1 / zdxtmp
1228                  asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1229               END DO
1230            END DO
1231         END DO
1232
1233      ELSE
1234           CALL ctl_stop( 'invalid polynomial type in cspline' )
1235      ENDIF
1236
1237   END SUBROUTINE cspline
1238
1239
1240   FUNCTION interp1(x, xl, xr, fl, fr)  RESULT(f)
1241      !!----------------------------------------------------------------------
1242      !!                 ***  ROUTINE interp1  ***
1243      !!
1244      !! ** Purpose :   1-d linear interpolation
1245      !!
1246      !! ** Method  :   interpolation is straight forward
1247      !!                extrapolation is also permitted (no value limit)
1248      !!----------------------------------------------------------------------
1249      IMPLICIT NONE
1250      REAL(wp), INTENT(in) ::  x, xl, xr, fl, fr
1251      REAL(wp)             ::  f ! result of the interpolation (extrapolation)
1252      REAL(wp)             ::  zdeltx
1253      !!----------------------------------------------------------------------
1254
1255      zdeltx = xr - xl
1256      IF(abs(zdeltx) <= 10._wp * EPSILON(x)) THEN
1257        f = 0.5_wp * (fl + fr)
1258      ELSE
1259        f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1260      ENDIF
1261
1262   END FUNCTION interp1
1263
1264
1265   FUNCTION interp2(x, a, b, c, d)  RESULT(f)
1266      !!----------------------------------------------------------------------
1267      !!                 ***  ROUTINE interp1  ***
1268      !!
1269      !! ** Purpose :   1-d constrained cubic spline interpolation
1270      !!
1271      !! ** Method  :  cubic spline interpolation
1272      !!
1273      !!----------------------------------------------------------------------
1274      IMPLICIT NONE
1275      REAL(wp), INTENT(in) ::  x, a, b, c, d
1276      REAL(wp)             ::  f ! value from the interpolation
1277      !!----------------------------------------------------------------------
1278
1279      f = a + x* ( b + x * ( c + d * x ) )
1280
1281   END FUNCTION interp2
1282
1283
1284   FUNCTION interp3(x, a, b, c, d)  RESULT(f)
1285      !!----------------------------------------------------------------------
1286      !!                 ***  ROUTINE interp1  ***
1287      !!
1288      !! ** Purpose :   Calculate the first order of deriavtive of
1289      !!                a cubic spline function y=a+b*x+c*x^2+d*x^3
1290      !!
1291      !! ** Method  :   f=dy/dx=b+2*c*x+3*d*x^2
1292      !!
1293      !!----------------------------------------------------------------------
1294      IMPLICIT NONE
1295      REAL(wp), INTENT(in) ::  x, a, b, c, d
1296      REAL(wp)             ::  f ! value from the interpolation
1297      !!----------------------------------------------------------------------
1298
1299      f = b + x * ( 2._wp * c + 3._wp * d * x)
1300
1301   END FUNCTION interp3
1302
1303
1304   FUNCTION integ_spline(xl, xr, a, b, c, d)  RESULT(f)
1305      !!----------------------------------------------------------------------
1306      !!                 ***  ROUTINE interp1  ***
1307      !!
1308      !! ** Purpose :   1-d constrained cubic spline integration
1309      !!
1310      !! ** Method  :  integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1311      !!
1312      !!----------------------------------------------------------------------
1313      IMPLICIT NONE
1314      REAL(wp), INTENT(in) ::  xl, xr, a, b, c, d
1315      REAL(wp)             ::  za1, za2, za3
1316      REAL(wp)             ::  f                   ! integration result
1317      !!----------------------------------------------------------------------
1318
1319      za1 = 0.5_wp * b
1320      za2 = c / 3.0_wp
1321      za3 = 0.25_wp * d
1322
1323      f  = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1324         & xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1325
1326   END FUNCTION integ_spline
1327
1328   !!======================================================================
1329END MODULE dynhpg
1330
Note: See TracBrowser for help on using the repository browser.