New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_iso.F90 in branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA – NEMO

source: branches/2015/dev_r5151_UKMO_ISF/NEMOGCM/NEMO/OPA_SRC/TRA/traldf_iso.F90 @ 5969

Last change on this file since 5969 was 5969, checked in by mathiot, 8 years ago

ISF: modifications to compile and run SETTE tests

  • Property svn:keywords set to Id
File size: 23.0 KB
Line 
1MODULE traldf_iso
2   !!======================================================================
3   !!                   ***  MODULE  traldf_iso  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  OPA  ! 1994-08  (G. Madec, M. Imbard)
7   !!            8.0  ! 1997-05  (G. Madec)  split into traldf and trazdf
8   !!            NEMO ! 2002-08  (G. Madec)  Free form, F90
9   !!            1.0  ! 2005-11  (G. Madec)  merge traldf and trazdf :-)
10   !!            3.3  ! 2010-09  (C. Ethe, G. Madec) Merge TRA-TRC
11   !!            3.7  ! 2014-01  (G. Madec, S. Masson)  restructuration/simplification of aht/aeiv specification
12   !!             -   ! 2014-02  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   tra_ldf_iso  : update the tracer trend with the horizontal component of a iso-neutral laplacian operator
17   !!                  and with the vertical part of the isopycnal or geopotential s-coord. operator
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and active tracers
20   USE dom_oce         ! ocean space and time domain
21   USE trc_oce         ! share passive tracers/Ocean variables
22   USE zdf_oce         ! ocean vertical physics
23   USE ldftra          ! lateral diffusion: tracer eddy coefficients
24   USE ldfslp          ! iso-neutral slopes
25   USE diaptr          ! poleward transport diagnostics
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O library
29   USE phycst          ! physical constants
30   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
31   USE wrk_nemo        ! Memory Allocation
32   USE timing          ! Timing
33
34   IMPLICIT NONE
35   PRIVATE
36
37   PUBLIC   tra_ldf_iso   ! routine called by step.F90
38
39   !! * Substitutions
40#  include "domzgr_substitute.h90"
41#  include "vectopt_loop_substitute.h90"
42   !!----------------------------------------------------------------------
43   !! NEMO/OPA 3.7 , NEMO Consortium (2015)
44   !! $Id$
45   !! Software governed by the CeCILL licence     (NEMOGCM/NEMO_CeCILL.txt)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49  SUBROUTINE tra_ldf_iso( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
50      &                                                   pgui, pgvi,   &
51      &                                       ptb , ptbb, pta , kjpt, kpass )
52      !!----------------------------------------------------------------------
53      !!                  ***  ROUTINE tra_ldf_iso  ***
54      !!
55      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
56      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
57      !!      add it to the general trend of tracer equation.
58      !!
59      !! ** Method  :   The horizontal component of the lateral diffusive trends
60      !!      is provided by a 2nd order operator rotated along neural or geopo-
61      !!      tential surfaces to which an eddy induced advection can be added
62      !!      It is computed using before fields (forward in time) and isopyc-
63      !!      nal or geopotential slopes computed in routine ldfslp.
64      !!
65      !!      1st part :  masked horizontal derivative of T  ( di[ t ] )
66      !!      ========    with partial cell update if ln_zps=T
67      !!                  with top     cell update if ln_isfcav
68      !!
69      !!      2nd part :  horizontal fluxes of the lateral mixing operator
70      !!      ========   
71      !!         zftu =  pahu e2u*e3u/e1u di[ tb ]
72      !!               - pahu e2u*uslp    dk[ mi(mk(tb)) ]
73      !!         zftv =  pahv e1v*e3v/e2v dj[ tb ]
74      !!               - pahv e2u*vslp    dk[ mj(mk(tb)) ]
75      !!      take the horizontal divergence of the fluxes:
76      !!         difft = 1/(e1e2t*e3t) {  di-1[ zftu ] +  dj-1[ zftv ]  }
77      !!      Add this trend to the general trend (ta,sa):
78      !!         ta = ta + difft
79      !!
80      !!      3rd part: vertical trends of the lateral mixing operator
81      !!      ========  (excluding the vertical flux proportional to dk[t] )
82      !!      vertical fluxes associated with the rotated lateral mixing:
83      !!         zftw = - {  mi(mk(pahu)) * e2t*wslpi di[ mi(mk(tb)) ]
84      !!                   + mj(mk(pahv)) * e1t*wslpj dj[ mj(mk(tb)) ]  }
85      !!      take the horizontal divergence of the fluxes:
86      !!         difft = 1/(e1e2t*e3t) dk[ zftw ]
87      !!      Add this trend to the general trend (ta,sa):
88      !!         pta = pta + difft
89      !!
90      !! ** Action :   Update pta arrays with the before rotated diffusion
91      !!----------------------------------------------------------------------
92      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
93      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
94      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
95      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
96      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
97      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
98      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu, pgv   ! tracer gradient at pstep levels
99      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
100      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
101      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
102      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
103      !
104      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
105      INTEGER  ::  ikt
106      INTEGER  ::  ierr             ! local integer
107      REAL(wp) ::  zmsku, zahu_w, zabe1, zcof1, zcoef3   ! local scalars
108      REAL(wp) ::  zmskv, zahv_w, zabe2, zcof2, zcoef4   !   -      -
109      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt   !   -      -
110#if defined key_diaar5
111      REAL(wp) ::   zztmp   ! local scalar
112#endif
113      REAL(wp), POINTER, DIMENSION(:,:)   ::   zdkt, zdk1t, z2d
114      REAL(wp), POINTER, DIMENSION(:,:,:) ::   zdit, zdjt, zftu, zftv, ztfw 
115      !!----------------------------------------------------------------------
116      !
117      IF( nn_timing == 1 )  CALL timing_start('tra_ldf_iso')
118      !
119      CALL wrk_alloc( jpi,jpj,       zdkt, zdk1t, z2d ) 
120      CALL wrk_alloc( jpi,jpj,jpk,   zdit, zdjt , zftu, zftv, ztfw  ) 
121      !
122      IF( kt == kit000 )  THEN
123         IF(lwp) WRITE(numout,*)
124         IF(lwp) WRITE(numout,*) 'tra_ldf_iso : rotated laplacian diffusion operator on ', cdtype
125         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
126         !
127         akz     (:,:,:) = 0._wp     
128         ah_wslp2(:,:,:) = 0._wp
129      ENDIF
130      !
131      !                                               ! set time step size (Euler/Leapfrog)
132      IF( neuler == 0 .AND. kt == nit000 ) THEN   ;   z2dt =     rdttra(1)      ! at nit000   (Euler)
133      ELSE                                        ;   z2dt = 2.* rdttra(1)      !             (Leapfrog)
134      ENDIF
135      z1_2dt = 1._wp / z2dt
136      !
137      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
138      ELSE                    ;   zsign = -1._wp
139      ENDIF
140         
141         
142      !!----------------------------------------------------------------------
143      !!   0 - calculate  ah_wslp2 and akz
144      !!----------------------------------------------------------------------
145      !
146      IF( kpass == 1 ) THEN                  !==  first pass only  ==!
147         !
148         DO jk = 2, jpkm1
149            DO jj = 2, jpjm1
150               DO ji = fs_2, fs_jpim1   ! vector opt.
151                  !
152                  zmsku = tmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
153                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
154                  zmskv = tmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
155                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
156                     !
157                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
158                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
159                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
160                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
161                     !
162                  ah_wslp2(ji,jj,jk) = zahu_w * wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
163                     &               + zahv_w * wslpj(ji,jj,jk) * wslpj(ji,jj,jk)
164               END DO
165            END DO
166         END DO
167         !
168         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
169            DO jk = 2, jpkm1
170               DO jj = 2, jpjm1
171                  DO ji = fs_2, fs_jpim1
172                     akz(ji,jj,jk) = 0.25_wp * (                                                                     &
173                        &              ( pahu(ji  ,jj,jk) + pahu(ji  ,jj,jk-1) ) / ( e1u(ji  ,jj) * e1u(ji  ,jj) )   &
174                        &            + ( pahu(ji-1,jj,jk) + pahu(ji-1,jj,jk-1) ) / ( e1u(ji-1,jj) * e1u(ji-1,jj) )   &
175                        &            + ( pahv(ji,jj  ,jk) + pahv(ji,jj  ,jk-1) ) / ( e2v(ji,jj  ) * e2v(ji,jj  ) )   &
176                        &            + ( pahv(ji,jj-1,jk) + pahv(ji,jj-1,jk-1) ) / ( e2v(ji,jj-1) * e2v(ji,jj-1) )   )
177                  END DO
178               END DO
179            END DO
180            !
181            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
182               DO jk = 2, jpkm1
183                  DO jj = 1, jpjm1
184                     DO ji = 1, fs_jpim1
185                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
186                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( fse3w(ji,jj,jk) * fse3w(ji,jj,jk) )  )
187                     END DO
188                  END DO
189               END DO
190            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
191               DO jk = 2, jpkm1
192                  DO jj = 1, jpjm1
193                     DO ji = 1, fs_jpim1
194                        ze3w_2 = fse3w(ji,jj,jk) * fse3w(ji,jj,jk)
195                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
196                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
197                     END DO
198                  END DO
199               END DO
200           ENDIF
201           !
202         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
203            akz(:,:,:) = ah_wslp2(:,:,:)     
204         ENDIF
205      ENDIF
206      !
207      !                                                          ! ===========
208      DO jn = 1, kjpt                                            ! tracer loop
209         !                                                       ! ===========
210         !                                               
211         !!----------------------------------------------------------------------
212         !!   I - masked horizontal derivative
213         !!----------------------------------------------------------------------
214!!gm : bug.... why (x,:,:)?   (1,jpj,:) and (jpi,1,:) should be sufficient....
215         zdit (1,:,:) = 0._wp     ;     zdit (jpi,:,:) = 0._wp
216         zdjt (1,:,:) = 0._wp     ;     zdjt (jpi,:,:) = 0._wp
217         !!end
218
219         ! Horizontal tracer gradient
220         DO jk = 1, jpkm1
221            DO jj = 1, jpjm1
222               DO ji = 1, fs_jpim1   ! vector opt.
223                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
224                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
225               END DO
226            END DO
227         END DO
228         IF( ln_zps ) THEN      ! botton and surface ocean correction of the horizontal gradient
229            DO jj = 1, jpjm1              ! bottom correction (partial bottom cell)
230               DO ji = 1, fs_jpim1   ! vector opt.
231                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)         
232                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
233               END DO
234            END DO
235            IF( ln_isfcav ) THEN      ! first wet level beneath a cavity
236               DO jj = 1, jpjm1
237                  DO ji = 1, fs_jpim1   ! vector opt.
238                     IF( miku(ji,jj) > 1 )   zdit(ji,jj,miku(ji,jj)) = pgui(ji,jj,jn)         
239                     IF( mikv(ji,jj) > 1 )   zdjt(ji,jj,mikv(ji,jj)) = pgvi(ji,jj,jn)     
240                  END DO
241               END DO
242            ENDIF
243         ENDIF
244
245         !!----------------------------------------------------------------------
246         !!   II - horizontal trend  (full)
247         !!----------------------------------------------------------------------
248         !
249         DO jk = 1, jpkm1                                 ! Horizontal slab
250            !
251            !                             !== Vertical tracer gradient
252            zdk1t(:,:) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * wmask(:,:,jk+1)     ! level jk+1
253            !
254            IF( jk == 1 ) THEN   ;   zdkt(:,:) = zdk1t(:,:)                          ! surface: zdkt(jk=1)=zdkt(jk=2)
255            ELSE                 ;   zdkt(:,:) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * wmask(:,:,jk)
256            ENDIF
257
258            DO jj = 1 , jpjm1            !==  Horizontal fluxes
259               DO ji = 1, fs_jpim1   ! vector opt.
260                  zabe1 = pahu(ji,jj,jk) * e2_e1u(ji,jj) * fse3u_n(ji,jj,jk)
261                  zabe2 = pahv(ji,jj,jk) * e1_e2v(ji,jj) * fse3v_n(ji,jj,jk)
262                  !
263                  zmsku = 1. / MAX(  wmask(ji+1,jj,jk  ) + wmask(ji,jj,jk+1)   &
264                     &             + wmask(ji+1,jj,jk+1) + wmask(ji,jj,jk  ), 1. )
265                  !
266                  zmskv = 1. / MAX(  wmask(ji,jj+1,jk  ) + wmask(ji,jj,jk+1)   &
267                     &             + wmask(ji,jj+1,jk+1) + wmask(ji,jj,jk  ), 1. )
268                  !
269                  zcof1 = - pahu(ji,jj,jk) * e2u(ji,jj) * uslp(ji,jj,jk) * zmsku
270                  zcof2 = - pahv(ji,jj,jk) * e1v(ji,jj) * vslp(ji,jj,jk) * zmskv
271                  !
272                  zftu(ji,jj,jk ) = (  zabe1 * zdit(ji,jj,jk)   &
273                     &               + zcof1 * (  zdkt (ji+1,jj) + zdk1t(ji,jj)      &
274                     &                          + zdk1t(ji+1,jj) + zdkt (ji,jj)  )  ) * umask(ji,jj,jk)
275                  zftv(ji,jj,jk) = (  zabe2 * zdjt(ji,jj,jk)   &
276                     &               + zcof2 * (  zdkt (ji,jj+1) + zdk1t(ji,jj)      &
277                     &                          + zdk1t(ji,jj+1) + zdkt (ji,jj)  )  ) * vmask(ji,jj,jk)                 
278               END DO
279            END DO
280            !
281            DO jj = 2 , jpjm1          !== horizontal divergence and add to pta
282               DO ji = fs_2, fs_jpim1   ! vector opt.
283                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji,jj,jk) - zftu(ji-1,jj,jk)      &
284                     &                                           + zftv(ji,jj,jk) - zftv(ji,jj-1,jk)  )   &
285                     &                                        / (  e1e2t(ji,jj) * fse3t(ji,jj,jk)  )
286               END DO
287            END DO
288         END DO                                        !   End of slab 
289
290
291         !!----------------------------------------------------------------------
292         !!   III - vertical trend (full)
293         !!----------------------------------------------------------------------
294         
295         ztfw(1,:,:) = 0._wp     ;     ztfw(jpi,:,:) = 0._wp
296         
297         ! Vertical fluxes
298         ! ---------------
299         
300         ! Surface and bottom vertical fluxes set to zero
301         ztfw(:,:, 1 ) = 0._wp      ;      ztfw(:,:,jpk) = 0._wp
302         
303         ! interior (2=<jk=<jpk-1)
304         DO jk = 2, jpkm1
305            DO jj = 2, jpjm1
306               DO ji = fs_2, fs_jpim1   ! vector opt.
307                  !
308                  zmsku = wmask(ji,jj,jk) / MAX(   umask(ji  ,jj,jk-1) + umask(ji-1,jj,jk)          &
309                     &                           + umask(ji-1,jj,jk-1) + umask(ji  ,jj,jk) , 1._wp  )
310                  zmskv = wmask(ji,jj,jk) / MAX(   vmask(ji,jj  ,jk-1) + vmask(ji,jj-1,jk)          &
311                     &                           + vmask(ji,jj-1,jk-1) + vmask(ji,jj  ,jk) , 1._wp  )
312                     !
313                  zahu_w = (   pahu(ji  ,jj,jk-1) + pahu(ji-1,jj,jk)    &
314                     &       + pahu(ji-1,jj,jk-1) + pahu(ji  ,jj,jk)  ) * zmsku
315                  zahv_w = (   pahv(ji,jj  ,jk-1) + pahv(ji,jj-1,jk)    &
316                     &       + pahv(ji,jj-1,jk-1) + pahv(ji,jj  ,jk)  ) * zmskv
317                     !
318                  zcoef3 = - zahu_w * e2t(ji,jj) * zmsku * wslpi (ji,jj,jk)   !wslpi & j are already w-masked
319                  zcoef4 = - zahv_w * e1t(ji,jj) * zmskv * wslpj (ji,jj,jk)
320                  !
321                  ztfw(ji,jj,jk) = zcoef3 * (   zdit(ji  ,jj  ,jk-1) + zdit(ji-1,jj  ,jk)      &
322                     &                        + zdit(ji-1,jj  ,jk-1) + zdit(ji  ,jj  ,jk)  )   &
323                     &           + zcoef4 * (   zdjt(ji  ,jj  ,jk-1) + zdjt(ji  ,jj-1,jk)      &
324                     &                        + zdjt(ji  ,jj-1,jk-1) + zdjt(ji  ,jj  ,jk)  )
325               END DO
326            END DO
327         END DO
328         !
329         !                                !==  add the vertical 33 flux  ==!
330         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
331            DO jk = 2, jpkm1       
332               DO jj = 1, jpjm1
333                  DO ji = fs_2, fs_jpim1
334                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / fse3w(ji,jj,jk) * wmask(ji,jj,jk)   &
335                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
336                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
337                  END DO
338               END DO
339            END DO
340            !
341         ELSE                                   ! bilaplacian
342            SELECT CASE( kpass )
343            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
344               DO jk = 2, jpkm1 
345                  DO jj = 1, jpjm1
346                     DO ji = fs_2, fs_jpim1
347                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk)    &
348                           &           + ah_wslp2(ji,jj,jk) * e1e2t(ji,jj)   &
349                           &           * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) ) * wmask(ji,jj,jk) / fse3w(ji,jj,jk)
350                     END DO
351                  END DO
352               END DO
353            CASE(  2  )                         ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
354               DO jk = 2, jpkm1 
355                  DO jj = 1, jpjm1
356                     DO ji = fs_2, fs_jpim1
357                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) + e1e2t(ji,jj) / fse3w(ji,jj,jk) * wmask(ji,jj,jk)                      &
358                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
359                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
360                     END DO
361                  END DO
362               END DO
363            END SELECT
364         ENDIF
365         !         
366         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
367            DO jj = 2, jpjm1
368               DO ji = fs_2, fs_jpim1   ! vector opt.
369                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw (ji,jj,jk) - ztfw(ji,jj,jk+1)  )   &
370                     &                                        / (  e1e2t(ji,jj) * fse3t_n(ji,jj,jk)  )
371               END DO
372            END DO
373         END DO
374         !
375         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
376             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
377            !
378            !                             ! "Poleward" diffusive heat or salt transports (T-S case only)
379            IF( cdtype == 'TRA' .AND. ln_diaptr ) THEN
380               ! note sign is reversed to give down-gradient diffusive transports (#1043)
381               IF( jn == jp_tem)   htr_ldf(:) = ptr_sj( -zftv(:,:,:) )
382               IF( jn == jp_sal)   str_ldf(:) = ptr_sj( -zftv(:,:,:) )
383            ENDIF
384            !
385            IF( iom_use("udiff_heattr") .OR. iom_use("vdiff_heattr") ) THEN
386              !
387              IF( cdtype == 'TRA' .AND. jn == jp_tem  ) THEN
388                  z2d(:,:) = zftu(ji,jj,1) 
389                  DO jk = 2, jpkm1
390                     DO jj = 2, jpjm1
391                        DO ji = fs_2, fs_jpim1   ! vector opt.
392                           z2d(ji,jj) = z2d(ji,jj) + zftu(ji,jj,jk) 
393                        END DO
394                     END DO
395                  END DO
396!!gm CAUTION I think there is an error of sign when using BLP operator....
397!!gm         a multiplication by zsign is required (to be checked twice !)
398                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
399                  CALL lbc_lnk( z2d, 'U', -1. )
400                  CALL iom_put( "udiff_heattr", z2d )                  ! heat transport in i-direction
401                  !
402                  z2d(:,:) = zftv(ji,jj,1) 
403                  DO jk = 2, jpkm1
404                     DO jj = 2, jpjm1
405                        DO ji = fs_2, fs_jpim1   ! vector opt.
406                           z2d(ji,jj) = z2d(ji,jj) + zftv(ji,jj,jk) 
407                        END DO
408                     END DO
409                  END DO
410                  z2d(:,:) = - rau0_rcp * z2d(:,:)     ! note sign is reversed to give down-gradient diffusive transports (#1043)
411                  CALL lbc_lnk( z2d, 'V', -1. )
412                  CALL iom_put( "vdiff_heattr", z2d )                  !  heat transport in i-direction
413               END IF
414               !
415            ENDIF
416            !
417         ENDIF                                                    !== end pass selection  ==!
418         !
419         !                                                        ! ===============
420      END DO                                                      ! end tracer loop
421      !                                                           ! ===============
422      !
423      CALL wrk_dealloc( jpi, jpj,      zdkt, zdk1t, z2d ) 
424      CALL wrk_dealloc( jpi, jpj, jpk, zdit, zdjt , zftu, zftv, ztfw  ) 
425      !
426      IF( nn_timing == 1 )  CALL timing_stop('tra_ldf_iso')
427      !
428   END SUBROUTINE tra_ldf_iso
429
430   !!==============================================================================
431END MODULE traldf_iso
Note: See TracBrowser for help on using the repository browser.